| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | !! sbc_init : read namsbc namelist |
|---|
| 20 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce ! ocean dynamics and tracers |
|---|
| 23 | USE dom_oce ! ocean space and time domain |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 26 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 27 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 28 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 29 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 30 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 31 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 32 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 33 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 34 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 35 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 36 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 37 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 38 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 39 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 40 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 41 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 42 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 43 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 44 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 45 | USE closea ! closed sea |
|---|
| 46 | USE icbstp ! Icebergs |
|---|
| 47 | USE traqsr ! active tracers: light penetration |
|---|
| 48 | USE sbcwave ! Wave module |
|---|
| 49 | USE bdy_par ! Require lk_bdy |
|---|
| 50 | ! |
|---|
| 51 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 52 | USE iom ! IOM library |
|---|
| 53 | USE in_out_manager ! I/O manager |
|---|
| 54 | USE lib_mpp ! MPP library |
|---|
| 55 | USE timing ! Timing |
|---|
| 56 | |
|---|
| 57 | USE diurnal_bulk, ONLY: & |
|---|
| 58 | & ln_diurnal_only |
|---|
| 59 | |
|---|
| 60 | IMPLICIT NONE |
|---|
| 61 | PRIVATE |
|---|
| 62 | |
|---|
| 63 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 64 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 65 | |
|---|
| 66 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 67 | |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 70 | !! $Id$ |
|---|
| 71 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | CONTAINS |
|---|
| 74 | |
|---|
| 75 | SUBROUTINE sbc_init |
|---|
| 76 | !!--------------------------------------------------------------------- |
|---|
| 77 | !! *** ROUTINE sbc_init *** |
|---|
| 78 | !! |
|---|
| 79 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 80 | !! |
|---|
| 81 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 82 | !! Call init routines for all other SBC modules that have one |
|---|
| 83 | !! |
|---|
| 84 | !! ** Action : - read namsbc parameters |
|---|
| 85 | !! - nsbc: type of sbc |
|---|
| 86 | !!---------------------------------------------------------------------- |
|---|
| 87 | INTEGER :: icpt ! local integer |
|---|
| 88 | !! |
|---|
| 89 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_blk_mfs, & |
|---|
| 90 | & ln_cpl , ln_mixcpl, nn_components , nn_limflx , & |
|---|
| 91 | & ln_traqsr, ln_dm2dc , & |
|---|
| 92 | & nn_ice , nn_ice_embd, & |
|---|
| 93 | & ln_rnf , ln_ssr , ln_isf , nn_fwb , ln_apr_dyn, & |
|---|
| 94 | & ln_wave , ln_cdgw , ln_sdw , ln_tauoc , ln_stcor , & |
|---|
| 95 | & nn_lsm |
|---|
| 96 | INTEGER :: ios |
|---|
| 97 | INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3, jpm |
|---|
| 98 | LOGICAL :: ll_purecpl |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | IF(lwp) THEN |
|---|
| 102 | WRITE(numout,*) |
|---|
| 103 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 104 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 105 | ENDIF |
|---|
| 106 | ! |
|---|
| 107 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 108 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 109 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 110 | ! |
|---|
| 111 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 112 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 113 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 114 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 115 | ! |
|---|
| 116 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 117 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 118 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 119 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 120 | IF( lk_cice ) nn_ice = 4 |
|---|
| 121 | ENDIF |
|---|
| 122 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 123 | ln_ana = .TRUE. |
|---|
| 124 | nn_ice = 0 |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | IF(lwp) THEN ! Control print |
|---|
| 128 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 129 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 130 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 131 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 132 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 133 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 134 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 135 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 136 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 137 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 138 | WRITE(numout,*) ' forced-coupled mixed formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 139 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 140 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 141 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 142 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 143 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 144 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 145 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 146 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 147 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 148 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 149 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 150 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 151 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 152 | WRITE(numout,*) ' iceshelf formulation ln_isf = ', ln_isf |
|---|
| 153 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 154 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 155 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 156 | WRITE(numout,*) ' Stokes drift corr. to vert. velocity ln_sdw = ', ln_sdw |
|---|
| 157 | WRITE(numout,*) ' wave modified ocean stress ln_tauoc = ', ln_tauoc |
|---|
| 158 | WRITE(numout,*) ' Stokes coriolis term ln_stcor = ', ln_stcor |
|---|
| 159 | WRITE(numout,*) ' neutral drag coefficient (CORE, MFS) ln_cdgw = ', ln_cdgw |
|---|
| 160 | ENDIF |
|---|
| 161 | ! |
|---|
| 162 | IF(lwp) THEN |
|---|
| 163 | WRITE(numout,*) |
|---|
| 164 | SELECT CASE ( nn_limflx ) ! LIM3 Multi-category heat flux formulation |
|---|
| 165 | CASE ( -1 ) ; WRITE(numout,*) ' LIM3: use per-category fluxes (nn_limflx = -1) ' |
|---|
| 166 | CASE ( 0 ) ; WRITE(numout,*) ' LIM3: use average per-category fluxes (nn_limflx = 0) ' |
|---|
| 167 | CASE ( 1 ) ; WRITE(numout,*) ' LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 168 | CASE ( 2 ) ; WRITE(numout,*) ' LIM3: Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 169 | END SELECT |
|---|
| 170 | ENDIF |
|---|
| 171 | ! |
|---|
| 172 | IF( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis ) & |
|---|
| 173 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 174 | IF( nn_components == jp_iam_opa .AND. ln_cpl ) & |
|---|
| 175 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 176 | IF( nn_components == jp_iam_opa .AND. ln_mixcpl ) & |
|---|
| 177 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 178 | IF( ln_cpl .AND. .NOT. lk_oasis ) & |
|---|
| 179 | & CALL ctl_stop( 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' ) |
|---|
| 180 | IF( ln_mixcpl .AND. .NOT. lk_oasis ) & |
|---|
| 181 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' ) |
|---|
| 182 | IF( ln_mixcpl .AND. .NOT. ln_cpl ) & |
|---|
| 183 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' ) |
|---|
| 184 | IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo ) & |
|---|
| 185 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' ) |
|---|
| 186 | |
|---|
| 187 | ! ! allocate sbc arrays |
|---|
| 188 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 189 | |
|---|
| 190 | ! ! Checks: |
|---|
| 191 | IF( .NOT. ln_isf ) THEN ! variable initialisation if no ice shelf |
|---|
| 192 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 193 | fwfisf (:,:) = 0.0_wp ; fwfisf_b (:,:) = 0.0_wp |
|---|
| 194 | risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp |
|---|
| 195 | END IF |
|---|
| 196 | IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! no ice in the domain, ice fraction is always zero |
|---|
| 197 | |
|---|
| 198 | sfx(:,:) = 0._wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 199 | ! only if sea-ice is present |
|---|
| 200 | |
|---|
| 201 | fmmflx(:,:) = 0._wp ! freezing-melting array initialisation |
|---|
| 202 | |
|---|
| 203 | taum(:,:) = 0._wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 204 | |
|---|
| 205 | ! ! restartability |
|---|
| 206 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 207 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 208 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 209 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' ) |
|---|
| 210 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 211 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 212 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 213 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 214 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 215 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 216 | IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 217 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 218 | IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 219 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 220 | |
|---|
| 221 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 222 | |
|---|
| 223 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 224 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 225 | |
|---|
| 226 | IF ( ln_wave ) THEN |
|---|
| 227 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 228 | IF ( .NOT.(ln_cdgw .OR. ln_sdw .OR. ln_tauoc .OR. ln_stcor ) ) THEN |
|---|
| 229 | CALL ctl_warn( 'Ask for wave coupling but ln_cdgw=F, ln_sdw=F, ln_tauoc=F, ln_stcor=F') |
|---|
| 230 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 231 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 232 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 233 | ELSEIF (ln_stcor .AND. .NOT. ln_sdw) THEN |
|---|
| 234 | CALL ctl_stop( 'Stokes-Coriolis term calculated only if activated Stokes Drift ln_sdw=T') |
|---|
| 235 | ENDIF |
|---|
| 236 | ELSE |
|---|
| 237 | IF ( ln_cdgw .OR. ln_sdw .OR. ln_tauoc .OR. ln_stcor ) & |
|---|
| 238 | & CALL ctl_stop( 'Not Activated Wave Module (ln_wave=F) but asked coupling ', & |
|---|
| 239 | & 'with drag coefficient (ln_cdgw =T) ' , & |
|---|
| 240 | & 'or Stokes Drift (ln_sdw=T) ' , & |
|---|
| 241 | & 'or ocean stress modification due to waves (ln_tauoc=T) ', & |
|---|
| 242 | & 'or Stokes-Coriolis term (ln_stcori=T)' ) |
|---|
| 243 | ENDIF |
|---|
| 244 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 245 | ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl |
|---|
| 246 | ! |
|---|
| 247 | icpt = 0 |
|---|
| 248 | IF( ln_ana ) THEN ; nsbc = jp_ana ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 249 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 250 | IF( ln_blk_clio ) THEN ; nsbc = jp_clio ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 251 | IF( ln_blk_core ) THEN ; nsbc = jp_core ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 252 | IF( ln_blk_mfs ) THEN ; nsbc = jp_mfs ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 253 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 254 | IF( cp_cfg == 'gyre') THEN ; nsbc = jp_gyre ; ENDIF ! GYRE analytical formulation |
|---|
| 255 | IF( nn_components == jp_iam_opa ) & |
|---|
| 256 | & THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 257 | ! |
|---|
| 258 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init: choose ONE and only ONE sbc option' ) |
|---|
| 259 | ! |
|---|
| 260 | IF(lwp) THEN |
|---|
| 261 | WRITE(numout,*) |
|---|
| 262 | SELECT CASE( nsbc ) |
|---|
| 263 | CASE( jp_gyre ) ; WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 264 | CASE( jp_ana ) ; WRITE(numout,*) ' analytical formulation' |
|---|
| 265 | CASE( jp_flx ) ; WRITE(numout,*) ' flux formulation' |
|---|
| 266 | CASE( jp_clio ) ; WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 267 | CASE( jp_core ) ; WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 268 | CASE( jp_purecpl ) ; WRITE(numout,*) ' pure coupled formulation' |
|---|
| 269 | CASE( jp_mfs ) ; WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 270 | CASE( jp_none ) ; WRITE(numout,*) ' OPA coupled to SAS via oasis' |
|---|
| 271 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 272 | END SELECT |
|---|
| 273 | IF( nn_components/= jp_iam_nemo ) & |
|---|
| 274 | & WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 275 | ENDIF |
|---|
| 276 | ! |
|---|
| 277 | IF( lk_oasis ) CALL sbc_cpl_init (nn_ice) ! OASIS initialisation. must be done before: (1) first time step |
|---|
| 278 | ! ! (2) the use of nn_fsbc |
|---|
| 279 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 280 | ! sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 281 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 282 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 283 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 284 | ! |
|---|
| 285 | IF(lwp)THEN |
|---|
| 286 | WRITE(numout,*) |
|---|
| 287 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 288 | WRITE(numout,*) |
|---|
| 289 | ENDIF |
|---|
| 290 | ENDIF |
|---|
| 291 | ! |
|---|
| 292 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 293 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 294 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 295 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 296 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 297 | ENDIF |
|---|
| 298 | ! |
|---|
| 299 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 300 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 301 | ! |
|---|
| 302 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 303 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 304 | ! |
|---|
| 305 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 306 | ! |
|---|
| 307 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 308 | ! |
|---|
| 309 | CALL sbc_rnf_init ! Runof initialisation |
|---|
| 310 | ! |
|---|
| 311 | IF( nn_ice == 3 ) CALL sbc_lim_init ! LIM3 initialisation |
|---|
| 312 | ! |
|---|
| 313 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 314 | ! |
|---|
| 315 | END SUBROUTINE sbc_init |
|---|
| 316 | |
|---|
| 317 | |
|---|
| 318 | SUBROUTINE sbc( kt ) |
|---|
| 319 | !!--------------------------------------------------------------------- |
|---|
| 320 | !! *** ROUTINE sbc *** |
|---|
| 321 | !! |
|---|
| 322 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 323 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 324 | !! |
|---|
| 325 | !! ** Method : blah blah to be written ????????? |
|---|
| 326 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 327 | !! |
|---|
| 328 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 329 | !! time step, i.e. |
|---|
| 330 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 331 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 332 | !! - updte the ice fraction : fr_i |
|---|
| 333 | !!---------------------------------------------------------------------- |
|---|
| 334 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 335 | !!--------------------------------------------------------------------- |
|---|
| 336 | ! |
|---|
| 337 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 338 | ! |
|---|
| 339 | ! ! ---------------------------------------- ! |
|---|
| 340 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 341 | ! ! ---------------------------------------- ! |
|---|
| 342 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 343 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 344 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 345 | emp_b (:,:) = emp (:,:) |
|---|
| 346 | sfx_b (:,:) = sfx (:,:) |
|---|
| 347 | IF ( ln_rnf ) THEN |
|---|
| 348 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 349 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 350 | ENDIF |
|---|
| 351 | ENDIF |
|---|
| 352 | ! ! ---------------------------------------- ! |
|---|
| 353 | ! ! forcing field computation ! |
|---|
| 354 | ! ! ---------------------------------------- ! |
|---|
| 355 | ! |
|---|
| 356 | IF( nn_components /= jp_iam_sas ) CALL sbc_ssm ( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 357 | ! ! averaged over nf_sbc time-step |
|---|
| 358 | IF( ln_wave ) CALL sbc_wave( kt ) ! surface waves |
|---|
| 359 | |
|---|
| 360 | |
|---|
| 361 | !== sbc formulation ==! |
|---|
| 362 | |
|---|
| 363 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 364 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 365 | CASE( jp_gyre ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 366 | CASE( jp_ana ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 367 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 368 | CASE( jp_clio ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 369 | CASE( jp_core ) |
|---|
| 370 | IF( nn_components == jp_iam_sas ) & |
|---|
| 371 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 372 | CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 373 | ! from oce: sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 374 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 375 | ! |
|---|
| 376 | CASE( jp_mfs ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 377 | CASE( jp_none ) |
|---|
| 378 | IF( nn_components == jp_iam_opa ) & |
|---|
| 379 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 380 | END SELECT |
|---|
| 381 | IF ( ln_wave .AND. ln_tauoc) THEN ! Wave stress subctracted |
|---|
| 382 | utau(:,:) = utau(:,:)*tauoc_wave(:,:) |
|---|
| 383 | vtau(:,:) = vtau(:,:)*tauoc_wave(:,:) |
|---|
| 384 | taum(:,:) = taum(:,:)*tauoc_wave(:,:) |
|---|
| 385 | ! |
|---|
| 386 | SELECT CASE( nsbc ) |
|---|
| 387 | CASE( 0,1,2,3,5,-1 ) ; |
|---|
| 388 | IF(lwp .AND. kt == nit000 ) WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. & |
|---|
| 389 | & If not requested select ln_tauoc=.false' |
|---|
| 390 | END SELECT |
|---|
| 391 | ! |
|---|
| 392 | END IF |
|---|
| 393 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 394 | |
|---|
| 395 | ! |
|---|
| 396 | ! !== Misc. Options ==! |
|---|
| 397 | ! |
|---|
| 398 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 399 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 400 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 401 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 402 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 403 | END SELECT |
|---|
| 404 | |
|---|
| 405 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 406 | |
|---|
| 407 | IF( ln_isf ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 408 | |
|---|
| 409 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 410 | |
|---|
| 411 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 412 | |
|---|
| 413 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 414 | |
|---|
| 415 | ! treatment of closed sea in the model domain |
|---|
| 416 | ! (update freshwater fluxes) |
|---|
| 417 | ! Should not be ran if ln_diurnal_only |
|---|
| 418 | IF( .NOT.(ln_diurnal_only) .AND. (nn_closea == 1) ) CALL sbc_clo( kt ) |
|---|
| 419 | |
|---|
| 420 | !RBbug do not understand why see ticket 667 |
|---|
| 421 | !clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 422 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 423 | ! |
|---|
| 424 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 425 | ! ! ---------------------------------------- ! |
|---|
| 426 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 427 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 428 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 429 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 430 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 431 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 432 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 433 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 434 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 435 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 436 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 437 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 438 | ELSE |
|---|
| 439 | sfx_b (:,:) = sfx(:,:) |
|---|
| 440 | ENDIF |
|---|
| 441 | ELSE !* no restart: set from nit000 values |
|---|
| 442 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 443 | utau_b(:,:) = utau(:,:) |
|---|
| 444 | vtau_b(:,:) = vtau(:,:) |
|---|
| 445 | qns_b (:,:) = qns (:,:) |
|---|
| 446 | emp_b (:,:) = emp(:,:) |
|---|
| 447 | sfx_b (:,:) = sfx(:,:) |
|---|
| 448 | ENDIF |
|---|
| 449 | ENDIF |
|---|
| 450 | ! ! ---------------------------------------- ! |
|---|
| 451 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 452 | ! ! ---------------------------------------- ! |
|---|
| 453 | IF(lwp) WRITE(numout,*) |
|---|
| 454 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 455 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 456 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 457 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 458 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 459 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 460 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 461 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 462 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 463 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 464 | ENDIF |
|---|
| 465 | ! ! ---------------------------------------- ! |
|---|
| 466 | ! ! Outputs and control print ! |
|---|
| 467 | ! ! ---------------------------------------- ! |
|---|
| 468 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 469 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 470 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 471 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 472 | ! (includes virtual salt flux beneath ice |
|---|
| 473 | ! in linear free surface case) |
|---|
| 474 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 475 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 476 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 477 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 478 | IF( nn_ice > 0 .OR. nn_components == jp_iam_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 479 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 480 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 481 | ENDIF |
|---|
| 482 | ! |
|---|
| 483 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 484 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 485 | ! |
|---|
| 486 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 487 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 488 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 489 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 490 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 491 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 492 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 493 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 494 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 495 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 496 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 497 | ENDIF |
|---|
| 498 | |
|---|
| 499 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 500 | ! |
|---|
| 501 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 502 | ! |
|---|
| 503 | END SUBROUTINE sbc |
|---|
| 504 | |
|---|
| 505 | |
|---|
| 506 | SUBROUTINE sbc_final |
|---|
| 507 | !!--------------------------------------------------------------------- |
|---|
| 508 | !! *** ROUTINE sbc_final *** |
|---|
| 509 | !! |
|---|
| 510 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 511 | !!--------------------------------------------------------------------- |
|---|
| 512 | ! |
|---|
| 513 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 514 | ! |
|---|
| 515 | END SUBROUTINE sbc_final |
|---|
| 516 | |
|---|
| 517 | !!====================================================================== |
|---|
| 518 | END MODULE sbcmod |
|---|
