New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

bdydta.F90 in branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

Context Navigation

source: branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 6862

Last change on this file since 6862 was 6862, checked in by lovato, 8 years ago
#1729 - trunk: removed key_bdy from the code and set usage of ln_bdy. Tested with SETTE.
Property svn:keywords set to `Id`
File size: 39.9 KB

Line
1	MODULE bdydta
2	!!======================================================================
3	!! * MODULE bdydta *
4	!! Open boundary data : read the data for the unstructured open boundaries.
5	!!======================================================================
6	!! History : 1.0 ! 2005-01 (J. Chanut, A. Sellar) Original code
7	!! - ! 2007-01 (D. Storkey) Update to use IOM module
8	!! - ! 2007-07 (D. Storkey) add bdy_dta_fla
9	!! 3.0 ! 2008-04 (NEMO team) add in the reference version
10	!! 3.3 ! 2010-09 (E.O'Dea) modifications for Shelf configurations
11	!! 3.3 ! 2010-09 (D.Storkey) add ice boundary conditions
12	!! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge
13	!! 3.6 ! 2012-01 (C. Rousset) add ice boundary conditions for lim3
14	!!----------------------------------------------------------------------
15	!! bdy_dta : read external data along open boundaries from file
16	!! bdy_dta_init : initialise arrays etc for reading of external data
17	!!----------------------------------------------------------------------
18	USE timing ! Timing
19	USE oce ! ocean dynamics and tracers
20	USE dom_oce ! ocean space and time domain
21	USE phycst ! physical constants
22	USE bdy_oce ! ocean open boundary conditions
23	USE bdytides ! tidal forcing at boundaries
24	USE fldread ! read input fields
25	USE iom ! IOM library
26	USE in_out_manager ! I/O logical units
27	#if defined key_lim2
28	USE ice_2
29	#elif defined key_lim3
30	USE ice
31	USE limvar ! redistribute ice input into categories
32	#endif
33	USE sbcapr
34
35	IMPLICIT NONE
36	PRIVATE
37
38	PUBLIC bdy_dta ! routine called by step.F90 and dynspg_ts.F90
39	PUBLIC bdy_dta_init ! routine called by nemogcm.F90
40
41	INTEGER, ALLOCATABLE, DIMENSION(:) :: nb_bdy_fld ! Number of fields to update for each boundary set.
42	INTEGER :: nb_bdy_fld_sum ! Total number of fields to update for all boundary sets.
43	LOGICAL, DIMENSION(jp_bdy) :: ln_full_vel_array ! =T => full velocities in 3D boundary conditions
44	! =F => baroclinic velocities in 3D boundary conditions
45	!$AGRIF_DO_NOT_TREAT
46	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET :: bf ! structure of input fields (file informations, fields read)
47	!$AGRIF_END_DO_NOT_TREAT
48	TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr ! array of pointers to nbmap
49
50	#if defined key_lim3
51	LOGICAL :: ll_bdylim3 ! determine whether ice input is lim2 (F) or lim3 (T) type
52	INTEGER :: jfld_hti, jfld_hts, jfld_ai ! indices of ice thickness, snow thickness and concentration in bf structure
53	#endif
54
55	!!----------------------------------------------------------------------
56	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
57	!! $Id$
58	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
59	!!----------------------------------------------------------------------
60	CONTAINS
61
62	SUBROUTINE bdy_dta( kt, jit, time_offset )
63	!!----------------------------------------------------------------------
64	!! * SUBROUTINE bdy_dta *
65	!!
66	!! ** Purpose : Update external data for open boundary conditions
67	!!
68	!! ** Method : Use fldread.F90
69	!!
70	!!----------------------------------------------------------------------
71	INTEGER, INTENT(in) :: kt ! ocean time-step index
72	INTEGER, INTENT(in), OPTIONAL :: jit ! subcycle time-step index (for timesplitting option)
73	INTEGER, INTENT(in), OPTIONAL :: time_offset ! time offset in units of timesteps. NB. if jit
74	! ! is present then units = subcycle timesteps.
75	! ! time_offset = 0 => get data at "now" time level
76	! ! time_offset = -1 => get data at "before" time level
77	! ! time_offset = +1 => get data at "after" time level
78	! ! etc.
79	!
80	INTEGER :: ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd, jl ! local indices
81	INTEGER, DIMENSION(jpbgrd) :: ilen1
82	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
83	TYPE(OBC_DATA), POINTER :: dta ! short cut
84	!!---------------------------------------------------------------------------
85	!
86	IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
87	!
88	! Initialise data arrays once for all from initial conditions where required
89	!---------------------------------------------------------------------------
90	IF( kt == nit000 .AND. .NOT.PRESENT(jit) ) THEN
91
92	! Calculate depth-mean currents
93	!-----------------------------
94
95	DO ib_bdy = 1, nb_bdy
96	!
97	nblen => idx_bdy(ib_bdy)%nblen
98	nblenrim => idx_bdy(ib_bdy)%nblenrim
99	dta => dta_bdy(ib_bdy)
100
101	IF( nn_dyn2d_dta(ib_bdy) == 0 ) THEN
102	ilen1(:) = nblen(:)
103	IF( dta%ll_ssh ) THEN
104	igrd = 1
105	DO ib = 1, ilen1(igrd)
106	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
107	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
108	dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)
109	END DO
110	END IF
111	IF( dta%ll_u2d ) THEN
112	igrd = 2
113	DO ib = 1, ilen1(igrd)
114	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
115	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
116	dta_bdy(ib_bdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)
117	END DO
118	END IF
119	IF( dta%ll_v2d ) THEN
120	igrd = 3
121	DO ib = 1, ilen1(igrd)
122	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
123	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
124	dta_bdy(ib_bdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)
125	END DO
126	END IF
127	ENDIF
128
129	IF( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
130	ilen1(:) = nblen(:)
131	IF( dta%ll_u3d ) THEN
132	igrd = 2
133	DO ib = 1, ilen1(igrd)
134	DO ik = 1, jpkm1
135	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
136	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
137	dta_bdy(ib_bdy)%u3d(ib,ik) = ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)
138	END DO
139	END DO
140	END IF
141	IF( dta%ll_v3d ) THEN
142	igrd = 3
143	DO ib = 1, ilen1(igrd)
144	DO ik = 1, jpkm1
145	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
146	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
147	dta_bdy(ib_bdy)%v3d(ib,ik) = ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)
148	END DO
149	END DO
150	END IF
151	ENDIF
152
153	IF( nn_tra_dta(ib_bdy) == 0 ) THEN
154	ilen1(:) = nblen(:)
155	IF( dta%ll_tem ) THEN
156	igrd = 1
157	DO ib = 1, ilen1(igrd)
158	DO ik = 1, jpkm1
159	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
160	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
161	dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)
162	END DO
163	END DO
164	END IF
165	IF( dta%ll_sal ) THEN
166	igrd = 1
167	DO ib = 1, ilen1(igrd)
168	DO ik = 1, jpkm1
169	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
170	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
171	dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)
172	END DO
173	END DO
174	END IF
175	ENDIF
176
177	#if defined key_lim2
178	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
179	ilen1(:) = nblen(:)
180	IF( dta%ll_frld ) THEN
181	igrd = 1
182	DO ib = 1, ilen1(igrd)
183	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
184	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
185	dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)
186	END DO
187	END IF
188	IF( dta%ll_hicif ) THEN
189	igrd = 1
190	DO ib = 1, ilen1(igrd)
191	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
192	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
193	dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)
194	END DO
195	END IF
196	IF( dta%ll_hsnif ) THEN
197	igrd = 1
198	DO ib = 1, ilen1(igrd)
199	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
200	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
201	dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)
202	END DO
203	END IF
204	ENDIF
205	#elif defined key_lim3
206	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
207	ilen1(:) = nblen(:)
208	IF( dta%ll_a_i ) THEN
209	igrd = 1
210	DO jl = 1, jpl
211	DO ib = 1, ilen1(igrd)
212	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
213	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
214	dta_bdy(ib_bdy)%a_i (ib,jl) = a_i(ii,ij,jl) * tmask(ii,ij,1)
215	END DO
216	END DO
217	ENDIF
218	IF( dta%ll_ht_i ) THEN
219	igrd = 1
220	DO jl = 1, jpl
221	DO ib = 1, ilen1(igrd)
222	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
223	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
224	dta_bdy(ib_bdy)%ht_i (ib,jl) = ht_i(ii,ij,jl) * tmask(ii,ij,1)
225	END DO
226	END DO
227	ENDIF
228	IF( dta%ll_ht_s ) THEN
229	igrd = 1
230	DO jl = 1, jpl
231	DO ib = 1, ilen1(igrd)
232	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
233	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
234	dta_bdy(ib_bdy)%ht_s (ib,jl) = ht_s(ii,ij,jl) * tmask(ii,ij,1)
235	END DO
236	END DO
237	ENDIF
238	ENDIF
239	#endif
240	END DO ! ib_bdy
241	!
242	ENDIF ! kt == nit000
243
244	! update external data from files
245	!--------------------------------
246
247	jstart = 1
248	DO ib_bdy = 1, nb_bdy
249	dta => dta_bdy(ib_bdy)
250	IF( nn_dta(ib_bdy) == 1 ) THEN ! skip this bit if no external data required
251
252	IF( PRESENT(jit) ) THEN
253	! Update barotropic boundary conditions only
254	! jit is optional argument for fld_read and bdytide_update
255	IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN
256	IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
257	IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
258	IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
259	IF( dta%ll_u3d ) dta%v2d(:) = 0._wp
260	ENDIF
261	IF (cn_tra(ib_bdy) /= 'runoff') THEN
262	IF( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
263
264	jend = jstart + dta%nread(2) - 1
265	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), &
266	& kit=jit, kt_offset=time_offset )
267
268	! If full velocities in boundary data then extract barotropic velocities from 3D fields
269	IF( ln_full_vel_array(ib_bdy) .AND. &
270	& ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. &
271	& nn_dyn3d_dta(ib_bdy) == 1 ) )THEN
272
273	igrd = 2 ! zonal velocity
274	dta%u2d(:) = 0._wp
275	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
276	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
277	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
278	DO ik = 1, jpkm1
279	dta%u2d(ib) = dta%u2d(ib) &
280	& + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
281	END DO
282	dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij)
283	END DO
284	igrd = 3 ! meridional velocity
285	dta%v2d(:) = 0._wp
286	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
287	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
288	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
289	DO ik = 1, jpkm1
290	dta%v2d(ib) = dta%v2d(ib) &
291	& + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
292	END DO
293	dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij)
294	END DO
295	ENDIF
296	ENDIF
297	IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
298	CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy), &
299	& jit=jit, time_offset=time_offset )
300	ENDIF
301	ENDIF
302	ENDIF
303	ELSE
304	IF (cn_tra(ib_bdy) == 'runoff') then ! runoff condition
305	jend = nb_bdy_fld(ib_bdy)
306	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
307	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
308	!
309	igrd = 2 ! zonal velocity
310	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
311	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
312	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
313	dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
314	END DO
315	!
316	igrd = 3 ! meridional velocity
317	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
318	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
319	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
320	dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
321	END DO
322	ELSE
323	IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
324	IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
325	IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
326	IF( dta%ll_v2d ) dta%v2d(:) = 0._wp
327	ENDIF
328	IF( dta%nread(1) .gt. 0 ) THEN ! update external data
329	jend = jstart + dta%nread(1) - 1
330	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
331	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
332	ENDIF
333	! If full velocities in boundary data then split into barotropic and baroclinic data
334	IF( ln_full_vel_array(ib_bdy) .and. &
335	& ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. &
336	& nn_dyn3d_dta(ib_bdy) == 1 ) ) THEN
337	igrd = 2 ! zonal velocity
338	dta%u2d(:) = 0._wp
339	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
340	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
341	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
342	DO ik = 1, jpkm1
343	dta%u2d(ib) = dta%u2d(ib) &
344	& + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
345	END DO
346	dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij)
347	DO ik = 1, jpkm1
348	dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
349	END DO
350	END DO
351	igrd = 3 ! meridional velocity
352	dta%v2d(:) = 0._wp
353	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
354	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
355	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
356	DO ik = 1, jpkm1
357	dta%v2d(ib) = dta%v2d(ib) &
358	& + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
359	END DO
360	dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij)
361	DO ik = 1, jpkm1
362	dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
363	END DO
364	END DO
365	ENDIF
366
367	ENDIF
368	#if defined key_lim3
369	IF( .NOT. ll_bdylim3 .AND. cn_ice_lim(ib_bdy) /= 'none' .AND. nn_ice_lim_dta(ib_bdy) == 1 ) THEN ! bdy ice input (case input is lim2 type)
370	CALL lim_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), &
371	& dta_bdy(ib_bdy)%ht_i, dta_bdy(ib_bdy)%ht_s, dta_bdy(ib_bdy)%a_i )
372	ENDIF
373	#endif
374	ENDIF
375	jstart = jstart + dta%nread(1)
376	END IF ! nn_dta(ib_bdy) = 1
377	END DO ! ib_bdy
378
379	#if defined key_tide
380	IF (ln_dynspg_ts) THEN ! Fill temporary arrays with slow-varying bdy data
381	DO ib_bdy = 1, nb_bdy ! Tidal component added in ts loop
382	IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
383	nblen => idx_bdy(ib_bdy)%nblen
384	nblenrim => idx_bdy(ib_bdy)%nblenrim
385	IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
386	IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen1(1)) = dta_bdy(ib_bdy)%ssh(1:ilen1(1))
387	IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen1(2)) = dta_bdy(ib_bdy)%u2d(1:ilen1(2))
388	IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen1(3)) = dta_bdy(ib_bdy)%v2d(1:ilen1(3))
389	ENDIF
390	END DO
391	ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
392	!
393	CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
394	ENDIF
395	#endif
396
397	IF ( ln_apr_obc ) THEN
398	DO ib_bdy = 1, nb_bdy
399	IF (cn_tra(ib_bdy) /= 'runoff')THEN
400	igrd = 1 ! meridional velocity
401	DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
402	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
403	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
404	dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
405	END DO
406	ENDIF
407	END DO
408	ENDIF
409	!
410	IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
411	!
412	END SUBROUTINE bdy_dta
413
414
415	SUBROUTINE bdy_dta_init
416	!!----------------------------------------------------------------------
417	!! * SUBROUTINE bdy_dta_init *
418	!!
419	!! ** Purpose : Initialise arrays for reading of external data
420	!! for open boundary conditions
421	!!
422	!! ** Method :
423	!!
424	!!----------------------------------------------------------------------
425	INTEGER :: ib_bdy, jfld, jstart, jend, ierror, ios ! Local integers
426	!
427	CHARACTER(len=100) :: cn_dir ! Root directory for location of data files
428	CHARACTER(len=100), DIMENSION(nb_bdy) :: cn_dir_array ! Root directory for location of data files
429	CHARACTER(len = 256):: clname ! temporary file name
430	LOGICAL :: ln_full_vel ! =T => full velocities in 3D boundary data
431	! =F => baroclinic velocities in 3D boundary data
432	INTEGER :: ilen_global ! Max length required for global bdy dta arrays
433	INTEGER, ALLOCATABLE, DIMENSION(:) :: ilen1, ilen3 ! size of 1st and 3rd dimensions of local arrays
434	INTEGER, ALLOCATABLE, DIMENSION(:) :: ibdy ! bdy set for a particular jfld
435	INTEGER, ALLOCATABLE, DIMENSION(:) :: igrid ! index for grid type (1,2,3 = T,U,V)
436	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
437	TYPE(OBC_DATA), POINTER :: dta ! short cut
438	#if defined key_lim3
439	INTEGER, DIMENSION(3) :: zdimsz ! number of elements in each of the 4 dimensions (i.e. i,j,t,ice-cat) for an array
440	INTEGER :: zndims ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat)
441	INTEGER :: inum,id1 ! local integer
442	#endif
443	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: blf_i ! array of namelist information structures
444	TYPE(FLD_N) :: bn_tem, bn_sal, bn_u3d, bn_v3d !
445	TYPE(FLD_N) :: bn_ssh, bn_u2d, bn_v2d ! informations about the fields to be read
446	#if defined key_lim2
447	TYPE(FLD_N) :: bn_frld, bn_hicif, bn_hsnif !
448	#elif defined key_lim3
449	TYPE(FLD_N) :: bn_a_i, bn_ht_i, bn_ht_s
450	#endif
451	NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d
452	#if defined key_lim2
453	NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
454	#elif defined key_lim3
455	NAMELIST/nambdy_dta/ bn_a_i, bn_ht_i, bn_ht_s
456	#endif
457	NAMELIST/nambdy_dta/ ln_full_vel
458	!!---------------------------------------------------------------------------
459	!
460	IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
461	!
462	IF(lwp) WRITE(numout,*)
463	IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
464	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
465	IF(lwp) WRITE(numout,*) ''
466
467	! Set nn_dta
468	DO ib_bdy = 1, nb_bdy
469	nn_dta(ib_bdy) = MAX( nn_dyn2d_dta(ib_bdy) &
470	,nn_dyn3d_dta(ib_bdy) &
471	,nn_tra_dta(ib_bdy) &
472	#if ( defined key_lim2 \|\| defined key_lim3 )
473	,nn_ice_lim_dta(ib_bdy) &
474	#endif
475	)
476	IF(nn_dta(ib_bdy) > 1) nn_dta(ib_bdy) = 1
477	END DO
478
479	! Work out upper bound of how many fields there are to read in and allocate arrays
480	! ---------------------------------------------------------------------------
481	ALLOCATE( nb_bdy_fld(nb_bdy) )
482	nb_bdy_fld(:) = 0
483	DO ib_bdy = 1, nb_bdy
484	IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) THEN
485	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
486	ENDIF
487	IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) == 1 ) THEN
488	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
489	ENDIF
490	IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) == 1 ) THEN
491	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
492	ENDIF
493	#if ( defined key_lim2 \|\| defined key_lim3 )
494	IF( cn_ice_lim(ib_bdy) /= 'none' .and. nn_ice_lim_dta(ib_bdy) == 1 ) THEN
495	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
496	ENDIF
497	#endif
498	IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
499	END DO
500
501	nb_bdy_fld_sum = SUM( nb_bdy_fld )
502
503	ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
504	IF( ierror > 0 ) THEN
505	CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' ) ; RETURN
506	ENDIF
507	ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
508	IF( ierror > 0 ) THEN
509	CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' ) ; RETURN
510	ENDIF
511	ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
512	IF( ierror > 0 ) THEN
513	CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' ) ; RETURN
514	ENDIF
515	ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) )
516	ALLOCATE( ibdy(nb_bdy_fld_sum) )
517	ALLOCATE( igrid(nb_bdy_fld_sum) )
518
519	! Read namelists
520	! --------------
521	REWIND(numnam_ref)
522	REWIND(numnam_cfg)
523	jfld = 0
524	DO ib_bdy = 1, nb_bdy
525	IF( nn_dta(ib_bdy) == 1 ) THEN
526	READ ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
527	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
528
529	READ ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
530	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
531	IF(lwm) WRITE( numond, nambdy_dta )
532
533	cn_dir_array(ib_bdy) = cn_dir
534	ln_full_vel_array(ib_bdy) = ln_full_vel
535
536	nblen => idx_bdy(ib_bdy)%nblen
537	nblenrim => idx_bdy(ib_bdy)%nblenrim
538	dta => dta_bdy(ib_bdy)
539	dta%nread(2) = 0
540
541	! Only read in necessary fields for this set.
542	! Important that barotropic variables come first.
543	IF( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
544
545	IF( dta%ll_ssh ) THEN
546	if(lwp) write(numout,*) '++++++ reading in ssh field'
547	jfld = jfld + 1
548	blf_i(jfld) = bn_ssh
549	ibdy(jfld) = ib_bdy
550	igrid(jfld) = 1
551	ilen1(jfld) = nblen(igrid(jfld))
552	ilen3(jfld) = 1
553	dta%nread(2) = dta%nread(2) + 1
554	ENDIF
555
556	IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
557	if(lwp) write(numout,*) '++++++ reading in u2d field'
558	jfld = jfld + 1
559	blf_i(jfld) = bn_u2d
560	ibdy(jfld) = ib_bdy
561	igrid(jfld) = 2
562	ilen1(jfld) = nblen(igrid(jfld))
563	ilen3(jfld) = 1
564	dta%nread(2) = dta%nread(2) + 1
565	ENDIF
566
567	IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
568	if(lwp) write(numout,*) '++++++ reading in v2d field'
569	jfld = jfld + 1
570	blf_i(jfld) = bn_v2d
571	ibdy(jfld) = ib_bdy
572	igrid(jfld) = 3
573	ilen1(jfld) = nblen(igrid(jfld))
574	ilen3(jfld) = 1
575	dta%nread(2) = dta%nread(2) + 1
576	ENDIF
577
578	ENDIF
579
580	! read 3D velocities if baroclinic velocities require OR if
581	! barotropic velocities required and ln_full_vel set to .true.
582	IF( nn_dyn3d_dta(ib_bdy) == 1 .OR. &
583	& ( ln_full_vel_array(ib_bdy) .AND. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
584
585	IF( dta%ll_u3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
586	if(lwp) write(numout,*) '++++++ reading in u3d field'
587	jfld = jfld + 1
588	blf_i(jfld) = bn_u3d
589	ibdy(jfld) = ib_bdy
590	igrid(jfld) = 2
591	ilen1(jfld) = nblen(igrid(jfld))
592	ilen3(jfld) = jpk
593	IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
594	ENDIF
595
596	IF( dta%ll_v3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
597	if(lwp) write(numout,*) '++++++ reading in v3d field'
598	jfld = jfld + 1
599	blf_i(jfld) = bn_v3d
600	ibdy(jfld) = ib_bdy
601	igrid(jfld) = 3
602	ilen1(jfld) = nblen(igrid(jfld))
603	ilen3(jfld) = jpk
604	IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
605	ENDIF
606
607	ENDIF
608
609	! temperature and salinity
610	IF( nn_tra_dta(ib_bdy) == 1 ) THEN
611
612	IF( dta%ll_tem ) THEN
613	if(lwp) write(numout,*) '++++++ reading in tem field'
614	jfld = jfld + 1
615	blf_i(jfld) = bn_tem
616	ibdy(jfld) = ib_bdy
617	igrid(jfld) = 1
618	ilen1(jfld) = nblen(igrid(jfld))
619	ilen3(jfld) = jpk
620	ENDIF
621
622	IF( dta%ll_sal ) THEN
623	if(lwp) write(numout,*) '++++++ reading in sal field'
624	jfld = jfld + 1
625	blf_i(jfld) = bn_sal
626	ibdy(jfld) = ib_bdy
627	igrid(jfld) = 1
628	ilen1(jfld) = nblen(igrid(jfld))
629	ilen3(jfld) = jpk
630	ENDIF
631
632	ENDIF
633
634	#if defined key_lim2
635	! sea ice
636	IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
637
638	IF( dta%ll_frld ) THEN
639	jfld = jfld + 1
640	blf_i(jfld) = bn_frld
641	ibdy(jfld) = ib_bdy
642	igrid(jfld) = 1
643	ilen1(jfld) = nblen(igrid(jfld))
644	ilen3(jfld) = 1
645	ENDIF
646
647	IF( dta%ll_hicif ) THEN
648	jfld = jfld + 1
649	blf_i(jfld) = bn_hicif
650	ibdy(jfld) = ib_bdy
651	igrid(jfld) = 1
652	ilen1(jfld) = nblen(igrid(jfld))
653	ilen3(jfld) = 1
654	ENDIF
655
656	IF( dta%ll_hsnif ) THEN
657	jfld = jfld + 1
658	blf_i(jfld) = bn_hsnif
659	ibdy(jfld) = ib_bdy
660	igrid(jfld) = 1
661	ilen1(jfld) = nblen(igrid(jfld))
662	ilen3(jfld) = 1
663	ENDIF
664
665	ENDIF
666	#elif defined key_lim3
667	! sea ice
668	IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
669	! Test for types of ice input (lim2 or lim3)
670	! Build file name to find dimensions
671	clname=TRIM(bn_a_i%clname)
672	IF( .NOT. bn_a_i%ln_clim ) THEN
673	WRITE(clname, '(a,"_y",i4.4)' ) TRIM( bn_a_i%clname ), nyear ! add year
674	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname ), nmonth ! add month
675	ELSE
676	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( bn_a_i%clname ), nmonth ! add month
677	ENDIF
678	IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) &
679	& WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname ), nday ! add day
680	!
681	CALL iom_open ( clname, inum )
682	id1 = iom_varid( inum, bn_a_i%clvar, kdimsz=zdimsz, kndims=zndims, ldstop = .FALSE. )
683	CALL iom_close ( inum )
684
685	IF ( zndims == 4 ) THEN
686	ll_bdylim3 = .TRUE. ! lim3 input
687	ELSE
688	ll_bdylim3 = .FALSE. ! lim2 input
689	ENDIF
690	! End test
691
692	IF( dta%ll_a_i ) THEN
693	jfld = jfld + 1
694	blf_i(jfld) = bn_a_i
695	ibdy(jfld) = ib_bdy
696	igrid(jfld) = 1
697	ilen1(jfld) = nblen(igrid(jfld))
698	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
699	ENDIF
700
701	IF( dta%ll_ht_i ) THEN
702	jfld = jfld + 1
703	blf_i(jfld) = bn_ht_i
704	ibdy(jfld) = ib_bdy
705	igrid(jfld) = 1
706	ilen1(jfld) = nblen(igrid(jfld))
707	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
708	ENDIF
709
710	IF( dta%ll_ht_s ) THEN
711	jfld = jfld + 1
712	blf_i(jfld) = bn_ht_s
713	ibdy(jfld) = ib_bdy
714	igrid(jfld) = 1
715	ilen1(jfld) = nblen(igrid(jfld))
716	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
717	ENDIF
718
719	ENDIF
720	#endif
721	! Recalculate field counts
722	!-------------------------
723	IF( ib_bdy == 1 ) THEN
724	nb_bdy_fld_sum = 0
725	nb_bdy_fld(ib_bdy) = jfld
726	nb_bdy_fld_sum = jfld
727	ELSE
728	nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
729	nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
730	ENDIF
731
732	dta%nread(1) = nb_bdy_fld(ib_bdy)
733
734	ENDIF ! nn_dta == 1
735	ENDDO ! ib_bdy
736
737	DO jfld = 1, nb_bdy_fld_sum
738	ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
739	IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
740	nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
741	nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld))
742	ENDDO
743
744	! fill bf with blf_i and control print
745	!-------------------------------------
746	jstart = 1
747	DO ib_bdy = 1, nb_bdy
748	jend = jstart - 1 + nb_bdy_fld(ib_bdy)
749	CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta', &
750	& 'open boundary conditions', 'nambdy_dta' )
751	jstart = jend + 1
752	ENDDO
753
754	! Initialise local boundary data arrays
755	! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
756	! nn_xxx_dta=1 : point to "fnow" arrays
757	!-------------------------------------
758
759	jfld = 0
760	DO ib_bdy=1, nb_bdy
761
762	nblen => idx_bdy(ib_bdy)%nblen
763	dta => dta_bdy(ib_bdy)
764
765	if(lwp) then
766	write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
767	write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
768	write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
769	write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
770	write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
771	write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
772	write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
773	endif
774
775	IF ( nn_dyn2d_dta(ib_bdy) == 0 .or. nn_dyn2d_dta(ib_bdy) == 2 ) THEN
776	if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
777	IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
778	IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
779	IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
780	ENDIF
781	IF ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
782	IF( dta%ll_ssh ) THEN
783	if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
784	jfld = jfld + 1
785	dta%ssh => bf(jfld)%fnow(:,1,1)
786	ENDIF
787	IF ( dta%ll_u2d ) THEN
788	IF ( ln_full_vel_array(ib_bdy) ) THEN
789	if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
790	ALLOCATE( dta%u2d(nblen(2)) )
791	ELSE
792	if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
793	jfld = jfld + 1
794	dta%u2d => bf(jfld)%fnow(:,1,1)
795	ENDIF
796	ENDIF
797	IF ( dta%ll_v2d ) THEN
798	IF ( ln_full_vel_array(ib_bdy) ) THEN
799	if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
800	ALLOCATE( dta%v2d(nblen(3)) )
801	ELSE
802	if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
803	jfld = jfld + 1
804	dta%v2d => bf(jfld)%fnow(:,1,1)
805	ENDIF
806	ENDIF
807	ENDIF
808
809	IF ( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
810	if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
811	IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) )
812	IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) )
813	ENDIF
814	IF ( nn_dyn3d_dta(ib_bdy) == 1 .or. &
815	& ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
816	IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
817	if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
818	jfld = jfld + 1
819	dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
820	ENDIF
821	IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
822	if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
823	jfld = jfld + 1
824	dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
825	ENDIF
826	ENDIF
827
828	IF( nn_tra_dta(ib_bdy) == 0 ) THEN
829	if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
830	IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) )
831	IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) )
832	ELSE
833	IF( dta%ll_tem ) THEN
834	if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
835	jfld = jfld + 1
836	dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
837	ENDIF
838	IF( dta%ll_sal ) THEN
839	if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
840	jfld = jfld + 1
841	dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
842	ENDIF
843	ENDIF
844
845	#if defined key_lim2
846	IF (cn_ice_lim(ib_bdy) /= 'none') THEN
847	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
848	ALLOCATE( dta_bdy(ib_bdy)%frld(nblen(1)) )
849	ALLOCATE( dta_bdy(ib_bdy)%hicif(nblen(1)) )
850	ALLOCATE( dta_bdy(ib_bdy)%hsnif(nblen(1)) )
851	ELSE
852	jfld = jfld + 1
853	dta_bdy(ib_bdy)%frld => bf(jfld)%fnow(:,1,1)
854	jfld = jfld + 1
855	dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
856	jfld = jfld + 1
857	dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
858	ENDIF
859	ENDIF
860	#elif defined key_lim3
861	IF (cn_ice_lim(ib_bdy) /= 'none') THEN
862	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
863	ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
864	ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
865	ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
866	ELSE
867	IF ( ll_bdylim3 ) THEN ! case input is lim3 type
868	jfld = jfld + 1
869	dta_bdy(ib_bdy)%a_i => bf(jfld)%fnow(:,1,:)
870	jfld = jfld + 1
871	dta_bdy(ib_bdy)%ht_i => bf(jfld)%fnow(:,1,:)
872	jfld = jfld + 1
873	dta_bdy(ib_bdy)%ht_s => bf(jfld)%fnow(:,1,:)
874	ELSE ! case input is lim2 type
875	jfld_ai = jfld + 1
876	jfld_hti = jfld + 2
877	jfld_hts = jfld + 3
878	jfld = jfld + 3
879	ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
880	ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
881	ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
882	dta_bdy(ib_bdy)%a_i (:,:) = 0._wp
883	dta_bdy(ib_bdy)%ht_i(:,:) = 0._wp
884	dta_bdy(ib_bdy)%ht_s(:,:) = 0._wp
885	ENDIF
886
887	ENDIF
888	ENDIF
889	#endif
890	!
891	END DO ! ib_bdy
892	!
893	IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
894	!
895	END SUBROUTINE bdy_dta_init
896
897	!!==============================================================================
898	END MODULE bdydta

Note: See TracBrowser for help on using the repository browser.

Download in other formats: