| 1 | MODULE dommsk |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE dommsk *** |
|---|
| 4 | !! Ocean initialization : domain land/sea mask |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1987-07 (G. Madec) Original code |
|---|
| 7 | !! 6.0 ! 1993-03 (M. Guyon) symetrical conditions (M. Guyon) |
|---|
| 8 | !! 7.0 ! 1996-01 (G. Madec) suppression of common work arrays |
|---|
| 9 | !! - ! 1996-05 (G. Madec) mask computed from tmask |
|---|
| 10 | !! 8.0 ! 1997-02 (G. Madec) mesh information put in domhgr.F |
|---|
| 11 | !! 8.1 ! 1997-07 (G. Madec) modification of kbat and fmask |
|---|
| 12 | !! - ! 1998-05 (G. Roullet) free surface |
|---|
| 13 | !! 8.2 ! 2000-03 (G. Madec) no slip accurate |
|---|
| 14 | !! - ! 2001-09 (J.-M. Molines) Open boundaries |
|---|
| 15 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and module |
|---|
| 16 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 17 | !! 3.2 ! 2009-07 (R. Benshila) Suppression of rigid-lid option |
|---|
| 18 | !! 3.6 ! 2015-05 (P. Mathiot) ISF: add wmask,wumask and wvmask |
|---|
| 19 | !! 4.0 ! 2016-06 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | !! dom_msk : compute land/ocean mask |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE oce ! ocean dynamics and tracers |
|---|
| 26 | USE dom_oce ! ocean space and time domain |
|---|
| 27 | USE usrdef_fmask ! user defined fmask |
|---|
| 28 | USE bdy_oce |
|---|
| 29 | USE in_out_manager ! I/O manager |
|---|
| 30 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 31 | USE lib_mpp ! Massively Parallel Processing library |
|---|
| 32 | USE wrk_nemo ! Memory allocation |
|---|
| 33 | USE timing ! Timing |
|---|
| 34 | |
|---|
| 35 | IMPLICIT NONE |
|---|
| 36 | PRIVATE |
|---|
| 37 | |
|---|
| 38 | PUBLIC dom_msk ! routine called by inidom.F90 |
|---|
| 39 | |
|---|
| 40 | ! !!* Namelist namlbc : lateral boundary condition * |
|---|
| 41 | REAL(wp) :: rn_shlat ! type of lateral boundary condition on velocity |
|---|
| 42 | LOGICAL, PUBLIC :: ln_vorlat ! consistency of vorticity boundary condition |
|---|
| 43 | ! with analytical eqs. |
|---|
| 44 | |
|---|
| 45 | !! * Substitutions |
|---|
| 46 | # include "vectopt_loop_substitute.h90" |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | !! NEMO/OPA 3.2 , LODYC-IPSL (2009) |
|---|
| 49 | !! $Id$ |
|---|
| 50 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | CONTAINS |
|---|
| 53 | |
|---|
| 54 | SUBROUTINE dom_msk( k_top, k_bot ) |
|---|
| 55 | !!--------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE dom_msk *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Compute land/ocean mask arrays at tracer points, hori- |
|---|
| 59 | !! zontal velocity points (u & v), vorticity points (f) points. |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : The ocean/land mask at t-point is deduced from ko_top |
|---|
| 62 | !! and ko_bot, the indices of the fist and last ocean t-levels which |
|---|
| 63 | !! are either defined in usrdef_zgr or read in zgr_read. |
|---|
| 64 | !! The velocity masks (umask, vmask, wmask, wumask, wvmask) |
|---|
| 65 | !! are deduced from a product of the two neighboring tmask. |
|---|
| 66 | !! The vorticity mask (fmask) is deduced from tmask taking |
|---|
| 67 | !! into account the choice of lateral boundary condition (rn_shlat) : |
|---|
| 68 | !! rn_shlat = 0, free slip (no shear along the coast) |
|---|
| 69 | !! rn_shlat = 2, no slip (specified zero velocity at the coast) |
|---|
| 70 | !! 0 < rn_shlat < 2, partial slip | non-linear velocity profile |
|---|
| 71 | !! 2 < rn_shlat, strong slip | in the lateral boundary layer |
|---|
| 72 | !! |
|---|
| 73 | !! tmask_i : interior ocean mask at t-point, i.e. excluding duplicated |
|---|
| 74 | !! rows/lines due to cyclic or North Fold boundaries as well |
|---|
| 75 | !! as MPP halos. |
|---|
| 76 | !! tmask_h : halo mask at t-point, i.e. excluding duplicated rows/lines |
|---|
| 77 | !! due to cyclic or North Fold boundaries as well as MPP halos. |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : tmask, umask, vmask, wmask, wumask, wvmask : land/ocean mask |
|---|
| 80 | !! at t-, u-, v- w, wu-, and wv-points (=0. or 1.) |
|---|
| 81 | !! fmask : land/ocean mask at f-point (=0., or =1., or |
|---|
| 82 | !! =rn_shlat along lateral boundaries) |
|---|
| 83 | !! tmask_i : interior ocean mask |
|---|
| 84 | !! tmask_h : halo mask |
|---|
| 85 | !! ssmask , ssumask, ssvmask, ssfmask : 2D ocean mask |
|---|
| 86 | !!---------------------------------------------------------------------- |
|---|
| 87 | INTEGER, DIMENSION(:,:), INTENT(in) :: k_top, k_bot ! first and last ocean level |
|---|
| 88 | ! |
|---|
| 89 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 90 | INTEGER :: iif, iil ! local integers |
|---|
| 91 | INTEGER :: ijf, ijl ! - - |
|---|
| 92 | INTEGER :: iktop, ikbot ! - - |
|---|
| 93 | INTEGER :: ios, inum |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,:) :: zwf ! 2D workspace |
|---|
| 95 | !! |
|---|
| 96 | NAMELIST/namlbc/ rn_shlat, ln_vorlat |
|---|
| 97 | NAMELIST/nambdy/ ln_bdy ,nb_bdy, ln_coords_file, cn_coords_file, & |
|---|
| 98 | & ln_mask_file, cn_mask_file, cn_dyn2d, nn_dyn2d_dta, & |
|---|
| 99 | & cn_dyn3d, nn_dyn3d_dta, cn_tra, nn_tra_dta, & |
|---|
| 100 | & ln_tra_dmp, ln_dyn3d_dmp, rn_time_dmp, rn_time_dmp_out, & |
|---|
| 101 | & cn_ice_lim, nn_ice_lim_dta, & |
|---|
| 102 | & rn_ice_tem, rn_ice_sal, rn_ice_age, & |
|---|
| 103 | & ln_vol, nn_volctl, nn_rimwidth, nb_jpk_bdy |
|---|
| 104 | !!--------------------------------------------------------------------- |
|---|
| 105 | ! |
|---|
| 106 | IF( nn_timing == 1 ) CALL timing_start('dom_msk') |
|---|
| 107 | ! |
|---|
| 108 | REWIND( numnam_ref ) ! Namelist namlbc in reference namelist : Lateral momentum boundary condition |
|---|
| 109 | READ ( numnam_ref, namlbc, IOSTAT = ios, ERR = 901 ) |
|---|
| 110 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlbc in reference namelist', lwp ) |
|---|
| 111 | |
|---|
| 112 | REWIND( numnam_cfg ) ! Namelist namlbc in configuration namelist : Lateral momentum boundary condition |
|---|
| 113 | READ ( numnam_cfg, namlbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 114 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlbc in configuration namelist', lwp ) |
|---|
| 115 | IF(lwm) WRITE ( numond, namlbc ) |
|---|
| 116 | |
|---|
| 117 | IF(lwp) THEN ! control print |
|---|
| 118 | WRITE(numout,*) |
|---|
| 119 | WRITE(numout,*) 'dommsk : ocean mask ' |
|---|
| 120 | WRITE(numout,*) '~~~~~~' |
|---|
| 121 | WRITE(numout,*) ' Namelist namlbc' |
|---|
| 122 | WRITE(numout,*) ' lateral momentum boundary cond. rn_shlat = ',rn_shlat |
|---|
| 123 | WRITE(numout,*) ' consistency with analytical form ln_vorlat = ',ln_vorlat |
|---|
| 124 | ENDIF |
|---|
| 125 | |
|---|
| 126 | IF ( rn_shlat == 0. ) THEN ; IF(lwp) WRITE(numout,*) ' ocean lateral free-slip ' |
|---|
| 127 | ELSEIF ( rn_shlat == 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ocean lateral no-slip ' |
|---|
| 128 | ELSEIF ( 0. < rn_shlat .AND. rn_shlat < 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ocean lateral partial-slip ' |
|---|
| 129 | ELSEIF ( 2. < rn_shlat ) THEN ; IF(lwp) WRITE(numout,*) ' ocean lateral strong-slip ' |
|---|
| 130 | ELSE |
|---|
| 131 | WRITE(ctmp1,*) ' rn_shlat is negative = ', rn_shlat |
|---|
| 132 | CALL ctl_stop( ctmp1 ) |
|---|
| 133 | ENDIF |
|---|
| 134 | |
|---|
| 135 | |
|---|
| 136 | ! Ocean/land mask at t-point (computed from ko_top and ko_bot) |
|---|
| 137 | ! ---------------------------- |
|---|
| 138 | ! |
|---|
| 139 | tmask(:,:,:) = 0._wp |
|---|
| 140 | DO jj = 1, jpj |
|---|
| 141 | DO ji = 1, jpi |
|---|
| 142 | iktop = k_top(ji,jj) |
|---|
| 143 | ikbot = k_bot(ji,jj) |
|---|
| 144 | IF( iktop /= 0 ) THEN ! water in the column |
|---|
| 145 | tmask(ji,jj,iktop:ikbot ) = 1._wp |
|---|
| 146 | ENDIF |
|---|
| 147 | END DO |
|---|
| 148 | END DO |
|---|
| 149 | !SF add here lbc_lnk: bug not still understood : cause now domain configuration is read ! |
|---|
| 150 | !!gm I don't understand why... |
|---|
| 151 | CALL lbc_lnk( tmask , 'T', 1._wp ) ! Lateral boundary conditions |
|---|
| 152 | |
|---|
| 153 | ! Ocean/land mask at u-, v-, and f-points (computed from tmask) |
|---|
| 154 | ! ---------------------------------------- |
|---|
| 155 | ! NB: at this point, fmask is designed for free slip lateral boundary condition |
|---|
| 156 | DO jk = 1, jpk |
|---|
| 157 | DO jj = 1, jpjm1 |
|---|
| 158 | DO ji = 1, fs_jpim1 ! vector loop |
|---|
| 159 | umask(ji,jj,jk) = tmask(ji,jj ,jk) * tmask(ji+1,jj ,jk) |
|---|
| 160 | vmask(ji,jj,jk) = tmask(ji,jj ,jk) * tmask(ji ,jj+1,jk) |
|---|
| 161 | END DO |
|---|
| 162 | DO ji = 1, jpim1 ! NO vector opt. |
|---|
| 163 | fmask(ji,jj,jk) = tmask(ji,jj ,jk) * tmask(ji+1,jj ,jk) & |
|---|
| 164 | & * tmask(ji,jj+1,jk) * tmask(ji+1,jj+1,jk) |
|---|
| 165 | END DO |
|---|
| 166 | END DO |
|---|
| 167 | END DO |
|---|
| 168 | CALL lbc_lnk( umask , 'U', 1._wp ) ! Lateral boundary conditions |
|---|
| 169 | CALL lbc_lnk( vmask , 'V', 1._wp ) |
|---|
| 170 | CALL lbc_lnk( fmask , 'F', 1._wp ) |
|---|
| 171 | |
|---|
| 172 | |
|---|
| 173 | ! Ocean/land mask at wu-, wv- and w points (computed from tmask) |
|---|
| 174 | !----------------------------------------- |
|---|
| 175 | wmask (:,:,1) = tmask(:,:,1) ! surface |
|---|
| 176 | wumask(:,:,1) = umask(:,:,1) |
|---|
| 177 | wvmask(:,:,1) = vmask(:,:,1) |
|---|
| 178 | DO jk = 2, jpk ! interior values |
|---|
| 179 | wmask (:,:,jk) = tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 180 | wumask(:,:,jk) = umask(:,:,jk) * umask(:,:,jk-1) |
|---|
| 181 | wvmask(:,:,jk) = vmask(:,:,jk) * vmask(:,:,jk-1) |
|---|
| 182 | END DO |
|---|
| 183 | |
|---|
| 184 | |
|---|
| 185 | ! Ocean/land column mask at t-, u-, and v-points (i.e. at least 1 wet cell in the vertical) |
|---|
| 186 | ! ---------------------------------------------- |
|---|
| 187 | ssmask (:,:) = MAXVAL( tmask(:,:,:), DIM=3 ) |
|---|
| 188 | ssumask(:,:) = MAXVAL( umask(:,:,:), DIM=3 ) |
|---|
| 189 | ssvmask(:,:) = MAXVAL( vmask(:,:,:), DIM=3 ) |
|---|
| 190 | |
|---|
| 191 | |
|---|
| 192 | ! Interior domain mask (used for global sum) |
|---|
| 193 | ! -------------------- |
|---|
| 194 | ! |
|---|
| 195 | iif = jpreci ; iil = nlci - jpreci + 1 |
|---|
| 196 | ijf = jprecj ; ijl = nlcj - jprecj + 1 |
|---|
| 197 | ! |
|---|
| 198 | ! ! halo mask : 0 on the halo and 1 elsewhere |
|---|
| 199 | tmask_h(:,:) = 1._wp |
|---|
| 200 | tmask_h( 1 :iif, : ) = 0._wp ! first columns |
|---|
| 201 | tmask_h(iil:jpi, : ) = 0._wp ! last columns (including mpp extra columns) |
|---|
| 202 | tmask_h( : , 1 :ijf) = 0._wp ! first rows |
|---|
| 203 | tmask_h( : ,ijl:jpj) = 0._wp ! last rows (including mpp extra rows) |
|---|
| 204 | ! |
|---|
| 205 | ! ! north fold mask |
|---|
| 206 | tpol(1:jpiglo) = 1._wp |
|---|
| 207 | fpol(1:jpiglo) = 1._wp |
|---|
| 208 | IF( jperio == 3 .OR. jperio == 4 ) THEN ! T-point pivot |
|---|
| 209 | tpol(jpiglo/2+1:jpiglo) = 0._wp |
|---|
| 210 | fpol( 1 :jpiglo) = 0._wp |
|---|
| 211 | IF( mjg(nlej) == jpjglo ) THEN ! only half of the nlcj-1 row for tmask_h |
|---|
| 212 | DO ji = iif+1, iil-1 |
|---|
| 213 | tmask_h(ji,nlej-1) = tmask_h(ji,nlej-1) * tpol(mig(ji)) |
|---|
| 214 | END DO |
|---|
| 215 | ENDIF |
|---|
| 216 | ENDIF |
|---|
| 217 | ! |
|---|
| 218 | IF( jperio == 5 .OR. jperio == 6 ) THEN ! F-point pivot |
|---|
| 219 | tpol( 1 :jpiglo) = 0._wp |
|---|
| 220 | fpol(jpiglo/2+1:jpiglo) = 0._wp |
|---|
| 221 | ENDIF |
|---|
| 222 | ! |
|---|
| 223 | ! ! interior mask : 2D ocean mask x halo mask |
|---|
| 224 | tmask_i(:,:) = ssmask(:,:) * tmask_h(:,:) |
|---|
| 225 | |
|---|
| 226 | |
|---|
| 227 | ! Lateral boundary conditions on velocity (modify fmask) |
|---|
| 228 | ! --------------------------------------- |
|---|
| 229 | IF( rn_shlat /= 0 ) THEN ! Not free-slip lateral boundary condition |
|---|
| 230 | ! |
|---|
| 231 | CALL wrk_alloc( jpi,jpj, zwf ) |
|---|
| 232 | ! |
|---|
| 233 | DO jk = 1, jpk |
|---|
| 234 | zwf(:,:) = fmask(:,:,jk) |
|---|
| 235 | DO jj = 2, jpjm1 |
|---|
| 236 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 237 | IF( fmask(ji,jj,jk) == 0._wp ) THEN |
|---|
| 238 | fmask(ji,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1), & |
|---|
| 239 | & zwf(ji-1,jj), zwf(ji,jj-1) ) ) |
|---|
| 240 | ENDIF |
|---|
| 241 | END DO |
|---|
| 242 | END DO |
|---|
| 243 | DO jj = 2, jpjm1 |
|---|
| 244 | IF( fmask(1,jj,jk) == 0._wp ) THEN |
|---|
| 245 | fmask(1 ,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(2,jj), zwf(1,jj+1), zwf(1,jj-1) ) ) |
|---|
| 246 | ENDIF |
|---|
| 247 | IF( fmask(jpi,jj,jk) == 0._wp ) THEN |
|---|
| 248 | fmask(jpi,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(jpi,jj+1), zwf(jpim1,jj), zwf(jpi,jj-1) ) ) |
|---|
| 249 | ENDIF |
|---|
| 250 | END DO |
|---|
| 251 | DO ji = 2, jpim1 |
|---|
| 252 | IF( fmask(ji,1,jk) == 0._wp ) THEN |
|---|
| 253 | fmask(ji, 1 ,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,1), zwf(ji,2), zwf(ji-1,1) ) ) |
|---|
| 254 | ENDIF |
|---|
| 255 | IF( fmask(ji,jpj,jk) == 0._wp ) THEN |
|---|
| 256 | fmask(ji,jpj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jpj), zwf(ji-1,jpj), zwf(ji,jpjm1) ) ) |
|---|
| 257 | ENDIF |
|---|
| 258 | END DO |
|---|
| 259 | END DO |
|---|
| 260 | ! |
|---|
| 261 | CALL wrk_dealloc( jpi,jpj, zwf ) |
|---|
| 262 | ! |
|---|
| 263 | CALL lbc_lnk( fmask, 'F', 1._wp ) ! Lateral boundary conditions on fmask |
|---|
| 264 | ! |
|---|
| 265 | ! CAUTION : The fmask may be further modified in dyn_vor_init ( dynvor.F90 ) depending on ln_vorlat |
|---|
| 266 | ! |
|---|
| 267 | ENDIF |
|---|
| 268 | |
|---|
| 269 | ! User defined alteration of fmask (use to reduce ocean transport in specified straits) |
|---|
| 270 | ! -------------------------------- |
|---|
| 271 | ! |
|---|
| 272 | CALL usr_def_fmask( cn_cfg, nn_cfg, fmask ) |
|---|
| 273 | ! |
|---|
| 274 | ! |
|---|
| 275 | IF( nn_timing == 1 ) CALL timing_stop('dom_msk') |
|---|
| 276 | ! |
|---|
| 277 | END SUBROUTINE dom_msk |
|---|
| 278 | |
|---|
| 279 | !!====================================================================== |
|---|
| 280 | END MODULE dommsk |
|---|
