| 1 | MODULE dynbfr |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE dynbfr *** |
|---|
| 4 | !! Ocean dynamics : bottom friction component of the momentum mixing trend |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : 3.2 ! 2008-11 (A. C. Coward) Original code |
|---|
| 7 | !! 3.4 ! 2011-09 (H. Liu) Make it consistent with semi-implicit |
|---|
| 8 | !! Bottom friction (ln_bfrimp = .true.) |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! dyn_bfr : Update the momentum trend with the bottom friction contribution |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers variables |
|---|
| 15 | USE dom_oce ! ocean space and time domain variables |
|---|
| 16 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 17 | USE zdfbfr ! ocean bottom friction variables |
|---|
| 18 | USE trd_oce ! trends: ocean variables |
|---|
| 19 | USE trddyn ! trend manager: dynamics |
|---|
| 20 | USE in_out_manager ! I/O manager |
|---|
| 21 | USE prtctl ! Print control |
|---|
| 22 | USE timing ! Timing |
|---|
| 23 | USE wrk_nemo ! Memory Allocation |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC dyn_bfr ! routine called by step.F90 |
|---|
| 29 | |
|---|
| 30 | !! * Substitutions |
|---|
| 31 | # include "vectopt_loop_substitute.h90" |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 34 | !! $Id$ |
|---|
| 35 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | CONTAINS |
|---|
| 38 | |
|---|
| 39 | SUBROUTINE dyn_bfr( kt ) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | !! *** ROUTINE dyn_bfr *** |
|---|
| 42 | !! |
|---|
| 43 | !! ** Purpose : compute the bottom friction ocean dynamics physics. |
|---|
| 44 | !! |
|---|
| 45 | !! ** Action : (ua,va) momentum trend increased by bottom friction trend |
|---|
| 46 | !!--------------------------------------------------------------------- |
|---|
| 47 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 48 | !! |
|---|
| 49 | INTEGER :: jk, ji, jj ! dummy loop indexes |
|---|
| 50 | INTEGER :: ikbu, ikbv ! local integers |
|---|
| 51 | REAL(wp) :: zm1_2dt ! local scalar |
|---|
| 52 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv |
|---|
| 53 | !!--------------------------------------------------------------------- |
|---|
| 54 | ! |
|---|
| 55 | IF( nn_timing == 1 ) CALL timing_start('dyn_bfr') |
|---|
| 56 | ! |
|---|
| 57 | !!gm issue: better to put the logical in step to control the call of zdf_bfr |
|---|
| 58 | !! ==> change the logical from ln_bfrimp to ln_bfr_exp !! |
|---|
| 59 | IF( .NOT.ln_bfrimp) THEN ! only for explicit bottom friction form |
|---|
| 60 | ! implicit bfr is implemented in dynzdf_imp |
|---|
| 61 | |
|---|
| 62 | !!gm bug : time step is only rdt (not 2 rdt if euler start !) |
|---|
| 63 | zm1_2dt = - 1._wp / ( 2._wp * rdt ) |
|---|
| 64 | |
|---|
| 65 | IF( l_trddyn ) THEN ! trends: store the input trends |
|---|
| 66 | CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv ) |
|---|
| 67 | !$OMP PARALLEL DO schedule(static) private(jk, jj, ji) |
|---|
| 68 | DO jk = 1, jpk |
|---|
| 69 | DO jj = 1, jpj |
|---|
| 70 | DO ji = 1, jpi |
|---|
| 71 | ztrdu(ji,jj,jk) = ua(ji,jj,jk) |
|---|
| 72 | ztrdv(ji,jj,jk) = va(ji,jj,jk) |
|---|
| 73 | END DO |
|---|
| 74 | END DO |
|---|
| 75 | END DO |
|---|
| 76 | ENDIF |
|---|
| 77 | |
|---|
| 78 | !$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv) |
|---|
| 79 | DO jj = 2, jpjm1 |
|---|
| 80 | DO ji = 2, jpim1 |
|---|
| 81 | ikbu = mbku(ji,jj) ! deepest ocean u- & v-levels |
|---|
| 82 | ikbv = mbkv(ji,jj) |
|---|
| 83 | ! |
|---|
| 84 | ! Apply stability criteria on absolute value : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt) |
|---|
| 85 | ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX( bfrua(ji,jj) / e3u_n(ji,jj,ikbu) , zm1_2dt ) * ub(ji,jj,ikbu) |
|---|
| 86 | va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX( bfrva(ji,jj) / e3v_n(ji,jj,ikbv) , zm1_2dt ) * vb(ji,jj,ikbv) |
|---|
| 87 | END DO |
|---|
| 88 | END DO |
|---|
| 89 | ! |
|---|
| 90 | IF( ln_isfcav ) THEN ! ocean cavities |
|---|
| 91 | !$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv) |
|---|
| 92 | DO jj = 2, jpjm1 |
|---|
| 93 | DO ji = 2, jpim1 |
|---|
| 94 | ! (ISF) stability criteria for top friction |
|---|
| 95 | ikbu = miku(ji,jj) ! first wet ocean u- & v-levels |
|---|
| 96 | ikbv = mikv(ji,jj) |
|---|
| 97 | ! |
|---|
| 98 | ! Apply stability criteria on absolute value : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt) |
|---|
| 99 | ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX( tfrua(ji,jj) / e3u_n(ji,jj,ikbu) , zm1_2dt ) * ub(ji,jj,ikbu) & |
|---|
| 100 | & * (1.-umask(ji,jj,1)) |
|---|
| 101 | va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX( tfrva(ji,jj) / e3v_n(ji,jj,ikbv) , zm1_2dt ) * vb(ji,jj,ikbv) & |
|---|
| 102 | & * (1.-vmask(ji,jj,1)) |
|---|
| 103 | ! (ISF) |
|---|
| 104 | END DO |
|---|
| 105 | END DO |
|---|
| 106 | END IF |
|---|
| 107 | ! |
|---|
| 108 | IF( l_trddyn ) THEN ! trends: send trends to trddyn for further diagnostics |
|---|
| 109 | !$OMP PARALLEL DO schedule(static) private(jk, jj, ji) |
|---|
| 110 | DO jk = 1, jpk |
|---|
| 111 | DO jj = 1, jpj |
|---|
| 112 | DO ji = 1, jpi |
|---|
| 113 | ztrdu(ji,jj,jk) = ua(ji,jj,jk) - ztrdu(ji,jj,jk) |
|---|
| 114 | ztrdv(ji,jj,jk) = va(ji,jj,jk) - ztrdv(ji,jj,jk) |
|---|
| 115 | END DO |
|---|
| 116 | END DO |
|---|
| 117 | END DO |
|---|
| 118 | CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt ) |
|---|
| 119 | CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv ) |
|---|
| 120 | ENDIF |
|---|
| 121 | ! ! print mean trends (used for debugging) |
|---|
| 122 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' bfr - Ua: ', mask1=umask, & |
|---|
| 123 | & tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
|---|
| 124 | ! |
|---|
| 125 | ENDIF ! end explicit bottom friction |
|---|
| 126 | ! |
|---|
| 127 | IF( nn_timing == 1 ) CALL timing_stop('dyn_bfr') |
|---|
| 128 | ! |
|---|
| 129 | END SUBROUTINE dyn_bfr |
|---|
| 130 | |
|---|
| 131 | !!============================================================================== |
|---|
| 132 | END MODULE dynbfr |
|---|
