New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytra.F90 in branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY/bdytra.F90 @ 7058

Last change on this file since 7058 was 7058, checked in by lovato, 8 years ago

#1783 - trunk: Generalize the open boundary schemes and revise TRA and TRC BDY wrappers
  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE timing         ! Timing
22
23   IMPLICIT NONE
24   PRIVATE
25
26   ! Local structure to rearrange tracers data
27   TYPE, PUBLIC ::   ztrabdy
28      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
29   END TYPE
30
31   PUBLIC   bdy_tra      ! called in tranxt.F90
32   PUBLIC   bdy_tra_dmp  ! called in step.F90
33
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 4.0, NEMO Consortium (2016)
36   !! $Id$
37   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE bdy_tra( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  SUBROUTINE bdy_tra  ***
44      !!
45      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
46      !!
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT(in) ::   kt   ! Main time step counter
49      !
50      INTEGER                        :: ib_bdy, jn   ! Loop indeces
51      TYPE(ztrabdy), DIMENSION(jpts) :: zdta         ! Temporary data structure
52      !!----------------------------------------------------------------------
53
54      DO ib_bdy=1, nb_bdy
55         !
56         zdta(1)%tra => dta_bdy(ib_bdy)%tem
57         zdta(2)%tra => dta_bdy(ib_bdy)%sal
58         !
59         DO jn = 1, jpts
60            !
61            SELECT CASE( cn_tra(ib_bdy) )
62            CASE('none'        )   ;   CYCLE
63            CASE('frs'         )   ;   CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
64            CASE('specified'   )   ;   CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
65            CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy),                tsa(:,:,:,jn)               )
66            CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.false. )
67            CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.true. )
68            CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn),               jn )
69            CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
70            END SELECT
71            ! Boundary points should be updated
72            CALL lbc_bdy_lnk( tsa(:,:,:,jn), 'T', 1., ib_bdy )
73            !
74         END DO
75      END DO
76      !
77   END SUBROUTINE bdy_tra
78
79   SUBROUTINE bdy_rnf( idx, pta, jpa )
80      !!----------------------------------------------------------------------
81      !!                 ***  SUBROUTINE bdy_rnf  ***
82      !!                   
83      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
84      !!                  - duplicate the neighbour value for the temperature
85      !!                  - specified to 0.1 PSU for the salinity
86      !!
87      !!----------------------------------------------------------------------
88      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
89      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
90      INTEGER,                             INTENT(in) ::   jpa  ! TRA index
91      !
92      REAL(wp) ::   zwgt           ! boundary weight
93      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
94      INTEGER  ::   ii, ij, ip, jp ! 2D addresses
95      !!----------------------------------------------------------------------
96      !
97      IF( nn_timing == 1 )   CALL timing_start('bdy_rnf')
98      !
99      igrd = 1                       ! Everything is at T-points here
100      DO ib = 1, idx%nblenrim(igrd)
101         ii = idx%nbi(ib,igrd)
102         ij = idx%nbj(ib,igrd)
103         DO ik = 1, jpkm1
104            ip = bdytmask(ii+1,ij  ) - bdytmask(ii-1,ij  )
105            jp = bdytmask(ii  ,ij+1) - bdytmask(ii  ,ij-1)
106            if (jpa == jp_tem) pta(ii,ij,ik) = pta(ii+ip,ij+jp,ik) * tmask(ii,ij,ik)
107            if (jpa == jp_sal) pta(ii,ij,ik) =                 0.1 * tmask(ii,ij,ik)
108         END DO
109      END DO
110      !
111      IF( nn_timing == 1 )   CALL timing_stop('bdy_rnf')
112      !
113   END SUBROUTINE bdy_rnf
114
115   SUBROUTINE bdy_tra_dmp( kt )
116      !!----------------------------------------------------------------------
117      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
118      !!                   
119      !! ** Purpose : Apply damping for tracers at open boundaries.
120      !!
121      !!----------------------------------------------------------------------
122      INTEGER, INTENT(in) ::   kt   !
123      !
124      REAL(wp) ::   zwgt           ! boundary weight
125      REAL(wp) ::   zta, zsa, ztime
126      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
127      INTEGER  ::   ii, ij         ! 2D addresses
128      INTEGER  ::   ib_bdy         ! Loop index
129      !!----------------------------------------------------------------------
130      !
131      IF( nn_timing == 1 )   CALL timing_start('bdy_tra_dmp')
132      !
133      DO ib_bdy = 1, nb_bdy
134         IF( ln_tra_dmp(ib_bdy) ) THEN
135            igrd = 1                       ! Everything is at T-points here
136            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
137               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
138               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
139               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
140               DO ik = 1, jpkm1
141                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
142                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
143                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
144                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
145               END DO
146            END DO
147         ENDIF
148      END DO
149      !
150      IF( nn_timing == 1 )   CALL timing_stop('bdy_tra_dmp')
151      !
152   END SUBROUTINE bdy_tra_dmp
153 
154   !!======================================================================
155END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.