New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

traadv.F90 in branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

Context Navigation

source: branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7351

Last change on this file since 7351 was 7351, checked in by emanuelaclementi, 8 years ago
ticket #1805 step 3: /2016/dev_INGV_UKMO_2016 aligned to the trunk at revision 7161
Property svn:keywords set to `Id`
File size: 16.4 KB

Rev	Line
[458]	1	MODULE traadv
	2	!!==============================================================================
	3	!! * MODULE traadv *
	4	!! Ocean active tracers: advection trend
	5	!!==============================================================================
[2528]	6	!! History : 2.0 ! 2005-11 (G. Madec) Original code
	7	!! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
[5836]	8	!! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation
	9	!! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes
	10	!! - ! 2014-12 (G. Madec) suppression of cross land advection option
[7350]	11	!! 3.6 ! 2015-06 (E. Clementi) Addition of Stokes drift in case of wave coupling
[458]	12	!!----------------------------------------------------------------------
[503]	13
	14	!!----------------------------------------------------------------------
[5836]	15	!! tra_adv : compute ocean tracer advection trend
	16	!! tra_adv_ctl : control the different options of advection scheme
[458]	17	!!----------------------------------------------------------------------
[5836]	18	USE oce ! ocean dynamics and active tracers
	19	USE dom_oce ! ocean space and time domain
	20	USE domvvl ! variable vertical scale factors
	21	USE traadv_cen ! centered scheme (tra_adv_cen routine)
	22	USE traadv_fct ! FCT scheme (tra_adv_fct routine)
	23	USE traadv_mus ! MUSCL scheme (tra_adv_mus routine)
	24	USE traadv_ubs ! UBS scheme (tra_adv_ubs routine)
	25	USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine)
	26	USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine)
	27	USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff.
	28	USE ldfslp ! Lateral diffusion: slopes of neutral surfaces
[5147]	29	!
[5836]	30	USE in_out_manager ! I/O manager
	31	USE iom ! I/O module
	32	USE prtctl ! Print control
	33	USE lib_mpp ! MPP library
	34	USE wrk_nemo ! Memory Allocation
	35	USE timing ! Timing
[7350]	36	USE sbcwave ! wave module
	37	USE sbc_oce ! surface boundary condition: ocean
	38	USE diaptr ! Poleward heat transport
[5836]	39
[458]	40	IMPLICIT NONE
	41	PRIVATE
	42
[2528]	43	PUBLIC tra_adv ! routine called by step module
	44	PUBLIC tra_adv_init ! routine called by opa module
[2715]	45
[5836]	46	! !!* Namelist namtra_adv *
	47	LOGICAL :: ln_traadv_cen ! centered scheme flag
	48	INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme
	49	LOGICAL :: ln_traadv_fct ! FCT scheme flag
	50	INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme
	51	INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping
	52	LOGICAL :: ln_traadv_mus ! MUSCL scheme flag
	53	LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths
	54	LOGICAL :: ln_traadv_ubs ! UBS scheme flag
	55	INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme
	56	LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag
[458]	57
[5836]	58	INTEGER :: nadv ! choice of the type of advection scheme
	59	!
	60	! ! associated indices:
	61	INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection
	62	INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme
	63	INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme
	64	INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping
	65	INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme
	66	INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme
	67	INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme
	68
[458]	69	!! * Substitutions
[503]	70	# include "vectopt_loop_substitute.h90"
[458]	71	!!----------------------------------------------------------------------
[5836]	72	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
[2528]	73	!! $Id$
	74	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
[458]	75	!!----------------------------------------------------------------------
	76	CONTAINS
	77
	78	SUBROUTINE tra_adv( kt )
	79	!!----------------------------------------------------------------------
	80	!! * ROUTINE tra_adv *
	81	!!
	82	!! ** Purpose : compute the ocean tracer advection trend.
	83	!!
[503]	84	!! ** Method : - Update (ua,va) with the advection term following nadv
[458]	85	!!----------------------------------------------------------------------
[503]	86	INTEGER, INTENT( in ) :: kt ! ocean time-step index
[2528]	87	!
	88	INTEGER :: jk ! dummy loop index
