New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2016/dev_merge_2016/NEMOGCM/NEMO/OFF_SRC – NEMO

Context Navigation

source: branches/2016/dev_merge_2016/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 7421

Last change on this file since 7421 was 7421, checked in by flavoni, 7 years ago
#1811 merge dev_CNRS_MERATOR_2016 with dev_merge_2016 branch
Property svn:keywords set to `Id`
File size: 31.6 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! nemo_gcm : off-line: solve ocean tracer only
13	!! nemo_init : initialization of the nemo model
14	!! nemo_ctl : initialisation of algorithm flag
15	!! nemo_closefile : close remaining files
16	!!----------------------------------------------------------------------
17	USE dom_oce ! ocean space domain variables
18	USE oce ! dynamics and tracers variables
19	USE c1d ! 1D configuration
20	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
21	USE usrdef_nam ! user defined configuration
22	USE eosbn2 ! equation of state (eos bn2 routine)
23	! ! ocean physics
24	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
25	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
26	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
27	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
28	USE traldf ! lateral physics (tra_ldf_init routine)
29	USE zdfini ! vertical physics: initialization
30	USE sbcmod ! surface boundary condition (sbc_init routine)
31	USE phycst ! physical constant (par_cst routine)
32	USE dtadyn ! Lecture and Interpolation of the dynamical fields
33	USE trcini ! Initilization of the passive tracers
34	USE daymod ! calendar (day routine)
35	USE trcstp ! passive tracer time-stepping (trc_stp routine)
36	USE dtadyn ! Lecture and interpolation of the dynamical fields
37	! ! Passive tracers needs
38	USE trc ! passive tracer : variables
39	USE trcnam ! passive tracer : namelist
40	USE trcrst ! passive tracer restart
41	USE diaptr ! Need to initialise this as some variables are used in if statements later
42	USE sbc_oce , ONLY : ln_rnf
43	USE sbcrnf ! surface boundary condition : runoffs
44	! ! I/O & MPP
45	USE iom ! I/O library
46	USE in_out_manager ! I/O manager
47	USE mppini ! shared/distributed memory setting (mpp_init routine)
48	USE lib_mpp ! distributed memory computing
49	#if defined key_iomput
50	USE xios
51	#endif
52	USE prtctl ! Print control (prt_ctl_init routine)
53	USE timing ! Timing
54	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
55	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
56
57
58
59	IMPLICIT NONE
60	PRIVATE
61
62	PUBLIC nemo_gcm ! called by nemo.F90
63
64	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
65
66	!!----------------------------------------------------------------------
67	!! NEMO/OFF 3.3 , NEMO Consortium (2010)
68	!! $Id$
69	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
70	!!----------------------------------------------------------------------
71	CONTAINS
72
73	SUBROUTINE nemo_gcm
74	!!----------------------------------------------------------------------
75	!! * ROUTINE nemo_gcm *
76	!!
77	!! ** Purpose : nemo solves the primitive equations on an orthogonal
78	!! curvilinear mesh on the sphere.
79	!!
80	!! ** Method : - model general initialization
81	!! - launch the time-stepping (dta_dyn and trc_stp)
82	!! - finalize the run by closing files and communications
83	!!
84	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
85	!! Madec, 2008, internal report, IPSL.
86	!!----------------------------------------------------------------------
87	INTEGER :: istp, indic ! time step index
88	!!----------------------------------------------------------------------
89
90	CALL nemo_init ! Initializations
91
92	! check that all process are still there... If some process have an error,
93	! they will never enter in step and other processes will wait until the end of the cpu time!
94	IF( lk_mpp ) CALL mpp_max( nstop )
95
96	! !-----------------------!
97	! !== time stepping ==!
98	! !-----------------------!
99	istp = nit000
100	!
101	! Initialize arrays of runoffs structures and read data from the namelist
102	IF ( ln_rnf ) CALL sbc_rnf(istp)
103	!
104	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
105	!
106	DO WHILE ( istp <= nitend .AND. nstop == 0 ) ! time stepping
107	!
108	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
109	CALL iom_setkt ( istp - nit000 + 1, "nemo" ) ! say to iom that we are at time step kstp
110	CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields
111	IF( .NOT.ln_linssh ) CALL dta_dyn_swp( istp ) ! swap of sea surface height and vertical scale factors
112
113	CALL trc_stp ( istp ) ! time-stepping
114	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
115	istp = istp + 1
116	IF( lk_mpp ) CALL mpp_max( nstop )
117	END DO
118	#if defined key_iomput
119	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
120	#endif
121
122	! !------------------------!
123	! !== finalize the run ==!
124	! !------------------------!
125	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
126
127	IF( nstop /= 0 .AND. lwp ) THEN ! error print
128	WRITE(numout,cform_err)
129	WRITE(numout,*) nstop, ' error have been found'
130	ENDIF
131	!
132	IF( nn_timing == 1 ) CALL timing_finalize
133	!
134	CALL nemo_closefile
135	!
136	# if defined key_iomput
137	CALL xios_finalize ! end mpp communications
138	# else
139	IF( lk_mpp ) CALL mppstop ! end mpp communications
140	# endif
141	!
142	END SUBROUTINE nemo_gcm
143
144
145	SUBROUTINE nemo_init
146	!!----------------------------------------------------------------------
147	!! * ROUTINE nemo_init *
148	!!
149	!! ** Purpose : initialization of the nemo model in off-line mode
150	!!----------------------------------------------------------------------
151	INTEGER :: ji ! dummy loop indices
152	INTEGER :: ilocal_comm ! local integer
153	INTEGER :: ios, inum
154	REAL(wp) :: ziglo, zjglo, zkglo, zperio ! local scalars
155	CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam
156	!!
157	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
158	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
159	& nn_timing, nn_diacfl
160
161	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
162	!!----------------------------------------------------------------------
163	cltxt = ''
164	cltxt2 = ''
165	clnam = ''
166	cxios_context = 'nemo'
167	!
168	! ! Open reference namelist and configuration namelist files
169	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
170	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
171	!
172	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
173	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
174	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
175
176	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
177	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
178	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
179
180	!
181	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
182	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
183	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
184
185	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
186	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
187	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
188
189
190	! !--------------------------!
191	! ! Set global domain size ! (control print return in cltxt2)
192	!
193	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
194	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
195	!
196	ELSE ! user-defined namelist
197	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
198	ENDIF
199	jpk = jpkglo
200	!
201	! !--------------------------------------------!
202	! ! set communicator & select the local node !
203	! ! NB: mynode also opens output.namelist.dyn !
204	! ! on unit number numond on first proc !
205	! !--------------------------------------------!
206	#if defined key_iomput
207	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
208	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection
209	#else
210	ilocal_comm = 0
211	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt)
212	#endif
213
214	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
215
216	lwm = (narea == 1) ! control of output namelists
217	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
218
219	IF(lwm) THEN
220	! write merged namelists from earlier to output namelist now that the
221	! file has been opened in call to mynode. nammpp has already been
222	! written in mynode (if lk_mpp_mpi)
223	WRITE( numond, namctl )
224	WRITE( numond, namcfg )
225	IF( .NOT.ln_read_cfg ) THEN
226	DO ji = 1, SIZE(clnam)
227	IF( TRIM(clnam (ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
228	END DO
229	ENDIF
230	ENDIF
231
232	! If dimensions of processor grid weren't specified in the namelist file
233	! then we calculate them here now that we have our communicator size
234	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
235	#if defined key_mpp_mpi
236	CALL nemo_partition(mppsize)
237	#else
238	jpni = 1
239	jpnj = 1
240	jpnij = jpni*jpnj
241	#endif
242	END IF
243
244	! Calculate domain dimensions given calculated jpni and jpnj
245	! This used to be done in par_oce.F90 when they were parameters rather
246	! than variables
247	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
248	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
249	jpim1 = jpi-1 ! inner domain indices
250	jpjm1 = jpj-1 ! " "
251	jpkm1 = jpk-1 ! " "
252	jpij = jpi*jpj ! jpi x j
253
254
255	IF(lwp) THEN ! open listing units
256	!
257	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
258	!
259	WRITE(numout,*)
260	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
261	WRITE(numout,*) ' NEMO team'
262	WRITE(numout,*) ' Ocean General Circulation Model'
263	WRITE(numout,*) ' version 3.6 (2015) '
264	WRITE(numout,*)
265	WRITE(numout,*)
266	DO ji = 1, SIZE(cltxt)
267	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
268	END DO
269	WRITE(numout,cform_aaa) ! Flag AAAAAAA
270	!
271	ENDIF
272
273	! Now we know the dimensions of the grid and numout has been set we can
274	! allocate arrays
275	CALL nemo_alloc()
276
277	! !--------------------------------!
278	! ! Model general initialization !
279	! !--------------------------------!
280
281	CALL nemo_ctl ! Control prints & Benchmark
282
283	! ! Domain decomposition
284	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
285	ELSE ; CALL mpp_init2 ! eliminate land processors
286	ENDIF
287	!
288	IF( nn_timing == 1 ) CALL timing_init
289	!
290
291	! ! General initialization
292	IF( nn_timing == 1 ) CALL timing_start( 'nemo_init')
293	!
294	CALL phy_cst ! Physical constants
295	CALL eos_init ! Equation of state
296	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
297
298	CALL dom_init ! Domain
299
300	CALL istate_init ! ocean initial state (Dynamics and tracers)
301
302	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
303
304	IF( ln_ctl ) CALL prt_ctl_init ! Print control
305
306	CALL sbc_init ! Forcings : surface module
307
308	CALL ldf_tra_init ! Lateral ocean tracer physics
309	CALL ldf_eiv_init ! Eddy induced velocity param
310	CALL tra_ldf_init ! lateral mixing
311	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
312
313	CALL tra_qsr_init ! penetrative solar radiation qsr
314	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
315
316	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
317	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
318	CALL dta_dyn_init ! Initialization for the dynamics
319
320	CALL trc_init ! Passive tracers initialization
321	CALL dia_ptr_init ! Initialise diaptr as some variables are used
322	! ! in various advection and diffusion routines
323	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
324	!
325	IF( nn_timing == 1 ) CALL timing_stop( 'nemo_init')
326	!
327	END SUBROUTINE nemo_init
328
329
330	SUBROUTINE nemo_ctl
331	!!----------------------------------------------------------------------
332	!! * ROUTINE nemo_ctl *
333	!!
334	!! ** Purpose : control print setting
335	!!
336	!! ** Method : - print namctl information and check some consistencies
337	!!----------------------------------------------------------------------
338	!
339	IF(lwp) THEN ! control print
340	WRITE(numout,*)
341	WRITE(numout,*) 'nemo_ctl: Control prints'
342	WRITE(numout,*) '~~~~~~~ '
343	WRITE(numout,*) ' Namelist namctl'
344	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
345	WRITE(numout,*) ' level of print nn_print = ', nn_print
346	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
347	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
348	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
349	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
350	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
351	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
352	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
353	ENDIF
354	!
355	nprint = nn_print ! convert DOCTOR namelist names into OLD names
356	nictls = nn_ictls
357	nictle = nn_ictle
358	njctls = nn_jctls
359	njctle = nn_jctle
360	isplt = nn_isplt
361	jsplt = nn_jsplt
362
363
364	IF(lwp) THEN ! control print
365	WRITE(numout,*)
366	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
367	WRITE(numout,*) '~~~~~~~ '
368	WRITE(numout,*) ' Namelist namcfg'
369	WRITE(numout,*) ' read domain configuration files ln_read_cfg = ', ln_read_cfg
370	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
371	WRITE(numout,*) ' write configuration definition files ln_write_cfg = ', ln_write_cfg
372	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
373	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
374	ENDIF
375
376	! ! Parameter control
377	!
378	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
379	IF( lk_mpp .AND. jpnij > 1 ) THEN
380	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
381	ELSE
382	IF( isplt == 1 .AND. jsplt == 1 ) THEN
383	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
384	& ' - the print control will be done over the whole domain' )
385	ENDIF
386	ijsplt = isplt * jsplt ! total number of processors ijsplt
387	ENDIF
388	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
389	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
390	!
391	! ! indices used for the SUM control
392	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
393	lsp_area = .FALSE.
394	ELSE ! print control done over a specific area
395	lsp_area = .TRUE.
396	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
397	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
398	nictls = 1
399	ENDIF
400	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
401	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
402	nictle = jpiglo
403	ENDIF
404	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
405	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
406	njctls = 1
407	ENDIF
408	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
409	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
410	njctle = jpjglo
411	ENDIF
412	ENDIF
413	ENDIF
414	!
415	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
416	& 'f2003 standard. ' , &
417	& 'Compile with key_nosignedzero enabled' )
418	!
419	END SUBROUTINE nemo_ctl
420
421
422	SUBROUTINE nemo_closefile
423	!!----------------------------------------------------------------------
424	!! * ROUTINE nemo_closefile *
425	!!
426	!! ** Purpose : Close the files
427	!!----------------------------------------------------------------------
428	!
429	IF ( lk_mpp ) CALL mppsync
430	!
431	CALL iom_close ! close all input/output files managed by iom_*
432	!
433	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
434	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
435	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
436	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
437	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
438
439	numout = 6 ! redefine numout in case it is used after this point...
440	!
441	END SUBROUTINE nemo_closefile
442
443
444	SUBROUTINE nemo_alloc
445	!!----------------------------------------------------------------------
446	!! * ROUTINE nemo_alloc *
447	!!
448	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
449	!!
450	!! ** Method :
451	!!----------------------------------------------------------------------
452	USE diawri, ONLY: dia_wri_alloc
453	USE dom_oce, ONLY: dom_oce_alloc
454	USE zdf_oce, ONLY: zdf_oce_alloc
455	USE trc_oce, ONLY: trc_oce_alloc
456	!
457	INTEGER :: ierr
458	!!----------------------------------------------------------------------
459	!
460	ierr = oce_alloc () ! ocean
461	ierr = ierr + dia_wri_alloc ()
462	ierr = ierr + dom_oce_alloc () ! ocean domain
463	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
464	!
465	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
466	!
467	IF( lk_mpp ) CALL mpp_sum( ierr )
468	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
469	!
470	END SUBROUTINE nemo_alloc
471
472
473	SUBROUTINE nemo_partition( num_pes )
474	!!----------------------------------------------------------------------
475	!! * ROUTINE nemo_partition *
476	!!
477	!! ** Purpose :
478	!!
479	!! ** Method :
480	!!----------------------------------------------------------------------
481	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
482	!
483	INTEGER, PARAMETER :: nfactmax = 20
484	INTEGER :: nfact ! The no. of factors returned
485	INTEGER :: ierr ! Error flag
486	INTEGER :: ji
487	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
488	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
489	!!----------------------------------------------------------------------
490
491	ierr = 0
492
493	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
494
495	IF( nfact <= 1 ) THEN
496	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
497	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
498	jpnj = 1
499	jpni = num_pes
500	ELSE
501	! Search through factors for the pair that are closest in value
502	mindiff = 1000000
503	imin = 1
504	DO ji = 1, nfact-1, 2
505	idiff = ABS( ifact(ji) - ifact(ji+1) )
506	IF( idiff < mindiff ) THEN
507	mindiff = idiff
508	imin = ji
509	ENDIF
510	END DO
511	jpnj = ifact(imin)
512	jpni = ifact(imin + 1)
513	ENDIF
514	!
515	jpnij = jpni*jpnj
516	!
517	END SUBROUTINE nemo_partition
518
519
520	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
521	!!----------------------------------------------------------------------
522	!! * ROUTINE factorise *
523	!!
524	!! ** Purpose : return the prime factors of n.
525	!! knfax factors are returned in array kfax which is of
526	!! maximum dimension kmaxfax.
527	!! ** Method :
528	!!----------------------------------------------------------------------
529	INTEGER , INTENT(in ) :: kn, kmaxfax
530	INTEGER , INTENT( out) :: kerr, knfax
531	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
532	!
533	INTEGER :: ifac, jl, inu
534	INTEGER, PARAMETER :: ntest = 14
535	INTEGER :: ilfax(ntest)
536	!
537	! lfax contains the set of allowed factors.
538	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
539	& 128, 64, 32, 16, 8, 4, 2 /
540	!!----------------------------------------------------------------------
541
542	! Clear the error flag and initialise output vars
543	kerr = 0
544	kfax = 1
545	knfax = 0
546
547	! Find the factors of n.
548	IF( kn == 1 ) GOTO 20
549
550	! nu holds the unfactorised part of the number.
551	! knfax holds the number of factors found.
552	! l points to the allowed factor list.
553	! ifac holds the current factor.
554
555	inu = kn
556	knfax = 0
557
558	DO jl = ntest, 1, -1
559	!
560	ifac = ilfax(jl)
561	IF( ifac > inu ) CYCLE
562
563	! Test whether the factor will divide.
564
565	IF( MOD(inu,ifac) == 0 ) THEN
566	!
567	knfax = knfax + 1 ! Add the factor to the list
568	IF( knfax > kmaxfax ) THEN
569	kerr = 6
570	write (,) 'FACTOR: insufficient space in factor array ', knfax
571	return
572	ENDIF
573	kfax(knfax) = ifac
574	! Store the other factor that goes with this one
575	knfax = knfax + 1
576	kfax(knfax) = inu / ifac
577	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
578	ENDIF
579	!
580	END DO
581
582	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
583	!
584	END SUBROUTINE factorise
585
586	#if defined key_mpp_mpi
587	SUBROUTINE nemo_northcomms
588	!!======================================================================
589	!! * ROUTINE nemo_northcomms *
590	!! nemo_northcomms : Setup for north fold exchanges with explicit
591	!! point-to-point messaging
592	!!=====================================================================
593	!!----------------------------------------------------------------------
594	!!
595	!! ** Purpose : Initialization of the northern neighbours lists.
596	!!----------------------------------------------------------------------
597	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
598	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S.
599	!Mocavero, CMCC)
600	!!----------------------------------------------------------------------
601
602	INTEGER :: sxM, dxM, sxT, dxT, jn
603	INTEGER :: njmppmax
604
605	njmppmax = MAXVAL( njmppt )
606
607	!initializes the north-fold communication variables
608	isendto(:) = 0
609	nsndto = 0
610
611	!if I am a process in the north
612	IF ( njmpp == njmppmax ) THEN
613	!sxM is the first point (in the global domain) needed to compute the
614	!north-fold for the current process
615	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
616	!dxM is the last point (in the global domain) needed to compute the
617	!north-fold for the current process
618	dxM = jpiglo - nimppt(narea) + 2
619
620	!loop over the other north-fold processes to find the processes
621	!managing the points belonging to the sxT-dxT range
622
623	DO jn = 1, jpni
624	!sxT is the first point (in the global domain) of the jn
625	!process
626	sxT = nfiimpp(jn, jpnj)
627	!dxT is the last point (in the global domain) of the jn
628	!process
629	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
630	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
631	nsndto = nsndto + 1
632	isendto(nsndto) = jn
633	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
634	nsndto = nsndto + 1
635	isendto(nsndto) = jn
636	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
637	nsndto = nsndto + 1
638	isendto(nsndto) = jn
639	END IF
640	END DO
641	nfsloop = 1
642	nfeloop = nlci
643	DO jn = 2,jpni-1
644	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
645	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
646	nfsloop = nldi
647	ENDIF
648	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
649	nfeloop = nlei
650	ENDIF
651	ENDIF
652	END DO
653
654	ENDIF
655	l_north_nogather = .TRUE.
656	END SUBROUTINE nemo_northcomms
657	#else
658	SUBROUTINE nemo_northcomms ! Dummy routine
659	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
660	END SUBROUTINE nemo_northcomms
661	#endif
662
663	SUBROUTINE istate_init
664	!!----------------------------------------------------------------------
665	!! * ROUTINE istate_init *
666	!!
667	!! ** Purpose : Initialization to zero of the dynamics and tracers.
668	!!----------------------------------------------------------------------
669	!
670	! now fields ! after fields !
671	un (:,:,:) = 0._wp ; ua(:,:,:) = 0._wp !
672	vn (:,:,:) = 0._wp ; va(:,:,:) = 0._wp !
673	wn (:,:,:) = 0._wp ! !
674	hdivn(:,:,:) = 0._wp ! !
675	tsn (:,:,:,:) = 0._wp ! !
676	!
677	rhd (:,:,:) = 0.e0
678	rhop (:,:,:) = 0.e0
679	rn2 (:,:,:) = 0.e0
680	!
681	END SUBROUTINE istate_init
682
683	SUBROUTINE stp_ctl( kt, kindic )
684	!!----------------------------------------------------------------------
685	!! * ROUTINE stp_ctl *
686	!!
687	!! ** Purpose : Control the run
688	!!
689	!! ** Method : - Save the time step in numstp
690	!!
691	!! ** Actions : 'time.step' file containing the last ocean time-step
692	!!----------------------------------------------------------------------
693	INTEGER, INTENT(in ) :: kt ! ocean time-step index
694	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
695	!!----------------------------------------------------------------------
696	!
697	IF( kt == nit000 .AND. lwp ) THEN
698	WRITE(numout,*)
699	WRITE(numout,*) 'stp_ctl : time-stepping control'
700	WRITE(numout,*) '~~~~~~~'
701	! open time.step file
702	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
703	ENDIF
704	!
705	IF(lwp) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
706	IF(lwp) REWIND( numstp ) ! --------------------------
707	!
708	END SUBROUTINE stp_ctl
709	!!======================================================================
710	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: