| 1 | MODULE sshwzv |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE sshwzv *** |
|---|
| 4 | !! Ocean dynamics : sea surface height and vertical velocity |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : 3.1 ! 2009-02 (G. Madec, M. Leclair) Original code |
|---|
| 7 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA |
|---|
| 8 | !! - ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 9 | !! - ! 2010-09 (D.Storkey and E.O'Dea) bug fixes for BDY module |
|---|
| 10 | !! 3.3 ! 2011-10 (M. Leclair) split former ssh_wzv routine and remove all vvl related work |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! ssh_nxt : after ssh |
|---|
| 15 | !! ssh_swp : filter ans swap the ssh arrays |
|---|
| 16 | !! wzv : compute now vertical velocity |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers variables |
|---|
| 19 | USE dom_oce ! ocean space and time domain variables |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE domvvl ! Variable volume |
|---|
| 22 | USE divhor ! horizontal divergence |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE bdy_oce , ONLY: ln_bdy, bdytmask |
|---|
| 25 | USE bdydyn2d ! bdy_ssh routine |
|---|
| 26 | #if defined key_agrif |
|---|
| 27 | USE agrif_opa_interp |
|---|
| 28 | #endif |
|---|
| 29 | #if defined key_asminc |
|---|
| 30 | USE asminc ! Assimilation increment |
|---|
| 31 | #endif |
|---|
| 32 | ! |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE restart ! only for lrst_oce |
|---|
| 35 | USE prtctl ! Print control |
|---|
| 36 | USE lbclnk ! ocean lateral boundary condition (or mpp link) |
|---|
| 37 | USE lib_mpp ! MPP library |
|---|
| 38 | USE wrk_nemo ! Memory Allocation |
|---|
| 39 | USE timing ! Timing |
|---|
| 40 | USE wet_dry ! Wetting/Drying flux limting |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | PRIVATE |
|---|
| 44 | |
|---|
| 45 | PUBLIC ssh_nxt ! called by step.F90 |
|---|
| 46 | PUBLIC wzv ! called by step.F90 |
|---|
| 47 | PUBLIC ssh_swp ! called by step.F90 |
|---|
| 48 | |
|---|
| 49 | !! * Substitutions |
|---|
| 50 | # include "vectopt_loop_substitute.h90" |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 53 | !! $Id$ |
|---|
| 54 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | CONTAINS |
|---|
| 57 | |
|---|
| 58 | SUBROUTINE ssh_nxt( kt ) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! *** ROUTINE ssh_nxt *** |
|---|
| 61 | !! |
|---|
| 62 | !! ** Purpose : compute the after ssh (ssha) |
|---|
| 63 | !! |
|---|
| 64 | !! ** Method : - Using the incompressibility hypothesis, the ssh increment |
|---|
| 65 | !! is computed by integrating the horizontal divergence and multiply by |
|---|
| 66 | !! by the time step. |
|---|
| 67 | !! |
|---|
| 68 | !! ** action : ssha, after sea surface height |
|---|
| 69 | !! |
|---|
| 70 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | INTEGER, INTENT(in) :: kt ! time step |
|---|
| 73 | ! |
|---|
| 74 | INTEGER :: jk ! dummy loop indice |
|---|
| 75 | REAL(wp) :: z2dt, zcoef ! local scalars |
|---|
| 76 | REAL(wp), POINTER, DIMENSION(:,: ) :: zhdiv ! 2D workspace |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | ! |
|---|
| 79 | IF( nn_timing == 1 ) CALL timing_start('ssh_nxt') |
|---|
| 80 | ! |
|---|
| 81 | CALL wrk_alloc( jpi,jpj, zhdiv ) |
|---|
| 82 | ! |
|---|
| 83 | IF( kt == nit000 ) THEN |
|---|
| 84 | IF(lwp) WRITE(numout,*) |
|---|
| 85 | IF(lwp) WRITE(numout,*) 'ssh_nxt : after sea surface height' |
|---|
| 86 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 87 | ENDIF |
|---|
| 88 | ! |
|---|
| 89 | CALL div_hor( kt ) ! Horizontal divergence |
|---|
| 90 | ! |
|---|
| 91 | z2dt = 2._wp * rdt ! set time step size (Euler/Leapfrog) |
|---|
| 92 | IF( neuler == 0 .AND. kt == nit000 ) z2dt = rdt |
|---|
| 93 | |
|---|
| 94 | ! !------------------------------! |
|---|
| 95 | ! ! After Sea Surface Height ! |
|---|
| 96 | ! !------------------------------! |
|---|
| 97 | zhdiv(:,:) = 0._wp |
|---|
| 98 | DO jk = 1, jpkm1 ! Horizontal divergence of barotropic transports |
|---|
| 99 | zhdiv(:,:) = zhdiv(:,:) + e3t_n(:,:,jk) * hdivn(:,:,jk) |
|---|
| 100 | END DO |
|---|
| 101 | ! ! Sea surface elevation time stepping |
|---|
| 102 | ! In time-split case we need a first guess of the ssh after (using the baroclinic timestep) in order to |
|---|
| 103 | ! compute the vertical velocity which can be used to compute the non-linear terms of the momentum equations. |
|---|
| 104 | ! |
|---|
| 105 | zcoef = 0.5_wp * r1_rau0 |
|---|
| 106 | |
|---|
| 107 | IF(ln_wd) CALL wad_lmt(sshb, zcoef * (emp_b(:,:) + emp(:,:)), z2dt) |
|---|
| 108 | |
|---|
| 109 | ssha(:,:) = ( sshb(:,:) - z2dt * ( zcoef * ( emp_b(:,:) + emp(:,:) ) + zhdiv(:,:) ) ) * ssmask(:,:) |
|---|
| 110 | |
|---|
| 111 | IF ( .NOT.ln_dynspg_ts ) THEN |
|---|
| 112 | ! These lines are not necessary with time splitting since |
|---|
| 113 | ! boundary condition on sea level is set during ts loop |
|---|
| 114 | # if defined key_agrif |
|---|
| 115 | CALL agrif_ssh( kt ) |
|---|
| 116 | # endif |
|---|
| 117 | IF( ln_bdy ) THEN |
|---|
| 118 | CALL lbc_lnk( ssha, 'T', 1. ) ! Not sure that's necessary |
|---|
| 119 | CALL bdy_ssh( ssha ) ! Duplicate sea level across open boundaries |
|---|
| 120 | ENDIF |
|---|
| 121 | ENDIF |
|---|
| 122 | |
|---|
| 123 | #if defined key_asminc |
|---|
| 124 | IF( lk_asminc .AND. ln_sshinc .AND. ln_asmiau ) THEN ! Include the IAU weighted SSH increment |
|---|
| 125 | CALL ssh_asm_inc( kt ) |
|---|
| 126 | ssha(:,:) = ssha(:,:) + z2dt * ssh_iau(:,:) |
|---|
| 127 | ENDIF |
|---|
| 128 | #endif |
|---|
| 129 | ! !------------------------------! |
|---|
| 130 | ! ! outputs ! |
|---|
| 131 | ! !------------------------------! |
|---|
| 132 | ! |
|---|
| 133 | IF(ln_ctl) CALL prt_ctl( tab2d_1=ssha, clinfo1=' ssha - : ', mask1=tmask, ovlap=1 ) |
|---|
| 134 | ! |
|---|
| 135 | CALL wrk_dealloc( jpi, jpj, zhdiv ) |
|---|
| 136 | ! |
|---|
| 137 | IF( nn_timing == 1 ) CALL timing_stop('ssh_nxt') |
|---|
| 138 | ! |
|---|
| 139 | END SUBROUTINE ssh_nxt |
|---|
| 140 | |
|---|
| 141 | |
|---|
| 142 | SUBROUTINE wzv( kt ) |
|---|
| 143 | !!---------------------------------------------------------------------- |
|---|
| 144 | !! *** ROUTINE wzv *** |
|---|
| 145 | !! |
|---|
| 146 | !! ** Purpose : compute the now vertical velocity |
|---|
| 147 | !! |
|---|
| 148 | !! ** Method : - Using the incompressibility hypothesis, the vertical |
|---|
| 149 | !! velocity is computed by integrating the horizontal divergence |
|---|
| 150 | !! from the bottom to the surface minus the scale factor evolution. |
|---|
| 151 | !! The boundary conditions are w=0 at the bottom (no flux) and. |
|---|
| 152 | !! |
|---|
| 153 | !! ** action : wn : now vertical velocity |
|---|
| 154 | !! |
|---|
| 155 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 156 | !!---------------------------------------------------------------------- |
|---|
| 157 | INTEGER, INTENT(in) :: kt ! time step |
|---|
| 158 | ! |
|---|
| 159 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 160 | REAL(wp) :: z1_2dt ! local scalars |
|---|
| 161 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d |
|---|
| 162 | REAL(wp), POINTER, DIMENSION(:,:,:) :: z3d, zhdiv |
|---|
| 163 | !!---------------------------------------------------------------------- |
|---|
| 164 | ! |
|---|
| 165 | IF( nn_timing == 1 ) CALL timing_start('wzv') |
|---|
| 166 | ! |
|---|
| 167 | IF( kt == nit000 ) THEN |
|---|
| 168 | IF(lwp) WRITE(numout,*) |
|---|
| 169 | IF(lwp) WRITE(numout,*) 'wzv : now vertical velocity ' |
|---|
| 170 | IF(lwp) WRITE(numout,*) '~~~~~ ' |
|---|
| 171 | ! |
|---|
| 172 | wn(:,:,jpk) = 0._wp ! bottom boundary condition: w=0 (set once for all) |
|---|
| 173 | ENDIF |
|---|
| 174 | ! !------------------------------! |
|---|
| 175 | ! ! Now Vertical Velocity ! |
|---|
| 176 | ! !------------------------------! |
|---|
| 177 | z1_2dt = 1. / ( 2. * rdt ) ! set time step size (Euler/Leapfrog) |
|---|
| 178 | IF( neuler == 0 .AND. kt == nit000 ) z1_2dt = 1. / rdt |
|---|
| 179 | ! |
|---|
| 180 | IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! z_tilde and layer cases |
|---|
| 181 | CALL wrk_alloc( jpi, jpj, jpk, zhdiv ) |
|---|
| 182 | ! |
|---|
| 183 | DO jk = 1, jpkm1 |
|---|
| 184 | ! horizontal divergence of thickness diffusion transport ( velocity multiplied by e3t) |
|---|
| 185 | ! - ML - note: computation already done in dom_vvl_sf_nxt. Could be optimized (not critical and clearer this way) |
|---|
| 186 | DO jj = 2, jpjm1 |
|---|
| 187 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 188 | zhdiv(ji,jj,jk) = r1_e1e2t(ji,jj) * ( un_td(ji,jj,jk) - un_td(ji-1,jj,jk) + vn_td(ji,jj,jk) - vn_td(ji,jj-1,jk) ) |
|---|
| 189 | END DO |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | CALL lbc_lnk(zhdiv, 'T', 1.) ! - ML - Perhaps not necessary: not used for horizontal "connexions" |
|---|
| 193 | ! ! Is it problematic to have a wrong vertical velocity in boundary cells? |
|---|
| 194 | ! ! Same question holds for hdivn. Perhaps just for security |
|---|
| 195 | DO jk = jpkm1, 1, -1 ! integrate from the bottom the hor. divergence |
|---|
| 196 | ! computation of w |
|---|
| 197 | wn(:,:,jk) = wn(:,:,jk+1) - ( e3t_n(:,:,jk) * hdivn(:,:,jk) + zhdiv(:,:,jk) & |
|---|
| 198 | & + z1_2dt * ( e3t_a(:,:,jk) - e3t_b(:,:,jk) ) ) * tmask(:,:,jk) |
|---|
| 199 | END DO |
|---|
| 200 | ! IF( ln_vvl_layer ) wn(:,:,:) = 0.e0 |
|---|
| 201 | CALL wrk_dealloc( jpi, jpj, jpk, zhdiv ) |
|---|
| 202 | ELSE ! z_star and linear free surface cases |
|---|
| 203 | DO jk = jpkm1, 1, -1 ! integrate from the bottom the hor. divergence |
|---|
| 204 | ! computation of w |
|---|
| 205 | wn(:,:,jk) = wn(:,:,jk+1) - ( e3t_n(:,:,jk) * hdivn(:,:,jk) & |
|---|
| 206 | & + z1_2dt * ( e3t_a(:,:,jk) - e3t_b(:,:,jk) ) ) * tmask(:,:,jk) |
|---|
| 207 | END DO |
|---|
| 208 | ENDIF |
|---|
| 209 | |
|---|
| 210 | IF( ln_bdy ) THEN |
|---|
| 211 | DO jk = 1, jpkm1 |
|---|
| 212 | wn(:,:,jk) = wn(:,:,jk) * bdytmask(:,:) |
|---|
| 213 | END DO |
|---|
| 214 | ENDIF |
|---|
| 215 | ! |
|---|
| 216 | IF( nn_timing == 1 ) CALL timing_stop('wzv') |
|---|
| 217 | ! |
|---|
| 218 | END SUBROUTINE wzv |
|---|
| 219 | |
|---|
| 220 | |
|---|
| 221 | SUBROUTINE ssh_swp( kt ) |
|---|
| 222 | !!---------------------------------------------------------------------- |
|---|
| 223 | !! *** ROUTINE ssh_nxt *** |
|---|
| 224 | !! |
|---|
| 225 | !! ** Purpose : achieve the sea surface height time stepping by |
|---|
| 226 | !! applying Asselin time filter and swapping the arrays |
|---|
| 227 | !! ssha already computed in ssh_nxt |
|---|
| 228 | !! |
|---|
| 229 | !! ** Method : - apply Asselin time fiter to now ssh (excluding the forcing |
|---|
| 230 | !! from the filter, see Leclair and Madec 2010) and swap : |
|---|
| 231 | !! sshn = ssha + atfp * ( sshb -2 sshn + ssha ) |
|---|
| 232 | !! - atfp * rdt * ( emp_b - emp ) / rau0 |
|---|
| 233 | !! sshn = ssha |
|---|
| 234 | !! |
|---|
| 235 | !! ** action : - sshb, sshn : before & now sea surface height |
|---|
| 236 | !! ready for the next time step |
|---|
| 237 | !! |
|---|
| 238 | !! Reference : Leclair, M., and G. Madec, 2009, Ocean Modelling. |
|---|
| 239 | !!---------------------------------------------------------------------- |
|---|
| 240 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 241 | ! |
|---|
| 242 | REAL(wp) :: zcoef ! local scalar |
|---|
| 243 | !!---------------------------------------------------------------------- |
|---|
| 244 | ! |
|---|
| 245 | IF( nn_timing == 1 ) CALL timing_start('ssh_swp') |
|---|
| 246 | ! |
|---|
| 247 | IF( kt == nit000 ) THEN |
|---|
| 248 | IF(lwp) WRITE(numout,*) |
|---|
| 249 | IF(lwp) WRITE(numout,*) 'ssh_swp : Asselin time filter and swap of sea surface height' |
|---|
| 250 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 251 | ENDIF |
|---|
| 252 | ! !== Euler time-stepping: no filter, just swap ==! |
|---|
| 253 | IF( ( neuler == 0 .AND. kt == nit000 ) .OR. & |
|---|
| 254 | & ( ln_bt_fw .AND. ln_dynspg_ts ) ) THEN |
|---|
| 255 | sshb(:,:) = sshn(:,:) ! before <-- now |
|---|
| 256 | sshn(:,:) = ssha(:,:) ! now <-- after (before already = now) |
|---|
| 257 | ! |
|---|
| 258 | ELSE !== Leap-Frog time-stepping: Asselin filter + swap ==! |
|---|
| 259 | ! ! before <-- now filtered |
|---|
| 260 | sshb(:,:) = sshn(:,:) + atfp * ( sshb(:,:) - 2 * sshn(:,:) + ssha(:,:) ) |
|---|
| 261 | IF( .NOT.ln_linssh ) THEN ! before <-- with forcing removed |
|---|
| 262 | zcoef = atfp * rdt * r1_rau0 |
|---|
| 263 | sshb(:,:) = sshb(:,:) - zcoef * ( emp_b(:,:) - emp (:,:) & |
|---|
| 264 | & - rnf_b(:,:) + rnf (:,:) & |
|---|
| 265 | & + fwfisf_b(:,:) - fwfisf(:,:) ) * ssmask(:,:) |
|---|
| 266 | ENDIF |
|---|
| 267 | sshn(:,:) = ssha(:,:) ! now <-- after |
|---|
| 268 | ENDIF |
|---|
| 269 | ! |
|---|
| 270 | IF(ln_ctl) CALL prt_ctl( tab2d_1=sshb, clinfo1=' sshb - : ', mask1=tmask, ovlap=1 ) |
|---|
| 271 | ! |
|---|
| 272 | IF( nn_timing == 1 ) CALL timing_stop('ssh_swp') |
|---|
| 273 | ! |
|---|
| 274 | END SUBROUTINE ssh_swp |
|---|
| 275 | |
|---|
| 276 | !!====================================================================== |
|---|
| 277 | END MODULE sshwzv |
|---|
