New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

zdftmx.F90 in branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

Context Navigation

source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/ZDF/zdftmx.F90 @ 8788

Last change on this file since 8788 was 8788, checked in by gsamson, 6 years ago
fix ticket #1954 in nemo_v3_6_STABLE
Property svn:keywords set to `Id`
File size: 52.7 KB

Line
1	MODULE zdftmx
2	!!========================================================================
3	!! * MODULE zdftmx *
4	!! Ocean physics: vertical tidal mixing coefficient
5	!!========================================================================
6	!! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code
7	!! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait
8	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
9	!!----------------------------------------------------------------------
10	#if defined key_zdftmx \|\| defined key_esopa
11	!!----------------------------------------------------------------------
12	!! 'key_zdftmx' Tidal vertical mixing
13	!!----------------------------------------------------------------------
14	!! zdf_tmx : global momentum & tracer Kz with tidal induced Kz
15	!! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz
16	!!----------------------------------------------------------------------
17	USE oce ! ocean dynamics and tracers variables
18	USE dom_oce ! ocean space and time domain variables
19	USE zdf_oce ! ocean vertical physics variables
20	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
21	USE eosbn2 ! ocean equation of state
22	USE phycst ! physical constants
23	USE prtctl ! Print control
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O Manager
26	USE lib_mpp ! MPP library
27	USE wrk_nemo ! work arrays
28	USE timing ! Timing
29	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC zdf_tmx ! called in step module
35	PUBLIC zdf_tmx_init ! called in opa module
36	PUBLIC zdf_tmx_alloc ! called in nemogcm module
37
38	LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag
39
40	! !!* Namelist namzdf_tmx : tidal mixing *
41	REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters)
42	REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1)
43	REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002)
44	REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980)
45	LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization
46	REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002)
47
48	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2)
49	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area
50	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz
51
52	!! * Substitutions
53	# include "domzgr_substitute.h90"
54	# include "vectopt_loop_substitute.h90"
55	!!----------------------------------------------------------------------
56	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
57	!! $Id$
58	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
59	!!----------------------------------------------------------------------
60	CONTAINS
61
62	INTEGER FUNCTION zdf_tmx_alloc()
63	!!----------------------------------------------------------------------
64	!! * FUNCTION zdf_tmx_alloc *
65	!!----------------------------------------------------------------------
66	ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc )
67	!
68	IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc )
69	IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays')
70	END FUNCTION zdf_tmx_alloc
71
72
73	SUBROUTINE zdf_tmx( kt )
74	!!----------------------------------------------------------------------
75	!! * ROUTINE zdf_tmx *
76	!!
77	!! ** Purpose : add to the vertical mixing coefficients the effect of
78	!! tidal mixing (Simmons et al 2004).
79	!!
80	!! ** Method : - tidal-induced vertical mixing is given by:
81	!! Kz_tides = az_tmx / max( rn_n2min, N^2 )
82	!! where az_tmx is a coefficient that specified the 3D space
83	!! distribution of the faction of tidal energy taht is used
84	!! for mixing. Its expression is set in zdf_tmx_init routine,
85	!! following Simmons et al. 2004.
86	!! NB: a specific bounding procedure is performed on av_tide
87	!! so that the input tidal energy is actually almost used. The
88	!! basic maximum value is 60 cm2/s, but values of 300 cm2/s
89	!! can be reached in area where bottom stratification is too
90	!! weak.
91	!!
92	!! - update av_tide in the Indonesian Through Flow area
93	!! following Koch-Larrouy et al. (2007) parameterisation
94	!! (see tmx_itf routine).
95	!!
96	!! - update the model vertical eddy viscosity and diffusivity:
97	!! avt = avt + av_tides
98	!! avm = avm + av_tides
99	!! avmu = avmu + mi(av_tides)
100	!! avmv = avmv + mj(av_tides)
101	!!
102	!! ** Action : avt, avm, avmu, avmv increased by tidal mixing
103	!!
104	!! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263.
105	!! Koch-Larrouy et al. 2007, GRL.
106	!!----------------------------------------------------------------------
107	USE oce, zav_tide => ua ! use ua as workspace
108	!!
109	INTEGER, INTENT(in) :: kt ! ocean time-step
110	!!
111	INTEGER :: ji, jj, jk ! dummy loop indices
112	REAL(wp) :: ztpc ! scalar workspace
113	REAL(wp), POINTER, DIMENSION(:,:) :: zkz
114	!!----------------------------------------------------------------------
115	!
116	IF( nn_timing == 1 ) CALL timing_start('zdf_tmx')
117	!
118	CALL wrk_alloc( jpi,jpj, zkz )
119
120	! ! ----------------------- !
121	! ! Standard tidal mixing ! (compute zav_tide)
122	! ! ----------------------- !
123	! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s
124	zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) )
125
126	zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column
127	DO jk = 2, jpkm1
128	zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk)
129	END DO
130
131	DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
132	DO ji = 1, jpi
133	IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj)
134	END DO
135	END DO
136
137	DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s
138	DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
139	DO ji = 1, jpi
140	zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s
141	END DO
142	END DO
143	END DO
144
145	IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide
146	ztpc = 0.e0
147	DO jk= 1, jpk
148	DO jj= 1, jpj
149	DO ji= 1, jpi
150	ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) &
151	& * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj)
152	END DO
153	END DO
154	END DO
155	ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc
156	IF(lwp) WRITE(numout,*)
157	IF(lwp) WRITE(numout,) ' N Total power consumption by av_tide : ztpc = ', ztpc 1.e-12 ,'TW'
158	ENDIF
159
160	! ! ----------------------- !
161	! ! ITF tidal mixing ! (update zav_tide)
162	! ! ----------------------- !
163	IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide )
164
165	! ! ----------------------- !
166	! ! Update mixing coefs !
167	! ! ----------------------- !
168	DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing
169	DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
170	DO ji = 1, jpi
171	avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
172	avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
173	END DO
174	END DO
175	END DO
176
177	DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing
178	DO jj = 2, jpjm1
179	DO ji = fs_2, fs_jpim1 ! vector opt.
180	avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk)
181	avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk)
182	END DO
183	END DO
184	END DO
185	CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition
186
187	! !* output tidal mixing coefficient
188	CALL iom_put( "av_tide", zav_tide )
189
190	IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
191	!
192	CALL wrk_dealloc( jpi,jpj, zkz )
193	!
194	IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx')
195	!
196	END SUBROUTINE zdf_tmx
197
198
199	SUBROUTINE tmx_itf( kt, pav )
200	!!----------------------------------------------------------------------
201	!! * ROUTINE tmx_itf *
202	!!
203	!! ** Purpose : modify the vertical eddy diffusivity coefficients
204	!! (pav) in the Indonesian Through Flow area (ITF).
205	!!
206	!! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined
207	!! by msk_itf (read in a file, see tmx_init), the tidal
208	!! mixing coefficient is computed with :
209	!! * q=1 (i.e. all the tidal energy remains trapped in
210	!! the area and thus is used for mixing)
211	!! * the vertical distribution of the tifal energy is a
212	!! proportional to N above the thermocline (d(N^2)/dz > 0)
213	!! and to N^2 below the thermocline (d(N^2)/dz < 0)
214	!!
215	!! ** Action : av_tide updated in the ITF area (msk_itf)
216	!!
217	!! References : Koch-Larrouy et al. 2007, GRL
218	!!----------------------------------------------------------------------
219	INTEGER , INTENT(in ) :: kt ! ocean time-step
220	REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef.
221	!!
222	INTEGER :: ji, jj, jk ! dummy loop indices
223	REAL(wp) :: zcoef, ztpc ! temporary scalar
224	REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace
225	REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - -
226	REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace
227	REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - -
228	REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - -
229	!!----------------------------------------------------------------------
230	!
231	IF( nn_timing == 1 ) CALL timing_start('tmx_itf')
232	!
233	CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum )
234	CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf )
235
236	! ! compute the form function using N2 at each time step
237	zdn2dz (:,:,jpk) = 0.e0
238	zempba_3d_1(:,:,jpk) = 0.e0
239	zempba_3d_2(:,:,jpk) = 0.e0
240	DO jk = 1, jpkm1
241	zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz
242	!CDIR NOVERRCHK
243	zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N
244	zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2
245	END DO
246	!
247	zsum (:,:) = 0.e0
248	zsum1(:,:) = 0.e0
249	zsum2(:,:) = 0.e0
250	DO jk= 2, jpk
251	zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)
252	zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)
253	END DO
254	DO jj = 1, jpj
255	DO ji = 1, jpi
256	IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj)
257	IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj)
258	END DO
259	END DO
260
261	DO jk= 1, jpk
262	DO jj = 1, jpj
263	DO ji = 1, jpi
264	zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise
265	ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef &
266	& + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef )
267	!
268	zempba_3d(ji,jj,jk) = ztpc
269	zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk)
270	END DO
271	END DO
272	END DO
273	DO jj = 1, jpj
274	DO ji = 1, jpi
275	IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj)
276	END DO
277	END DO
278
279	! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min)
280	zcoef = rn_tfe_itf / ( rn_tfe * rau0 )
281	DO jk = 1, jpk
282	zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) &
283	& / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) )
284	END DO
285
286	zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column
287	DO jk = 2, jpkm1
288	zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)
289	END DO
290
291	DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
292	DO ji = 1, jpi
293	IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj)
294	END DO
295	END DO
296
297	DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s
298	zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * tmask(:,:,jk) * tmask(:,:,jk-1) ! kz max = 120 cm2/s
299	END DO
300
301	IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf
302	ztpc = 0.e0
303	DO jk= 1, jpk
304	DO jj= 1, jpj
305	DO ji= 1, jpi
306	ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) &
307	& * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj)
308	END DO
309	END DO
310	END DO
311	ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf )
312	IF(lwp) WRITE(numout,) ' N Total power consumption by zavt_itf: ztpc = ', ztpc 1.e-12 ,'TW'
313	ENDIF
314
315	! ! Update pav with the ITF mixing coefficient
316	DO jk = 2, jpkm1
317	pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) &
318	& + zavt_itf(:,:,jk) * mask_itf(:,:)
319	END DO
320	!
321	CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum )
322	CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf )
323	!
324	IF( nn_timing == 1 ) CALL timing_stop('tmx_itf')
325	!
326	END SUBROUTINE tmx_itf
327
328
329	SUBROUTINE zdf_tmx_init
330	!!----------------------------------------------------------------------
331	!! * ROUTINE zdf_tmx_init *
332	!!
333	!! ** Purpose : Initialization of the vertical tidal mixing, Reading
334	!! of M2 and K1 tidal energy in nc files
335	!!
336	!! ** Method : - Read the namtmx namelist and check the parameters
337	!!
338	!! - Read the input data in NetCDF files :
339	!! M2 and K1 tidal energy. The total tidal energy, en_tmx,
340	!! is the sum of M2, K1 and S2 energy where S2 is assumed
341	!! to be: S2=(1/2)^2 * M2
342	!! mask_itf, a mask array that determine where substituing
343	!! the standard Simmons et al. (2005) formulation with the
344	!! one of Koch_Larrouy et al. (2007).
345	!!
346	!! - Compute az_tmx, a 3D coefficient that allows to compute
347	!! the standard tidal-induced vertical mixing as follows:
348	!! Kz_tides = az_tmx / max( rn_n2min, N^2 )
349	!! with az_tmx a bottom intensified coefficient is given by:
350	!! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx )
351	!! / ( 1. - EXP( - H /rn_htmx ) )
352	!! where rn_htmx the characteristic length scale of the bottom
353	!! intensification, en_tmx the tidal energy, and H the ocean depth
354	!!
355	!! ** input : - Namlist namtmx
356	!! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc
357	!!
358	!! ** Action : - Increase by 1 the nstop flag is setting problem encounter
359	!! - defined az_tmx used to compute tidal-induced mixing
360	!!
361	!! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263.
362	!! Koch-Larrouy et al. 2007, GRL.
363	!!----------------------------------------------------------------------
364	USE oce , zav_tide => ua ! ua used as workspace
365	!!
366	INTEGER :: ji, jj, jk ! dummy loop indices
367	INTEGER :: inum ! local integer
368	INTEGER :: ios
369	REAL(wp) :: ztpc, ze_z ! local scalars
370	REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy
371	REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy
372	REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function
373	REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth
374	REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption
375	!!
376	NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf
377	!!----------------------------------------------------------------------
378	!
379	IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init')
380	!
381	CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep )
382	CALL wrk_alloc( jpi,jpj,jpk, zpc )
383
384	REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing
385	READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901)
386	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp )
387
388	REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing
389	READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 )
390	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp )
391	IF(lwm) WRITE ( numond, namzdf_tmx )
392
393	IF(lwp) THEN ! Control print
394	WRITE(numout,*)
395	WRITE(numout,*) 'zdf_tmx_init : tidal mixing'
396	WRITE(numout,*) '~~~~~~~~~~~~'
397	WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters'
398	WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx
399	WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min
400	WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe
401	WRITE(numout,*) ' Mixing efficiency = ', rn_me
402	WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf
403	WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf
404	ENDIF
405
406	! ! allocate tmx arrays
407	IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' )
408
409	IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask
410	CALL iom_open('mask_itf',inum)
411	CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) !
412	CALL iom_close(inum)
413	ENDIF
414
415	! read M2 tidal energy flux : W/m2 ( zem2 < 0 )
416	CALL iom_open('M2rowdrg',inum)
417	CALL iom_get (inum, jpdom_data, 'field',zem2,1) !
418	CALL iom_close(inum)
419
420	! read K1 tidal energy flux : W/m2 ( zek1 < 0 )
421	CALL iom_open('K1rowdrg',inum)
422	CALL iom_get (inum, jpdom_data, 'field',zek1,1) !
423	CALL iom_close(inum)
424
425	! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 )
426	! only the energy available for mixing is taken into account,
427	! (mixing efficiency tidal dissipation efficiency)
428	en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:)
429
430	!============
431	!TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep?
432	! Vertical structure (az_tmx)
433	DO jj = 1, jpj ! part independent of the level
434	DO ji = 1, jpi
435	zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean
436	zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) )
437	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj)
438	END DO
439	END DO
440	DO jk= 1, jpk ! complete with the level-dependent part
441	DO jj = 1, jpj
442	DO ji = 1, jpi
443	az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk)
444	END DO
445	END DO
446	END DO
447	!===========
448
449	IF( nprint == 1 .AND. lwp ) THEN
450	! Control print
451	! Total power consumption due to vertical mixing
452	! zpc = rau0 * 1/rn_me * rn2 * zav_tide
453	zav_tide(:,:,:) = 0.e0
454	DO jk = 2, jpkm1
455	zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) )
456	END DO
457
458	ztpc = 0.e0
459	zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:)
460	DO jk= 2, jpkm1
461	DO jj = 1, jpj
462	DO ji = 1, jpi
463	ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
464	END DO
465	END DO
466	END DO
467	ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc
468
469	WRITE(numout,*)
470	WRITE(numout,) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc 1.e-12 ,'TW'
471
472
473	! control print 2
474	zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 )
475	zkz(:,:) = 0.e0
476	DO jk = 2, jpkm1
477	DO jj = 1, jpj
478	DO ji = 1, jpi
479	zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX(0.e0, rn2(ji,jj,jk)) * rau0 * zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
480	END DO
481	END DO
482	END DO
483	! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz
484	DO jj = 1, jpj
485	DO ji = 1, jpi
486	IF( zkz(ji,jj) /= 0.e0 ) THEN
487	zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj)
488	ENDIF
489	END DO
490	END DO
491	ztpc = 1.e50
492	DO jj = 1, jpj
493	DO ji = 1, jpi
494	IF( zkz(ji,jj) /= 0.e0 ) THEN
495	ztpc = Min( zkz(ji,jj), ztpc)
496	ENDIF
497	END DO
498	END DO
499	WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) )
500
501	DO jk = 2, jpkm1
502	DO jj = 1, jpj
503	DO ji = 1, jpi
504	zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s
505	END DO
506	END DO
507	END DO
508	ztpc = 0.e0
509	zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:)
510	DO jk= 1, jpk
511	DO jj = 1, jpj
512	DO ji = 1, jpi
513	ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
514	END DO
515	END DO
516	END DO
517	ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc
518	WRITE(numout,) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc 1.e-12 ,'TW'
519
520	DO jk = 1, jpk
521	ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) &
522	& / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
523	ztpc = 1.E50
524	DO jj = 1, jpj
525	DO ji = 1, jpi
526	IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) )
527	END DO
528	END DO
529	WRITE(numout,) ' N2 min - jk= ', jk,' ', ze_z 1.e4,' cm2/s min= ',ztpc*1.e4, &
530	& 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s'
531	END DO
532
533	WRITE(numout,) ' e_tide : ', SUM( e1te2ten_tmx ) / ( rn_tfe rn_me ) * 1.e-12, 'TW'
534	WRITE(numout,*)
535	WRITE(numout,*) ' Initial profile of tidal vertical mixing'
536	DO jk = 1, jpk
537	DO jj = 1,jpj
538	DO ji = 1,jpi
539	zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) )
540	END DO
541	END DO
542	ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) &
543	& / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
544	WRITE(numout,) ' jk= ', jk,' ', ze_z 1.e4,' cm2/s'
545	END DO
546	DO jk = 1, jpk
547	zkz(:,:) = az_tmx(:,:,jk) /rn_n2min
548	ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) &
549	& / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
550	WRITE(numout,*)
551	WRITE(numout,) ' N2 min - jk= ', jk,' ', ze_z 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, &
552	& 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s'
553	END DO
554	!
555	ENDIF
556	!
557	CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep )
558	CALL wrk_dealloc( jpi,jpj,jpk, zpc )
559	!
560	IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init')
561	!
562	END SUBROUTINE zdf_tmx_init
563
564	#elif defined key_zdftmx_new
565	!!----------------------------------------------------------------------
566	!! 'key_zdftmx_new' Internal wave-driven vertical mixing
567	!!----------------------------------------------------------------------
568	!! zdf_tmx : global momentum & tracer Kz with wave induced Kz
569	!! zdf_tmx_init : global momentum & tracer Kz with wave induced Kz
570	!!----------------------------------------------------------------------
571	USE oce ! ocean dynamics and tracers variables
572	USE dom_oce ! ocean space and time domain variables
573	USE zdf_oce ! ocean vertical physics variables
574	USE zdfddm ! ocean vertical physics: double diffusive mixing
575	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
576	USE eosbn2 ! ocean equation of state
577	USE phycst ! physical constants
578	USE prtctl ! Print control
579	USE in_out_manager ! I/O manager
580	USE iom ! I/O Manager
581	USE lib_mpp ! MPP library
582	USE wrk_nemo ! work arrays
583	USE timing ! Timing
584	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
585
586	IMPLICIT NONE
587	PRIVATE
588
589	PUBLIC zdf_tmx ! called in step module
590	PUBLIC zdf_tmx_init ! called in nemogcm module
591	PUBLIC zdf_tmx_alloc ! called in nemogcm module
592
593	LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: wave-driven mixing flag
594
595	! !!* Namelist namzdf_tmx : internal wave-driven mixing *
596	INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
597	LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency
598	LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F)
599
600	REAL(wp) :: r1_6 = 1._wp / 6._wp
601
602	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_tmx ! power available from high-mode wave breaking (W/m2)
603	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_tmx ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
604	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_tmx ! power available from low-mode, critical slope wave breaking (W/m2)
605	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_tmx ! WKB decay scale for high-mode energy dissipation (m)
606	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_tmx ! decay scale for low-mode critical slope dissipation (m)
607	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emix_tmx ! local energy density available for mixing (W/kg)
608	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: bflx_tmx ! buoyancy flux Kz * N^2 (W/kg)
609	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: pcmap_tmx ! vertically integrated buoyancy flux (W/m2)
610	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T)
611	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_wave ! Internal wave-induced diffusivity
612
613	!! * Substitutions
614	# include "zdfddm_substitute.h90"
615	# include "domzgr_substitute.h90"
616	# include "vectopt_loop_substitute.h90"
617	!!----------------------------------------------------------------------
618	!! NEMO/OPA 4.0 , NEMO Consortium (2016)
619	!! $Id$
620	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
621	!!----------------------------------------------------------------------
622	CONTAINS
623
624	INTEGER FUNCTION zdf_tmx_alloc()
625	!!----------------------------------------------------------------------
626	!! * FUNCTION zdf_tmx_alloc *
627	!!----------------------------------------------------------------------
628	ALLOCATE( ebot_tmx(jpi,jpj), epyc_tmx(jpi,jpj), ecri_tmx(jpi,jpj) , &
629	& hbot_tmx(jpi,jpj), hcri_tmx(jpi,jpj), emix_tmx(jpi,jpj,jpk), &
630	& bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk), &
631	& zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc )
632	!
633	IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc )
634	IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays')
635	END FUNCTION zdf_tmx_alloc
636
637
638	SUBROUTINE zdf_tmx( kt )
639	!!----------------------------------------------------------------------
640	!! * ROUTINE zdf_tmx *
641	!!
642	!! ** Purpose : add to the vertical mixing coefficients the effect of
643	!! breaking internal waves.
644	!!
645	!! ** Method : - internal wave-driven vertical mixing is given by:
646	!! Kz_wave = min( 100 cm2/s, f( Reb = emix_tmx /( Nu * N^2 ) )
647	!! where emix_tmx is the 3D space distribution of the wave-breaking
648	!! energy and Nu the molecular kinematic viscosity.
649	!! The function f(Reb) is linear (constant mixing efficiency)
650	!! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
651	!!
652	!! - Compute emix_tmx, the 3D power density that allows to compute
653	!! Reb and therefrom the wave-induced vertical diffusivity.
654	!! This is divided into three components:
655	!! 1. Bottom-intensified low-mode dissipation at critical slopes
656	!! emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx )
657	!! / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx
658	!! where hcri_tmx is the characteristic length scale of the bottom
659	!! intensification, ecri_tmx a map of available power, and H the ocean depth.
660	!! 2. Pycnocline-intensified low-mode dissipation
661	!! emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
662	!! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
663	!! where epyc_tmx is a map of available power, and nn_zpyc
664	!! is the chosen stratification-dependence of the internal wave
665	!! energy dissipation.
666	!! 3. WKB-height dependent high mode dissipation
667	!! emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx)
668	!! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) )
669	!! where hbot_tmx is the characteristic length scale of the WKB bottom
670	!! intensification, ebot_tmx is a map of available power, and z_wkb is the
671	!! WKB-stretched height above bottom defined as
672	!! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
673	!! / SUM( sqrt(rn2(z')) * e3w(z') )
674	!!
675	!! - update the model vertical eddy viscosity and diffusivity:
676	!! avt = avt + av_wave
677	!! avm = avm + av_wave
678	!! avmu = avmu + mi(av_wave)
679	!! avmv = avmv + mj(av_wave)
680	!!
681	!! - if namelist parameter ln_tsdiff = T, account for differential mixing:
682	!! avs = avt + av_wave * diffusivity_ratio(Reb)
683	!!
684	!! ** Action : - Define emix_tmx used to compute internal wave-induced mixing
685	!! - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing
686	!!
687	!! References : de Lavergne et al. 2015, JPO; 2016, in prep.
688	!!----------------------------------------------------------------------
689	INTEGER, INTENT(in) :: kt ! ocean time-step
690	!
691	INTEGER :: ji, jj, jk ! dummy loop indices
692	REAL(wp) :: ztpc ! scalar workspace
693	REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! Used for vertical structure
694	REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth
695	REAL(wp), DIMENSION(:,:,:), POINTER :: zwkb ! WKB-stretched height above bottom
696	REAL(wp), DIMENSION(:,:,:), POINTER :: zweight ! Weight for high mode vertical distribution
697	REAL(wp), DIMENSION(:,:,:), POINTER :: znu_t ! Molecular kinematic viscosity (T grid)
698	REAL(wp), DIMENSION(:,:,:), POINTER :: znu_w ! Molecular kinematic viscosity (W grid)
699	REAL(wp), DIMENSION(:,:,:), POINTER :: zReb ! Turbulence intensity parameter
700	!!----------------------------------------------------------------------
701	!
702	IF( nn_timing == 1 ) CALL timing_start('zdf_tmx')
703	!
704	CALL wrk_alloc( jpi,jpj, zfact, zhdep )
705	CALL wrk_alloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb )
706
707	! ! ----------------------------- !
708	! ! Internal wave-driven mixing ! (compute zav_wave)
709	! ! ----------------------------- !
710	!
711	! !* Critical slope mixing: distribute energy over the time-varying ocean depth,
712	! using an exponential decay from the seafloor.
713	DO jj = 1, jpj ! part independent of the level
714	DO ji = 1, jpi
715	zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean
716	zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) ) )
717	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj)
718	END DO
719	END DO
720
721	DO jk = 2, jpkm1 ! complete with the level-dependent part
722	emix_tmx(:,:,jk) = zfact(:,:) * ( EXP( ( fsde3w(:,:,jk ) - zhdep(:,:) ) / hcri_tmx(:,:) ) &
723	& - EXP( ( fsde3w(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) ) ) * wmask(:,:,jk) &
724	& / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) )
725	END DO
726
727	! !* Pycnocline-intensified mixing: distribute energy over the time-varying
728	! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
729
730	SELECT CASE ( nn_zpyc )
731
732	CASE ( 1 ) ! Dissipation scales as N (recommended)
733
734	zfact(:,:) = 0._wp
735	DO jk = 2, jpkm1 ! part independent of the level
736	zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
737	END DO
738
739	DO jj = 1, jpj
740	DO ji = 1, jpi
741	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
742	END DO
743	END DO
744
745	DO jk = 2, jpkm1 ! complete with the level-dependent part
746	emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
747	END DO
748
749	CASE ( 2 ) ! Dissipation scales as N^2
750
751	zfact(:,:) = 0._wp
752	DO jk = 2, jpkm1 ! part independent of the level
753	zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
754	END DO
755
756	DO jj= 1, jpj
757	DO ji = 1, jpi
758	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
759	END DO
760	END DO
761
762	DO jk = 2, jpkm1 ! complete with the level-dependent part
763	emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
764	END DO
765
766	END SELECT
767
768	! !* WKB-height dependent mixing: distribute energy over the time-varying
769	! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
770
771	zwkb(:,:,:) = 0._wp
772	zfact(:,:) = 0._wp
773	DO jk = 2, jpkm1
774	zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
775	zwkb(:,:,jk) = zfact(:,:)
776	END DO
777
778	DO jk = 2, jpkm1
779	DO jj = 1, jpj
780	DO ji = 1, jpi
781	IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) &
782	& * tmask(ji,jj,jk) / zfact(ji,jj)
783	END DO
784	END DO
785	END DO
786	zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1)
787
788	zweight(:,:,:) = 0._wp
789	DO jk = 2, jpkm1
790	zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk) &
791	& * ( EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) ) )
792	END DO
793
794	zfact(:,:) = 0._wp
795	DO jk = 2, jpkm1 ! part independent of the level
796	zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
797	END DO
798
799	DO jj = 1, jpj
800	DO ji = 1, jpi
801	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
802	END DO
803	END DO
804
805	DO jk = 2, jpkm1 ! complete with the level-dependent part
806	emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) &
807	& / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) )
808	END DO
809
810
811	! Calculate molecular kinematic viscosity
812	znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) &
813	& + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0
814	DO jk = 2, jpkm1
815	znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
816	END DO
817
818	! Calculate turbulence intensity parameter Reb
819	DO jk = 2, jpkm1
820	zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
821	END DO
822
823	! Define internal wave-induced diffusivity
824	DO jk = 2, jpkm1
825	zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6
826	END DO
827
828	IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the
829	DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
830	DO jj = 1, jpj
831	DO ji = 1, jpi
832	IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
833	zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
834	ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
835	zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
836	ENDIF
837	END DO
838	END DO
839	END DO
840	ENDIF
841
842	DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s
843	zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk)
844	END DO
845
846	IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave
847	ztpc = 0._wp
848	DO jk = 2, jpkm1
849	DO jj = 1, jpj
850	DO ji = 1, jpi
851	ztpc = ztpc + fse3w(ji,jj,jk) * e1e2t(ji,jj) &
852	& * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
853	END DO
854	END DO
855	END DO
856	IF( lk_mpp ) CALL mpp_sum( ztpc )
857	ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing
858
859	IF(lwp) THEN
860	WRITE(numout,*)
861	WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)'
862	WRITE(numout,*) '~~~~~~~ '
863	WRITE(numout,*)
864	WRITE(numout,) ' Total power consumption by av_wave: ztpc = ', ztpc 1.e-12_wp, 'TW'
865	ENDIF
866	ENDIF
867
868	! ! ----------------------- !
869	! ! Update mixing coefs !
870	! ! ----------------------- !
871	!
872	IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature
873	DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb
874	DO jj = 1, jpj
875	DO ji = 1, jpi
876	zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * &
877	& TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) &
878	& ) * wmask(ji,jj,jk)
879	END DO
880	END DO
881	END DO
882	CALL iom_put( "av_ratio", zav_ratio )
883	DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing
884	fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
885	avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
886	avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
887	END DO
888	!
889	ELSE !* update momentum & tracer diffusivity with wave-driven mixing
890	DO jk = 2, jpkm1
891	fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
892	avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
893	avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
894	END DO
895	ENDIF
896
897	DO jk = 2, jpkm1 !* update momentum diffusivity at wu and wv points
898	DO jj = 2, jpjm1
899	DO ji = fs_2, fs_jpim1 ! vector opt.
900	avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj ,jk) ) * wumask(ji,jj,jk)
901	avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji ,jj+1,jk) ) * wvmask(ji,jj,jk)
902	END DO
903	END DO
904	END DO
905	CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition
906
907	! !* output internal wave-driven mixing coefficient
908	CALL iom_put( "av_wave", zav_wave )
909	!* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx),
910	! vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx)
911	IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN
912	bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
913	pcmap_tmx(:,:) = 0._wp
914	DO jk = 2, jpkm1
915	pcmap_tmx(:,:) = pcmap_tmx(:,:) + fse3w(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk)
916	END DO
917	pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:)
918	CALL iom_put( "bflx_tmx", bflx_tmx )
919	CALL iom_put( "pcmap_tmx", pcmap_tmx )
920	ENDIF
921	CALL iom_put( "bn2", rn2 )
922	CALL iom_put( "emix_tmx", emix_tmx )
923
924	CALL wrk_dealloc( jpi,jpj, zfact, zhdep )
925	CALL wrk_dealloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb )
926
927	IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
928	!
929	IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx')
930	!
931	END SUBROUTINE zdf_tmx
932
933
934	SUBROUTINE zdf_tmx_init
935	!!----------------------------------------------------------------------
936	!! * ROUTINE zdf_tmx_init *
937	!!
938	!! ** Purpose : Initialization of the wave-driven vertical mixing, reading
939	!! of input power maps and decay length scales in netcdf files.
940	!!
941	!! ** Method : - Read the namzdf_tmx namelist and check the parameters
942	!!
943	!! - Read the input data in NetCDF files :
944	!! power available from high-mode wave breaking (mixing_power_bot.nc)
945	!! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
946	!! power available from critical slope wave-breaking (mixing_power_cri.nc)
947	!! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
948	!! decay scale for critical slope wave-breaking (decay_scale_cri.nc)
949	!!
950	!! ** input : - Namlist namzdf_tmx
951	!! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
952	!! decay_scale_bot.nc decay_scale_cri.nc
953	!!
954	!! ** Action : - Increase by 1 the nstop flag is setting problem encounter
955	!! - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx
956	!!
957	!! References : de Lavergne et al. 2015, JPO; 2016, in prep.
958	!!
959	!!----------------------------------------------------------------------
960	INTEGER :: ji, jj, jk ! dummy loop indices
961	INTEGER :: inum ! local integer
962	INTEGER :: ios
963	REAL(wp) :: zbot, zpyc, zcri ! local scalars
964	!!
965	NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff
966	!!----------------------------------------------------------------------
967	!
968	IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init')
969	!
970	REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing
971	READ ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901)
972	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp )
973	!
974	REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing
975	READ ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 )
976	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp )
977	IF(lwm) WRITE ( numond, namzdf_tmx_new )
978	!
979	IF(lwp) THEN ! Control print
980	WRITE(numout,*)
981	WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing'
982	WRITE(numout,*) '~~~~~~~~~~~~'
983	WRITE(numout,*) ' Namelist namzdf_tmx_new : set wave-driven mixing parameters'
984	WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
985	WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar
986	WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff
987	ENDIF
988
989	! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
990	! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
991	! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
992	avmb(:) = 1.4e-6_wp ! viscous molecular value
993	avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_tmx)
994	avtb_2d(:,:) = 1.e0_wp ! uniform
995	IF(lwp) THEN ! Control print
996	WRITE(numout,*)
997	WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', &
998	& 'the viscous molecular value & a very small diffusive value, resp.'
999	ENDIF
1000
1001	IF( .NOT.lk_zdfddm ) CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' )
1002
1003	! ! allocate tmx arrays
1004	IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' )
1005	!
1006	! ! read necessary fields
1007	CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2]
1008	CALL iom_get (inum, jpdom_data, 'field', ebot_tmx, 1 )
1009	CALL iom_close(inum)
1010	!
1011	CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2]
1012	CALL iom_get (inum, jpdom_data, 'field', epyc_tmx, 1 )
1013	CALL iom_close(inum)
1014	!
1015	CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2]
1016	CALL iom_get (inum, jpdom_data, 'field', ecri_tmx, 1 )
1017	CALL iom_close(inum)
1018	!
1019	CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m]
1020	CALL iom_get (inum, jpdom_data, 'field', hbot_tmx, 1 )
1021	CALL iom_close(inum)
1022	!
1023	CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m]
1024	CALL iom_get (inum, jpdom_data, 'field', hcri_tmx, 1 )
1025	CALL iom_close(inum)
1026
1027	ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:)
1028	epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:)
1029	ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:)
1030
1031	! Set once for all to zero the first and last vertical levels of appropriate variables
1032	emix_tmx (:,:, 1 ) = 0._wp
1033	emix_tmx (:,:,jpk) = 0._wp
1034	zav_ratio(:,:, 1 ) = 0._wp
1035	zav_ratio(:,:,jpk) = 0._wp
1036	zav_wave (:,:, 1 ) = 0._wp
1037	zav_wave (:,:,jpk) = 0._wp
1038
1039	zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) )
1040	zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) )
1041	zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) )
1042	IF(lwp) THEN
1043	WRITE(numout,) ' High-mode wave-breaking energy: ', zbot 1.e-12_wp, 'TW'
1044	WRITE(numout,) ' Pycnocline-intensifed wave-breaking energy: ', zpyc 1.e-12_wp, 'TW'
1045	WRITE(numout,) ' Critical slope wave-breaking energy: ', zcri 1.e-12_wp, 'TW'
1046	ENDIF
1047	!
1048	IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init')
1049	!
1050	END SUBROUTINE zdf_tmx_init
1051
1052	#else
1053	!!----------------------------------------------------------------------
1054	!! Default option Dummy module NO Tidal MiXing
1055	!!----------------------------------------------------------------------
1056	LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag
1057	CONTAINS
1058	SUBROUTINE zdf_tmx_init ! Dummy routine
1059	WRITE(,) 'zdf_tmx: You should not have seen this print! error?'
1060	END SUBROUTINE zdf_tmx_init
1061	SUBROUTINE zdf_tmx( kt ) ! Dummy routine
1062	WRITE(,) 'zdf_tmx: You should not have seen this print! error?', kt
1063	END SUBROUTINE zdf_tmx
1064	#endif
1065
1066	!!======================================================================
1067	END MODULE zdftmx

Note: See TracBrowser for help on using the repository browser.

Download in other formats: