New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2016/dev_r6393_NOC_WAD/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6393_NOC_WAD/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 7030

Last change on this file since 7030 was 7030, checked in by acc, 8 years ago

Branch dev_r6393_NOC_WAD. Added over-topping test case to WAD_TEST_CASES (jp_cfg=6). Also removed last references to redundant wduflt and wdvflt arrays
  • Property svn:keywords set to Id
File size: 70.5 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE wrk_nemo        ! Memory Allocation
47   USE timing          ! Timing
48   USE iom
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC   dyn_hpg        ! routine called by step module
54   PUBLIC   dyn_hpg_init   ! routine called by opa module
55
56   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
57   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
58   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
59   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
60   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
61   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
62   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
63
64   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
65
66   !! * Substitutions
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147      !
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164      ENDIF
165      !
166      IF( ln_hpg_djc )   &
167         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
168                           & currently disabled (bugs under investigation). Please select &
169                           & either  ln_hpg_sco or  ln_hpg_prj instead')
170      !
171      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )        &
172         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
173         &                 '   the standard jacobian formulation hpg_sco    or '    , &
174         &                 '   the pressure jacobian formulation hpg_prj'            )
175
176      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
177         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
178      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
179         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
180      !
181      !                               ! Set nhpg from ln_hpg_... flags
182      IF( ln_hpg_zco )   nhpg = 0
183      IF( ln_hpg_zps )   nhpg = 1
184      IF( ln_hpg_sco )   nhpg = 2
185      IF( ln_hpg_djc )   nhpg = 3
186      IF( ln_hpg_prj )   nhpg = 4
187      IF( ln_hpg_isf )   nhpg = 5
188      !
189      !                               ! Consistency check
190      ioptio = 0
191      IF( ln_hpg_zco )   ioptio = ioptio + 1
192      IF( ln_hpg_zps )   ioptio = ioptio + 1
193      IF( ln_hpg_sco )   ioptio = ioptio + 1
194      IF( ln_hpg_djc )   ioptio = ioptio + 1
195      IF( ln_hpg_prj )   ioptio = ioptio + 1
196      IF( ln_hpg_isf )   ioptio = ioptio + 1
197      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
198      !
199      ! initialisation of ice shelf load
200      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
201      IF (       ln_isfcav ) THEN
202         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
203         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
204         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
205         !
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
208         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
209
210         ! To use density and not density anomaly
211         znad=1._wp
212         
213         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
214         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
215
216         ! compute density of the water displaced by the ice shelf
217         DO jk = 1, jpk
218            CALL eos(ztstop(:,:,:),gdept_n(:,:,jk),zrhd(:,:,jk))
219         END DO
220     
221         ! compute rhd at the ice/oce interface (ice shelf side)
222         CALL eos(ztstop,risfdep,zrhdtop_isf)
223
224         ! Surface value + ice shelf gradient
225         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
226         ! divided by 2 later
227         ziceload = 0._wp
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230               ikt=mikt(ji,jj)
231               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
232               DO jk=2,ikt-1
233                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
234                     &                              * (1._wp - tmask(ji,jj,jk))
235               END DO
236               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
237                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
238            END DO
239         END DO
240         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
241
242         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
243         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
244         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
245      END IF
246      !
247   END SUBROUTINE dyn_hpg_init
248
249
250   SUBROUTINE hpg_zco( kt )
251      !!---------------------------------------------------------------------
252      !!                  ***  ROUTINE hpg_zco  ***
253      !!
254      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
255      !!      The now hydrostatic pressure gradient at a given level, jk,
256      !!      is computed by taking the vertical integral of the in-situ
257      !!      density gradient along the model level from the suface to that
258      !!      level:    zhpi = grav .....
259      !!                zhpj = grav .....
260      !!      add it to the general momentum trend (ua,va).
261      !!            ua = ua - 1/e1u * zhpi
262      !!            va = va - 1/e2v * zhpj
263      !!
264      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
265      !!----------------------------------------------------------------------
266      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
267      !
268      INTEGER  ::   ji, jj, jk       ! dummy loop indices
269      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
270      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
271      !!----------------------------------------------------------------------
272      !
273      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
274      !
275      IF( kt == nit000 ) THEN
276         IF(lwp) WRITE(numout,*)
277         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
278         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
279      ENDIF
280
281      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
282
283      ! Surface value
284      DO jj = 2, jpjm1
285         DO ji = fs_2, fs_jpim1   ! vector opt.
286            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
287            ! hydrostatic pressure gradient
288            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
289            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
290            ! add to the general momentum trend
291            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
292            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
293         END DO
294      END DO
295
296      !
297      ! interior value (2=<jk=<jpkm1)
298      DO jk = 2, jpkm1
299         DO jj = 2, jpjm1
300            DO ji = fs_2, fs_jpim1   ! vector opt.
301               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
302               ! hydrostatic pressure gradient
303               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
304                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
305                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
306
307               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
308                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
309                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
310               ! add to the general momentum trend
311               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
312               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
313            END DO
314         END DO
315      END DO
316      !
317      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
318      !
319   END SUBROUTINE hpg_zco
320
321
322   SUBROUTINE hpg_zps( kt )
323      !!---------------------------------------------------------------------
324      !!                 ***  ROUTINE hpg_zps  ***
325      !!
326      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
327      !!
328      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
329      !!----------------------------------------------------------------------
330      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
331      !!
332      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
333      INTEGER  ::   iku, ikv                         ! temporary integers
334      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
335      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
336      !!----------------------------------------------------------------------
337      !
338      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
339      !
340      IF( kt == nit000 ) THEN
341         IF(lwp) WRITE(numout,*)
342         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
343         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
344      ENDIF
345
346      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
347!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
348
349      ! Local constant initialization
350      zcoef0 = - grav * 0.5_wp
351
352      !  Surface value (also valid in partial step case)
353      DO jj = 2, jpjm1
354         DO ji = fs_2, fs_jpim1   ! vector opt.
355            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
356            ! hydrostatic pressure gradient
357            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
358            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
359            ! add to the general momentum trend
360            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
361            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
362         END DO
363      END DO
364
365      ! interior value (2=<jk=<jpkm1)
366      DO jk = 2, jpkm1
367         DO jj = 2, jpjm1
368            DO ji = fs_2, fs_jpim1   ! vector opt.
369               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
370               ! hydrostatic pressure gradient
371               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
372                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
373                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
374
375               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
376                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
377                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
378               ! add to the general momentum trend
379               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
380               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
381            END DO
382         END DO
383      END DO
384
385      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
386      DO jj = 2, jpjm1
387         DO ji = 2, jpim1
388            iku = mbku(ji,jj)
389            ikv = mbkv(ji,jj)
390            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
391            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
392            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
393               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
394               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
395                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
396               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
397            ENDIF
398            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
399               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
400               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
401                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
402               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
403            ENDIF
404         END DO
405      END DO
406      !
407      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
408      !
409   END SUBROUTINE hpg_zps
410
411
412   SUBROUTINE hpg_sco( kt )
413      !!---------------------------------------------------------------------
414      !!                  ***  ROUTINE hpg_sco  ***
415      !!
416      !! ** Method  :   s-coordinate case. Jacobian scheme.
417      !!      The now hydrostatic pressure gradient at a given level, jk,
418      !!      is computed by taking the vertical integral of the in-situ
419      !!      density gradient along the model level from the suface to that
420      !!      level. s-coordinates (ln_sco): a corrective term is added
421      !!      to the horizontal pressure gradient :
422      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
423      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
424      !!      add it to the general momentum trend (ua,va).
425      !!         ua = ua - 1/e1u * zhpi
426      !!         va = va - 1/e2v * zhpj
427      !!
428      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429      !!----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
431      !!
432      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
433      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
434      LOGICAL  ::   ll_tmp1, ll_tmp2, ll_tmp3            ! local logical variables
435      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
436      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy !W/D pressure filter
437      !!----------------------------------------------------------------------
438      !
439      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
440      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
441      !
442      IF( kt == nit000 ) THEN
443         IF(lwp) WRITE(numout,*)
444         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
445         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
446      ENDIF
447      !
448      zcoef0 = - grav * 0.5_wp
449      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
450      ELSE                    ;   znad = 1._wp         ! Variable volume: density
451      ENDIF
452      !
453      IF(ln_wd) THEN
454        DO jj = 2, jpjm1
455           DO ji = 2, jpim1 
456             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) 
457             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) > rn_wdmin1 + rn_wdmin2
458             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) + &
459                                                       & rn_wdmin1 + rn_wdmin2
460
461             IF(ll_tmp1.AND.ll_tmp2) THEN
462               zcpx(ji,jj) = 1.0_wp
463             ELSE IF(ll_tmp3) THEN
464               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
465               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) / &
466                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
467             ELSE
468               zcpx(ji,jj) = 0._wp
469             END IF
470     
471             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) 
472             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) > rn_wdmin1 + rn_wdmin2
473             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) + &
474                                                       & rn_wdmin1 + rn_wdmin2
475
476             IF(ll_tmp1.AND.ll_tmp2) THEN
477               zcpy(ji,jj) = 1.0_wp
478             ELSE IF(ll_tmp3) THEN
479               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
480               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) / &
481                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
482             ELSE
483               zcpy(ji,jj) = 0._wp
484             END IF
485           END DO
486        END DO
487        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
488      ENDIF
489
490
491      ! Surface value
492      DO jj = 2, jpjm1
493         DO ji = fs_2, fs_jpim1   ! vector opt.
494            ! hydrostatic pressure gradient along s-surfaces
495            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
496               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
497            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
498               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
499            ! s-coordinate pressure gradient correction
500            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
501               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
502            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
503               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
504
505
506            IF(ln_wd) THEN
507
508              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
509              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
510              zuap = zuap * zcpx(ji,jj)
511              zvap = zvap * zcpy(ji,jj)
512            ENDIF
513
514            ! add to the general momentum trend
515            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
516            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
517         END DO
518      END DO
519
520      ! interior value (2=<jk=<jpkm1)
521      DO jk = 2, jpkm1
522         DO jj = 2, jpjm1
523            DO ji = fs_2, fs_jpim1   ! vector opt.
524               ! hydrostatic pressure gradient along s-surfaces
525               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
526                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
527                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
528               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
529                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
530                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
531               ! s-coordinate pressure gradient correction
532               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
533                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
534               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
535                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
536
537               IF(ln_wd) THEN
538                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
539                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
540                 zuap = zuap * zcpx(ji,jj)
541                 zvap = zvap * zcpy(ji,jj)
542               ENDIF
543
544               ! add to the general momentum trend
545               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
546               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
547            END DO
548         END DO
549      END DO
550      !
551      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
552      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
553      !
554   END SUBROUTINE hpg_sco
555
556
557   SUBROUTINE hpg_isf( kt )
558      !!---------------------------------------------------------------------
559      !!                  ***  ROUTINE hpg_isf  ***
560      !!
561      !! ** Method  :   s-coordinate case. Jacobian scheme.
562      !!      The now hydrostatic pressure gradient at a given level, jk,
563      !!      is computed by taking the vertical integral of the in-situ
564      !!      density gradient along the model level from the suface to that
565      !!      level. s-coordinates (ln_sco): a corrective term is added
566      !!      to the horizontal pressure gradient :
567      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
568      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
569      !!      add it to the general momentum trend (ua,va).
570      !!         ua = ua - 1/e1u * zhpi
571      !!         va = va - 1/e2v * zhpj
572      !!      iceload is added and partial cell case are added to the top and bottom
573      !!     
574      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
575      !!----------------------------------------------------------------------
576      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
577      !!
578      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
579      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
580      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
581      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
582      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
583      !!----------------------------------------------------------------------
584      !
585      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
586      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
587      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
588      !
589      ! Local constant initialization
590      zcoef0 = - grav * 0.5_wp
591 
592      ! To use density and not density anomaly
593      znad=1._wp
594
595      ! iniitialised to 0. zhpi zhpi
596      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
597
598      ! compute rhd at the ice/oce interface (ocean side)
599      ! usefull to reduce residual current in the test case ISOMIP with no melting
600      DO ji=1,jpi
601        DO jj=1,jpj
602          ikt=mikt(ji,jj)
603          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
604          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
605        END DO
606      END DO
607      CALL eos( ztstop, risfdep, zrhdtop_oce )
608
609!==================================================================================     
610!===== Compute surface value =====================================================
611!==================================================================================
612      DO jj = 2, jpjm1
613         DO ji = fs_2, fs_jpim1   ! vector opt.
614            ikt    = mikt(ji,jj)
615            iktp1i = mikt(ji+1,jj)
616            iktp1j = mikt(ji,jj+1)
617            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
618            ! we assume ISF is in isostatic equilibrium
619            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
620               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
621               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
622               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
623               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
624            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
625               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
626               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
627               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
628               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
629            ! s-coordinate pressure gradient correction (=0 if z coordinate)
630            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
631               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
632            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
633               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
634            ! add to the general momentum trend
635            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
636            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
637         END DO
638      END DO
639!==================================================================================     
640!===== Compute interior value =====================================================
641!==================================================================================
642      ! interior value (2=<jk=<jpkm1)
643      DO jk = 2, jpkm1
644         DO jj = 2, jpjm1
645            DO ji = fs_2, fs_jpim1   ! vector opt.
646               ! hydrostatic pressure gradient along s-surfaces
647               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
648                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
649                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
650               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
651                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
652                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
653               ! s-coordinate pressure gradient correction
654               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
655                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
656               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
657                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
658               ! add to the general momentum trend
659               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
660               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
661            END DO
662         END DO
663      END DO
664     !
665      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
666      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
667      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
668      !
669   END SUBROUTINE hpg_isf
670
671
672   SUBROUTINE hpg_djc( kt )
673      !!---------------------------------------------------------------------
674      !!                  ***  ROUTINE hpg_djc  ***
675      !!
676      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
677      !!
678      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
679      !!----------------------------------------------------------------------
680      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
681      !!
682      INTEGER  ::   ji, jj, jk          ! dummy loop indices
683      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
684      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
685      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
686      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
687      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
688      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
689      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
690      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
691      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
692      !!----------------------------------------------------------------------
693      !
694      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
695      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
696      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
697      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
698      !
699      !
700      IF(ln_wd) THEN
701        DO jj = 2, jpjm1
702           DO ji = 2, jpim1 
703             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
704                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
705                     &  > rn_wdmin1 + rn_wdmin2
706             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
707                                                       & rn_wdmin1 + rn_wdmin2
708
709             IF(ll_tmp1) THEN
710               zcpx(ji,jj) = 1.0_wp
711             ELSE IF(ll_tmp2) THEN
712               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
713               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
714                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
715             ELSE
716               zcpx(ji,jj) = 0._wp
717             END IF
718     
719             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
720                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
721                     &  > rn_wdmin1 + rn_wdmin2
722             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
723                                                       & rn_wdmin1 + rn_wdmin2
724
725             IF(ll_tmp1) THEN
726               zcpy(ji,jj) = 1.0_wp
727             ELSE IF(ll_tmp2) THEN
728               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
729               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
730                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
731             ELSE
732               zcpy(ji,jj) = 0._wp
733             END IF
734           END DO
735        END DO
736        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
737      ENDIF
738
739
740      IF( kt == nit000 ) THEN
741         IF(lwp) WRITE(numout,*)
742         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
743         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
744      ENDIF
745
746      ! Local constant initialization
747      zcoef0 = - grav * 0.5_wp
748      z1_10  = 1._wp / 10._wp
749      z1_12  = 1._wp / 12._wp
750
751      !----------------------------------------------------------------------------------------
752      !  compute and store in provisional arrays elementary vertical and horizontal differences
753      !----------------------------------------------------------------------------------------
754
755!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
756
757      DO jk = 2, jpkm1
758         DO jj = 2, jpjm1
759            DO ji = fs_2, fs_jpim1   ! vector opt.
760               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
761               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
762               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
763               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
764               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
765               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
766            END DO
767         END DO
768      END DO
769
770      !-------------------------------------------------------------------------
771      ! compute harmonic averages using eq. 5.18
772      !-------------------------------------------------------------------------
773      zep = 1.e-15
774
775!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
776!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
777
778      DO jk = 2, jpkm1
779         DO jj = 2, jpjm1
780            DO ji = fs_2, fs_jpim1   ! vector opt.
781               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
782
783               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
784               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
785
786               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
787               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
788
789               IF( cffw > zep) THEN
790                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
791                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
792               ELSE
793                  drhow(ji,jj,jk) = 0._wp
794               ENDIF
795
796               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
797                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
798
799               IF( cffu > zep ) THEN
800                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
801                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
802               ELSE
803                  drhou(ji,jj,jk ) = 0._wp
804               ENDIF
805
806               IF( cffx > zep ) THEN
807                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
808                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
809               ELSE
810                  dzu(ji,jj,jk) = 0._wp
811               ENDIF
812
813               IF( cffv > zep ) THEN
814                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
815                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
816               ELSE
817                  drhov(ji,jj,jk) = 0._wp
818               ENDIF
819
820               IF( cffy > zep ) THEN
821                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
822                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
823               ELSE
824                  dzv(ji,jj,jk) = 0._wp
825               ENDIF
826
827            END DO
828         END DO
829      END DO
830
831      !----------------------------------------------------------------------------------
832      ! apply boundary conditions at top and bottom using 5.36-5.37
833      !----------------------------------------------------------------------------------
834      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
835      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
836      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
837
838      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
839      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
840      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
841
842
843      !--------------------------------------------------------------
844      ! Upper half of top-most grid box, compute and store
845      !-------------------------------------------------------------
846
847!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
848!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
849
850      DO jj = 2, jpjm1
851         DO ji = fs_2, fs_jpim1   ! vector opt.
852            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
853               &                   * (  rhd(ji,jj,1)                                     &
854               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
855               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
856               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
857         END DO
858      END DO
859
860!!bug gm    : here also, simplification is possible
861!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
862
863      DO jk = 2, jpkm1
864         DO jj = 2, jpjm1
865            DO ji = fs_2, fs_jpim1   ! vector opt.
866
867               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
868                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
869                  &            - grav * z1_10 * (                                                                   &
870                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
871                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
872                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
873                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
874                  &                             )
875
876               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
877                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
878                  &            - grav* z1_10 * (                                                                    &
879                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
880                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
881                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
882                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
883                  &                            )
884
885               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
886                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
887                  &            - grav* z1_10 * (                                                                    &
888                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
889                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
890                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
891                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
892                  &                            )
893
894            END DO
895         END DO
896      END DO
897      CALL lbc_lnk(rho_k,'W',1.)
898      CALL lbc_lnk(rho_i,'U',1.)
899      CALL lbc_lnk(rho_j,'V',1.)
900
901
902      ! ---------------
903      !  Surface value
904      ! ---------------
905      DO jj = 2, jpjm1
906         DO ji = fs_2, fs_jpim1   ! vector opt.
907            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
908            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
909            IF(ln_wd) THEN
910              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
911              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
912            ENDIF
913            ! add to the general momentum trend
914            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
915            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
916         END DO
917      END DO
918
919      ! ----------------
920      !  interior value   (2=<jk=<jpkm1)
921      ! ----------------
922      DO jk = 2, jpkm1
923         DO jj = 2, jpjm1
924            DO ji = fs_2, fs_jpim1   ! vector opt.
925               ! hydrostatic pressure gradient along s-surfaces
926               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
927                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
928                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
929               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
930                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
931                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
932               IF(ln_wd) THEN
933                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
934                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
935               ENDIF
936               ! add to the general momentum trend
937               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
938               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
939            END DO
940         END DO
941      END DO
942      !
943      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
944      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
945      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
946      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
947      !
948   END SUBROUTINE hpg_djc
949
950
951   SUBROUTINE hpg_prj( kt )
952      !!---------------------------------------------------------------------
953      !!                  ***  ROUTINE hpg_prj  ***
954      !!
955      !! ** Method  :   s-coordinate case.
956      !!      A Pressure-Jacobian horizontal pressure gradient method
957      !!      based on the constrained cubic-spline interpolation for
958      !!      all vertical coordinate systems
959      !!
960      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
961      !!----------------------------------------------------------------------
962      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
963      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
964      !!
965      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
966      REAL(wp) ::   zcoef0, znad                    ! local scalars
967      !
968      !! The local variables for the correction term
969      INTEGER  :: jk1, jis, jid, jjs, jjd
970      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
971      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
972      REAL(wp) :: zrhdt1
973      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
974      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
975      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
976      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
977      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
978      !!----------------------------------------------------------------------
979      !
980      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
981      CALL wrk_alloc( jpi,jpj,jpk,   zdept, zrhh )
982      CALL wrk_alloc( jpi,jpj,       zsshu_n, zsshv_n )
983      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
984      !
985      IF( kt == nit000 ) THEN
986         IF(lwp) WRITE(numout,*)
987         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
988         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
989      ENDIF
990
991      ! Local constant initialization
992      zcoef0 = - grav
993      znad = 1._wp
994      IF( ln_linssh )   znad = 0._wp
995
996      IF(ln_wd) THEN
997        DO jj = 2, jpjm1
998           DO ji = 2, jpim1 
999             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
1000                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
1001                     &  > rn_wdmin1 + rn_wdmin2
1002             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
1003                                                       & rn_wdmin1 + rn_wdmin2
1004
1005             IF(ll_tmp1) THEN
1006               zcpx(ji,jj) = 1.0_wp
1007             ELSE IF(ll_tmp2) THEN
1008               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
1009               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
1010                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
1011             ELSE
1012               zcpx(ji,jj) = 0._wp
1013             END IF
1014     
1015             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
1016                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
1017                     &  > rn_wdmin1 + rn_wdmin2
1018             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
1019                                                       & rn_wdmin1 + rn_wdmin2
1020
1021             IF(ll_tmp1.OR.ll_tmp2) THEN
1022               zcpy(ji,jj) = 1.0_wp
1023             ELSE IF(ll_tmp2) THEN
1024               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
1025               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
1026                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
1027             ELSE
1028               zcpy(ji,jj) = 0._wp
1029             END IF
1030           END DO
1031        END DO
1032        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
1033      ENDIF
1034
1035      ! Clean 3-D work arrays
1036      zhpi(:,:,:) = 0._wp
1037      zrhh(:,:,:) = rhd(:,:,:)
1038
1039      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1040      DO jj = 1, jpj
1041        DO ji = 1, jpi
1042          jk = mbathy(ji,jj)
1043          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1044          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1045          ELSEIF( jk < jpkm1 ) THEN
1046             DO jkk = jk+1, jpk
1047                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1048                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1049             END DO
1050          ENDIF
1051        END DO
1052      END DO
1053
1054      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1055      DO jj = 1, jpj
1056         DO ji = 1, jpi
1057            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1058         END DO
1059      END DO
1060
1061      DO jk = 2, jpk
1062         DO jj = 1, jpj
1063            DO ji = 1, jpi
1064               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1065            END DO
1066         END DO
1067      END DO
1068
1069      fsp(:,:,:) = zrhh (:,:,:)
1070      xsp(:,:,:) = zdept(:,:,:)
1071
1072      ! Construct the vertical density profile with the
1073      ! constrained cubic spline interpolation
1074      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1075      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1076
1077      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1078      DO jj = 2, jpj
1079        DO ji = 2, jpi
1080          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1081             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1082
1083          ! assuming linear profile across the top half surface layer
1084          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1085        END DO
1086      END DO
1087
1088      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1089      DO jk = 2, jpkm1
1090        DO jj = 2, jpj
1091          DO ji = 2, jpi
1092            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1093               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1094               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1095               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1096          END DO
1097        END DO
1098      END DO
1099
1100      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1101
1102      ! Prepare zsshu_n and zsshv_n
1103      DO jj = 2, jpjm1
1104        DO ji = 2, jpim1
1105!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1106!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1107!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1108!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1109!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1110!!gm not this:
1111          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1112                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1113          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1114                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1115        END DO
1116      END DO
1117
1118      CALL lbc_lnk (zsshu_n, 'U', 1.)
1119      CALL lbc_lnk (zsshv_n, 'V', 1.)
1120
1121      DO jj = 2, jpjm1
1122        DO ji = 2, jpim1
1123          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1124          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1125        END DO
1126      END DO
1127
1128      DO jk = 2, jpkm1
1129        DO jj = 2, jpjm1
1130          DO ji = 2, jpim1
1131            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1132            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1133          END DO
1134        END DO
1135      END DO
1136
1137      DO jk = 1, jpkm1
1138        DO jj = 2, jpjm1
1139          DO ji = 2, jpim1
1140            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1141            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1142          END DO
1143        END DO
1144      END DO
1145
1146      DO jk = 1, jpkm1
1147        DO jj = 2, jpjm1
1148          DO ji = 2, jpim1
1149            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1150            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1151            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1152            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1153          END DO
1154        END DO
1155      END DO
1156
1157
1158      DO jk = 1, jpkm1
1159        DO jj = 2, jpjm1
1160          DO ji = 2, jpim1
1161            zpwes = 0._wp; zpwed = 0._wp
1162            zpnss = 0._wp; zpnsd = 0._wp
1163            zuijk = zu(ji,jj,jk)
1164            zvijk = zv(ji,jj,jk)
1165
1166            !!!!!     for u equation
1167            IF( jk <= mbku(ji,jj) ) THEN
1168               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1169                 jis = ji + 1; jid = ji
1170               ELSE
1171                 jis = ji;     jid = ji +1
1172               ENDIF
1173
1174               ! integrate the pressure on the shallow side
1175               jk1 = jk
1176               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1177                 IF( jk1 == mbku(ji,jj) ) THEN
1178                   zuijk = -zdept(jis,jj,jk1)
1179                   EXIT
1180                 ENDIF
1181                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1182                 zpwes = zpwes +                                    &
1183                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1184                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1185                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1186                 jk1 = jk1 + 1
1187               END DO
1188
1189               ! integrate the pressure on the deep side
1190               jk1 = jk
1191               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1192                 IF( jk1 == 1 ) THEN
1193                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1194                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1195                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1196                                                     dsp(jid,jj,1)) * zdeps
1197                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1198                   EXIT
1199                 ENDIF
1200                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1201                 zpwed = zpwed +                                        &
1202                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1203                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1204                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1205                 jk1 = jk1 - 1
1206               END DO
1207
1208               ! update the momentum trends in u direction
1209
1210               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1211               IF( .NOT.ln_linssh ) THEN
1212                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1213                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1214                ELSE
1215                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1216               ENDIF
1217               IF(ln_wd) THEN
1218                  zdpdx1 = zdpdx1 * zcpx(ji,jj)
1219                  zdpdx2 = zdpdx2 * zcpx(ji,jj)
1220               ENDIF
1221               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1222            ENDIF
1223
1224            !!!!!     for v equation
1225            IF( jk <= mbkv(ji,jj) ) THEN
1226               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1227                 jjs = jj + 1; jjd = jj
1228               ELSE
1229                 jjs = jj    ; jjd = jj + 1
1230               ENDIF
1231
1232               ! integrate the pressure on the shallow side
1233               jk1 = jk
1234               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1235                 IF( jk1 == mbkv(ji,jj) ) THEN
1236                   zvijk = -zdept(ji,jjs,jk1)
1237                   EXIT
1238                 ENDIF
1239                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1240                 zpnss = zpnss +                                      &
1241                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1242                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1243                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1244                 jk1 = jk1 + 1
1245               END DO
1246
1247               ! integrate the pressure on the deep side
1248               jk1 = jk
1249               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1250                 IF( jk1 == 1 ) THEN
1251                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1252                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1253                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1254                                                     dsp(ji,jjd,1) ) * zdeps
1255                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1256                   EXIT
1257                 ENDIF
1258                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1259                 zpnsd = zpnsd +                                        &
1260                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1261                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1262                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1263                 jk1 = jk1 - 1
1264               END DO
1265
1266
1267               ! update the momentum trends in v direction
1268
1269               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1270               IF( .NOT.ln_linssh ) THEN
1271                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1272                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1273               ELSE
1274                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1275               ENDIF
1276               IF(ln_wd) THEN
1277                  zdpdy1 = zdpdy1 * zcpy(ji,jj)
1278                  zdpdy2 = zdpdy2 * zcpy(ji,jj)
1279               ENDIF
1280
1281               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1282            ENDIF
1283               !
1284            END DO
1285         END DO
1286      END DO
1287      !
1288      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1289      CALL wrk_dealloc( jpi,jpj,jpk,   zdept, zrhh )
1290      CALL wrk_dealloc( jpi,jpj,       zsshu_n, zsshv_n )
1291      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1292      !
1293   END SUBROUTINE hpg_prj
1294
1295
1296   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1297      !!----------------------------------------------------------------------
1298      !!                 ***  ROUTINE cspline  ***
1299      !!
1300      !! ** Purpose :   constrained cubic spline interpolation
1301      !!
1302      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1303      !!
1304      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1305      !!----------------------------------------------------------------------
1306      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1307      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1308      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1309      !
1310      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1311      INTEGER  ::   jpi, jpj, jpkm1
1312      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1313      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1314      REAL(wp) ::   zdf(size(fsp,3))
1315      !!----------------------------------------------------------------------
1316      !
1317!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1318      jpi   = size(fsp,1)
1319      jpj   = size(fsp,2)
1320      jpkm1 = size(fsp,3) - 1
1321      !
1322      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1323         DO ji = 1, jpi
1324            DO jj = 1, jpj
1325           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1326           !    DO jk = 2, jpkm1-1
1327           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1328           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1329           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1330           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1331           !
1332           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1333           !
1334           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1335           !           zdf(jk) = 0._wp
1336           !       ELSE
1337           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1338           !       ENDIF
1339           !    END DO
1340
1341           !!Simply geometric average
1342               DO jk = 2, jpkm1-1
1343                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1344                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1345
1346                  IF(zdf1 * zdf2 <= 0._wp) THEN
1347                     zdf(jk) = 0._wp
1348                  ELSE
1349                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1350                  ENDIF
1351               END DO
1352
1353               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1354                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1355               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1356                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1357
1358               DO jk = 1, jpkm1 - 1
1359                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1360                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1361                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1362                 zddf1  = -2._wp * ztmp1 + ztmp2
1363                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1364                 zddf2  =  2._wp * ztmp1 - ztmp2
1365
1366                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1367                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1368                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1369                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1370                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1371                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1372                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1373                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1374                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1375               END DO
1376            END DO
1377         END DO
1378
1379      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1380         DO ji = 1, jpi
1381            DO jj = 1, jpj
1382               DO jk = 1, jpkm1-1
1383                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1384                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1385
1386                  dsp(ji,jj,jk) = 0._wp
1387                  csp(ji,jj,jk) = 0._wp
1388                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1389                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1390               END DO
1391            END DO
1392         END DO
1393
1394      ELSE
1395           CALL ctl_stop( 'invalid polynomial type in cspline' )
1396      ENDIF
1397
1398   END SUBROUTINE cspline
1399
1400
1401   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1402      !!----------------------------------------------------------------------
1403      !!                 ***  ROUTINE interp1  ***
1404      !!
1405      !! ** Purpose :   1-d linear interpolation
1406      !!
1407      !! ** Method  :   interpolation is straight forward
1408      !!                extrapolation is also permitted (no value limit)
1409      !!----------------------------------------------------------------------
1410      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1411      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1412      REAL(wp)             ::  zdeltx
1413      !!----------------------------------------------------------------------
1414      !
1415      zdeltx = xr - xl
1416      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1417         f = 0.5_wp * (fl + fr)
1418      ELSE
1419         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1420      ENDIF
1421      !
1422   END FUNCTION interp1
1423
1424
1425   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1426      !!----------------------------------------------------------------------
1427      !!                 ***  ROUTINE interp1  ***
1428      !!
1429      !! ** Purpose :   1-d constrained cubic spline interpolation
1430      !!
1431      !! ** Method  :  cubic spline interpolation
1432      !!
1433      !!----------------------------------------------------------------------
1434      REAL(wp), INTENT(in) ::  x, a, b, c, d
1435      REAL(wp)             ::  f ! value from the interpolation
1436      !!----------------------------------------------------------------------
1437      !
1438      f = a + x* ( b + x * ( c + d * x ) )
1439      !
1440   END FUNCTION interp2
1441
1442
1443   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1444      !!----------------------------------------------------------------------
1445      !!                 ***  ROUTINE interp1  ***
1446      !!
1447      !! ** Purpose :   Calculate the first order of deriavtive of
1448      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1449      !!
1450      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1451      !!
1452      !!----------------------------------------------------------------------
1453      REAL(wp), INTENT(in) ::  x, a, b, c, d
1454      REAL(wp)             ::  f ! value from the interpolation
1455      !!----------------------------------------------------------------------
1456      !
1457      f = b + x * ( 2._wp * c + 3._wp * d * x)
1458      !
1459   END FUNCTION interp3
1460
1461
1462   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1463      !!----------------------------------------------------------------------
1464      !!                 ***  ROUTINE interp1  ***
1465      !!
1466      !! ** Purpose :   1-d constrained cubic spline integration
1467      !!
1468      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1469      !!
1470      !!----------------------------------------------------------------------
1471      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1472      REAL(wp)             ::  za1, za2, za3
1473      REAL(wp)             ::  f                   ! integration result
1474      !!----------------------------------------------------------------------
1475      !
1476      za1 = 0.5_wp * b
1477      za2 = c / 3.0_wp
1478      za3 = 0.25_wp * d
1479      !
1480      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1481         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1482      !
1483   END FUNCTION integ_spline
1484
1485   !!======================================================================
1486END MODULE dynhpg
1487
Note: See TracBrowser for help on using the repository browser.