New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf_imp.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf_imp.F90 @ 6748

Last change on this file since 6748 was 6748, checked in by mocavero, 8 years ago

GYRE hybrid parallelization
  • Property svn:keywords set to Id
File size: 17.1 KB
Line 
1MODULE dynzdf_imp
2   !!======================================================================
3   !!                    ***  MODULE  dynzdf_imp  ***
4   !! Ocean dynamics:  vertical component(s) of the momentum mixing trend, implicit scheme
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            8.0  !  1997-05  (G. Madec)  vertical component of isopycnal
8   !!   NEMO     0.5  !  2002-08  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!            3.4  !  2012-01  (H. Liu) Semi-implicit bottom friction
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   dyn_zdf_imp   : compute the vertical diffusion using a implicit scheme
15   !!                   together with the Leap-Frog time integration.
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable volume
21   USE sbc_oce        ! surface boundary condition: ocean
22   USE dynadv   , ONLY: ln_dynadv_vec ! Momentum advection form
23   USE zdf_oce        ! ocean vertical physics
24   USE zdfbfr         ! Bottom friction setup
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! Memory Allocation
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf_imp   ! called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dyn_zdf_imp( kt, p2dt )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_zdf_imp  ***
50      !!                   
51      !! ** Purpose :   Compute the trend due to the vert. momentum diffusion
52      !!              together with the Leap-Frog time stepping using an
53      !!              implicit scheme.
54      !!
55      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
56      !!         ua =         ub + 2*dt *       ua             vector form or linear free surf.
57      !!         ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a   otherwise
58      !!               - update the after velocity with the implicit vertical mixing.
59      !!      This requires to solver the following system:
60      !!         ua = ua + 1/e3u_a dk+1[ avmu / e3uw_a dk[ua] ]
61      !!      with the following surface/top/bottom boundary condition:
62      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
63      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfbfr.F)
64      !!
65      !! ** Action :   (ua,va) after velocity
66      !!---------------------------------------------------------------------
67      INTEGER , INTENT(in) ::  kt     ! ocean time-step index
68      REAL(wp), INTENT(in) ::  p2dt   ! vertical profile of tracer time-step
69      !
70      INTEGER  ::   ji, jj, jk    ! dummy loop indices
71      INTEGER  ::   ikbu, ikbv    ! local integers
72      REAL(wp) ::   zzwi, ze3ua   ! local scalars
73      REAL(wp) ::   zzws, ze3va   !   -      -
74      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwi, zwd, zws
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('dyn_zdf_imp')
78      !
79      CALL wrk_alloc( jpi,jpj,jpk, zwi, zwd, zws ) 
80      !
81      IF( kt == nit000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
84         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
85         !
86         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
87         ELSE                   ;    r_vvl = 1._wp
88         ENDIF
89      ENDIF
90      !
91      !              !==  Time step dynamics  ==!
92      !
93      IF( ln_dynadv_vec .OR. ln_linssh ) THEN      ! applied on velocity
94         DO jk = 1, jpkm1
95            ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk)
96            va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk)
97         END DO
98      ELSE                                         ! applied on thickness weighted velocity
99         DO jk = 1, jpkm1
100            ua(:,:,jk) = (         e3u_b(:,:,jk) * ub(:,:,jk)  &
101               &          + p2dt * e3u_n(:,:,jk) * ua(:,:,jk)  ) / e3u_a(:,:,jk) * umask(:,:,jk)
102            va(:,:,jk) = (         e3v_b(:,:,jk) * vb(:,:,jk)  &
103               &          + p2dt * e3v_n(:,:,jk) * va(:,:,jk)  ) / e3v_a(:,:,jk) * vmask(:,:,jk)
104         END DO
105      ENDIF
106      !
107      !              !==  Apply semi-implicit bottom friction  ==!
108      !
109      ! Only needed for semi-implicit bottom friction setup. The explicit
110      ! bottom friction has been included in "u(v)a" which act as the R.H.S
111      ! column vector of the tri-diagonal matrix equation
112      !
113      IF( ln_bfrimp ) THEN
114!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
115         DO jj = 2, jpjm1
116            DO ji = 2, jpim1
117               ikbu = mbku(ji,jj)       ! ocean bottom level at u- and v-points
118               ikbv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
119               avmu(ji,jj,ikbu+1) = -bfrua(ji,jj) * e3uw_n(ji,jj,ikbu+1)
120               avmv(ji,jj,ikbv+1) = -bfrva(ji,jj) * e3vw_n(ji,jj,ikbv+1)
121            END DO
122         END DO
123         IF ( ln_isfcav ) THEN
124!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
125            DO jj = 2, jpjm1
126               DO ji = 2, jpim1
127                  ikbu = miku(ji,jj)       ! ocean top level at u- and v-points
128                  ikbv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
129                  IF( ikbu >= 2 )   avmu(ji,jj,ikbu) = -tfrua(ji,jj) * e3uw_n(ji,jj,ikbu)
130                  IF( ikbv >= 2 )   avmv(ji,jj,ikbv) = -tfrva(ji,jj) * e3vw_n(ji,jj,ikbv)
131               END DO
132            END DO
133         END IF
134      ENDIF
135      !
136      ! With split-explicit free surface, barotropic stress is treated explicitly
137      ! Update velocities at the bottom.
138      ! J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
139      !            not lead to the effective stress seen over the whole barotropic loop.
140      ! G. Madec : in linear free surface, e3u_a = e3u_n = e3u_0, so systematic use of e3u_a
141      IF( ln_bfrimp .AND. ln_dynspg_ts ) THEN
142         DO jk = 1, jpkm1        ! remove barotropic velocities
143            ua(:,:,jk) = ( ua(:,:,jk) - ua_b(:,:) ) * umask(:,:,jk)
144            va(:,:,jk) = ( va(:,:,jk) - va_b(:,:) ) * vmask(:,:,jk)
145         END DO
146         DO jj = 2, jpjm1        ! Add bottom/top stress due to barotropic component only
147            DO ji = fs_2, fs_jpim1   ! vector opt.
148               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
149               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
150               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
151               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
152               ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * bfrua(ji,jj) * ua_b(ji,jj) / ze3ua
153               va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * bfrva(ji,jj) * va_b(ji,jj) / ze3va
154            END DO
155         END DO
156         IF( ln_isfcav ) THEN    ! Ocean cavities (ISF)
157            DO jj = 2, jpjm1       
158               DO ji = fs_2, fs_jpim1   ! vector opt.
159                  ikbu = miku(ji,jj)         ! top ocean level at u- and v-points
160                  ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
161                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
162                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
163                  ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * tfrua(ji,jj) * ua_b(ji,jj) / ze3ua
164                  va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * tfrva(ji,jj) * va_b(ji,jj) / ze3va
165               END DO
166            END DO
167         END IF
168      ENDIF
169      !
170      !              !==  Vertical diffusion on u  ==!
171      !
172      ! Matrix and second member construction
173      ! bottom boundary condition: both zwi and zws must be masked as avmu can take
174      ! non zero value at the ocean bottom depending on the bottom friction used.
175      !
176!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, ze3ua, zzwi, zzws)
177      DO jk = 1, jpkm1        ! Matrix
178         DO jj = 2, jpjm1 
179            DO ji = fs_2, fs_jpim1   ! vector opt.
180               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,jk) + r_vvl * e3u_a(ji,jj,jk)   ! after scale factor at T-point
181               zzwi = - p2dt * avmu(ji,jj,jk  ) / ( ze3ua * e3uw_n(ji,jj,jk  ) )
182               zzws = - p2dt * avmu(ji,jj,jk+1) / ( ze3ua * e3uw_n(ji,jj,jk+1) )
183               zwi(ji,jj,jk) = zzwi * wumask(ji,jj,jk  )
184               zws(ji,jj,jk) = zzws * wumask(ji,jj,jk+1)
185               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
186            END DO
187         END DO
188      END DO
189      DO jj = 2, jpjm1        ! Surface boundary conditions
190         DO ji = fs_2, fs_jpim1   ! vector opt.
191            zwi(ji,jj,1) = 0._wp
192            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
193         END DO
194      END DO
195
196      ! Matrix inversion starting from the first level
197      !-----------------------------------------------------------------------
198      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
199      !
200      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
201      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
202      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
203      !        (        ...               )( ...  ) ( ...  )
204      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
205      !
206      !   m is decomposed in the product of an upper and a lower triangular matrix
207      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
208      !   The solution (the after velocity) is in ua
209      !-----------------------------------------------------------------------
210      !
211      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
212!$OMP PARALLEL DO schedule(static) private(jj, ji)
213         DO jj = 2, jpjm1   
214            DO ji = fs_2, fs_jpim1   ! vector opt.
215               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
216            END DO
217         END DO
218      END DO
219      !
220!$OMP PARALLEL DO schedule(static) private(jj, ji, ze3ua)
221      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
222         DO ji = fs_2, fs_jpim1   ! vector opt.
223            ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,1) + r_vvl * e3u_a(ji,jj,1) 
224            ua(ji,jj,1) = ua(ji,jj,1) + p2dt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
225               &                                      / ( ze3ua * rau0 ) * umask(ji,jj,1) 
226         END DO
227      END DO
228      DO jk = 2, jpkm1
229!$OMP PARALLEL DO schedule(static) private(jj, ji)
230         DO jj = 2, jpjm1
231            DO ji = fs_2, fs_jpim1
232               ua(ji,jj,jk) = ua(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * ua(ji,jj,jk-1)
233            END DO
234         END DO
235      END DO
236      !
237!$OMP PARALLEL DO schedule(static) private(jj, ji)
238        DO jj = 2, jpjm1        !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
239         DO ji = fs_2, fs_jpim1   ! vector opt.
240            ua(ji,jj,jpkm1) = ua(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
241         END DO
242      END DO
243      DO jk = jpk-2, 1, -1
244!$OMP PARALLEL DO schedule(static) private(jj, ji)
245        DO jj = 2, jpjm1
246            DO ji = fs_2, fs_jpim1
247               ua(ji,jj,jk) = ( ua(ji,jj,jk) - zws(ji,jj,jk) * ua(ji,jj,jk+1) ) / zwd(ji,jj,jk)
248            END DO
249         END DO
250      END DO
251      !
252      !              !==  Vertical diffusion on v  ==!
253      !
254      ! Matrix and second member construction
255      ! bottom boundary condition: both zwi and zws must be masked as avmv can take
256      ! non zero value at the ocean bottom depending on the bottom friction used
257      !
258!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, ze3va, zzwi, zzws)
259      DO jk = 1, jpkm1        ! Matrix
260         DO jj = 2, jpjm1   
261            DO ji = fs_2, fs_jpim1   ! vector opt.
262               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,jk) + r_vvl * e3v_a(ji,jj,jk)   ! after scale factor at T-point
263               zzwi = - p2dt * avmv (ji,jj,jk  ) / ( ze3va * e3vw_n(ji,jj,jk  ) )
264               zzws = - p2dt * avmv (ji,jj,jk+1) / ( ze3va * e3vw_n(ji,jj,jk+1) )
265               zwi(ji,jj,jk) = zzwi * wvmask(ji,jj,jk  )
266               zws(ji,jj,jk) = zzws * wvmask(ji,jj,jk+1)
267               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
268            END DO
269         END DO
270      END DO
271!$OMP PARALLEL DO schedule(static) private(jj, ji)
272      DO jj = 2, jpjm1        ! Surface boundary conditions
273         DO ji = fs_2, fs_jpim1   ! vector opt.
274            zwi(ji,jj,1) = 0._wp
275            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
276         END DO
277      END DO
278
279      ! Matrix inversion
280      !-----------------------------------------------------------------------
281      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
282      !
283      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
284      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
285      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
286      !        (        ...               )( ...  ) ( ...  )
287      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
288      !
289      !   m is decomposed in the product of an upper and lower triangular matrix
290      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
291      !   The solution (after velocity) is in 2d array va
292      !-----------------------------------------------------------------------
293      !
294      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
295!$OMP PARALLEL DO schedule(static) private(jj, ji)
296         DO jj = 2, jpjm1   
297            DO ji = fs_2, fs_jpim1   ! vector opt.
298               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
299            END DO
300         END DO
301      END DO
302      !
303!$OMP PARALLEL DO schedule(static) private(jj, ji, ze3va)
304      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
305         DO ji = fs_2, fs_jpim1   ! vector opt.         
306            ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,1) + r_vvl * e3v_a(ji,jj,1) 
307            va(ji,jj,1) = va(ji,jj,1) + p2dt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
308               &                                      / ( ze3va * rau0 ) 
309         END DO
310      END DO
311      DO jk = 2, jpkm1
312!$OMP PARALLEL DO schedule(static) private(jj, ji)
313         DO jj = 2, jpjm1
314            DO ji = fs_2, fs_jpim1   ! vector opt.
315               va(ji,jj,jk) = va(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * va(ji,jj,jk-1)
316            END DO
317         END DO
318      END DO
319      !
320!$OMP PARALLEL DO schedule(static) private(jj, ji)
321      DO jj = 2, jpjm1        !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
322         DO ji = fs_2, fs_jpim1   ! vector opt.
323            va(ji,jj,jpkm1) = va(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
324         END DO
325      END DO
326      DO jk = jpk-2, 1, -1
327!$OMP PARALLEL DO schedule(static) private(jj, ji)
328         DO jj = 2, jpjm1
329            DO ji = fs_2, fs_jpim1
330               va(ji,jj,jk) = ( va(ji,jj,jk) - zws(ji,jj,jk) * va(ji,jj,jk+1) ) / zwd(ji,jj,jk)
331            END DO
332         END DO
333      END DO
334     
335      ! J. Chanut: Lines below are useless ?
336      !! restore bottom layer avmu(v)
337      !!gm  I almost sure it is !!!!
338      IF( ln_bfrimp ) THEN
339!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
340        DO jj = 2, jpjm1
341           DO ji = 2, jpim1
342              ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
343              ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
344              avmu(ji,jj,ikbu+1) = 0._wp
345              avmv(ji,jj,ikbv+1) = 0._wp
346           END DO
347        END DO
348        IF (ln_isfcav) THEN
349!$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv)
350           DO jj = 2, jpjm1
351              DO ji = 2, jpim1
352                 ikbu = miku(ji,jj)         ! ocean top level at u- and v-points
353                 ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
354                 IF( ikbu > 1 )   avmu(ji,jj,ikbu) = 0._wp
355                 IF( ikbv > 1 )   avmv(ji,jj,ikbv) = 0._wp
356              END DO
357           END DO
358        ENDIF
359      ENDIF
360      !
361      CALL wrk_dealloc( jpi,jpj,jpk,   zwi, zwd, zws) 
362      !
363      IF( nn_timing == 1 )   CALL timing_stop('dyn_zdf_imp')
364      !
365   END SUBROUTINE dyn_zdf_imp
366
367   !!==============================================================================
368END MODULE dynzdf_imp
Note: See TracBrowser for help on using the repository browser.