source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 7607

Last change on this file since 7607 was 7607, checked in by cetlod, 4 years ago

v3.6 stable : add missing features for CMIP6 exercise, see ticket #1834

File size: 9.5 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!----------------------------------------------------------------------
14#if defined key_pisces
15   !!----------------------------------------------------------------------
16   !!   'key_pisces'                                       PISCES bio-model
17   !!----------------------------------------------------------------------
18   !!   p4z_lys        :   Compute the CaCO3 dissolution
19   !!   p4z_lys_init   :   Read the namelist parameters
20   !!----------------------------------------------------------------------
21   USE oce_trc         !  shared variables between ocean and passive tracers
22   USE trc             !  passive tracers common variables
23   USE sms_pisces      !  PISCES Source Minus Sink variables
24   USE prtctl_trc      !  print control for debugging
25   USE p4zche          !  Chemical model
26   USE iom             !  I/O manager
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
32   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
36   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
37
38   !! * Module variables
39   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
40 
41   INTEGER  :: rmtss                      !: number of seconds per month
42
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
45   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
46   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE p4z_lys( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_lys  ***
54      !!
55      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
56      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
57      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      !
62      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
63      INTEGER  ::   ji, jj, jk
64      REAL(wp) ::   zdispot, zfact, zcalcon
65      REAL(wp) ::   zomegaca, zexcess, zexcess0
66      CHARACTER (len=25) :: charout
67      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zco3sat, zcaldiss, zhinit, zhi   
68      !!---------------------------------------------------------------------
69      !
70      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
71      !
72      CALL wrk_alloc( jpi, jpj, jpk, zco3, zco3sat, zcaldiss, zhinit, zhi )
73      !
74      zco3    (:,:,:) = 0.
75      zcaldiss(:,:,:) = 0.
76      zhinit(:,:,:)   = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
77      !     -------------------------------------------
78      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
79      !     -------------------------------------------
80
81      CALL p4z_che_solve_hi( zhinit, zhi )
82
83      DO jk = 1, jpkm1
84         DO jj = 1, jpj
85            DO ji = 1, jpi
86               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
87               &                + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
88               hi(ji,jj,jk)   = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
89            END DO
90         END DO
91      END DO
92
93      !     ---------------------------------------------------------
94      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
95      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
96      !        MGCO3)
97      !     ---------------------------------------------------------
98
99      DO jk = 1, jpkm1
100         DO jj = 1, jpj
101            DO ji = 1, jpi
102
103               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
104               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
105               zcalcon  = calcon * ( tsn(ji,jj,jk,jp_sal) / 35._wp )
106               zfact    = rhop(ji,jj,jk) / 1000._wp
107               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
108               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
109
110               ! SET DEGREE OF UNDER-/SUPERSATURATION
111               excess(ji,jj,jk) = 1._wp - zomegaca
112               zexcess0 = MAX( 0., excess(ji,jj,jk) )
113               zexcess  = zexcess0**nca
114
115               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
116               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
117               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
118               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
119# if defined key_degrad
120               zdispot = zdispot * facvol(ji,jj,jk)
121# endif
122              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
123              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
124              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
125              !
126              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
127              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
128              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
129            END DO
130         END DO
131      END DO
132      !
133
134      IF( lk_iomput .AND. knt == nrdttrc ) THEN
135         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
136         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)    * 1.e+3            * tmask(:,:,:) )
137         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:) * 1.e+3            * tmask(:,:,:) )
138         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
139      ELSE
140         IF( ln_diatrc ) THEN
141            trc3d(:,:,:,jp_pcs0_3d    ) = -1. * LOG10( hi(:,:,:) ) * tmask(:,:,:)
142            trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)              * tmask(:,:,:)
143            trc3d(:,:,:,jp_pcs0_3d + 2) = zco3sat(:,:,:)           * tmask(:,:,:)
144         ENDIF
145      ENDIF
146      !
147      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
148        WRITE(charout, FMT="('lys ')")
149        CALL prt_ctl_trc_info(charout)
150        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
151      ENDIF
152      !
153      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zcaldiss, zhinit, zhi, zco3sat )
154      !
155      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
156      !
157   END SUBROUTINE p4z_lys
158
159   SUBROUTINE p4z_lys_init
160
161      !!----------------------------------------------------------------------
162      !!                  ***  ROUTINE p4z_lys_init  ***
163      !!
164      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
165      !!
166      !! ** Method  :   Read the nampiscal namelist and check the parameters
167      !!      called at the first timestep (nittrc000)
168      !!
169      !! ** input   :   Namelist nampiscal
170      !!
171      !!----------------------------------------------------------------------
172      INTEGER  ::  ios                 ! Local integer output status for namelist read
173      NAMELIST/nampiscal/ kdca, nca
174      !!----------------------------------------------------------------------
175
176      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
177      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
178901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
179
180      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
181      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
182902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
183      IF(lwm) WRITE ( numonp, nampiscal )
184
185      IF(lwp) THEN                         ! control print
186         WRITE(numout,*) ' '
187         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
188         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
189         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
190         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
191      ENDIF
192
193      ! Number of seconds per month
194      rmtss =  nyear_len(1) * rday / raamo
195      !
196   END SUBROUTINE p4z_lys_init
197
198#else
199   !!======================================================================
200   !!  Dummy module :                                   No PISCES bio-model
201   !!======================================================================
202CONTAINS
203   SUBROUTINE p4z_lys( kt )                   ! Empty routine
204      INTEGER, INTENT( in ) ::   kt
205      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
206   END SUBROUTINE p4z_lys
207#endif 
208   !!======================================================================
209END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.