source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 8532

Last change on this file since 8532 was 8532, checked in by cetlod, 3 years ago

v3.6 stable: bugfixes to solve problem particle in PISCES, see ticket #1940

File size: 18.3 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_top'       and                                      TOP models
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
16   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
17   !!   p4z_rem_alloc :  Allocate remineralisation variables
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p4zche          !  chemical model
24   USE p4zprod         !  Growth rate of the 2 phyto groups
25   USE p4zmeso         !  Sources and sinks of mesozooplankton
26   USE p4zint          !  interpolation and computation of various fields
27   USE p4zlim
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_rem         ! called in p4zbio.F90
36   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p4z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
41   REAL(wp), PUBLIC ::  xremip     !: remineralisation rate of DOC
42   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
43   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
44   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
45   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
46
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitnh4   !: -    -    -    -   -
49
50   !!* Substitution
51#  include "top_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE p4z_rem( kt, knt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_rem  ***
62      !!
63      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      !
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zremip, zremik, zsiremin, zammonic 
72      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
73      REAL(wp) ::   zbactfer, zorem, zorem2, zofer, zolimit
74      REAL(wp) ::   zosil, ztem
75#if ! defined key_kriest
76      REAL(wp) ::   zofer2
77#endif
78      REAL(wp) ::   zonitr, zstep, zfact
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zdepprod, zw3d
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zoxyrem
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
86      !
87      ! Allocate temporary workspace
88      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
89      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zoxyrem )
90
91      ! Initialisation of temprary arrys
92      zdepprod(:,:,:) = 1._wp
93      ztempbac(:,:)   = 0._wp
94
95      ! Computation of the mean phytoplankton concentration as
96      ! a crude estimate of the bacterial biomass
97      ! this parameterization has been deduced from a model version
98      ! that was modeling explicitely bacteria
99      ! -------------------------------------------------------
100      DO jk = 1, jpkm1
101         DO jj = 1, jpj
102            DO ji = 1, jpi
103               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
104               IF( fsdept(ji,jj,jk) < zdep ) THEN
105                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
106                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
107               ELSE
108                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
109                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
110                  zdepprod(ji,jj,jk) = zdepmin**0.273
111               ENDIF
112            END DO
113         END DO
114      END DO
115
116      DO jk = 1, jpkm1
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119               zstep   = xstep
120# if defined key_degrad
121               zstep = zstep * facvol(ji,jj,jk)
122# endif
123               ! DOC ammonification. Depends on depth, phytoplankton biomass
124               ! and a limitation term which is supposed to be a parameterization
125               !     of the bacterial activity.
126               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
127               zremik = MAX( zremik, 2.74e-4 * xstep )
128               ! Ammonification in oxic waters with oxygen consumption
129               ! -----------------------------------------------------
130               zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
131               zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
132               ! Ammonification in suboxic waters with denitrification
133               ! -------------------------------------------------------
134               zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
135               denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
136               zoxyrem(ji,jj,jk) = zammonic *        nitrfac2(ji,jj,jk)
137               !
138               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
139               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
140               zoxyrem(ji,jj,jk) = MAX( 0.e0, zoxyrem(ji,jj,jk) )
141               !
142            END DO
143         END DO
144      END DO
145
146
147      DO jk = 1, jpkm1
148         DO jj = 1, jpj
149            DO ji = 1, jpi
150               zstep   = xstep
151# if defined key_degrad
152               zstep = zstep * facvol(ji,jj,jk)
153# endif
154               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
155               ! below 2 umol/L. Inhibited at strong light
156               ! ----------------------------------------------------------
157               zonitr  =nitrif * zstep * trb(ji,jj,jk,jpnh4) / ( 1.+ emoy(ji,jj,jk) ) * ( 1.- nitrfac(ji,jj,jk) ) 
158               denitnh4(ji,jj,jk) = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
159               ! Update of the tracers trends
160               ! ----------------------------
161               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - denitnh4(ji,jj,jk)
162               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * denitnh4(ji,jj,jk)
163               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
164               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr &
165                  &                + rno3 * ( rdenita - 1. ) * denitnh4(ji,jj,jk)
166            END DO
167         END DO
168      END DO
169
170       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
171         WRITE(charout, FMT="('rem1')")
172         CALL prt_ctl_trc_info(charout)
173         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
174       ENDIF
175
176      DO jk = 1, jpkm1
177         DO jj = 1, jpj
178            DO ji = 1, jpi
179
180               ! Bacterial uptake of iron. No iron is available in DOC. So
181               ! Bacteries are obliged to take up iron from the water. Some
182               ! studies (especially at Papa) have shown this uptake to be significant
183               ! ----------------------------------------------------------
184               zbactfer = 10.e-6 *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
185                  &              * trb(ji,jj,jk,jpfer) / ( 2.5E-10 + trb(ji,jj,jk,jpfer) )    &
186                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
187#if defined key_kriest
188               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
189               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
190#else
191               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
192               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
193               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
194#endif
195            END DO
196         END DO
197      END DO
198
199       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
200         WRITE(charout, FMT="('rem2')")
201         CALL prt_ctl_trc_info(charout)
202         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
203       ENDIF
204
205      DO jk = 1, jpkm1
206         DO jj = 1, jpj
207            DO ji = 1, jpi
208               zstep   = xstep
209# if defined key_degrad
210               zstep = zstep * facvol(ji,jj,jk)
211# endif
212               ! POC disaggregation by turbulence and bacterial activity.
213               ! --------------------------------------------------------
214               zremip = xremip * zstep * tgfunc(ji,jj,jk) * ( 1.- 0.55 * nitrfac(ji,jj,jk) ) 
215
216               ! POC disaggregation rate is reduced in anoxic zone as shown by
217               ! sediment traps data. In oxic area, the exponent of the martin s
218               ! law is around -0.87. In anoxic zone, it is around -0.35. This
219               ! means a disaggregation constant about 0.5 the value in oxic zones
220               ! -----------------------------------------------------------------
221               zorem  = zremip * trb(ji,jj,jk,jppoc)
222               zofer  = zremip * trb(ji,jj,jk,jpsfe)
223#if ! defined key_kriest
224               zorem2 = zremip * trb(ji,jj,jk,jpgoc)
225               zofer2 = zremip * trb(ji,jj,jk,jpbfe)
226#else
227               zorem2 = zremip * trb(ji,jj,jk,jpnum)
228#endif
229
230               ! Update the appropriate tracers trends
231               ! -------------------------------------
232
233               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zorem
234               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
235#if defined key_kriest
236               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zorem
237               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zorem2
238               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
239#else
240               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zorem2 - zorem
241               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zorem2
242               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zofer2 - zofer
243               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
244#endif
245
246            END DO
247         END DO
248      END DO
249
250       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
251         WRITE(charout, FMT="('rem3')")
252         CALL prt_ctl_trc_info(charout)
253         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
254       ENDIF
255
256      DO jk = 1, jpkm1
257         DO jj = 1, jpj
258            DO ji = 1, jpi
259               zstep   = xstep
260# if defined key_degrad
261               zstep = zstep * facvol(ji,jj,jk)
262# endif
263               ! Remineralization rate of BSi depedant on T and saturation
264               ! ---------------------------------------------------------
265               zsatur   = ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
266               zsatur   = MAX( rtrn, zsatur )
267               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
268               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
269               znusil2  = 0.225  * ( 1. + tsn(ji,jj,1,jp_tem) / 15.) + 0.775 * zsatur2
270
271               ! Two classes of BSi are considered : a labile fraction and
272               ! a more refractory one. The ratio between both fractions is
273               ! constant and specified in the namelist.
274               ! ----------------------------------------------------------
275               zdep     = MAX( hmld(ji,jj), heup(ji,jj) ) 
276               zdep     = MAX( 0., fsdept(ji,jj,jk) - zdep )
277               ztem     = MAX( tsn(ji,jj,1,jp_tem), 0. )
278               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * znusil2 * zdep / wsbio2 ) * ztem / ( ztem + 10. )
279               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
280               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
281               !
282               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
283               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
284               !
285            END DO
286         END DO
287      END DO
288
289      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
290         WRITE(charout, FMT="('rem4')")
291         CALL prt_ctl_trc_info(charout)
292         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
293       ENDIF
294
295      ! Update the arrays TRA which contain the biological sources and sinks
296      ! --------------------------------------------------------------------
297
298      DO jk = 1, jpkm1
299         tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zolimi (:,:,jk) + denitr(:,:,jk) + zoxyrem(:,:,jk)
300         tra(:,:,jk,jpnh4) = tra(:,:,jk,jpnh4) + zolimi (:,:,jk) + denitr(:,:,jk) + zoxyrem(:,:,jk)
301         tra(:,:,jk,jpno3) = tra(:,:,jk,jpno3) - denitr (:,:,jk) * rdenit
302         tra(:,:,jk,jpdoc) = tra(:,:,jk,jpdoc) - zolimi (:,:,jk) - denitr(:,:,jk) - zoxyrem(:,:,jk)
303         tra(:,:,jk,jpoxy) = tra(:,:,jk,jpoxy) - zolimi (:,:,jk) * o2ut
304         tra(:,:,jk,jpdic) = tra(:,:,jk,jpdic) + zolimi (:,:,jk) + denitr(:,:,jk) + zoxyrem(:,:,jk)
305         tra(:,:,jk,jptal) = tra(:,:,jk,jptal) + rno3 * ( zolimi(:,:,jk) + zoxyrem(:,:,jk) &
306              &                                        + ( rdenit + 1.) * denitr(:,:,jk) )
307      END DO
308
309      IF( knt == nrdttrc ) THEN
310          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
311          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
312          !
313          IF( iom_use( "REMIN" ) )  THEN
314              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
315              CALL iom_put( "REMIN"  , zw3d )
316          ENDIF
317          IF( iom_use( "DENIT" ) )  THEN
318              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
319              CALL iom_put( "DENIT"  , zw3d )
320          ENDIF
321          !
322          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
323       ENDIF
324
325      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
326         WRITE(charout, FMT="('rem6')")
327         CALL prt_ctl_trc_info(charout)
328         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
329      ENDIF
330      !
331      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
332      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi )
333      !
334      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
335      !
336   END SUBROUTINE p4z_rem
337
338
339   SUBROUTINE p4z_rem_init
340      !!----------------------------------------------------------------------
341      !!                  ***  ROUTINE p4z_rem_init  ***
342      !!
343      !! ** Purpose :   Initialization of remineralization parameters
344      !!
345      !! ** Method  :   Read the nampisrem namelist and check the parameters
346      !!      called at the first timestep
347      !!
348      !! ** input   :   Namelist nampisrem
349      !!
350      !!----------------------------------------------------------------------
351      NAMELIST/nampisrem/ xremik, xremip, nitrif, xsirem, xsiremlab, xsilab
352      INTEGER :: ios                 ! Local integer output status for namelist read
353
354      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
355      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
356901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
357
358      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
359      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
360902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
361      IF(lwm) WRITE ( numonp, nampisrem )
362
363      IF(lwp) THEN                         ! control print
364         WRITE(numout,*) ' '
365         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
366         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
367         WRITE(numout,*) '    remineralisation rate of POC              xremip    =', xremip
368         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
369         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
370         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
371         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
372         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
373      ENDIF
374      !
375      denitr  (:,:,:) = 0._wp
376      denitnh4(:,:,:) = 0._wp
377      !
378   END SUBROUTINE p4z_rem_init
379
380
381   INTEGER FUNCTION p4z_rem_alloc()
382      !!----------------------------------------------------------------------
383      !!                     ***  ROUTINE p4z_rem_alloc  ***
384      !!----------------------------------------------------------------------
385      ALLOCATE( denitr(jpi,jpj,jpk), denitnh4(jpi,jpj,jpk), STAT=p4z_rem_alloc )
386      !
387      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
388      !
389   END FUNCTION p4z_rem_alloc
390
391#else
392   !!======================================================================
393   !!  Dummy module :                                   No PISCES bio-model
394   !!======================================================================
395CONTAINS
396   SUBROUTINE p4z_rem                    ! Empty routine
397   END SUBROUTINE p4z_rem
398#endif 
399
400   !!======================================================================
401END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.