New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlim.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlim.F90 @ 7525

Last change on this file since 7525 was 7525, checked in by mocavero, 7 years ago

changes after review

File size: 15.4 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_lim        :   Compute the nutrients limitation terms
15   !!   p4z_lim_init   :   Read the namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         ! Shared ocean-passive tracers variables
18   USE trc             ! Tracers defined
19   USE sms_pisces      ! PISCES variables
20   USE p4zopt          ! Optical
21   USE iom             !  I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC p4z_lim   
27   PUBLIC p4z_lim_init   
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
31   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
32   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for phyto 
33   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
34   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
35   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
36   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
37   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
38   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
39   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
40   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
41   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
42   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
43   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
44   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
45   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
46   REAL(wp), PUBLIC ::  qnfelim     !:  optimal Fe quota for nanophyto
47   REAL(wp), PUBLIC ::  qdfelim     !:  optimal Fe quota for diatoms
48   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
49
50   ! Coefficient for iron limitation
51   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
52   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
53   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
54
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
57   !! $Id: p4zlim.F90 3160 2011-11-20 14:27:18Z cetlod $
58   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60
61CONTAINS
62
63   SUBROUTINE p4z_lim( kt, knt )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p4z_lim  ***
66      !!
67      !! ** Purpose :   Compute the co-limitations by the various nutrients
68      !!              for the various phytoplankton species
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in)  :: kt, knt
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
77      REAL(wp) ::   zconcd, zconcd2, zconcn, zconcn2
78      REAL(wp) ::   z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2
79      REAL(wp) ::   zdenom, zratio, zironmin
80      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
81      !!---------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('p4z_lim')
84      !
85!$OMP PARALLEL
86!$OMP DO schedule(static) private(jk,jj,ji,zno3,zferlim,zconcd,zconcd2,zconcn,zconcn2,z1_trbphy,z1_trbdia) &
87!$OMP& private(zconc1d,zconc1dnh4,zconc0n,zconc0nnh4,zdenom,zlim1,zlim2,zlim3,zlim4,zratio,zironmin)
88      DO jk = 1, jpkm1
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               
92               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
93               !-------------------------------------
94               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
95               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
96               zferlim = MIN( zferlim, 7e-11 )
97               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
98
99               ! Computation of a variable Ks for iron on diatoms taking into account
100               ! that increasing biomass is made of generally bigger cells
101               !------------------------------------------------
102               zconcd   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
103               zconcd2  = trb(ji,jj,jk,jpdia) - zconcd
104               zconcn   = MAX( 0.e0 , trb(ji,jj,jk,jpphy) - xsizephy )
105               zconcn2  = trb(ji,jj,jk,jpphy) - zconcn
106               z1_trbphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
107               z1_trbdia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
108
109               concdfe(ji,jj,jk) = MAX( concdfer, ( zconcd2 * concdfer + concdfer * xsizerd * zconcd ) * z1_trbdia )
110               zconc1d           = MAX( concdno3, ( zconcd2 * concdno3 + concdno3 * xsizerd * zconcd ) * z1_trbdia )
111               zconc1dnh4        = MAX( concdnh4, ( zconcd2 * concdnh4 + concdnh4 * xsizerd * zconcd ) * z1_trbdia )
112
113               concnfe(ji,jj,jk) = MAX( concnfer, ( zconcn2 * concnfer + concnfer * xsizern * zconcn ) * z1_trbphy )
114               zconc0n           = MAX( concnno3, ( zconcn2 * concnno3 + concnno3 * xsizern * zconcn ) * z1_trbphy )
115               zconc0nnh4        = MAX( concnnh4, ( zconcn2 * concnnh4 + concnnh4 * xsizern * zconcn ) * z1_trbphy )
116
117               ! Michaelis-Menten Limitation term for nutrients Small bacteria
118               ! -------------------------------------------------------------
119               zdenom = 1. /  ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) )
120               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom
121               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom
122               !
123               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
124               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 )
125               zlim3    = trb(ji,jj,jk,jpfer) / ( concbfe + trb(ji,jj,jk,jpfer) )
126               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
127               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
128               xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
129
130               ! Michaelis-Menten Limitation term for nutrients Small flagellates
131               ! -----------------------------------------------
132               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) )
133               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
134               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n    * zdenom
135               !
136               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
137               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 )
138               zratio   = trb(ji,jj,jk,jpnfe) * z1_trbphy 
139               zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
140               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
141               xnanopo4(ji,jj,jk) = zlim2
142               xlimnfe (ji,jj,jk) = MIN( 1., zlim3 )
143               xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
144               !
145               !   Michaelis-Menten Limitation term for nutrients Diatoms
146               !   ----------------------------------------------
147               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) )
148               xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
149               xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d    * zdenom
150               !
151               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
152               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4  )
153               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
154               zratio   = trb(ji,jj,jk,jpdfe) * z1_trbdia
155               zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
156               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
157               xdiatpo4(ji,jj,jk) = zlim2
158               xlimdfe (ji,jj,jk) = MIN( 1., zlim4 )
159               xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
160               xlimsi  (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 )
161           END DO
162         END DO
163      END DO
164!$OMP END DO NOWAIT
165
166      ! Compute the fraction of nanophytoplankton that is made of calcifiers
167      ! --------------------------------------------------------------------
168!$OMP DO schedule(static) private(jk,jj,ji,zlim1,zlim2,zlim3,ztem1,ztem2,zetot1,zetot2)
169      DO jk = 1, jpkm1
170         DO jj = 1, jpj
171            DO ji = 1, jpi
172               zlim1 =  ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 )    &
173                  &   / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) 
174               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 )
175               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11   )
176               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
177               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
178               zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) 
179               zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) 
180
181               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
182                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
183                  &                       * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
184                  &                       * zetot1 * zetot2               &
185                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
186                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
187               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
188               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
189            END DO
190         END DO
191      END DO
192!$OMP END DO NOWAIT
193!$OMP END PARALLEL
194      !
195      !
196      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
197        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
198        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
199        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
200        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
201        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
202      ENDIF
203      !
204      IF( nn_timing == 1 )  CALL timing_stop('p4z_lim')
205      !
206   END SUBROUTINE p4z_lim
207
208   SUBROUTINE p4z_lim_init
209
210      !!----------------------------------------------------------------------
211      !!                  ***  ROUTINE p4z_lim_init  ***
212      !!
213      !! ** Purpose :   Initialization of nutrient limitation parameters
214      !!
215      !! ** Method  :   Read the nampislim namelist and check the parameters
216      !!      called at the first timestep (nittrc000)
217      !!
218      !! ** input   :   Namelist nampislim
219      !!
220      !!----------------------------------------------------------------------
221
222      NAMELIST/nampislim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe,   &
223         &                concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd,          & 
224         &                xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r
225      INTEGER :: ios                 ! Local integer output status for namelist read
226
227      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
228      READ  ( numnatp_ref, nampislim, IOSTAT = ios, ERR = 901)
229901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp )
230
231      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
232      READ  ( numnatp_cfg, nampislim, IOSTAT = ios, ERR = 902 )
233902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp )
234      IF(lwm) WRITE ( numonp, nampislim )
235
236      IF(lwp) THEN                         ! control print
237         WRITE(numout,*) ' '
238         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim'
239         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
240         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
241         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
242         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
243         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
244         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
245         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
246         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
247         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
248         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
249         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
250         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
251         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
252         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
253         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
254         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
255         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
256         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
257         WRITE(numout,*) '    optimal Fe quota for nano.               qnfelim   = ', qnfelim
258         WRITE(numout,*) '    Optimal Fe quota for diatoms             qdfelim   = ', qdfelim
259      ENDIF
260
261   END SUBROUTINE p4z_lim_init
262
263#else
264   !!======================================================================
265   !!  Dummy module :                                   No PISCES bio-model
266   !!======================================================================
267CONTAINS
268   SUBROUTINE p4z_lim                   ! Empty routine
269   END SUBROUTINE p4z_lim
270#endif 
271
272   !!======================================================================
273END MODULE p4zlim
Note: See TracBrowser for help on using the repository browser.