New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6748

Last change on this file since 6748 was 6748, checked in by mocavero, 8 years ago

GYRE hybrid parallelization
  • Property svn:keywords set to Id
File size: 70.9 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE wrk_nemo        ! Memory Allocation
47   USE timing          ! Timing
48   USE iom
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC   dyn_hpg        ! routine called by step module
54   PUBLIC   dyn_hpg_init   ! routine called by opa module
55
56   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
57   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
58   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
59   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
60   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
61   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
62   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
63
64   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
65
66   !! * Substitutions
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93!$OMP PARALLEL WORKSHARE
94         ztrdu(:,:,:) = ua(:,:,:)
95         ztrdv(:,:,:) = va(:,:,:)
96!$OMP END PARALLEL WORKSHARE
97      ENDIF
98      !
99      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
100      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
101      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
102      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
103      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
104      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
105      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
106      END SELECT
107      !
108      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
109!$OMP PARALLEL WORKSHARE
110         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
111         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
112!$OMP END PARALLEL WORKSHARE
113         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
114         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
115      ENDIF
116      !
117      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
118         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
119      !
120      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
121      !
122   END SUBROUTINE dyn_hpg
123
124
125   SUBROUTINE dyn_hpg_init
126      !!----------------------------------------------------------------------
127      !!                 ***  ROUTINE dyn_hpg_init  ***
128      !!
129      !! ** Purpose :   initializations for the hydrostatic pressure gradient
130      !!              computation and consistency control
131      !!
132      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
133      !!      with the type of vertical coordinate used (zco, zps, sco)
134      !!----------------------------------------------------------------------
135      INTEGER ::   ioptio = 0      ! temporary integer
136      INTEGER ::   ios             ! Local integer output status for namelist read
137      !!
138      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
139      REAL(wp) ::   znad
140      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
141      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
142      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
143      !!
144      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
145         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
146      !!----------------------------------------------------------------------
147      !
148      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
149      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
150901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
151      !
152      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
153      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
154902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
155      IF(lwm) WRITE ( numond, namdyn_hpg )
156      !
157      IF(lwp) THEN                   ! Control print
158         WRITE(numout,*)
159         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
160         WRITE(numout,*) '~~~~~~~~~~~~'
161         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
162         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
163         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
164         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
165         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
166         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
167         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
168      ENDIF
169      !
170      IF( ln_hpg_djc )   &
171         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
172                           & currently disabled (bugs under investigation). Please select &
173                           & either  ln_hpg_sco or  ln_hpg_prj instead')
174      !
175      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )        &
176         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
177         &                 '   the standard jacobian formulation hpg_sco    or '    , &
178         &                 '   the pressure jacobian formulation hpg_prj'            )
179
180      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
181         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
182      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
183         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
184      !
185      !                               ! Set nhpg from ln_hpg_... flags
186      IF( ln_hpg_zco )   nhpg = 0
187      IF( ln_hpg_zps )   nhpg = 1
188      IF( ln_hpg_sco )   nhpg = 2
189      IF( ln_hpg_djc )   nhpg = 3
190      IF( ln_hpg_prj )   nhpg = 4
191      IF( ln_hpg_isf )   nhpg = 5
192      !
193      !                               ! Consistency check
194      ioptio = 0
195      IF( ln_hpg_zco )   ioptio = ioptio + 1
196      IF( ln_hpg_zps )   ioptio = ioptio + 1
197      IF( ln_hpg_sco )   ioptio = ioptio + 1
198      IF( ln_hpg_djc )   ioptio = ioptio + 1
199      IF( ln_hpg_prj )   ioptio = ioptio + 1
200      IF( ln_hpg_isf )   ioptio = ioptio + 1
201      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
202      !
203      ! initialisation of ice shelf load
204      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
205      IF (       ln_isfcav ) THEN
206         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
207         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
208         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
209         !
210         IF(lwp) WRITE(numout,*)
211         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
212         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
213
214         ! To use density and not density anomaly
215         znad=1._wp
216         
217         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
218         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
219
220         ! compute density of the water displaced by the ice shelf
221         DO jk = 1, jpk
222            CALL eos(ztstop(:,:,:),gdept_n(:,:,jk),zrhd(:,:,jk))
223         END DO
224     
225         ! compute rhd at the ice/oce interface (ice shelf side)
226         CALL eos(ztstop,risfdep,zrhdtop_isf)
227
228         ! Surface value + ice shelf gradient
229         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
230         ! divided by 2 later
231         ziceload = 0._wp
232         DO jj = 1, jpj
233            DO ji = 1, jpi
234               ikt=mikt(ji,jj)
235               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
236               DO jk=2,ikt-1
237                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
238                     &                              * (1._wp - tmask(ji,jj,jk))
239               END DO
240               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
241                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
242            END DO
243         END DO
244!$OMP PARALLEL WORKSHARE
245         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
246!$OMP END PARALLEL WORKSHARE
247
248         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
249         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
250         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
251      END IF
252      !
253   END SUBROUTINE dyn_hpg_init
254
255
256   SUBROUTINE hpg_zco( kt )
257      !!---------------------------------------------------------------------
258      !!                  ***  ROUTINE hpg_zco  ***
259      !!
260      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
261      !!      The now hydrostatic pressure gradient at a given level, jk,
262      !!      is computed by taking the vertical integral of the in-situ
263      !!      density gradient along the model level from the suface to that
264      !!      level:    zhpi = grav .....
265      !!                zhpj = grav .....
266      !!      add it to the general momentum trend (ua,va).
267      !!            ua = ua - 1/e1u * zhpi
268      !!            va = va - 1/e2v * zhpj
269      !!
270      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
271      !!----------------------------------------------------------------------
272      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
273      !
274      INTEGER  ::   ji, jj, jk       ! dummy loop indices
275      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
276      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
277      !!----------------------------------------------------------------------
278      !
279      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
280      !
281      IF( kt == nit000 ) THEN
282         IF(lwp) WRITE(numout,*)
283         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
284         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
285      ENDIF
286
287      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
288
289      ! Surface value
290!$OMP PARALLEL DO private(ji,jj, zcoef1)
291      DO jj = 2, jpjm1
292         DO ji = fs_2, fs_jpim1   ! vector opt.
293            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
294            ! hydrostatic pressure gradient
295            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
296            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
297            ! add to the general momentum trend
298            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
299            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
300         END DO
301      END DO
302
303      !
304      ! interior value (2=<jk=<jpkm1)
305      DO jk = 2, jpkm1
306!$OMP PARALLEL DO private(ji,jj, zcoef1)
307         DO jj = 2, jpjm1
308            DO ji = fs_2, fs_jpim1   ! vector opt.
309               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
310               ! hydrostatic pressure gradient
311               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
312                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
313                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
314
315               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
316                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
317                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
318               ! add to the general momentum trend
319               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
320               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
321            END DO
322         END DO
323      END DO
324      !
325      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
326      !
327   END SUBROUTINE hpg_zco
328
329
330   SUBROUTINE hpg_zps( kt )
331      !!---------------------------------------------------------------------
332      !!                 ***  ROUTINE hpg_zps  ***
333      !!
334      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
335      !!
336      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
337      !!----------------------------------------------------------------------
338      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
339      !!
340      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
341      INTEGER  ::   iku, ikv                         ! temporary integers
342      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
343      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
344      !!----------------------------------------------------------------------
345      !
346      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
347      !
348      IF( kt == nit000 ) THEN
349         IF(lwp) WRITE(numout,*)
350         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
351         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
352      ENDIF
353
354      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
355!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
356
357      ! Local constant initialization
358      zcoef0 = - grav * 0.5_wp
359
360      !  Surface value (also valid in partial step case)
361      DO jj = 2, jpjm1
362         DO ji = fs_2, fs_jpim1   ! vector opt.
363            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
364            ! hydrostatic pressure gradient
365            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
366            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
367            ! add to the general momentum trend
368            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
369            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
370         END DO
371      END DO
372
373      ! interior value (2=<jk=<jpkm1)
374      DO jk = 2, jpkm1
375         DO jj = 2, jpjm1
376            DO ji = fs_2, fs_jpim1   ! vector opt.
377               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
378               ! hydrostatic pressure gradient
379               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
380                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
381                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
382
383               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
384                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
385                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
386               ! add to the general momentum trend
387               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
388               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
389            END DO
390         END DO
391      END DO
392
393      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
394      DO jj = 2, jpjm1
395         DO ji = 2, jpim1
396            iku = mbku(ji,jj)
397            ikv = mbkv(ji,jj)
398            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
399            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
400            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
401               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
402               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
403                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
404               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
405            ENDIF
406            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
407               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
408               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
409                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
410               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
411            ENDIF
412         END DO
413      END DO
414      !
415      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
416      !
417   END SUBROUTINE hpg_zps
418
419
420   SUBROUTINE hpg_sco( kt )
421      !!---------------------------------------------------------------------
422      !!                  ***  ROUTINE hpg_sco  ***
423      !!
424      !! ** Method  :   s-coordinate case. Jacobian scheme.
425      !!      The now hydrostatic pressure gradient at a given level, jk,
426      !!      is computed by taking the vertical integral of the in-situ
427      !!      density gradient along the model level from the suface to that
428      !!      level. s-coordinates (ln_sco): a corrective term is added
429      !!      to the horizontal pressure gradient :
430      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
431      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
432      !!      add it to the general momentum trend (ua,va).
433      !!         ua = ua - 1/e1u * zhpi
434      !!         va = va - 1/e2v * zhpj
435      !!
436      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
437      !!----------------------------------------------------------------------
438      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
439      !!
440      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
441      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
442      LOGICAL  ::   ll_tmp1, ll_tmp2, ll_tmp3            ! local logical variables
443      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
444      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy !W/D pressure filter
445      !!----------------------------------------------------------------------
446      !
447      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
448      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
449      !
450      IF( kt == nit000 ) THEN
451         IF(lwp) WRITE(numout,*)
452         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
453         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
454      ENDIF
455      !
456      zcoef0 = - grav * 0.5_wp
457      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
458      ELSE                    ;   znad = 1._wp         ! Variable volume: density
459      ENDIF
460      !
461      IF(ln_wd) THEN
462        DO jj = 2, jpjm1
463           DO ji = 2, jpim1 
464             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) 
465             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) > rn_wdmin1 + rn_wdmin2
466             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) + &
467                                                       & rn_wdmin1 + rn_wdmin2
468
469             IF(ll_tmp1.AND.ll_tmp2) THEN
470               zcpx(ji,jj) = 1.0_wp
471               wduflt(ji,jj) = 1.0_wp
472             ELSE IF(ll_tmp3) THEN
473               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
474               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) / &
475                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
476               wduflt(ji,jj) = 1.0_wp
477             ELSE
478               zcpx(ji,jj) = 0._wp
479               wduflt(ji,jj) = 0.0_wp
480             END IF
481     
482             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) 
483             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) > rn_wdmin1 + rn_wdmin2
484             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) + &
485                                                       & rn_wdmin1 + rn_wdmin2
486
487             IF(ll_tmp1.AND.ll_tmp2) THEN
488               zcpy(ji,jj) = 1.0_wp
489               wdvflt(ji,jj) = 1.0_wp
490             ELSE IF(ll_tmp3) THEN
491               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
492               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) / &
493                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
494               wdvflt(ji,jj) = 1.0_wp
495             ELSE
496               zcpy(ji,jj) = 0._wp
497               wdvflt(ji,jj) = 0.0_wp
498             END IF
499           END DO
500        END DO
501        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
502      ENDIF
503
504
505      ! Surface value
506      DO jj = 2, jpjm1
507         DO ji = fs_2, fs_jpim1   ! vector opt.
508            ! hydrostatic pressure gradient along s-surfaces
509            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
510               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
511            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
512               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
513            ! s-coordinate pressure gradient correction
514            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
515               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
516            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
517               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
518
519
520            IF(ln_wd) THEN
521
522              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
523              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
524              zuap = zuap * zcpx(ji,jj)
525              zvap = zvap * zcpy(ji,jj)
526            ENDIF
527
528            ! add to the general momentum trend
529            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
530            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
531         END DO
532      END DO
533
534      ! interior value (2=<jk=<jpkm1)
535      DO jk = 2, jpkm1
536         DO jj = 2, jpjm1
537            DO ji = fs_2, fs_jpim1   ! vector opt.
538               ! hydrostatic pressure gradient along s-surfaces
539               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
540                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
541                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
542               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
543                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
544                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
545               ! s-coordinate pressure gradient correction
546               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
547                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
548               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
549                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
550
551               IF(ln_wd) THEN
552                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
553                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
554                 zuap = zuap * zcpx(ji,jj)
555                 zvap = zvap * zcpy(ji,jj)
556               ENDIF
557
558               ! add to the general momentum trend
559               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
560               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
561            END DO
562         END DO
563      END DO
564      !
565      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
566      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
567      !
568   END SUBROUTINE hpg_sco
569
570
571   SUBROUTINE hpg_isf( kt )
572      !!---------------------------------------------------------------------
573      !!                  ***  ROUTINE hpg_isf  ***
574      !!
575      !! ** Method  :   s-coordinate case. Jacobian scheme.
576      !!      The now hydrostatic pressure gradient at a given level, jk,
577      !!      is computed by taking the vertical integral of the in-situ
578      !!      density gradient along the model level from the suface to that
579      !!      level. s-coordinates (ln_sco): a corrective term is added
580      !!      to the horizontal pressure gradient :
581      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
582      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
583      !!      add it to the general momentum trend (ua,va).
584      !!         ua = ua - 1/e1u * zhpi
585      !!         va = va - 1/e2v * zhpj
586      !!      iceload is added and partial cell case are added to the top and bottom
587      !!     
588      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
589      !!----------------------------------------------------------------------
590      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
591      !!
592      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
593      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
594      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
595      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
596      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
597      !!----------------------------------------------------------------------
598      !
599      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
600      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
601      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
602      !
603      ! Local constant initialization
604      zcoef0 = - grav * 0.5_wp
605 
606      ! To use density and not density anomaly
607      znad=1._wp
608
609      ! iniitialised to 0. zhpi zhpi
610      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
611
612      ! compute rhd at the ice/oce interface (ocean side)
613      ! usefull to reduce residual current in the test case ISOMIP with no melting
614      DO ji=1,jpi
615        DO jj=1,jpj
616          ikt=mikt(ji,jj)
617          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
618          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
619        END DO
620      END DO
621      CALL eos( ztstop, risfdep, zrhdtop_oce )
622
623!==================================================================================     
624!===== Compute surface value =====================================================
625!==================================================================================
626      DO jj = 2, jpjm1
627         DO ji = fs_2, fs_jpim1   ! vector opt.
628            ikt    = mikt(ji,jj)
629            iktp1i = mikt(ji+1,jj)
630            iktp1j = mikt(ji,jj+1)
631            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
632            ! we assume ISF is in isostatic equilibrium
633            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
634               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
635               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
636               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
637               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
638            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
639               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
640               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
641               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
642               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
643            ! s-coordinate pressure gradient correction (=0 if z coordinate)
644            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
645               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
646            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
647               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
648            ! add to the general momentum trend
649            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
650            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
651         END DO
652      END DO
653!==================================================================================     
654!===== Compute interior value =====================================================
655!==================================================================================
656      ! interior value (2=<jk=<jpkm1)
657      DO jk = 2, jpkm1
658         DO jj = 2, jpjm1
659            DO ji = fs_2, fs_jpim1   ! vector opt.
660               ! hydrostatic pressure gradient along s-surfaces
661               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
662                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
663                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
664               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
665                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
666                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
667               ! s-coordinate pressure gradient correction
668               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
669                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
670               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
671                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
672               ! add to the general momentum trend
673               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
674               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
675            END DO
676         END DO
677      END DO
678     !
679      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
680      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
681      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
682      !
683   END SUBROUTINE hpg_isf
684
685
686   SUBROUTINE hpg_djc( kt )
687      !!---------------------------------------------------------------------
688      !!                  ***  ROUTINE hpg_djc  ***
689      !!
690      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
691      !!
692      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
693      !!----------------------------------------------------------------------
694      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
695      !!
696      INTEGER  ::   ji, jj, jk          ! dummy loop indices
697      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
698      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
699      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
700      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
701      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
702      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
703      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
704      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
705      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
706      !!----------------------------------------------------------------------
707      !
708      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
709      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
710      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
711      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
712      !
713      !
714      IF(ln_wd) THEN
715        DO jj = 2, jpjm1
716           DO ji = 2, jpim1 
717             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
718                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
719                     &  > rn_wdmin1 + rn_wdmin2
720             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
721                                                       & rn_wdmin1 + rn_wdmin2
722
723             IF(ll_tmp1) THEN
724               zcpx(ji,jj) = 1.0_wp
725             ELSE IF(ll_tmp2) THEN
726               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
727               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
728                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
729             ELSE
730               zcpx(ji,jj) = 0._wp
731             END IF
732     
733             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
734                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
735                     &  > rn_wdmin1 + rn_wdmin2
736             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
737                                                       & rn_wdmin1 + rn_wdmin2
738
739             IF(ll_tmp1) THEN
740               zcpy(ji,jj) = 1.0_wp
741             ELSE IF(ll_tmp2) THEN
742               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
743               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
744                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
745             ELSE
746               zcpy(ji,jj) = 0._wp
747             END IF
748           END DO
749        END DO
750        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
751      ENDIF
752
753
754      IF( kt == nit000 ) THEN
755         IF(lwp) WRITE(numout,*)
756         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
757         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
758      ENDIF
759
760      ! Local constant initialization
761      zcoef0 = - grav * 0.5_wp
762      z1_10  = 1._wp / 10._wp
763      z1_12  = 1._wp / 12._wp
764
765      !----------------------------------------------------------------------------------------
766      !  compute and store in provisional arrays elementary vertical and horizontal differences
767      !----------------------------------------------------------------------------------------
768
769!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
770
771      DO jk = 2, jpkm1
772         DO jj = 2, jpjm1
773            DO ji = fs_2, fs_jpim1   ! vector opt.
774               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
775               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
776               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
777               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
778               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
779               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
780            END DO
781         END DO
782      END DO
783
784      !-------------------------------------------------------------------------
785      ! compute harmonic averages using eq. 5.18
786      !-------------------------------------------------------------------------
787      zep = 1.e-15
788
789!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
790!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
791
792      DO jk = 2, jpkm1
793         DO jj = 2, jpjm1
794            DO ji = fs_2, fs_jpim1   ! vector opt.
795               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
796
797               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
798               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
799
800               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
801               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
802
803               IF( cffw > zep) THEN
804                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
805                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
806               ELSE
807                  drhow(ji,jj,jk) = 0._wp
808               ENDIF
809
810               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
811                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
812
813               IF( cffu > zep ) THEN
814                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
815                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
816               ELSE
817                  drhou(ji,jj,jk ) = 0._wp
818               ENDIF
819
820               IF( cffx > zep ) THEN
821                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
822                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
823               ELSE
824                  dzu(ji,jj,jk) = 0._wp
825               ENDIF
826
827               IF( cffv > zep ) THEN
828                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
829                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
830               ELSE
831                  drhov(ji,jj,jk) = 0._wp
832               ENDIF
833
834               IF( cffy > zep ) THEN
835                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
836                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
837               ELSE
838                  dzv(ji,jj,jk) = 0._wp
839               ENDIF
840
841            END DO
842         END DO
843      END DO
844
845      !----------------------------------------------------------------------------------
846      ! apply boundary conditions at top and bottom using 5.36-5.37
847      !----------------------------------------------------------------------------------
848      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
849      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
850      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
851
852      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
853      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
854      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
855
856
857      !--------------------------------------------------------------
858      ! Upper half of top-most grid box, compute and store
859      !-------------------------------------------------------------
860
861!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
862!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
863
864      DO jj = 2, jpjm1
865         DO ji = fs_2, fs_jpim1   ! vector opt.
866            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
867               &                   * (  rhd(ji,jj,1)                                     &
868               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
869               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
870               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
871         END DO
872      END DO
873
874!!bug gm    : here also, simplification is possible
875!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
876
877      DO jk = 2, jpkm1
878         DO jj = 2, jpjm1
879            DO ji = fs_2, fs_jpim1   ! vector opt.
880
881               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
882                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
883                  &            - grav * z1_10 * (                                                                   &
884                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
885                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
886                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
887                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
888                  &                             )
889
890               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
891                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
892                  &            - grav* z1_10 * (                                                                    &
893                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
894                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
895                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
896                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
897                  &                            )
898
899               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
900                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
901                  &            - grav* z1_10 * (                                                                    &
902                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
903                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
904                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
905                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
906                  &                            )
907
908            END DO
909         END DO
910      END DO
911      CALL lbc_lnk(rho_k,'W',1.)
912      CALL lbc_lnk(rho_i,'U',1.)
913      CALL lbc_lnk(rho_j,'V',1.)
914
915
916      ! ---------------
917      !  Surface value
918      ! ---------------
919      DO jj = 2, jpjm1
920         DO ji = fs_2, fs_jpim1   ! vector opt.
921            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
922            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
923            IF(ln_wd) THEN
924              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
925              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
926            ENDIF
927            ! add to the general momentum trend
928            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
929            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
930         END DO
931      END DO
932
933      ! ----------------
934      !  interior value   (2=<jk=<jpkm1)
935      ! ----------------
936      DO jk = 2, jpkm1
937         DO jj = 2, jpjm1
938            DO ji = fs_2, fs_jpim1   ! vector opt.
939               ! hydrostatic pressure gradient along s-surfaces
940               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
941                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
942                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
943               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
944                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
945                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
946               IF(ln_wd) THEN
947                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
948                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
949               ENDIF
950               ! add to the general momentum trend
951               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
952               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
953            END DO
954         END DO
955      END DO
956      !
957      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
958      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
959      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
960      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
961      !
962   END SUBROUTINE hpg_djc
963
964
965   SUBROUTINE hpg_prj( kt )
966      !!---------------------------------------------------------------------
967      !!                  ***  ROUTINE hpg_prj  ***
968      !!
969      !! ** Method  :   s-coordinate case.
970      !!      A Pressure-Jacobian horizontal pressure gradient method
971      !!      based on the constrained cubic-spline interpolation for
972      !!      all vertical coordinate systems
973      !!
974      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
975      !!----------------------------------------------------------------------
976      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
977      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
978      !!
979      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
980      REAL(wp) ::   zcoef0, znad                    ! local scalars
981      !
982      !! The local variables for the correction term
983      INTEGER  :: jk1, jis, jid, jjs, jjd
984      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
985      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
986      REAL(wp) :: zrhdt1
987      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
988      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
989      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
990      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
991      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
992      !!----------------------------------------------------------------------
993      !
994      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
995      CALL wrk_alloc( jpi,jpj,jpk,   zdept, zrhh )
996      CALL wrk_alloc( jpi,jpj,       zsshu_n, zsshv_n )
997      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
998      !
999      IF( kt == nit000 ) THEN
1000         IF(lwp) WRITE(numout,*)
1001         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1002         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
1003      ENDIF
1004
1005      ! Local constant initialization
1006      zcoef0 = - grav
1007      znad = 1._wp
1008      IF( ln_linssh )   znad = 0._wp
1009
1010      IF(ln_wd) THEN
1011        DO jj = 2, jpjm1
1012           DO ji = 2, jpim1 
1013             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
1014                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
1015                     &  > rn_wdmin1 + rn_wdmin2
1016             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
1017                                                       & rn_wdmin1 + rn_wdmin2
1018
1019             IF(ll_tmp1) THEN
1020               zcpx(ji,jj) = 1.0_wp
1021             ELSE IF(ll_tmp2) THEN
1022               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
1023               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
1024                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
1025             ELSE
1026               zcpx(ji,jj) = 0._wp
1027             END IF
1028     
1029             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
1030                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
1031                     &  > rn_wdmin1 + rn_wdmin2
1032             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
1033                                                       & rn_wdmin1 + rn_wdmin2
1034
1035             IF(ll_tmp1.OR.ll_tmp2) THEN
1036               zcpy(ji,jj) = 1.0_wp
1037             ELSE IF(ll_tmp2) THEN
1038               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
1039               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
1040                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
1041             ELSE
1042               zcpy(ji,jj) = 0._wp
1043             END IF
1044           END DO
1045        END DO
1046        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
1047      ENDIF
1048
1049      ! Clean 3-D work arrays
1050      zhpi(:,:,:) = 0._wp
1051      zrhh(:,:,:) = rhd(:,:,:)
1052
1053      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1054      DO jj = 1, jpj
1055        DO ji = 1, jpi
1056          jk = mbathy(ji,jj)
1057          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1058          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1059          ELSEIF( jk < jpkm1 ) THEN
1060             DO jkk = jk+1, jpk
1061                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1062                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1063             END DO
1064          ENDIF
1065        END DO
1066      END DO
1067
1068      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1069      DO jj = 1, jpj
1070         DO ji = 1, jpi
1071            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1072         END DO
1073      END DO
1074
1075      DO jk = 2, jpk
1076         DO jj = 1, jpj
1077            DO ji = 1, jpi
1078               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1079            END DO
1080         END DO
1081      END DO
1082
1083      fsp(:,:,:) = zrhh (:,:,:)
1084      xsp(:,:,:) = zdept(:,:,:)
1085
1086      ! Construct the vertical density profile with the
1087      ! constrained cubic spline interpolation
1088      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1089      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1090
1091      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1092      DO jj = 2, jpj
1093        DO ji = 2, jpi
1094          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1095             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1096
1097          ! assuming linear profile across the top half surface layer
1098          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1099        END DO
1100      END DO
1101
1102      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1103      DO jk = 2, jpkm1
1104        DO jj = 2, jpj
1105          DO ji = 2, jpi
1106            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1107               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1108               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1109               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1110          END DO
1111        END DO
1112      END DO
1113
1114      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1115
1116      ! Prepare zsshu_n and zsshv_n
1117      DO jj = 2, jpjm1
1118        DO ji = 2, jpim1
1119!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1120!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1121!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1122!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1123!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1124!!gm not this:
1125          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1126                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1127          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1128                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1129        END DO
1130      END DO
1131
1132      CALL lbc_lnk (zsshu_n, 'U', 1.)
1133      CALL lbc_lnk (zsshv_n, 'V', 1.)
1134
1135      DO jj = 2, jpjm1
1136        DO ji = 2, jpim1
1137          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1138          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1139        END DO
1140      END DO
1141
1142      DO jk = 2, jpkm1
1143        DO jj = 2, jpjm1
1144          DO ji = 2, jpim1
1145            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1146            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1147          END DO
1148        END DO
1149      END DO
1150
1151      DO jk = 1, jpkm1
1152        DO jj = 2, jpjm1
1153          DO ji = 2, jpim1
1154            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1155            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1156          END DO
1157        END DO
1158      END DO
1159
1160      DO jk = 1, jpkm1
1161        DO jj = 2, jpjm1
1162          DO ji = 2, jpim1
1163            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1164            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1165            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1166            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1167          END DO
1168        END DO
1169      END DO
1170
1171
1172      DO jk = 1, jpkm1
1173        DO jj = 2, jpjm1
1174          DO ji = 2, jpim1
1175            zpwes = 0._wp; zpwed = 0._wp
1176            zpnss = 0._wp; zpnsd = 0._wp
1177            zuijk = zu(ji,jj,jk)
1178            zvijk = zv(ji,jj,jk)
1179
1180            !!!!!     for u equation
1181            IF( jk <= mbku(ji,jj) ) THEN
1182               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1183                 jis = ji + 1; jid = ji
1184               ELSE
1185                 jis = ji;     jid = ji +1
1186               ENDIF
1187
1188               ! integrate the pressure on the shallow side
1189               jk1 = jk
1190               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1191                 IF( jk1 == mbku(ji,jj) ) THEN
1192                   zuijk = -zdept(jis,jj,jk1)
1193                   EXIT
1194                 ENDIF
1195                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1196                 zpwes = zpwes +                                    &
1197                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1198                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1199                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1200                 jk1 = jk1 + 1
1201               END DO
1202
1203               ! integrate the pressure on the deep side
1204               jk1 = jk
1205               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1206                 IF( jk1 == 1 ) THEN
1207                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1208                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1209                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1210                                                     dsp(jid,jj,1)) * zdeps
1211                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1212                   EXIT
1213                 ENDIF
1214                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1215                 zpwed = zpwed +                                        &
1216                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1217                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1218                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1219                 jk1 = jk1 - 1
1220               END DO
1221
1222               ! update the momentum trends in u direction
1223
1224               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1225               IF( .NOT.ln_linssh ) THEN
1226                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1227                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1228                ELSE
1229                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1230               ENDIF
1231               IF(ln_wd) THEN
1232                  zdpdx1 = zdpdx1 * zcpx(ji,jj)
1233                  zdpdx2 = zdpdx2 * zcpx(ji,jj)
1234               ENDIF
1235               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1236            ENDIF
1237
1238            !!!!!     for v equation
1239            IF( jk <= mbkv(ji,jj) ) THEN
1240               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1241                 jjs = jj + 1; jjd = jj
1242               ELSE
1243                 jjs = jj    ; jjd = jj + 1
1244               ENDIF
1245
1246               ! integrate the pressure on the shallow side
1247               jk1 = jk
1248               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1249                 IF( jk1 == mbkv(ji,jj) ) THEN
1250                   zvijk = -zdept(ji,jjs,jk1)
1251                   EXIT
1252                 ENDIF
1253                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1254                 zpnss = zpnss +                                      &
1255                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1256                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1257                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1258                 jk1 = jk1 + 1
1259               END DO
1260
1261               ! integrate the pressure on the deep side
1262               jk1 = jk
1263               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1264                 IF( jk1 == 1 ) THEN
1265                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1266                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1267                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1268                                                     dsp(ji,jjd,1) ) * zdeps
1269                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1270                   EXIT
1271                 ENDIF
1272                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1273                 zpnsd = zpnsd +                                        &
1274                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1275                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1276                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1277                 jk1 = jk1 - 1
1278               END DO
1279
1280
1281               ! update the momentum trends in v direction
1282
1283               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1284               IF( .NOT.ln_linssh ) THEN
1285                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1286                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1287               ELSE
1288                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1289               ENDIF
1290               IF(ln_wd) THEN
1291                  zdpdy1 = zdpdy1 * zcpy(ji,jj)
1292                  zdpdy2 = zdpdy2 * zcpy(ji,jj)
1293               ENDIF
1294
1295               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1296            ENDIF
1297               !
1298            END DO
1299         END DO
1300      END DO
1301      !
1302      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1303      CALL wrk_dealloc( jpi,jpj,jpk,   zdept, zrhh )
1304      CALL wrk_dealloc( jpi,jpj,       zsshu_n, zsshv_n )
1305      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1306      !
1307   END SUBROUTINE hpg_prj
1308
1309
1310   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1311      !!----------------------------------------------------------------------
1312      !!                 ***  ROUTINE cspline  ***
1313      !!
1314      !! ** Purpose :   constrained cubic spline interpolation
1315      !!
1316      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1317      !!
1318      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1319      !!----------------------------------------------------------------------
1320      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1321      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1322      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1323      !
1324      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1325      INTEGER  ::   jpi, jpj, jpkm1
1326      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1327      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1328      REAL(wp) ::   zdf(size(fsp,3))
1329      !!----------------------------------------------------------------------
1330      !
1331!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1332      jpi   = size(fsp,1)
1333      jpj   = size(fsp,2)
1334      jpkm1 = size(fsp,3) - 1
1335      !
1336      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1337         DO ji = 1, jpi
1338            DO jj = 1, jpj
1339           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1340           !    DO jk = 2, jpkm1-1
1341           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1342           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1343           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1344           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1345           !
1346           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1347           !
1348           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1349           !           zdf(jk) = 0._wp
1350           !       ELSE
1351           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1352           !       ENDIF
1353           !    END DO
1354
1355           !!Simply geometric average
1356               DO jk = 2, jpkm1-1
1357                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1358                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1359
1360                  IF(zdf1 * zdf2 <= 0._wp) THEN
1361                     zdf(jk) = 0._wp
1362                  ELSE
1363                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1364                  ENDIF
1365               END DO
1366
1367               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1368                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1369               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1370                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1371
1372               DO jk = 1, jpkm1 - 1
1373                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1374                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1375                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1376                 zddf1  = -2._wp * ztmp1 + ztmp2
1377                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1378                 zddf2  =  2._wp * ztmp1 - ztmp2
1379
1380                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1381                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1382                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1383                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1384                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1385                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1386                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1387                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1388                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1389               END DO
1390            END DO
1391         END DO
1392
1393      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1394         DO ji = 1, jpi
1395            DO jj = 1, jpj
1396               DO jk = 1, jpkm1-1
1397                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1398                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1399
1400                  dsp(ji,jj,jk) = 0._wp
1401                  csp(ji,jj,jk) = 0._wp
1402                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1403                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1404               END DO
1405            END DO
1406         END DO
1407
1408      ELSE
1409           CALL ctl_stop( 'invalid polynomial type in cspline' )
1410      ENDIF
1411
1412   END SUBROUTINE cspline
1413
1414
1415   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1416      !!----------------------------------------------------------------------
1417      !!                 ***  ROUTINE interp1  ***
1418      !!
1419      !! ** Purpose :   1-d linear interpolation
1420      !!
1421      !! ** Method  :   interpolation is straight forward
1422      !!                extrapolation is also permitted (no value limit)
1423      !!----------------------------------------------------------------------
1424      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1425      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1426      REAL(wp)             ::  zdeltx
1427      !!----------------------------------------------------------------------
1428      !
1429      zdeltx = xr - xl
1430      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1431         f = 0.5_wp * (fl + fr)
1432      ELSE
1433         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1434      ENDIF
1435      !
1436   END FUNCTION interp1
1437
1438
1439   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1440      !!----------------------------------------------------------------------
1441      !!                 ***  ROUTINE interp1  ***
1442      !!
1443      !! ** Purpose :   1-d constrained cubic spline interpolation
1444      !!
1445      !! ** Method  :  cubic spline interpolation
1446      !!
1447      !!----------------------------------------------------------------------
1448      REAL(wp), INTENT(in) ::  x, a, b, c, d
1449      REAL(wp)             ::  f ! value from the interpolation
1450      !!----------------------------------------------------------------------
1451      !
1452      f = a + x* ( b + x * ( c + d * x ) )
1453      !
1454   END FUNCTION interp2
1455
1456
1457   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1458      !!----------------------------------------------------------------------
1459      !!                 ***  ROUTINE interp1  ***
1460      !!
1461      !! ** Purpose :   Calculate the first order of deriavtive of
1462      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1463      !!
1464      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1465      !!
1466      !!----------------------------------------------------------------------
1467      REAL(wp), INTENT(in) ::  x, a, b, c, d
1468      REAL(wp)             ::  f ! value from the interpolation
1469      !!----------------------------------------------------------------------
1470      !
1471      f = b + x * ( 2._wp * c + 3._wp * d * x)
1472      !
1473   END FUNCTION interp3
1474
1475
1476   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1477      !!----------------------------------------------------------------------
1478      !!                 ***  ROUTINE interp1  ***
1479      !!
1480      !! ** Purpose :   1-d constrained cubic spline integration
1481      !!
1482      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1483      !!
1484      !!----------------------------------------------------------------------
1485      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1486      REAL(wp)             ::  za1, za2, za3
1487      REAL(wp)             ::  f                   ! integration result
1488      !!----------------------------------------------------------------------
1489      !
1490      za1 = 0.5_wp * b
1491      za2 = c / 3.0_wp
1492      za3 = 0.25_wp * d
1493      !
1494      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1495         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1496      !
1497   END FUNCTION integ_spline
1498
1499   !!======================================================================
1500END MODULE dynhpg
1501
Note: See TracBrowser for help on using the repository browser.