[3294]	89	REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
[458]	90	!!----------------------------------------------------------------------
[2715]	91	!
[3294]	92	IF( nn_timing == 1 ) CALL timing_start('tra_adv')
	93	!
[5836]	94	CALL wrk_alloc( jpi,jpj,jpk, zun, zvn, zwn )
	95	!
[2528]	96	! ! set time step
[7350]	97	zun(:,:,:) = 0.0
	98	zvn(:,:,:) = 0.0
	99	zwn(:,:,:) = 0.0
	100	!
[2528]	101	IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000
[7351]	102	r2dt = rdt ! = rdt (restarting with Euler time stepping)
[2528]	103	ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1
[7351]	104	r2dt = 2._wp * rdt ! = 2 rdt (leapfrog)
[458]	105	ENDIF
[2528]	106	!
[5836]	107	! !== effective transport ==!
[7350]	108	IF( ln_wave .AND. ln_sdw ) THEN
	109	DO jk = 1, jpkm1
	110	zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * &
	111	& ( un(:,:,jk) + usd3d(:,:,jk) ) ! eulerian transport + Stokes Drift
	112	zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * &
	113	& ( vn(:,:,jk) + vsd3d(:,:,jk) )
	114	zwn(:,:,jk) = e1e2t(:,:) * &
	115	& ( wn(:,:,jk) + wsd3d(:,:,jk) )
	116	END DO
	117	ELSE
	118	DO jk = 1, jpkm1
	119	zun(:,:,jk) = e2u (:,:) * fse3u(:,:,jk) * un(:,:,jk) ! eulerian transport only
	120	zvn(:,:,jk) = e1v (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
	121	zwn(:,:,jk) = e1e2t(:,:) * wn(:,:,jk)
	122	END DO
	123	ENDIF
[4292]	124	!
[5836]	125	IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections
[4292]	126	zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
	127	zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
	128	ENDIF
	129	!
[5836]	130	zun(:,:,jpk) = 0._wp ! no transport trough the bottom
	131	zvn(:,:,jpk) = 0._wp
	132	zwn(:,:,jpk) = 0._wp
[2528]	133	!
[5836]	134	IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) &
	135	& CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary)
[2528]	136	!
[5836]	137	IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary)
[5147]	138	!
[5836]	139	CALL iom_put( "uocetr_eff", zun ) ! output effective transport
[2561]	140	CALL iom_put( "vocetr_eff", zvn )
	141	CALL iom_put( "wocetr_eff", zwn )
[5147]	142	!
[5836]	143	!!gm ???
	144	IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF
	145	!!gm ???
[5147]	146	!
[5836]	147	SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==!
[503]	148	!
[5836]	149	CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order
	150	CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
	151	CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order
[7351]	152	CALL tra_adv_fct ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
[5836]	153	CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting
[7351]	154	CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts )
[5836]	155	CASE ( np_MUS ) ! MUSCL
[7351]	156	CALL tra_adv_mus ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups )
[5836]	157	CASE ( np_UBS ) ! UBS
[7351]	158	CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v )
[5836]	159	CASE ( np_QCK ) ! QUICKEST
[7351]	160	CALL tra_adv_qck ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )
[5836]	161	!
[458]	162	END SELECT
[2528]	163	!
[7351]	164	! ! print mean trends (used for debugging)
[2528]	165	IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, &
	166	& tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' )
[503]	167	!
[4245]	168	IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' )
[2715]	169	!
[5836]	170	CALL wrk_dealloc( jpi,jpj,jpk, zun, zvn, zwn )
[3294]	171	!
[458]	172	END SUBROUTINE tra_adv
	173
	174
[2528]	175	SUBROUTINE tra_adv_init
[458]	176	!!---------------------------------------------------------------------
[2528]	177	!! * ROUTINE tra_adv_init *
[458]	178	!!
[503]	179	!! ** Purpose : Control the consistency between namelist options for
	180	!! tracer advection schemes and set nadv
[458]	181	!!----------------------------------------------------------------------
[5836]	182	INTEGER :: ioptio, ios ! Local integers
	183	!
	184	NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN
	185	& ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT
	186	& ln_traadv_mus, ln_mus_ups, & ! MUSCL
	187	& ln_traadv_ubs, nn_ubs_v, & ! UBS
	188	& ln_traadv_qck ! QCK
