New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 7200

Last change on this file since 7200 was 7200, checked in by gm, 7 years ago

#1692 - branch SIMPLIF_2_usrdef: add depth_e3 module + management of ORCA family + domain_cfg filename (in&out) given in namelist
  • Property svn:keywords set to Id
File size: 47.7 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !                                        ! tridiag solver associated indices:
41   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
42   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
43
44   !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
54      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_adv_fct  ***
57      !!
58      !! **  Purpose :   Compute the now trend due to total advection of tracers
59      !!               and add it to the general trend of tracer equations
60      !!
61      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
62      !!               (choice through the value of kn_fct)
63      !!               - on the vertical the 4th order is a compact scheme
64      !!               - corrected flux (monotonic correction)
65      !!
66      !! ** Action : - update pta  with the now advective tracer trends
67      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
68      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
75      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
76      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
82      REAL(wp) ::   ztra                                     ! local scalar
83      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
84      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97      ENDIF
98      !
99      l_trd = .FALSE.
100      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
101      !
102      IF( l_trd )  THEN
103         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
104         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
105      ENDIF
106      !
107      !                          ! surface & bottom value : flux set to zero one for all
108      zwz(:,:, 1 ) = 0._wp           
109      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
110      !
111      zwi(:,:,:) = 0._wp       
112      !
113      DO jn = 1, kjpt            !==  loop over the tracers  ==!
114         !
115         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
116         !                    !* upstream tracer flux in the i and j direction
117         DO jk = 1, jpkm1
118            DO jj = 1, jpjm1
119               DO ji = 1, fs_jpim1   ! vector opt.
120                  ! upstream scheme
121                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
122                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
123                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
124                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
125                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
126                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
127               END DO
128            END DO
129         END DO
130         !                    !* upstream tracer flux in the k direction *!
131         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
132            DO jj = 1, jpj
133               DO ji = 1, jpi
134                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
135                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
136                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
137               END DO
138            END DO
139         END DO
140         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
141            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
142               DO jj = 1, jpj
143                  DO ji = 1, jpi
144                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
145                  END DO
146               END DO   
147            ELSE                             ! no cavities: only at the ocean surface
148               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
149            ENDIF
150         ENDIF
151         !               
152         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
153            DO jj = 2, jpjm1
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  !                             ! total intermediate advective trends
156                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
157                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
158                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
159                  !                             ! update and guess with monotonic sheme
160                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
161                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
166         !               
167         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
168            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
169         END IF
170         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
171         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
172           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
173           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
174         ENDIF
175         !
176         !        !==  anti-diffusive flux : high order minus low order  ==!
177         !
178         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
179         !
180         CASE(  2  )                   !- 2nd order centered
181            DO jk = 1, jpkm1
182               DO jj = 1, jpjm1
183                  DO ji = 1, fs_jpim1   ! vector opt.
184                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
185                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
186                  END DO
187               END DO
188            END DO
189            !
190         CASE(  4  )                   !- 4th order centered
191            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
192            zltv(:,:,jpk) = 0._wp
193            DO jk = 1, jpkm1                 ! Laplacian
194               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
195                  DO ji = 1, fs_jpim1   ! vector opt.
196                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
197                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
198                  END DO
199               END DO
200               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
201                  DO ji = fs_2, fs_jpim1   ! vector opt.
202                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
203                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
204                  END DO
205               END DO
206            END DO
207            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
208            !
209            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
210               DO jj = 1, jpjm1
211                  DO ji = 1, fs_jpim1   ! vector opt.
212                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
213                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
214                     !                                                  ! C4 minus upstream advective fluxes
215                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
216                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
217                  END DO
218               END DO
219            END DO         
220            !
221         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
222            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
223            ztv(:,:,jpk) = 0._wp
224            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
225               DO jj = 1, jpjm1
226                  DO ji = 1, fs_jpim1   ! vector opt.
227                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
228                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
229                  END DO
230               END DO
231            END DO
232            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
233            !
234            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
235               DO jj = 2, jpjm1
236                  DO ji = 2, fs_jpim1   ! vector opt.
237                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
238                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
239                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
240                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
241                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
242                     !                                                  ! C4 minus upstream advective fluxes
243                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
244                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
245                  END DO
246               END DO
247            END DO
248            !
249         END SELECT
250         !                     
251         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
252         !
253         CASE(  2  )                   !- 2nd order centered
254            DO jk = 2, jpkm1   
255               DO jj = 2, jpjm1
256                  DO ji = fs_2, fs_jpim1
257                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
258                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
259                  END DO
260               END DO
261            END DO
262            !
263         CASE(  4  )                   !- 4th order COMPACT
264            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
265            DO jk = 2, jpkm1
266               DO jj = 2, jpjm1
267                  DO ji = fs_2, fs_jpim1
268                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
269                  END DO
270               END DO
271            END DO
272            !
273         END SELECT
274         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
275            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
276         ENDIF
277         !
278         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
279         CALL lbc_lnk( zwz, 'W',  1. )
280         !
281         !        !==  monotonicity algorithm  ==!
282         !
283         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
284         !
285         !        !==  final trend with corrected fluxes  ==!
286         !
287         DO jk = 1, jpkm1
288            DO jj = 2, jpjm1
289               DO ji = fs_2, fs_jpim1   ! vector opt. 
290                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
291                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
292                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
293                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
294               END DO
295            END DO
296         END DO
297         !
298         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
299            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
300            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
301            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
302            !
303            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
304            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
305            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
306            !
307            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
308         END IF
309         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
310         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
311           IF( jn == jp_tem )   htr_adv(:) = htr_adv(:) + ptr_sj( zwy(:,:,:) )
312           IF( jn == jp_sal )   str_adv(:) = str_adv(:) + ptr_sj( zwy(:,:,:) )
313         ENDIF
314         !
315      END DO                     ! end of tracer loop
316      !
317      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
318      !
319      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
320      !
321   END SUBROUTINE tra_adv_fct
322
323
324   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
325      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
326      !!----------------------------------------------------------------------
327      !!                  ***  ROUTINE tra_adv_fct_zts  ***
328      !!
329      !! **  Purpose :   Compute the now trend due to total advection of
330      !!       tracers and add it to the general trend of tracer equations
331      !!
332      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
333      !!       corrected flux (monotonic correction). This version use sub-
334      !!       timestepping for the vertical advection which increases stability
335      !!       when vertical metrics are small.
336      !!       note: - this advection scheme needs a leap-frog time scheme
337      !!
338      !! ** Action : - update (pta) with the now advective tracer trends
339      !!             - save the trends
340      !!----------------------------------------------------------------------
341      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
342      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
343      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
344      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
345      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
346      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
347      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
348      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
349      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
350      !
351      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
352      REAL(wp)                                             ::   zr_p2dt         ! reciprocal of tracer timestep
353      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
354      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
355      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
356      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
357      REAL(wp) ::   ztra            ! local scalar
358      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
359      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
360      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
361      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
362      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
363      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
364      !!----------------------------------------------------------------------
365      !
366      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
367      !
368      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
369      CALL wrk_alloc( jpi,jpj,jpk,         zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
370      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
371      !
372      IF( kt == kit000 )  THEN
373         IF(lwp) WRITE(numout,*)
374         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
375         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
376      ENDIF
377      !
378      l_trd = .FALSE.
379      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
380      !
381      IF( l_trd )  THEN
382         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
383         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
384      ENDIF
385      !
386      zwi(:,:,:) = 0._wp
387      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
388      zr_p2dt = 1._wp / p2dt
389      !
390      ! surface & Bottom value : flux set to zero for all tracers
391      zwz(:,:, 1 ) = 0._wp
392      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
393      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
394      !
395      !                                                          ! ===========
396      DO jn = 1, kjpt                                            ! tracer loop
397         !                                                       ! ===========
398         !
399         ! Upstream advection with initial mass fluxes & intermediate update
400         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
401            DO jj = 1, jpjm1
402               DO ji = 1, fs_jpim1   ! vector opt.
403                  ! upstream scheme
404                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
405                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
406                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
407                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
408                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
409                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
410               END DO
411            END DO
412         END DO
413         !                       ! upstream tracer flux in the k direction
414         DO jk = 2, jpkm1              ! Interior value
415            DO jj = 1, jpj
416               DO ji = 1, jpi
417                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
418                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
419                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
420               END DO
421            END DO
422         END DO
423         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
424            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
425               DO jj = 1, jpj
426                  DO ji = 1, jpi
427                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
428                  END DO
429               END DO   
430            ELSE                             ! no cavities, surface value
431               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
432            ENDIF
433         ENDIF
434         !
435         DO jk = 1, jpkm1         ! total advective trend
436            DO jj = 2, jpjm1
437               DO ji = fs_2, fs_jpim1   ! vector opt.
438                  !                             ! total intermediate advective trends
439                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
440                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
441                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj)
442                  !                             ! update and guess with monotonic sheme
443                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
444                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
445               END DO
446            END DO
447         END DO
448         !                           
449         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
450         !               
451         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
452            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
453         END IF
454         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
455         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
456           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
457           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
458         ENDIF
459
460         ! 3. anti-diffusive flux : high order minus low order
461         ! ---------------------------------------------------
462
463         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
464            !
465            DO jj = 1, jpjm1
466               DO ji = 1, fs_jpim1   ! vector opt.
467                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
468                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
469                  !
470                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
471                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
472               END DO
473            END DO
474            !
475            DO jj = 2, jpjm1                    ! partial horizontal divergence
476               DO ji = fs_2, fs_jpim1
477                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
478                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
479               END DO
480            END DO
481            !
482            DO jj = 1, jpjm1
483               DO ji = 1, fs_jpim1   ! vector opt.
484                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
485                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
486               END DO
487            END DO
488         END DO
489         !
490         !                                !* vertical anti-diffusive flux
491         zwz_sav(:,:,:)   = zwz(:,:,:)
492         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
493         ztrs   (:,:,1,2) = ptb(:,:,1,jn)
494         ztrs   (:,:,1,3) = ptb(:,:,1,jn)
495         zwzts  (:,:,:)   = 0._wp
496         !
497         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
498            !
499            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
500               jtb = 1   ;   jtn = 1   ;   jta = 2
501               zts(:) = p2dt * z_rzts
502               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
503               !                                            ! starting at jl =1 if kn_fct_zts is odd;
504               !                                            ! starting at jl =2 otherwise
505            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
506               jtb = 1   ;   jtn = 2   ;   jta = 3
507               zts(:) = 2._wp * p2dt * z_rzts
508            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
509               jtb = MOD(jtb,3) + 1
510               jtn = MOD(jtn,3) + 1
511               jta = MOD(jta,3) + 1
512            ENDIF
513            DO jk = 2, jpkm1                          ! interior value
514               DO jj = 2, jpjm1
515                  DO ji = fs_2, fs_jpim1
516                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
517                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
518                  END DO
519               END DO
520            END DO
521            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
522               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
523                  DO jj = 1, jpj
524                     DO ji = 1, jpi
525                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
526                     END DO
527                  END DO   
528               ELSE                                      ! no ocean cavities
529                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
530               ENDIF
531            ENDIF
532            !
533            jtaken = MOD( jtaken + 1 , 2 )
534            !
535            DO jk = 2, jpkm1                             ! total advective trends
536               DO jj = 2, jpjm1
537                  DO ji = fs_2, fs_jpim1
538                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
539                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
540                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
541                  END DO
542               END DO
543            END DO
544            !
545         END DO
546
547         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
548            DO jj = 2, jpjm1
549               DO ji = fs_2, fs_jpim1
550                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
551               END DO
552            END DO
553         END DO
554         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
555         CALL lbc_lnk( zwz, 'W',  1. )
556
557         ! 4. monotonicity algorithm
558         ! -------------------------
559         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
560
561
562         ! 5. final trend with corrected fluxes
563         ! ------------------------------------
564         DO jk = 1, jpkm1
565            DO jj = 2, jpjm1
566               DO ji = fs_2, fs_jpim1   ! vector opt. 
567                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
568                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
569                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
570               END DO
571            END DO
572         END DO
573
574         !                                 ! trend diagnostics (contribution of upstream fluxes)
575         IF( l_trd )  THEN
576            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
577            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
578            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
579            !
580            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
581            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
582            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
583            !
584            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
585         END IF
586         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
587         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
588           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
589           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
590         ENDIF
591         !
592      END DO
593      !
594      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
595      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
596      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
597      !
598      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
599      !
600   END SUBROUTINE tra_adv_fct_zts
601
602
603   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
604      !!---------------------------------------------------------------------
605      !!                    ***  ROUTINE nonosc  ***
606      !!     
607      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
608      !!       scheme and the before field by a nonoscillatory algorithm
609      !!
610      !! **  Method  :   ... ???
611      !!       warning : pbef and paft must be masked, but the boundaries
612      !!       conditions on the fluxes are not necessary zalezak (1979)
613      !!       drange (1995) multi-dimensional forward-in-time and upstream-
614      !!       in-space based differencing for fluid
615      !!----------------------------------------------------------------------
616      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
617      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
618      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
619      !
620      INTEGER  ::   ji, jj, jk   ! dummy loop indices
621      INTEGER  ::   ikm1         ! local integer
622      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
623      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
624      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
625      !!----------------------------------------------------------------------
626      !
627      IF( nn_timing == 1 )  CALL timing_start('nonosc')
628      !
629      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
630      !
631      zbig  = 1.e+40_wp
632      zrtrn = 1.e-15_wp
633      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
634
635      ! Search local extrema
636      ! --------------------
637      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
638      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
639         &        paft * tmask - zbig * ( 1._wp - tmask )  )
640      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
641         &        paft * tmask + zbig * ( 1._wp - tmask )  )
642
643      DO jk = 1, jpkm1
644         ikm1 = MAX(jk-1,1)
645         DO jj = 2, jpjm1
646            DO ji = fs_2, fs_jpim1   ! vector opt.
647
648               ! search maximum in neighbourhood
649               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
650                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
651                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
652                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
653
654               ! search minimum in neighbourhood
655               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
656                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
657                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
658                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
659
660               ! positive part of the flux
661               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
662                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
663                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
664
665               ! negative part of the flux
666               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
667                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
668                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
669
670               ! up & down beta terms
671               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
672               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
673               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
674            END DO
675         END DO
676      END DO
677      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
678
679      ! 3. monotonic flux in the i & j direction (paa & pbb)
680      ! ----------------------------------------
681      DO jk = 1, jpkm1
682         DO jj = 2, jpjm1
683            DO ji = fs_2, fs_jpim1   ! vector opt.
684               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
685               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
686               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
687               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
688
689               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
690               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
691               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
692               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
693
694      ! monotonic flux in the k direction, i.e. pcc
695      ! -------------------------------------------
696               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
697               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
698               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
699               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
700            END DO
701         END DO
702      END DO
703      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
704      !
705      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
706      !
707      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
708      !
709   END SUBROUTINE nonosc
710
711
712   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
713      !!----------------------------------------------------------------------
714      !!                  ***  ROUTINE interp_4th_cpt_org  ***
715      !!
716      !! **  Purpose :   Compute the interpolation of tracer at w-point
717      !!
718      !! **  Method  :   4th order compact interpolation
719      !!----------------------------------------------------------------------
720      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
721      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
722      !
723      INTEGER :: ji, jj, jk   ! dummy loop integers
724      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
725      !!----------------------------------------------------------------------
726     
727      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
728         DO jj = 1, jpj
729            DO ji = 1, jpi
730               zwd (ji,jj,jk) = 4._wp
731               zwi (ji,jj,jk) = 1._wp
732               zws (ji,jj,jk) = 1._wp
733               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
734               !
735               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
736                  zwd (ji,jj,jk) = 1._wp
737                  zwi (ji,jj,jk) = 0._wp
738                  zws (ji,jj,jk) = 0._wp
739                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
740               ENDIF
741            END DO
742         END DO
743      END DO
744      !
745      jk = 2                                          ! Switch to second order centered at top
746      DO jj = 1, jpj
747         DO ji = 1, jpi
748            zwd (ji,jj,jk) = 1._wp
749            zwi (ji,jj,jk) = 0._wp
750            zws (ji,jj,jk) = 0._wp
751            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
752         END DO
753      END DO   
754      !
755      !                       !==  tridiagonal solve  ==!
756      DO jj = 1, jpj                ! first recurrence
757         DO ji = 1, jpi
758            zwt(ji,jj,2) = zwd(ji,jj,2)
759         END DO
760      END DO
761      DO jk = 3, jpkm1
762         DO jj = 1, jpj
763            DO ji = 1, jpi
764               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
765            END DO
766         END DO
767      END DO
768      !
769      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
770         DO ji = 1, jpi
771            pt_out(ji,jj,2) = zwrm(ji,jj,2)
772         END DO
773      END DO
774      DO jk = 3, jpkm1
775         DO jj = 1, jpj
776            DO ji = 1, jpi
777               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
778            END DO
779         END DO
780      END DO
781
782      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
783         DO ji = 1, jpi
784            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
785         END DO
786      END DO
787      DO jk = jpk-2, 2, -1
788         DO jj = 1, jpj
789            DO ji = 1, jpi
790               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
791            END DO
792         END DO
793      END DO
794      !   
795   END SUBROUTINE interp_4th_cpt_org
796   
797
798   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
799      !!----------------------------------------------------------------------
800      !!                  ***  ROUTINE interp_4th_cpt  ***
801      !!
802      !! **  Purpose :   Compute the interpolation of tracer at w-point
803      !!
804      !! **  Method  :   4th order compact interpolation
805      !!----------------------------------------------------------------------
806      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
807      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
808      !
809      INTEGER ::   ji, jj, jk   ! dummy loop integers
810      INTEGER ::   ikt, ikb     ! local integers
811      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
812      !!----------------------------------------------------------------------
813      !
814      !                      !==  build the three diagonal matrix & the RHS  ==!
815      !
816      DO jk = 3, jpkm1                 ! interior (from jk=3 to jpk-1)
817         DO jj = 2, jpjm1
818            DO ji = fs_2, fs_jpim1
819               zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
820               zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
821               zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
822               zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
823                  &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
824            END DO
825         END DO
826      END DO
827      !
828!!gm
829!      SELECT CASE( kbc )               !* boundary condition
830!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
831!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
832!      END SELECT
833!!gm 
834      !
835      DO jj = 2, jpjm1                 ! 2nd order centered at top & bottom
836         DO ji = fs_2, fs_jpim1
837            ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
838            ikb = mbkt(ji,jj)                !     -   above the last wet point
839            !
840            zwd (ji,jj,ikt) = 1._wp          ! top
841            zwi (ji,jj,ikt) = 0._wp
842            zws (ji,jj,ikt) = 0._wp
843            zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
844            !
845            zwd (ji,jj,ikb) = 1._wp          ! bottom
846            zwi (ji,jj,ikb) = 0._wp
847            zws (ji,jj,ikb) = 0._wp
848            zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )           
849         END DO
850      END DO   
851      !
852      !                       !==  tridiagonal solver  ==!
853      !
854      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
855         DO ji = fs_2, fs_jpim1
856            zwt(ji,jj,2) = zwd(ji,jj,2)
857         END DO
858      END DO
859      DO jk = 3, jpkm1
860         DO jj = 2, jpjm1
861            DO ji = fs_2, fs_jpim1
862               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
863            END DO
864         END DO
865      END DO
866      !
867      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
868         DO ji = fs_2, fs_jpim1
869            pt_out(ji,jj,2) = zwrm(ji,jj,2)
870         END DO
871      END DO
872      DO jk = 3, jpkm1
873         DO jj = 2, jpjm1
874            DO ji = fs_2, fs_jpim1
875               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
876            END DO
877         END DO
878      END DO
879
880      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
881         DO ji = fs_2, fs_jpim1
882            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
883         END DO
884      END DO
885      DO jk = jpk-2, 2, -1
886         DO jj = 2, jpjm1
887            DO ji = fs_2, fs_jpim1
888               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
889            END DO
890         END DO
891      END DO
892      !   
893   END SUBROUTINE interp_4th_cpt
894
895
896   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
897      !!----------------------------------------------------------------------
898      !!                  ***  ROUTINE tridia_solver  ***
899      !!
900      !! **  Purpose :   solve a symmetric 3diagonal system
901      !!
902      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
903      !!     
904      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
905      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
906      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
907      !!             (        ...          )( ... )   ( ...  )
908      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
909      !!     
910      !!        M is decomposed in the product of an upper and lower triangular matrix.
911      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
912      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
913      !!        The solution is pta.
914      !!        The 3d array zwt is used as a work space array.
915      !!----------------------------------------------------------------------
916      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
917      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
918      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
919      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
920      !                                                           ! =0 pt at t-level
921      INTEGER ::   ji, jj, jk   ! dummy loop integers
922      INTEGER ::   kstart       ! local indices
923      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
924      !!----------------------------------------------------------------------
925      !
926      kstart =  1  + klev
927      !
928      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
929         DO ji = fs_2, fs_jpim1
930            zwt(ji,jj,kstart) = pD(ji,jj,kstart)
931         END DO
932      END DO
933      DO jk = kstart+1, jpkm1
934         DO jj = 2, jpjm1
935            DO ji = fs_2, fs_jpim1
936               zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
937            END DO
938         END DO
939      END DO
940      !
941      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
942         DO ji = fs_2, fs_jpim1
943            pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
944         END DO
945      END DO
946      DO jk = kstart+1, jpkm1
947         DO jj = 2, jpjm1
948            DO ji = fs_2, fs_jpim1
949               pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
950            END DO
951         END DO
952      END DO
953
954      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
955         DO ji = fs_2, fs_jpim1
956            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
957         END DO
958      END DO
959      DO jk = jpk-2, kstart, -1
960         DO jj = 2, jpjm1
961            DO ji = fs_2, fs_jpim1
962               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
963            END DO
964         END DO
965      END DO
966      !
967   END SUBROUTINE tridia_solver
968
969   !!======================================================================
970END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.