| 1 | MODULE p4zflx |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zflx *** |
|---|
| 4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) additions |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modifications |
|---|
| 9 | !! 1.0 ! 2004 (O. Aumont) modifications |
|---|
| 10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 11 | !! ! 2011-02 (J. Simeon, J. Orr) Include total atm P correction |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_pisces |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_pisces' PISCES bio-model |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 18 | !! p4z_flx_init : Read the namelist |
|---|
| 19 | !! p4z_patm : Read sfc atm pressure [atm] for each grid cell |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 22 | USE trc ! passive tracers common variables |
|---|
| 23 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 24 | USE p4zche ! Chemical model |
|---|
| 25 | USE prtctl_trc ! print control for debugging |
|---|
| 26 | USE iom ! I/O manager |
|---|
| 27 | USE fldread ! read input fields |
|---|
| 28 | #if defined key_cpl_carbon_cycle |
|---|
| 29 | USE sbc_oce, ONLY : atm_co2 ! atmospheric pCO2 |
|---|
| 30 | #endif |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC p4z_flx |
|---|
| 36 | PUBLIC p4z_flx_init |
|---|
| 37 | PUBLIC p4z_flx_alloc |
|---|
| 38 | |
|---|
| 39 | ! !!** Namelist nampisext ** |
|---|
| 40 | REAL(wp) :: atcco2 !: pre-industrial atmospheric [co2] (ppm) |
|---|
| 41 | LOGICAL :: ln_co2int !: flag to read in a file and interpolate atmospheric pco2 or not |
|---|
| 42 | CHARACTER(len=34) :: clname !: filename of pco2 values |
|---|
| 43 | INTEGER :: nn_offset !: Offset model-data start year (default = 0) |
|---|
| 44 | |
|---|
| 45 | !! Variables related to reading atmospheric CO2 time history |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years |
|---|
| 47 | INTEGER :: nmaxrec, numco2 |
|---|
| 48 | |
|---|
| 49 | ! !!* nampisatm namelist (Atmospheric PRessure) * |
|---|
| 50 | LOGICAL, PUBLIC :: ln_presatm !: ref. pressure: global mean Patm (F) or a constant (F) |
|---|
| 51 | |
|---|
| 52 | REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) :: patm ! atmospheric pressure at kt [N/m2] |
|---|
| 53 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_patm ! structure of input fields (file informations, fields read) |
|---|
| 54 | |
|---|
| 55 | |
|---|
| 56 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2 !: ocean carbon flux |
|---|
| 57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2 !: atmospheric pco2 |
|---|
| 58 | |
|---|
| 59 | REAL(wp) :: xconv = 0.01_wp / 3600._wp !: coefficients for conversion |
|---|
| 60 | |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | SUBROUTINE p4z_flx ( kt, knt ) |
|---|
| 69 | !!--------------------------------------------------------------------- |
|---|
| 70 | !! *** ROUTINE p4z_flx *** |
|---|
| 71 | !! |
|---|
| 72 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 73 | !! |
|---|
| 74 | !! ** Method : |
|---|
| 75 | !! - Include total atm P correction via Esbensen & Kushnir (1981) |
|---|
| 76 | !! - Pressure correction NOT done for key_cpl_carbon_cycle |
|---|
| 77 | !! - Remove Wanninkhof chemical enhancement; |
|---|
| 78 | !! - Add option for time-interpolation of atcco2.txt |
|---|
| 79 | !!--------------------------------------------------------------------- |
|---|
| 80 | ! |
|---|
| 81 | INTEGER, INTENT(in) :: kt, knt ! |
|---|
| 82 | ! |
|---|
| 83 | INTEGER :: ji, jj, jm, iind, iindm1 |
|---|
| 84 | REAL(wp) :: ztc, ztc2, ztc3, ztc4, zws, zkgwan |
|---|
| 85 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
|---|
| 86 | REAL(wp) :: zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2 |
|---|
| 87 | REAL(wp) :: zyr_dec, zdco2dt |
|---|
| 88 | CHARACTER (len=25) :: charout |
|---|
| 89 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d |
|---|
| 90 | !!--------------------------------------------------------------------- |
|---|
| 91 | ! |
|---|
| 92 | IF( nn_timing == 1 ) CALL timing_start('p4z_flx') |
|---|
| 93 | ! |
|---|
| 94 | CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
|---|
| 95 | ! |
|---|
| 96 | |
|---|
| 97 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
|---|
| 98 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
|---|
| 99 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
|---|
| 100 | |
|---|
| 101 | IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt ) ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs |
|---|
| 102 | |
|---|
| 103 | IF( ln_co2int ) THEN |
|---|
| 104 | ! Linear temporal interpolation of atmospheric pco2. atcco2.txt has annual values. |
|---|
| 105 | ! Caveats: First column of .txt must be in years, decimal years preferably. |
|---|
| 106 | ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy) |
|---|
| 107 | ! then the first atmospheric CO2 record read is at years(1) |
|---|
| 108 | zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp ) |
|---|
| 109 | jm = 1 |
|---|
| 110 | DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ; jm = jm + 1 ; END DO |
|---|
| 111 | iind = jm ; iindm1 = jm - 1 |
|---|
| 112 | zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn ) |
|---|
| 113 | atcco2 = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1) |
|---|
| 114 | satmco2(:,:) = atcco2 |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | #if defined key_cpl_carbon_cycle |
|---|
| 118 | satmco2(:,:) = atm_co2(:,:) |
|---|
| 119 | #endif |
|---|
| 120 | |
|---|
| 121 | !$OMP PARALLEL |
|---|
| 122 | DO jm = 1, 10 |
|---|
| 123 | !$OMP DO schedule(static) private(jj,ji,zbot,zfact,zdic,zph,zalka,zalk,zah2) |
|---|
| 124 | DO jj = 1, jpj |
|---|
| 125 | DO ji = 1, jpi |
|---|
| 126 | |
|---|
| 127 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
|---|
| 128 | zbot = borat(ji,jj,1) |
|---|
| 129 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
|---|
| 130 | zdic = trb(ji,jj,1,jpdic) / zfact |
|---|
| 131 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
|---|
| 132 | zalka = trb(ji,jj,1,jptal) / zfact |
|---|
| 133 | |
|---|
| 134 | ! CALCULATE [ALK]([CO3--], [HCO3-]) |
|---|
| 135 | zalk = zalka - ( akw3(ji,jj,1) / zph - zph / aphscale(ji,jj,1) & |
|---|
| 136 | & + zbot / ( 1.+ zph / akb3(ji,jj,1) ) ) |
|---|
| 137 | |
|---|
| 138 | ! CALCULATE [H+] AND [H2CO3] |
|---|
| 139 | zah2 = SQRT( (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1) & |
|---|
| 140 | & / ak13(ji,jj,1) ) * ( 2.* zdic - zalk ) ) |
|---|
| 141 | zah2 = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 ) |
|---|
| 142 | zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact |
|---|
| 143 | hi(ji,jj,1) = zah2 * zfact |
|---|
| 144 | END DO |
|---|
| 145 | END DO |
|---|
| 146 | !$OMP END DO NOWAIT |
|---|
| 147 | END DO |
|---|
| 148 | |
|---|
| 149 | |
|---|
| 150 | ! -------------- |
|---|
| 151 | ! COMPUTE FLUXES |
|---|
| 152 | ! -------------- |
|---|
| 153 | |
|---|
| 154 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
|---|
| 155 | ! ------------------------------------------- |
|---|
| 156 | |
|---|
| 157 | !$OMP DO schedule(static) private(jj,ji,ztc,ztc2,ztc3,ztc4,zsch_co2,zsch_o2,zws,zkgwan) |
|---|
| 158 | DO jj = 1, jpj |
|---|
| 159 | DO ji = 1, jpi |
|---|
| 160 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
|---|
| 161 | ztc2 = ztc * ztc |
|---|
| 162 | ztc3 = ztc * ztc2 |
|---|
| 163 | ztc4 = ztc2 * ztc2 |
|---|
| 164 | ! Compute the schmidt Number both O2 and CO2 |
|---|
| 165 | zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4 |
|---|
| 166 | zsch_o2 = 1920.4 - 135.6 * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4 |
|---|
| 167 | ! wind speed |
|---|
| 168 | zws = wndm(ji,jj) * wndm(ji,jj) |
|---|
| 169 | ! Compute the piston velocity for O2 and CO2 |
|---|
| 170 | zkgwan = 0.251 * zws |
|---|
| 171 | zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 172 | # if defined key_degrad |
|---|
| 173 | zkgwan = zkgwan * facvol(ji,jj,1) |
|---|
| 174 | #endif |
|---|
| 175 | ! compute gas exchange for CO2 and O2 |
|---|
| 176 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 ) |
|---|
| 177 | zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 ) |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | |
|---|
| 181 | !$OMP DO schedule(static) private(jj,ji,zfld,zflu,zfld16,zflu16) |
|---|
| 182 | DO jj = 1, jpj |
|---|
| 183 | DO ji = 1, jpi |
|---|
| 184 | ! Compute CO2 flux for the sea and air |
|---|
| 185 | zfld = satmco2(ji,jj) * patm(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj) * zkgco2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 186 | zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) (m/s) ? |
|---|
| 187 | oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
|---|
| 188 | ! compute the trend |
|---|
| 189 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / e3t_n(ji,jj,1) |
|---|
| 190 | |
|---|
| 191 | ! Compute O2 flux |
|---|
| 192 | zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * tmask(ji,jj,1) * zkgo2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 193 | zflu16 = trb(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj) |
|---|
| 194 | zoflx(ji,jj) = zfld16 - zflu16 |
|---|
| 195 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_n(ji,jj,1) |
|---|
| 196 | END DO |
|---|
| 197 | END DO |
|---|
| 198 | !$OMP END DO NOWAIT |
|---|
| 199 | !$OMP END PARALLEL |
|---|
| 200 | |
|---|
| 201 | t_oce_co2_flx = glob_sum( oce_co2(:,:) ) ! Total Flux of Carbon |
|---|
| 202 | t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx ! Cumulative Total Flux of Carbon |
|---|
| 203 | ! t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) ) ! Total atmospheric pCO2 |
|---|
| 204 | t_atm_co2_flx = atcco2 ! Total atmospheric pCO2 |
|---|
| 205 | |
|---|
| 206 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 207 | WRITE(charout, FMT="('flx ')") |
|---|
| 208 | CALL prt_ctl_trc_info(charout) |
|---|
| 209 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 210 | ENDIF |
|---|
| 211 | |
|---|
| 212 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
|---|
| 213 | CALL wrk_alloc( jpi, jpj, zw2d ) |
|---|
| 214 | IF( iom_use( "Cflx" ) ) THEN |
|---|
| 215 | zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 216 | CALL iom_put( "Cflx" , zw2d ) |
|---|
| 217 | ENDIF |
|---|
| 218 | IF( iom_use( "Oflx" ) ) THEN |
|---|
| 219 | zw2d(:,:) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 220 | CALL iom_put( "Oflx" , zw2d ) |
|---|
| 221 | ENDIF |
|---|
| 222 | IF( iom_use( "Kg" ) ) THEN |
|---|
| 223 | zw2d(:,:) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 224 | CALL iom_put( "Kg" , zw2d ) |
|---|
| 225 | ENDIF |
|---|
| 226 | IF( iom_use( "Dpco2" ) ) THEN |
|---|
| 227 | zw2d(:,:) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:) + rtrn ) ) * tmask(:,:,1) |
|---|
| 228 | CALL iom_put( "Dpco2" , zw2d ) |
|---|
| 229 | ENDIF |
|---|
| 230 | IF( iom_use( "Dpo2" ) ) THEN |
|---|
| 231 | zw2d(:,:) = ( atcox * patm(:,:) - atcox * trn(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) |
|---|
| 232 | CALL iom_put( "Dpo2" , zw2d ) |
|---|
| 233 | ENDIF |
|---|
| 234 | IF( iom_use( "tcflx" ) ) CALL iom_put( "tcflx" , t_oce_co2_flx * rfact2r ) ! molC/s |
|---|
| 235 | CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum ) ! molC |
|---|
| 236 | ! |
|---|
| 237 | CALL wrk_dealloc( jpi, jpj, zw2d ) |
|---|
| 238 | ELSE |
|---|
| 239 | IF( ln_diatrc ) THEN |
|---|
| 240 | trc2d(:,:,jp_pcs0_2d ) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
|---|
| 241 | trc2d(:,:,jp_pcs0_2d + 1) = zoflx(:,:) * 1000 * tmask(:,:,1) |
|---|
| 242 | trc2d(:,:,jp_pcs0_2d + 2) = zkgco2(:,:) * tmask(:,:,1) |
|---|
| 243 | trc2d(:,:,jp_pcs0_2d + 3) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:) + rtrn ) ) * tmask(:,:,1) |
|---|
| 244 | ENDIF |
|---|
| 245 | ENDIF |
|---|
| 246 | ! |
|---|
| 247 | CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
|---|
| 248 | ! |
|---|
| 249 | IF( nn_timing == 1 ) CALL timing_stop('p4z_flx') |
|---|
| 250 | ! |
|---|
| 251 | END SUBROUTINE p4z_flx |
|---|
| 252 | |
|---|
| 253 | |
|---|
| 254 | SUBROUTINE p4z_flx_init |
|---|
| 255 | !!---------------------------------------------------------------------- |
|---|
| 256 | !! *** ROUTINE p4z_flx_init *** |
|---|
| 257 | !! |
|---|
| 258 | !! ** Purpose : Initialization of atmospheric conditions |
|---|
| 259 | !! |
|---|
| 260 | !! ** Method : Read the nampisext namelist and check the parameters |
|---|
| 261 | !! called at the first timestep (nittrc000) |
|---|
| 262 | !! ** input : Namelist nampisext |
|---|
| 263 | !!---------------------------------------------------------------------- |
|---|
| 264 | NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset |
|---|
| 265 | INTEGER :: jm |
|---|
| 266 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 267 | !!---------------------------------------------------------------------- |
|---|
| 268 | ! |
|---|
| 269 | |
|---|
| 270 | REWIND( numnatp_ref ) ! Namelist nampisext in reference namelist : Pisces atm. conditions |
|---|
| 271 | READ ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901) |
|---|
| 272 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp ) |
|---|
| 273 | |
|---|
| 274 | REWIND( numnatp_cfg ) ! Namelist nampisext in configuration namelist : Pisces atm. conditions |
|---|
| 275 | READ ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 ) |
|---|
| 276 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp ) |
|---|
| 277 | IF(lwm) WRITE ( numonp, nampisext ) |
|---|
| 278 | ! |
|---|
| 279 | IF(lwp) THEN ! control print |
|---|
| 280 | WRITE(numout,*) ' ' |
|---|
| 281 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext' |
|---|
| 282 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 283 | WRITE(numout,*) ' Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int |
|---|
| 284 | WRITE(numout,*) ' ' |
|---|
| 285 | ENDIF |
|---|
| 286 | IF( .NOT.ln_co2int ) THEN |
|---|
| 287 | IF(lwp) THEN ! control print |
|---|
| 288 | WRITE(numout,*) ' Constant Atmospheric pCO2 value atcco2 =', atcco2 |
|---|
| 289 | WRITE(numout,*) ' ' |
|---|
| 290 | ENDIF |
|---|
| 291 | satmco2(:,:) = atcco2 ! Initialisation of atmospheric pco2 |
|---|
| 292 | ELSE |
|---|
| 293 | IF(lwp) THEN |
|---|
| 294 | WRITE(numout,*) ' Atmospheric pCO2 value from file clname =', TRIM( clname ) |
|---|
| 295 | WRITE(numout,*) ' Offset model-data start year nn_offset =', nn_offset |
|---|
| 296 | WRITE(numout,*) ' ' |
|---|
| 297 | ENDIF |
|---|
| 298 | CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp ) |
|---|
| 299 | jm = 0 ! Count the number of record in co2 file |
|---|
| 300 | DO |
|---|
| 301 | READ(numco2,*,END=100) |
|---|
| 302 | jm = jm + 1 |
|---|
| 303 | END DO |
|---|
| 304 | 100 nmaxrec = jm - 1 |
|---|
| 305 | ALLOCATE( years (nmaxrec) ) ; years (:) = 0._wp |
|---|
| 306 | ALLOCATE( atcco2h(nmaxrec) ) ; atcco2h(:) = 0._wp |
|---|
| 307 | |
|---|
| 308 | REWIND(numco2) |
|---|
| 309 | DO jm = 1, nmaxrec ! get xCO2 data |
|---|
| 310 | READ(numco2, *) years(jm), atcco2h(jm) |
|---|
| 311 | IF(lwp) WRITE(numout, '(f6.0,f7.2)') years(jm), atcco2h(jm) |
|---|
| 312 | END DO |
|---|
| 313 | CLOSE(numco2) |
|---|
| 314 | ENDIF |
|---|
| 315 | ! |
|---|
| 316 | oce_co2(:,:) = 0._wp ! Initialization of Flux of Carbon |
|---|
| 317 | t_oce_co2_flx = 0._wp |
|---|
| 318 | t_atm_co2_flx = 0._wp |
|---|
| 319 | ! |
|---|
| 320 | CALL p4z_patm( nit000 ) |
|---|
| 321 | ! |
|---|
| 322 | END SUBROUTINE p4z_flx_init |
|---|
| 323 | |
|---|
| 324 | SUBROUTINE p4z_patm( kt ) |
|---|
| 325 | |
|---|
| 326 | !!---------------------------------------------------------------------- |
|---|
| 327 | !! *** ROUTINE p4z_atm *** |
|---|
| 328 | !! |
|---|
| 329 | !! ** Purpose : Read and interpolate the external atmospheric sea-levl pressure |
|---|
| 330 | !! ** Method : Read the files and interpolate the appropriate variables |
|---|
| 331 | !! |
|---|
| 332 | !!---------------------------------------------------------------------- |
|---|
| 333 | !! * arguments |
|---|
| 334 | INTEGER, INTENT( in ) :: kt ! ocean time step |
|---|
| 335 | ! |
|---|
| 336 | INTEGER :: ierr |
|---|
| 337 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 338 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 339 | TYPE(FLD_N) :: sn_patm ! informations about the fields to be read |
|---|
| 340 | !! |
|---|
| 341 | NAMELIST/nampisatm/ ln_presatm, sn_patm, cn_dir |
|---|
| 342 | |
|---|
| 343 | ! ! ----------------------- ! |
|---|
| 344 | IF( kt == nit000 ) THEN ! First call kt=nittrc000 ! |
|---|
| 345 | |
|---|
| 346 | REWIND( numnatp_ref ) ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file |
|---|
| 347 | READ ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901) |
|---|
| 348 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp ) |
|---|
| 349 | |
|---|
| 350 | REWIND( numnatp_cfg ) ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file |
|---|
| 351 | READ ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 ) |
|---|
| 352 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp ) |
|---|
| 353 | IF(lwm) WRITE ( numonp, nampisatm ) |
|---|
| 354 | ! |
|---|
| 355 | ! |
|---|
| 356 | IF(lwp) THEN !* control print |
|---|
| 357 | WRITE(numout,*) |
|---|
| 358 | WRITE(numout,*) ' Namelist nampisatm : Atmospheric Pressure as external forcing' |
|---|
| 359 | WRITE(numout,*) ' constant atmopsheric pressure (F) or from a file (T) ln_presatm = ', ln_presatm |
|---|
| 360 | WRITE(numout,*) |
|---|
| 361 | ENDIF |
|---|
| 362 | ! |
|---|
| 363 | IF( ln_presatm ) THEN |
|---|
| 364 | ALLOCATE( sf_patm(1), STAT=ierr ) !* allocate and fill sf_patm (forcing structure) with sn_patm |
|---|
| 365 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' ) |
|---|
| 366 | ! |
|---|
| 367 | CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' ) |
|---|
| 368 | ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1) ) |
|---|
| 369 | IF( sn_patm%ln_tint ) ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 370 | ENDIF |
|---|
| 371 | ! |
|---|
| 372 | IF( .NOT.ln_presatm ) patm(:,:) = 1.e0 ! Initialize patm if no reading from a file |
|---|
| 373 | ! |
|---|
| 374 | ENDIF |
|---|
| 375 | ! |
|---|
| 376 | IF( ln_presatm ) THEN |
|---|
| 377 | CALL fld_read( kt, 1, sf_patm ) !* input Patm provided at kt + 1/2 |
|---|
| 378 | patm(:,:) = sf_patm(1)%fnow(:,:,1) ! atmospheric pressure |
|---|
| 379 | ENDIF |
|---|
| 380 | ! |
|---|
| 381 | END SUBROUTINE p4z_patm |
|---|
| 382 | |
|---|
| 383 | INTEGER FUNCTION p4z_flx_alloc() |
|---|
| 384 | !!---------------------------------------------------------------------- |
|---|
| 385 | !! *** ROUTINE p4z_flx_alloc *** |
|---|
| 386 | !!---------------------------------------------------------------------- |
|---|
| 387 | ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc ) |
|---|
| 388 | ! |
|---|
| 389 | IF( p4z_flx_alloc /= 0 ) CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays') |
|---|
| 390 | ! |
|---|
| 391 | END FUNCTION p4z_flx_alloc |
|---|
| 392 | |
|---|
| 393 | #else |
|---|
| 394 | !!====================================================================== |
|---|
| 395 | !! Dummy module : No PISCES bio-model |
|---|
| 396 | !!====================================================================== |
|---|
| 397 | CONTAINS |
|---|
| 398 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
|---|
| 399 | INTEGER, INTENT( in ) :: kt |
|---|
| 400 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
|---|
| 401 | END SUBROUTINE p4z_flx |
|---|
| 402 | #endif |
|---|
| 403 | |
|---|
| 404 | !!====================================================================== |
|---|
| 405 | END MODULE p4zflx |
|---|
