| 1 | MODULE sshwzv |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE sshwzv *** |
|---|
| 4 | !! Ocean dynamics : sea surface height and vertical velocity |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : 3.1 ! 2009-02 (G. Madec, M. Leclair) Original code |
|---|
| 7 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA |
|---|
| 8 | !! - ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 9 | !! - ! 2010-09 (D.Storkey and E.O'Dea) bug fixes for BDY module |
|---|
| 10 | !! 3.3 ! 2011-10 (M. Leclair) split former ssh_wzv routine and remove all vvl related work |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! ssh_nxt : after ssh |
|---|
| 15 | !! ssh_swp : filter ans swap the ssh arrays |
|---|
| 16 | !! wzv : compute now vertical velocity |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers variables |
|---|
| 19 | USE dom_oce ! ocean space and time domain variables |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE domvvl ! Variable volume |
|---|
| 22 | USE divhor ! horizontal divergence |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE bdy_oce ! |
|---|
| 25 | USE bdy_par ! |
|---|
| 26 | USE bdydyn2d ! bdy_ssh routine |
|---|
| 27 | #if defined key_agrif |
|---|
| 28 | USE agrif_opa_interp |
|---|
| 29 | #endif |
|---|
| 30 | #if defined key_asminc |
|---|
| 31 | USE asminc ! Assimilation increment |
|---|
| 32 | #endif |
|---|
| 33 | ! |
|---|
| 34 | USE in_out_manager ! I/O manager |
|---|
| 35 | USE restart ! only for lrst_oce |
|---|
| 36 | USE prtctl ! Print control |
|---|
| 37 | USE lbclnk ! ocean lateral boundary condition (or mpp link) |
|---|
| 38 | USE lib_mpp ! MPP library |
|---|
| 39 | USE wrk_nemo ! Memory Allocation |
|---|
| 40 | USE timing ! Timing |
|---|
| 41 | USE wet_dry ! Wetting/Drying flux limting |
|---|
| 42 | |
|---|
| 43 | IMPLICIT NONE |
|---|
| 44 | PRIVATE |
|---|
| 45 | |
|---|
| 46 | PUBLIC ssh_nxt ! called by step.F90 |
|---|
| 47 | PUBLIC wzv ! called by step.F90 |
|---|
| 48 | PUBLIC ssh_swp ! called by step.F90 |
|---|
| 49 | |
|---|
| 50 | !! * Substitutions |
|---|
| 51 | # include "vectopt_loop_substitute.h90" |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 54 | !! $Id$ |
|---|
| 55 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | CONTAINS |
|---|
| 58 | |
|---|
| 59 | SUBROUTINE ssh_nxt( kt ) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! *** ROUTINE ssh_nxt *** |
|---|
| 62 | !! |
|---|
| 63 | !! ** Purpose : compute the after ssh (ssha) |
|---|
| 64 | !! |
|---|
| 65 | !! ** Method : - Using the incompressibility hypothesis, the ssh increment |
|---|
| 66 | !! is computed by integrating the horizontal divergence and multiply by |
|---|
| 67 | !! by the time step. |
|---|
| 68 | !! |
|---|
| 69 | !! ** action : ssha, after sea surface height |
|---|
| 70 | !! |
|---|
| 71 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | INTEGER, INTENT(in) :: kt ! time step |
|---|
| 74 | ! |
|---|
| 75 | INTEGER :: jk, jj, ji ! dummy loop indice |
|---|
| 76 | REAL(wp) :: z2dt, zcoef ! local scalars |
|---|
| 77 | REAL(wp), POINTER, DIMENSION(:,: ) :: zhdiv ! 2D workspace |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | ! |
|---|
| 80 | IF( nn_timing == 1 ) CALL timing_start('ssh_nxt') |
|---|
| 81 | ! |
|---|
| 82 | CALL wrk_alloc( jpi,jpj, zhdiv ) |
|---|
| 83 | ! |
|---|
| 84 | IF( kt == nit000 ) THEN |
|---|
| 85 | IF(lwp) WRITE(numout,*) |
|---|
| 86 | IF(lwp) WRITE(numout,*) 'ssh_nxt : after sea surface height' |
|---|
| 87 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 88 | ENDIF |
|---|
| 89 | ! |
|---|
| 90 | CALL div_hor( kt ) ! Horizontal divergence |
|---|
| 91 | ! |
|---|
| 92 | z2dt = 2._wp * rdt ! set time step size (Euler/Leapfrog) |
|---|
| 93 | IF( neuler == 0 .AND. kt == nit000 ) z2dt = rdt |
|---|
| 94 | |
|---|
| 95 | ! !------------------------------! |
|---|
| 96 | ! ! After Sea Surface Height ! |
|---|
| 97 | ! !------------------------------! |
|---|
| 98 | !$OMP PARALLEL |
|---|
| 99 | !$OMP DO schedule(static) private(jj, ji) |
|---|
| 100 | DO jj = 1, jpj |
|---|
| 101 | DO ji = 1, jpi |
|---|
| 102 | zhdiv(ji,jj) = 0._wp |
|---|
| 103 | END DO |
|---|
| 104 | END DO |
|---|
| 105 | DO jk = 1, jpkm1 ! Horizontal divergence of barotropic transports |
|---|
| 106 | !$OMP DO schedule(static) private(jj, ji) |
|---|
| 107 | DO jj = 1, jpj |
|---|
| 108 | DO ji = 1, jpi ! vector opt. |
|---|
| 109 | zhdiv(ji,jj) = zhdiv(ji,jj) + e3t_n(ji,jj,jk) * hdivn(ji,jj,jk) |
|---|
| 110 | END DO |
|---|
| 111 | END DO |
|---|
| 112 | END DO |
|---|
| 113 | !$OMP END PARALLEL |
|---|
| 114 | ! ! Sea surface elevation time stepping |
|---|
| 115 | ! In time-split case we need a first guess of the ssh after (using the baroclinic timestep) in order to |
|---|
| 116 | ! compute the vertical velocity which can be used to compute the non-linear terms of the momentum equations. |
|---|
| 117 | ! |
|---|
| 118 | zcoef = 0.5_wp * r1_rau0 |
|---|
| 119 | |
|---|
| 120 | IF(ln_wd) CALL wad_lmt(sshb, zcoef * (emp_b(:,:) + emp(:,:)), z2dt) |
|---|
| 121 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 122 | DO jj = 1, jpj |
|---|
| 123 | DO ji = 1, jpi |
|---|
| 124 | ssha(ji,jj) = ( sshb(ji,jj) - z2dt * ( zcoef * ( emp_b(ji,jj) + emp(ji,jj) ) + zhdiv(ji,jj) ) ) * ssmask(ji,jj) |
|---|
| 125 | END DO |
|---|
| 126 | END DO |
|---|
| 127 | IF ( .NOT.ln_dynspg_ts ) THEN |
|---|
| 128 | ! These lines are not necessary with time splitting since |
|---|
| 129 | ! boundary condition on sea level is set during ts loop |
|---|
| 130 | # if defined key_agrif |
|---|
| 131 | CALL agrif_ssh( kt ) |
|---|
| 132 | # endif |
|---|
| 133 | # if defined key_bdy |
|---|
| 134 | IF( lk_bdy ) THEN |
|---|
| 135 | CALL lbc_lnk( ssha, 'T', 1. ) ! Not sure that's necessary |
|---|
| 136 | CALL bdy_ssh( ssha ) ! Duplicate sea level across open boundaries |
|---|
| 137 | ENDIF |
|---|
| 138 | # endif |
|---|
| 139 | ENDIF |
|---|
| 140 | |
|---|
| 141 | #if defined key_asminc |
|---|
| 142 | IF( lk_asminc .AND. ln_sshinc .AND. ln_asmiau ) THEN ! Include the IAU weighted SSH increment |
|---|
| 143 | CALL ssh_asm_inc( kt ) |
|---|
| 144 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 145 | DO jj = 1, jpj |
|---|
| 146 | DO ji = 1, jpi |
|---|
| 147 | ssha(ji,jj) = ssha(ji,jj) + z2dt * ssh_iau(ji,jj) |
|---|
| 148 | END DO |
|---|
| 149 | END DO |
|---|
| 150 | ENDIF |
|---|
| 151 | #endif |
|---|
| 152 | ! !------------------------------! |
|---|
| 153 | ! ! outputs ! |
|---|
| 154 | ! !------------------------------! |
|---|
| 155 | ! |
|---|
| 156 | IF(ln_ctl) CALL prt_ctl( tab2d_1=ssha, clinfo1=' ssha - : ', mask1=tmask, ovlap=1 ) |
|---|
| 157 | ! |
|---|
| 158 | CALL wrk_dealloc( jpi, jpj, zhdiv ) |
|---|
| 159 | ! |
|---|
| 160 | IF( nn_timing == 1 ) CALL timing_stop('ssh_nxt') |
|---|
| 161 | ! |
|---|
| 162 | END SUBROUTINE ssh_nxt |
|---|
| 163 | |
|---|
| 164 | |
|---|
| 165 | SUBROUTINE wzv( kt ) |
|---|
| 166 | !!---------------------------------------------------------------------- |
|---|
| 167 | !! *** ROUTINE wzv *** |
|---|
| 168 | !! |
|---|
| 169 | !! ** Purpose : compute the now vertical velocity |
|---|
| 170 | !! |
|---|
| 171 | !! ** Method : - Using the incompressibility hypothesis, the vertical |
|---|
| 172 | !! velocity is computed by integrating the horizontal divergence |
|---|
| 173 | !! from the bottom to the surface minus the scale factor evolution. |
|---|
| 174 | !! The boundary conditions are w=0 at the bottom (no flux) and. |
|---|
| 175 | !! |
|---|
| 176 | !! ** action : wn : now vertical velocity |
|---|
| 177 | !! |
|---|
| 178 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 179 | !!---------------------------------------------------------------------- |
|---|
| 180 | INTEGER, INTENT(in) :: kt ! time step |
|---|
| 181 | ! |
|---|
| 182 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 183 | REAL(wp) :: z1_2dt ! local scalars |
|---|
| 184 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d |
|---|
| 185 | REAL(wp), POINTER, DIMENSION(:,:,:) :: z3d, zhdiv |
|---|
| 186 | !!---------------------------------------------------------------------- |
|---|
| 187 | ! |
|---|
| 188 | IF( nn_timing == 1 ) CALL timing_start('wzv') |
|---|
| 189 | ! |
|---|
| 190 | IF( kt == nit000 ) THEN |
|---|
| 191 | IF(lwp) WRITE(numout,*) |
|---|
| 192 | IF(lwp) WRITE(numout,*) 'wzv : now vertical velocity ' |
|---|
| 193 | IF(lwp) WRITE(numout,*) '~~~~~ ' |
|---|
| 194 | ! |
|---|
| 195 | wn(ji,jj,jpk) = 0._wp ! bottom boundary condition: w=0 (set once for all) |
|---|
| 196 | ENDIF |
|---|
| 197 | ! !------------------------------! |
|---|
| 198 | ! ! Now Vertical Velocity ! |
|---|
| 199 | ! !------------------------------! |
|---|
| 200 | z1_2dt = 1. / ( 2. * rdt ) ! set time step size (Euler/Leapfrog) |
|---|
| 201 | IF( neuler == 0 .AND. kt == nit000 ) z1_2dt = 1. / rdt |
|---|
| 202 | ! |
|---|
| 203 | IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! z_tilde and layer cases |
|---|
| 204 | CALL wrk_alloc( jpi, jpj, jpk, zhdiv ) |
|---|
| 205 | !$OMP PARALLEL DO schedule(static) private(jk, jj, ji) |
|---|
| 206 | DO jk = 1, jpkm1 |
|---|
| 207 | ! horizontal divergence of thickness diffusion transport ( velocity multiplied by e3t) |
|---|
| 208 | ! - ML - note: computation already done in dom_vvl_sf_nxt. Could be optimized (not critical and clearer this way) |
|---|
| 209 | DO jj = 2, jpjm1 |
|---|
| 210 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 211 | zhdiv(ji,jj,jk) = r1_e1e2t(ji,jj) * ( un_td(ji,jj,jk) - un_td(ji-1,jj,jk) + vn_td(ji,jj,jk) - vn_td(ji,jj-1,jk) ) |
|---|
| 212 | END DO |
|---|
| 213 | END DO |
|---|
| 214 | END DO |
|---|
| 215 | CALL lbc_lnk(zhdiv, 'T', 1.) ! - ML - Perhaps not necessary: not used for horizontal "connexions" |
|---|
| 216 | ! ! Is it problematic to have a wrong vertical velocity in boundary cells? |
|---|
| 217 | ! ! Same question holds for hdivn. Perhaps just for security |
|---|
| 218 | DO jk = jpkm1, 1, -1 ! integrate from the bottom the hor. divergence |
|---|
| 219 | ! computation of w |
|---|
| 220 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 221 | DO jj = 1, jpj |
|---|
| 222 | DO ji = 1, jpi ! vector opt. |
|---|
| 223 | wn(ji,jj,jk) = wn(ji,jj,jk+1) - ( e3t_n(ji,jj,jk) * hdivn(ji,jj,jk) + zhdiv(ji,jj,jk) & |
|---|
| 224 | & + z1_2dt * ( e3t_a(ji,jj,jk) - e3t_b(ji,jj,jk) ) ) * tmask(ji,jj,jk) |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | END DO |
|---|
| 228 | ! IF( ln_vvl_layer ) wn(:,:,:) = 0.e0 |
|---|
| 229 | CALL wrk_dealloc( jpi, jpj, jpk, zhdiv ) |
|---|
| 230 | ELSE ! z_star and linear free surface cases |
|---|
| 231 | DO jk = jpkm1, 1, -1 ! integrate from the bottom the hor. divergence |
|---|
| 232 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 233 | DO jj = 1, jpj |
|---|
| 234 | DO ji = 1, jpi ! vector opt. |
|---|
| 235 | ! computation of w |
|---|
| 236 | wn(ji,jj,jk) = wn(ji,jj,jk+1) - ( e3t_n(ji,jj,jk) * hdivn(ji,jj,jk) & |
|---|
| 237 | & + z1_2dt * ( e3t_a(ji,jj,jk) - e3t_b(ji,jj,jk) ) ) * tmask(ji,jj,jk) |
|---|
| 238 | END DO |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | ENDIF |
|---|
| 242 | |
|---|
| 243 | #if defined key_bdy |
|---|
| 244 | IF( lk_bdy ) THEN |
|---|
| 245 | !$OMP PARALLEL DO schedule(static) private(jk) |
|---|
| 246 | DO jk = 1, jpkm1 |
|---|
| 247 | wn(:,:,jk) = wn(:,:,jk) * bdytmask(:,:) |
|---|
| 248 | END DO |
|---|
| 249 | ENDIF |
|---|
| 250 | #endif |
|---|
| 251 | ! |
|---|
| 252 | IF( nn_timing == 1 ) CALL timing_stop('wzv') |
|---|
| 253 | ! |
|---|
| 254 | END SUBROUTINE wzv |
|---|
| 255 | |
|---|
| 256 | |
|---|
| 257 | SUBROUTINE ssh_swp( kt ) |
|---|
| 258 | !!---------------------------------------------------------------------- |
|---|
| 259 | !! *** ROUTINE ssh_nxt *** |
|---|
| 260 | !! |
|---|
| 261 | !! ** Purpose : achieve the sea surface height time stepping by |
|---|
| 262 | !! applying Asselin time filter and swapping the arrays |
|---|
| 263 | !! ssha already computed in ssh_nxt |
|---|
| 264 | !! |
|---|
| 265 | !! ** Method : - apply Asselin time fiter to now ssh (excluding the forcing |
|---|
| 266 | !! from the filter, see Leclair and Madec 2010) and swap : |
|---|
| 267 | !! sshn = ssha + atfp * ( sshb -2 sshn + ssha ) |
|---|
| 268 | !! - atfp * rdt * ( emp_b - emp ) / rau0 |
|---|
| 269 | !! sshn = ssha |
|---|
| 270 | !! |
|---|
| 271 | !! ** action : - sshb, sshn : before & now sea surface height |
|---|
| 272 | !! ready for the next time step |
|---|
| 273 | !! |
|---|
| 274 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 275 | !!---------------------------------------------------------------------- |
|---|
| 276 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 277 | ! |
|---|
| 278 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 279 | REAL(wp) :: zcoef ! local scalar |
|---|
| 280 | !!---------------------------------------------------------------------- |
|---|
| 281 | ! |
|---|
| 282 | IF( nn_timing == 1 ) CALL timing_start('ssh_swp') |
|---|
| 283 | ! |
|---|
| 284 | IF( kt == nit000 ) THEN |
|---|
| 285 | IF(lwp) WRITE(numout,*) |
|---|
| 286 | IF(lwp) WRITE(numout,*) 'ssh_swp : Asselin time filter and swap of sea surface height' |
|---|
| 287 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 288 | ENDIF |
|---|
| 289 | ! !== Euler time-stepping: no filter, just swap ==! |
|---|
| 290 | IF( ( neuler == 0 .AND. kt == nit000 ) .OR. & |
|---|
| 291 | & ( ln_bt_fw .AND. ln_dynspg_ts ) ) THEN |
|---|
| 292 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 293 | DO jj = 1, jpj |
|---|
| 294 | DO ji = 1, jpi |
|---|
| 295 | sshb(ji,jj) = sshn(ji,jj) ! before <-- now |
|---|
| 296 | sshn(ji,jj) = ssha(ji,jj) ! now <-- after (before already = now) |
|---|
| 297 | END DO |
|---|
| 298 | END DO |
|---|
| 299 | ! |
|---|
| 300 | ELSE !== Leap-Frog time-stepping: Asselin filter + swap ==! |
|---|
| 301 | ! ! before <-- now filtered |
|---|
| 302 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 303 | DO jj = 1, jpj |
|---|
| 304 | DO ji = 1, jpi |
|---|
| 305 | sshb(ji,jj) = sshn(ji,jj) + atfp * ( sshb(ji,jj) - 2 * sshn(ji,jj) + ssha(ji,jj) ) |
|---|
| 306 | END DO |
|---|
| 307 | END DO |
|---|
| 308 | IF( .NOT.ln_linssh ) THEN ! before <-- with forcing removed |
|---|
| 309 | zcoef = atfp * rdt * r1_rau0 |
|---|
| 310 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 311 | DO jj = 1, jpj |
|---|
| 312 | DO ji = 1, jpi |
|---|
| 313 | sshb(ji,jj) = sshb(ji,jj) - zcoef * ( emp_b(ji,jj) - emp (ji,jj) & |
|---|
| 314 | & - rnf_b(ji,jj) + rnf (ji,jj) & |
|---|
| 315 | & + fwfisf_b(ji,jj) - fwfisf(ji,jj) ) * ssmask(ji,jj) |
|---|
| 316 | END DO |
|---|
| 317 | END DO |
|---|
| 318 | ENDIF |
|---|
| 319 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 320 | DO jj = 1, jpj |
|---|
| 321 | DO ji = 1, jpi |
|---|
| 322 | sshn(ji,jj) = ssha(ji,jj) ! now <-- after |
|---|
| 323 | END DO |
|---|
| 324 | END DO |
|---|
| 325 | ENDIF |
|---|
| 326 | ! |
|---|
| 327 | IF(ln_ctl) CALL prt_ctl( tab2d_1=sshb, clinfo1=' sshb - : ', mask1=tmask, ovlap=1 ) |
|---|
| 328 | ! |
|---|
| 329 | IF( nn_timing == 1 ) CALL timing_stop('ssh_swp') |
|---|
| 330 | ! |
|---|
| 331 | END SUBROUTINE ssh_swp |
|---|
| 332 | |
|---|
| 333 | !!====================================================================== |
|---|
| 334 | END MODULE sshwzv |
|---|