[458]	189	!!----------------------------------------------------------------------
[5836]	190	!
	191	! !== Namelist ==!
	192	REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme
[4147]	193	READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
[7351]	194	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
[5836]	195	!
	196	REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
[4147]	197	READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
[7351]	198	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
	199	IF(lwm) WRITE( numond, namtra_adv )
	200	!
[5836]	201	IF(lwp) THEN ! Namelist print
[458]	202	WRITE(numout,*)
[2528]	203	WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
[458]	204	WRITE(numout,*) '~~~~~~~~~~~'
[1601]	205	WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers'
[5836]	206	WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen
	207	WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h
	208	WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v
	209	WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct
	210	WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h
	211	WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v
	212	WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts
	213	WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus
	214	WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups
	215	WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs
	216	WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v
	217	WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck
[2528]	218	ENDIF
[7351]	219	!
[5836]	220	ioptio = 0 !== Parameter control ==!
	221	IF( ln_traadv_cen ) ioptio = ioptio + 1
	222	IF( ln_traadv_fct ) ioptio = ioptio + 1
	223	IF( ln_traadv_mus ) ioptio = ioptio + 1
	224	IF( ln_traadv_ubs ) ioptio = ioptio + 1
	225	IF( ln_traadv_qck ) ioptio = ioptio + 1
	226	!
	227	IF( ioptio == 0 ) THEN
	228	nadv = np_NO_adv
	229	CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
	230	ENDIF
[7351]	231	IF( ioptio /= 1 ) CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
[5836]	232	!
	233	IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered
	234	.AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN
	235	CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
	236	ENDIF
	237	IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT
	238	.AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN
	239	CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
	240	ENDIF
	241	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
	242	IF( nn_fct_h == 4 ) THEN
	243	nn_fct_h = 2
	244	CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
	245	ENDIF
[7351]	246	IF( .NOT.ln_linssh ) THEN
[5836]	247	CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
	248	ENDIF
	249	IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
	250	ENDIF
	251	IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS
	252	CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
	253	ENDIF
	254	IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
	255	CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
	256	ENDIF
	257	IF( ln_isfcav ) THEN ! ice-shelf cavities
[7351]	258	IF( ln_traadv_cen .AND. nn_cen_v == 4 .OR. & ! NO 4th order with ISF
	259	& ln_traadv_fct .AND. nn_fct_v == 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
[5836]	260	ENDIF
	261	!
	262	! !== used advection scheme ==!
	263	! ! set nadv
	264	IF( ln_traadv_cen ) nadv = np_CEN
	265	IF( ln_traadv_fct ) nadv = np_FCT
	266	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts
	267	IF( ln_traadv_mus ) nadv = np_MUS
	268	IF( ln_traadv_ubs ) nadv = np_UBS
	269	IF( ln_traadv_qck ) nadv = np_QCK
[7351]	270	!
[5836]	271	IF(lwp) THEN ! Print the choice
[503]	272	WRITE(numout,*)
[7351]	273	SELECT CASE ( nadv )
	274	CASE( np_NO_adv ) ; WRITE(numout,*) ' NO T-S advection'
	275	CASE( np_CEN ) ; WRITE(numout,*) ' CEN scheme is used. Horizontal order: ', nn_cen_h, &
	276	& ' Vertical order: ', nn_cen_v
	277	CASE( np_FCT ) ; WRITE(numout,*) ' FCT scheme is used. Horizontal order: ', nn_fct_h, &
	278	& ' Vertical order: ', nn_fct_v
	279	CASE( np_FCT_zts ) ; WRITE(numout,*) ' use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
	280	CASE( np_MUS ) ; WRITE(numout,*) ' MUSCL scheme is used'
	281	CASE( np_UBS ) ; WRITE(numout,*) ' UBS scheme is used'
	282	CASE( np_QCK ) ; WRITE(numout,*) ' QUICKEST scheme is used'
	283	END SELECT
[458]	284	ENDIF
[503]	285	!
[5836]	286	CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==!
[4245]	287	!
[2528]	288	END SUBROUTINE tra_adv_init
[458]	289
	290	!!======================================================================
	291	END MODULE traadv

Note: See TracBrowser for help on using the repository browser.

Download in other formats: