New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/CONFIG/OVERFLOW/MY_SRC – NEMO

source: branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/CONFIG/OVERFLOW/MY_SRC/traadv_fct.F90 @ 6879

Last change on this file since 6879 was 6879, checked in by flavoni, 8 years ago

commit small modifications in ly_src routines for OVERFLOW
File size: 40.4 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
44   !! $Id: traadv_fct.F90 6140 2015-12-21 11:35:23Z timgraham $
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
50      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_adv_fct  ***
53      !!
54      !! **  Purpose :   Compute the now trend due to total advection of tracers
55      !!               and add it to the general trend of tracer equations
56      !!
57      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
58      !!               (choice through the value of kn_fct)
59      !!               - on the vertical the 4th order is a compact scheme
60      !!               - corrected flux (monotonic correction)
61      !!
62      !! ** Action : - update pta  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
71      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
72      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
78      REAL(wp) ::   ztra                                     ! local scalar
79      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
80      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      !
98      IF( l_trd )  THEN
99         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
100         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
101      ENDIF
102      !
103      !                          ! surface & bottom value : flux set to zero one for all
104      zwz(:,:, 1 ) = 0._wp           
105      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
106      !
107      zwi(:,:,:) = 0._wp       
108      !
109      DO jn = 1, kjpt            !==  loop over the tracers  ==!
110         !
111         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
112         !                    !* upstream tracer flux in the i and j direction
113         DO jk = 1, jpkm1
114            DO jj = 1, jpjm1
115               DO ji = 1, fs_jpim1   ! vector opt.
116                  ! upstream scheme
117                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
118                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
119                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
120                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
121                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
122                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
123               END DO
124            END DO
125         END DO
126         !                    !* upstream tracer flux in the k direction *!
127         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
128            DO jj = 1, jpj
129               DO ji = 1, jpi
130                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
131                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
132                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
133               END DO
134            END DO
135         END DO
136         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
137            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
138               DO jj = 1, jpj
139                  DO ji = 1, jpi
140                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
141                  END DO
142               END DO   
143            ELSE                             ! no cavities: only at the ocean surface
144               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
145            ENDIF
146         ENDIF
147         !               
148         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
149            DO jj = 2, jpjm1
150               DO ji = fs_2, fs_jpim1   ! vector opt.
151                  ! total intermediate advective trends
152                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
153                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
154                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
155                  ! update and guess with monotonic sheme
156!!gm why tmask added in the two following lines ???    the mask is done in tranxt !
157                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)        + ztra   * tmask(ji,jj,jk)
158!!gm BUG                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + p2dt * ztra ) * tmask(ji,jj,jk)
159                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + e3t_n(ji,jj,jk) * p2dt * ztra )   &
160                     &             /   e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
161               END DO
162            END DO
163         END DO
164         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
165         !               
166         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
167            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
168         END IF
169         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
170         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
171           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
172           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
173         ENDIF
174         !
175         !        !==  anti-diffusive flux : high order minus low order  ==!
176         !
177         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
178         !
179         CASE(  2  )                   !- 2nd order centered
180            DO jk = 1, jpkm1
181               DO jj = 1, jpjm1
182                  DO ji = 1, fs_jpim1   ! vector opt.
183                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
184                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
185                  END DO
186               END DO
187            END DO
188            !
189         CASE(  4  )                   !- 4th order centered
190            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
191            zltv(:,:,jpk) = 0._wp
192            DO jk = 1, jpkm1                 ! Laplacian
193               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
194                  DO ji = 1, fs_jpim1   ! vector opt.
195                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
196                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
197                  END DO
198               END DO
199               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
200                  DO ji = fs_2, fs_jpim1   ! vector opt.
201                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
202                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
203                  END DO
204               END DO
205            END DO
206            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
207            !
208            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
209               DO jj = 1, jpjm1
210                  DO ji = 1, fs_jpim1   ! vector opt.
211                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
212                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
213                     !                                                  ! C4 minus upstream advective fluxes
214                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
215                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
216                  END DO
217               END DO
218            END DO         
219            !
220         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
221            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
222            ztv(:,:,jpk) = 0._wp
223            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
224               DO jj = 1, jpjm1
225                  DO ji = 1, fs_jpim1   ! vector opt.
226                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
227                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
228                  END DO
229               END DO
230            END DO
231            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
232            !
233            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
234               DO jj = 2, jpjm1
235                  DO ji = 2, fs_jpim1   ! vector opt.
236                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
237                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
238                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
239                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
240                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
241                     !                                                  ! C4 minus upstream advective fluxes
242                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
243                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
244                  END DO
245               END DO
246            END DO
247            !
248         END SELECT
249         !                     
250         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
251         !
252         CASE(  2  )                   !- 2nd order centered
253            DO jk = 2, jpkm1   
254               DO jj = 2, jpjm1
255                  DO ji = fs_2, fs_jpim1
256                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
257                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
258                  END DO
259               END DO
260            END DO
261            !
262         CASE(  4  )                   !- 4th order COMPACT
263            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
264            DO jk = 2, jpkm1
265               DO jj = 2, jpjm1
266                  DO ji = fs_2, fs_jpim1
267                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
268                  END DO
269               END DO
270            END DO
271            !
272         END SELECT
273         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
274            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
275         ENDIF
276         !
277         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
278         CALL lbc_lnk( zwz, 'W',  1. )
279         !
280         !        !==  monotonicity algorithm  ==!
281         !
282         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
283         !
284         !        !==  final trend with corrected fluxes  ==!
285         !
286         DO jk = 1, jpkm1
287            DO jj = 2, jpjm1
288               DO ji = fs_2, fs_jpim1   ! vector opt. 
289                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
290                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
291                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
292                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
293               END DO
294            END DO
295         END DO
296         !
297         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
298            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
299            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
300            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
301            !
302            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
303            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
304            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
305            !
306            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
307         END IF
308         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
309         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
310           IF( jn == jp_tem )   htr_adv(:) = htr_adv(:) + ptr_sj( zwy(:,:,:) )
311           IF( jn == jp_sal )   str_adv(:) = str_adv(:) + ptr_sj( zwy(:,:,:) )
312         ENDIF
313         !
314      END DO                     ! end of tracer loop
315      !
316      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
317      !
318      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
319      !
320   END SUBROUTINE tra_adv_fct
321
322
323   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
324      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
325      !!----------------------------------------------------------------------
326      !!                  ***  ROUTINE tra_adv_fct_zts  ***
327      !!
328      !! **  Purpose :   Compute the now trend due to total advection of
329      !!       tracers and add it to the general trend of tracer equations
330      !!
331      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
332      !!       corrected flux (monotonic correction). This version use sub-
333      !!       timestepping for the vertical advection which increases stability
334      !!       when vertical metrics are small.
335      !!       note: - this advection scheme needs a leap-frog time scheme
336      !!
337      !! ** Action : - update (pta) with the now advective tracer trends
338      !!             - save the trends
339      !!----------------------------------------------------------------------
340      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
341      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
342      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
343      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
344      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
345      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
346      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
347      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
348      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
349      !
350      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
351      REAL(wp)                                             ::   zr_p2dt         ! reciprocal of tracer timestep
352      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
353      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
354      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
355      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
356      REAL(wp) ::   ztra            ! local scalar
357      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
358      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
359      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
360      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
361      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
362      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
363      !!----------------------------------------------------------------------
364      !
365      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
366      !
367      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
368      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
369      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
370      !
371      IF( kt == kit000 )  THEN
372         IF(lwp) WRITE(numout,*)
373         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
374         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
375      ENDIF
376      !
377      l_trd = .FALSE.
378      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
379      !
380      IF( l_trd )  THEN
381         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
382         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
383      ENDIF
384      !
385      zwi(:,:,:) = 0._wp
386      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
387      zr_p2dt = 1._wp / p2dt
388      !
389      ! surface & Bottom value : flux set to zero for all tracers
390      zwz(:,:, 1 ) = 0._wp
391      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
392      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
393      !
394      !                                                          ! ===========
395      DO jn = 1, kjpt                                            ! tracer loop
396         !                                                       ! ===========
397         !
398         ! Upstream advection with initial mass fluxes & intermediate update
399         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
400            DO jj = 1, jpjm1
401               DO ji = 1, fs_jpim1   ! vector opt.
402                  ! upstream scheme
403                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
404                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
405                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
406                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
407                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
408                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
409               END DO
410            END DO
411         END DO
412         !                       ! upstream tracer flux in the k direction
413         DO jk = 2, jpkm1              ! Interior value
414            DO jj = 1, jpj
415               DO ji = 1, jpi
416                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
417                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
418                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
419               END DO
420            END DO
421         END DO
422         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
423            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
424               DO jj = 1, jpj
425                  DO ji = 1, jpi
426                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
427                  END DO
428               END DO   
429            ELSE                             ! no cavities, surface value
430               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
431            ENDIF
432         ENDIF
433         !
434         DO jk = 1, jpkm1         ! total advective trend
435            DO jj = 2, jpjm1
436               DO ji = fs_2, fs_jpim1   ! vector opt.
437                  !                             ! total intermediate advective trends
438                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
439                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
440                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
441                  !                             ! update and guess with monotonic sheme
442                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
443                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + p2dt * ztra ) * tmask(ji,jj,jk)
444               END DO
445            END DO
446         END DO
447         !                           
448         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
449         !               
450         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
451            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
452         END IF
453         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
454         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
455           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
456           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
457         ENDIF
458
459         ! 3. anti-diffusive flux : high order minus low order
460         ! ---------------------------------------------------
461
462         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
463            !
464            DO jj = 1, jpjm1
465               DO ji = 1, fs_jpim1   ! vector opt.
466                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
467                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
468                  !
469                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
470                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
471               END DO
472            END DO
473            !
474            DO jj = 2, jpjm1                    ! partial horizontal divergence
475               DO ji = fs_2, fs_jpim1
476                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
477                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
478               END DO
479            END DO
480            !
481            DO jj = 1, jpjm1
482               DO ji = 1, fs_jpim1   ! vector opt.
483                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
484                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
485               END DO
486            END DO
487         END DO
488         !
489         !                                !* vertical anti-diffusive flux
490         zwz_sav(:,:,:)   = zwz(:,:,:)
491         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
492         zwzts  (:,:,:)   = 0._wp
493         !
494         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
495            !
496            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
497               jtb = 1   ;   jtn = 1   ;   jta = 2
498               zts(:) = p2dt * z_rzts
499               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
500               !                                            ! starting at jl =1 if kn_fct_zts is odd;
501               !                                            ! starting at jl =2 otherwise
502            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
503               jtb = 1   ;   jtn = 2   ;   jta = 3
504               zts(:) = 2._wp * p2dt * z_rzts
505            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
506               jtb = MOD(jtb,3) + 1
507               jtn = MOD(jtn,3) + 1
508               jta = MOD(jta,3) + 1
509            ENDIF
510            DO jk = 2, jpkm1                          ! interior value
511               DO jj = 2, jpjm1
512                  DO ji = fs_2, fs_jpim1
513                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
514                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
515                  END DO
516               END DO
517            END DO
518            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
519               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
520                  DO jj = 1, jpj
521                     DO ji = 1, jpi
522                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
523                     END DO
524                  END DO   
525               ELSE                                      ! no ocean cavities
526                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
527               ENDIF
528            ENDIF
529            !
530            jtaken = MOD( jtaken + 1 , 2 )
531            !
532            DO jk = 2, jpkm1                             ! total advective trends
533               DO jj = 2, jpjm1
534                  DO ji = fs_2, fs_jpim1
535                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
536                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
537                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
538                  END DO
539               END DO
540            END DO
541            !
542         END DO
543
544         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
545            DO jj = 2, jpjm1
546               DO ji = fs_2, fs_jpim1
547                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
548               END DO
549            END DO
550         END DO
551         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
552         CALL lbc_lnk( zwz, 'W',  1. )
553
554         ! 4. monotonicity algorithm
555         ! -------------------------
556         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
557
558
559         ! 5. final trend with corrected fluxes
560         ! ------------------------------------
561         DO jk = 1, jpkm1
562            DO jj = 2, jpjm1
563               DO ji = fs_2, fs_jpim1   ! vector opt. 
564                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
565                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
566                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
567               END DO
568            END DO
569         END DO
570
571         !                                 ! trend diagnostics (contribution of upstream fluxes)
572         IF( l_trd )  THEN
573            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
574            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
575            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
576            !
577            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
578            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
579            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
580            !
581            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
582         END IF
583         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
584         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
585           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
586           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
587         ENDIF
588         !
589      END DO
590      !
591      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
592      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
593      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
594      !
595      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
596      !
597   END SUBROUTINE tra_adv_fct_zts
598
599
600   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
601      !!---------------------------------------------------------------------
602      !!                    ***  ROUTINE nonosc  ***
603      !!     
604      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
605      !!       scheme and the before field by a nonoscillatory algorithm
606      !!
607      !! **  Method  :   ... ???
608      !!       warning : pbef and paft must be masked, but the boundaries
609      !!       conditions on the fluxes are not necessary zalezak (1979)
610      !!       drange (1995) multi-dimensional forward-in-time and upstream-
611      !!       in-space based differencing for fluid
612      !!----------------------------------------------------------------------
613      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
614      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
615      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
616      !
617      INTEGER  ::   ji, jj, jk   ! dummy loop indices
618      INTEGER  ::   ikm1         ! local integer
619      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
620      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
621      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
622      !!----------------------------------------------------------------------
623      !
624      IF( nn_timing == 1 )  CALL timing_start('nonosc')
625      !
626      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
627      !
628      zbig  = 1.e+40_wp
629      zrtrn = 1.e-15_wp
630      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
631
632      ! Search local extrema
633      ! --------------------
634      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
635      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
636         &        paft * tmask - zbig * ( 1._wp - tmask )  )
637      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
638         &        paft * tmask + zbig * ( 1._wp - tmask )  )
639
640      DO jk = 1, jpkm1
641         ikm1 = MAX(jk-1,1)
642         DO jj = 2, jpjm1
643            DO ji = fs_2, fs_jpim1   ! vector opt.
644
645               ! search maximum in neighbourhood
646               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
647                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
648                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
649                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
650
651               ! search minimum in neighbourhood
652               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
653                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
654                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
655                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
656
657               ! positive part of the flux
658               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
659                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
660                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
661
662               ! negative part of the flux
663               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
664                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
665                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
666
667               ! up & down beta terms
668               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
669               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
670               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
671            END DO
672         END DO
673      END DO
674      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
675
676      ! 3. monotonic flux in the i & j direction (paa & pbb)
677      ! ----------------------------------------
678      DO jk = 1, jpkm1
679         DO jj = 2, jpjm1
680            DO ji = fs_2, fs_jpim1   ! vector opt.
681               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
682               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
683               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
684               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
685
686               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
687               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
688               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
689               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
690
691      ! monotonic flux in the k direction, i.e. pcc
692      ! -------------------------------------------
693               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
694               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
695               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
696               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
697            END DO
698         END DO
699      END DO
700      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
701      !
702      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
703      !
704      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
705      !
706   END SUBROUTINE nonosc
707
708
709   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
710      !!----------------------------------------------------------------------
711      !!                  ***  ROUTINE interp_4th_cpt  ***
712      !!
713      !! **  Purpose :   Compute the interpolation of tracer at w-point
714      !!
715      !! **  Method  :   4th order compact interpolation
716      !!----------------------------------------------------------------------
717      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
718      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
719      !
720      INTEGER :: ji, jj, jk   ! dummy loop integers
721      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
722      !!----------------------------------------------------------------------
723     
724      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
725         DO jj = 1, jpj
726            DO ji = 1, jpi
727               zwd (ji,jj,jk) = 4._wp
728               zwi (ji,jj,jk) = 1._wp
729               zws (ji,jj,jk) = 1._wp
730               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
731               !
732               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
733                  zwd (ji,jj,jk) = 1._wp
734                  zwi (ji,jj,jk) = 0._wp
735                  zws (ji,jj,jk) = 0._wp
736                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
737               ENDIF
738            END DO
739         END DO
740      END DO
741      !
742      jk=2                                            ! Switch to second order centered at top
743      DO jj=1,jpj
744         DO ji=1,jpi
745            zwd (ji,jj,jk) = 1._wp
746            zwi (ji,jj,jk) = 0._wp
747            zws (ji,jj,jk) = 0._wp
748            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
749         END DO
750      END DO   
751      !
752      !                       !==  tridiagonal solve  ==!
753      DO jj = 1, jpj                ! first recurrence
754         DO ji = 1, jpi
755            zwt(ji,jj,2) = zwd(ji,jj,2)
756         END DO
757      END DO
758      DO jk = 3, jpkm1
759         DO jj = 1, jpj
760            DO ji = 1, jpi
761               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
762            END DO
763         END DO
764      END DO
765      !
766      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
767         DO ji = 1, jpi
768            pt_out(ji,jj,2) = zwrm(ji,jj,2)
769         END DO
770      END DO
771      DO jk = 3, jpkm1
772         DO jj = 1, jpj
773            DO ji = 1, jpi
774               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
775            END DO
776         END DO
777      END DO
778
779      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
780         DO ji = 1, jpi
781            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
782         END DO
783      END DO
784      DO jk = jpk-2, 2, -1
785         DO jj = 1, jpj
786            DO ji = 1, jpi
787               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
788            END DO
789         END DO
790      END DO
791      !   
792   END SUBROUTINE interp_4th_cpt
793   
794   !!======================================================================
795END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.