New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 7525

Last change on this file since 7525 was 7525, checked in by mocavero, 7 years ago

changes after review
  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcnam          ! Namelist read
21   USE daymod          ! calendar manager
22   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
23   USE trcsub          ! variables to substep passive tracers
24   USE trcrst
25   USE lib_mpp         ! distribued memory computing library
26   USE sbc_oce
27   USE trcice          ! tracers in sea ice
28   USE trcbc,   only : trc_bc_init ! generalized Boundary Conditions
29 
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   trc_init   ! called by opa
34
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41   
42   SUBROUTINE trc_init
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE trc_init  ***
45      !!
46      !! ** Purpose :   Initialization of the passive tracer fields
47      !!
48      !! ** Method  : - read namelist
49      !!              - control the consistancy
50      !!              - compute specific initialisations
51      !!              - set initial tracer fields (either read restart
52      !!                or read data or analytical formulation
53      !!---------------------------------------------------------------------
54      !
55      IF( nn_timing == 1 )   CALL timing_start('trc_init')
56      !
57      IF(lwp) WRITE(numout,*)
58      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
59      IF(lwp) WRITE(numout,*) '~~~~~~~'
60
61      !
62      CALL top_alloc()   ! allocate TOP arrays
63      !
64      CALL trc_ini_ctl   ! control
65      !
66      CALL trc_nam       ! read passive tracers namelists
67      !
68      IF(lwp) WRITE(numout,*)
69      !
70      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
71      !
72      IF(lwp) WRITE(numout,*)
73      !
74      CALL trc_ini_sms   ! SMS
75      !
76      CALL trc_ini_trp   ! passive tracers transport
77      !
78      CALL trc_ice_ini   ! Tracers in sea ice
79      !
80      IF( lwp )  &
81         &  CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
82      !
83      CALL trc_ini_state  !  passive tracers initialisation : from a restart or from clim
84      !
85      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
86      !
87      CALL trc_ini_inv   ! Inventories
88      !
89      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
90      !
91   END SUBROUTINE trc_init
92
93
94   SUBROUTINE trc_ini_ctl
95      !!----------------------------------------------------------------------
96      !!                     ***  ROUTINE trc_ini_ctl  ***
97      !! ** Purpose :        Control  + ocean volume
98      !!----------------------------------------------------------------------
99      INTEGER ::   jk    ! dummy loop indices
100      !
101      ! Define logical parameter ton control dirunal cycle in TOP
102      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
103      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
104      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
105         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
106      !
107   END SUBROUTINE trc_ini_ctl
108
109
110   SUBROUTINE trc_ini_inv
111      !!----------------------------------------------------------------------
112      !!                     ***  ROUTINE trc_ini_stat  ***
113      !! ** Purpose :      passive tracers inventories at initialsation phase
114      !!----------------------------------------------------------------------
115      INTEGER ::  jk, jn, jj, ji    ! dummy loop indices
116      CHARACTER (len=25) :: charout
117      !!----------------------------------------------------------------------
118      !                                                              ! masked grid volume
119!$OMP PARALLEL DO schedule(static) private(jk)
120      DO jk = 1, jpk
121         DO jj = 1, jpj
122            DO ji = 1, jpi
123               cvol(ji,jj,jk) = e1e2t(ji,jj) * e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
124            END DO
125         END DO
126      END DO
127      IF( lk_degrad ) THEN 
128!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
129         DO jk = 1, jpk
130            DO jj = 1, jpj
131               DO ji = 1, jpi
132                  cvol(ji,jj,jk) = cvol(ji,jj,jk) * facvol(ji,jj,jk)    ! degrad option: reduction by facvol
133               END DO
134            END DO
135         END DO
136      END IF
137      !                                                              ! total volume of the ocean
138      areatot = glob_sum( cvol(:,:,:) )
139      !
140      trai(:) = 0._wp                                                   ! initial content of all tracers
141      DO jn = 1, jptra
142         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
143      END DO
144
145      IF(lwp) THEN               ! control print
146         WRITE(numout,*)
147         WRITE(numout,*)
148         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
149         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
150         WRITE(numout,*) '          *** Total inital content of all tracers '
151         WRITE(numout,*)
152         DO jn = 1, jptra
153            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
154         ENDDO
155         WRITE(numout,*)
156      ENDIF
157      IF(lwp) WRITE(numout,*)
158      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
159         CALL prt_ctl_trc_init
160         WRITE(charout, FMT="('ini ')")
161         CALL prt_ctl_trc_info( charout )
162         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
163      ENDIF
1649000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
165      !
166   END SUBROUTINE trc_ini_inv
167
168
169   SUBROUTINE trc_ini_sms
170      !!----------------------------------------------------------------------
171      !!                     ***  ROUTINE trc_ini_sms  ***
172      !! ** Purpose :   SMS initialisation
173      !!----------------------------------------------------------------------
174      USE trcini_cfc      ! CFC      initialisation
175      USE trcini_pisces   ! PISCES   initialisation
176      USE trcini_c14b     ! C14 bomb initialisation
177      USE trcini_my_trc   ! MY_TRC   initialisation
178      !!----------------------------------------------------------------------
179      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
180      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
181      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
182      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
183      !
184   END SUBROUTINE trc_ini_sms
185
186   SUBROUTINE trc_ini_trp
187      !!----------------------------------------------------------------------
188      !!                     ***  ROUTINE trc_ini_trp  ***
189      !!
190      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
191      !!----------------------------------------------------------------------
192      USE trcdmp , ONLY:  trc_dmp_ini
193      USE trcadv , ONLY:  trc_adv_ini
194      USE trcldf , ONLY:  trc_ldf_ini
195      USE trczdf , ONLY:  trc_zdf_ini
196      USE trcrad , ONLY:  trc_rad_ini
197      !
198      INTEGER :: ierr
199      !!----------------------------------------------------------------------
200      !
201      IF( ln_trcdmp )  CALL  trc_dmp_ini          ! damping
202                       CALL  trc_adv_ini          ! advection
203                       CALL  trc_ldf_ini          ! lateral diffusion
204                       CALL  trc_zdf_ini          ! vertical diffusion
205                       CALL  trc_rad_ini          ! positivity of passive tracers
206      !
207   END SUBROUTINE trc_ini_trp
208
209
210   SUBROUTINE trc_ini_state
211      !!----------------------------------------------------------------------
212      !!                     ***  ROUTINE trc_ini_state ***
213      !! ** Purpose :          Initialisation of passive tracer concentration
214      !!----------------------------------------------------------------------
215      USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
216      USE trcrst          ! passive tracers restart
217      USE trcdta          ! initialisation from files
218      !
219      INTEGER ::   jk, jn, jl, jj, ji    ! dummy loop indices
220      !!----------------------------------------------------------------------
221      !
222      ! Initialisation of tracers Initial Conditions
223      IF( ln_trcdta )      CALL trc_dta_init(jptra)
224
225      ! Initialisation of tracers Boundary Conditions
226      IF( lk_my_trc )     CALL trc_bc_init(jptra)
227
228      IF( ln_rsttr ) THEN
229        !
230        CALL trc_rst_read              ! restart from a file
231        !
232      ELSE
233        !
234        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
235            !
236           DO jn = 1, jptra
237               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
238                  jl = n_trc_index(jn) 
239                  CALL trc_dta( nit000, sf_trcdta(jl) )   ! read tracer data at nit000
240!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
241                  DO jk = 1, jpk
242                     DO jj = 1, jpj
243                        DO ji = 1, jpi
244                           trn(ji,jj,jk,jn) = sf_trcdta(jl)%fnow(ji,jj,jk) * tmask(ji,jj,jk) * rf_trfac(jl)
245                        END DO
246                     END DO
247                  END DO
248                  !
249                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
250                     !                                                    (data used only for initialisation)
251                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
252                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
253                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
254                     !
255                  ENDIF
256               ENDIF
257            ENDDO
258            !
259        ENDIF
260        !
261!$OMP PARALLEL DO schedule(static) private(jn,jk,jj,ji)
262      DO jn = 1, jptra
263         DO jk = 1, jpk
264            DO jj = 1, jpj
265               DO ji = 1, jpi
266                  trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn)
267               END DO
268            END DO
269         END DO
270      END DO
271        !
272      ENDIF
273 
274!$OMP PARALLEL DO schedule(static) private(jn,jk,jj,ji)
275      DO jn = 1, jptra
276         DO jk = 1, jpk
277            DO jj = 1, jpj
278               DO ji = 1, jpi
279                  tra(ji,jj,jk,jn) = 0._wp
280               END DO
281            END DO
282         END DO
283      END DO
284      !                                                         ! Partial top/bottom cell: GRADh(trn)
285   END SUBROUTINE trc_ini_state
286
287   SUBROUTINE top_alloc
288      !!----------------------------------------------------------------------
289      !!                     ***  ROUTINE top_alloc  ***
290      !!
291      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
292      !!----------------------------------------------------------------------
293      USE trc           , ONLY:   trc_alloc
294      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
295#if defined key_trdmxl_trc 
296      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
297#endif
298      !
299      INTEGER :: ierr
300      !!----------------------------------------------------------------------
301      !
302      ierr =        trc_alloc()
303      ierr = ierr + trd_trc_oce_alloc()
304#if defined key_trdmxl_trc 
305      ierr = ierr + trd_mxl_trc_alloc()
306#endif
307      !
308      IF( lk_mpp    )   CALL mpp_sum( ierr )
309      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
310      !
311   END SUBROUTINE top_alloc
312
313#else
314   !!----------------------------------------------------------------------
315   !!  Empty module :                                     No passive tracer
316   !!----------------------------------------------------------------------
317CONTAINS
318   SUBROUTINE trc_init                      ! Dummy routine   
319   END SUBROUTINE trc_init
320#endif
321
322   !!======================================================================
323END MODULE trcini
Note: See TracBrowser for help on using the repository browser.