New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 6862

Last change on this file since 6862 was 6862, checked in by lovato, 8 years ago

#1729 - trunk: removed key_bdy from the code and set usage of ln_bdy. Tested with SETTE.
  • Property svn:keywords set to Id
File size: 14.3 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice covered area using LIM sea-ice model
5   !! Sea-Ice model  :  LIM-2 Sea ice model time-stepping
6   !!======================================================================
7   !! History :  1.0   !  06-2006  (G. Madec)  from icestp_2.F90
8   !!            3.0   !  08-2008  (S. Masson, E. .... ) coupled interface
9   !!            3.3   !  05-2009  (G.Garric) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                    LIM-2 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   sbc_ice_lim_2   : sea-ice model time-stepping and update ocean sbc over ice-covered area
16   !!----------------------------------------------------------------------
17   USE oce              ! ocean dynamics and tracers
18   USE dom_oce          ! ocean space and time domain
19   USE ice_2
20   USE par_ice_2
21   USE iceini_2
22   USE dom_ice_2
23
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice   fields
26   USE sbcblk_core      ! Surface boundary condition: CORE bulk
27   USE sbcblk_clio      ! Surface boundary condition: CLIO bulk
28   USE sbccpl           ! Surface boundary condition: coupled interface
29   USE albedo
30
31   USE phycst           ! Define parameters for the routines
32   USE eosbn2           ! equation of state
33   USE limdyn_2
34   USE limtrp_2
35   USE limdmp_2
36   USE limthd_2
37   USE limsbc_2         ! sea surface boundary condition
38   USE limdia_2
39   USE limwri_2
40   USE limrst_2
41
42   USE c1d              ! 1D vertical configuration
43
44   USE lbclnk           ! lateral boundary condition - MPP link
45   USE lib_mpp          ! MPP library
46   USE wrk_nemo         ! work arrays
47   USE iom              ! I/O manager library
48   USE in_out_manager   ! I/O manager
49   USE prtctl           ! Print control
50
51# if defined key_agrif
52   USE agrif_ice
53   USE agrif_lim2_update
54# endif
55
56   USE bdy_oce   , ONLY: ln_bdy
57   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
58
59   IMPLICIT NONE
60   PRIVATE
61
62   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
63
64   !! * Substitutions
65#  include "vectopt_loop_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   SUBROUTINE sbc_ice_lim_2( kt, ksbc )
74      !!---------------------------------------------------------------------
75      !!                  ***  ROUTINE sbc_ice_lim_2  ***
76      !!                   
77      !! ** Purpose :   update the ocean surface boundary condition via the
78      !!                Louvain la Neuve Sea Ice Model time stepping
79      !!
80      !! ** Method  :   ice model time stepping
81      !!              - call the ice dynamics routine
82      !!              - call the ice advection/diffusion routine
83      !!              - call the ice thermodynamics routine
84      !!              - call the routine that computes mass and
85      !!                heat fluxes at the ice/ocean interface
86      !!              - save the outputs
87      !!              - save the outputs for restart when necessary
88      !!
89      !! ** Action  : - time evolution of the LIM sea-ice model
90      !!              - update all sbc variables below sea-ice:
91      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
92      !!---------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt      ! ocean time step
94      INTEGER, INTENT(in) ::   ksbc    ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled )
95      !!
96      INTEGER  ::   ji, jj   ! dummy loop indices
97      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_os   ! ice albedo under overcast sky
98      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_cs   ! ice albedo under clear sky
99      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice  ! mean ice albedo
100      REAL(wp), DIMENSION(:,:,:), POINTER :: zsist     ! ice surface temperature (K)
101      REAL(wp), DIMENSION(:,:  ), POINTER :: zutau_ice, zvtau_ice 
102      !!----------------------------------------------------------------------
103
104      IF( kt == nit000 ) THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
108         !
109         CALL ice_init_2
110         !
111# if defined key_agrif
112         IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2   ! AGRIF: set the meshes
113# endif
114      ENDIF
115
116      !                                        !----------------------!
117      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
118         !                                     !----------------------!
119# if defined key_agrif
120         IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()&
121         &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1
122# endif
123
124         CALL wrk_alloc( jpi,jpj  , zutau_ice, zvtau_ice)
125         CALL wrk_alloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
126
127         !  Bulk Formulea !
128         !----------------!
129         ! ... mean surface ocean current at ice dynamics point
130         SELECT CASE( cp_ice_msh )
131         CASE( 'I' )                  !== B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
132            DO jj = 2, jpj
133               DO ji = 2, jpi   ! NO vector opt. possible
134                  u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj  ) * umask(ji-1,jj  ,1) &
135                     &                    + ssu_m(ji-1,jj-1) * umask(ji-1,jj-1,1) ) * tmu(ji,jj)
136                  v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji  ,jj-1) * vmask(ji  ,jj-1,1) &
137                     &                    + ssv_m(ji-1,jj-1) * vmask(ji-1,jj-1,1) ) * tmu(ji,jj)
138               END DO
139            END DO
140            CALL lbc_lnk( u_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
141            CALL lbc_lnk( v_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
142            !
143         CASE( 'C' )                  !== C-grid ice dynamics :   U & V-points (same as ocean)
144            u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)                     ! mean surface ocean current at ice velocity point
145            v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
146            !
147         END SELECT
148
149         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
150         CALL eos_fzp( sss_m(:,:), tfu(:,:) )
151         tfu(:,:) = tfu(:,:) + rt0
152
153         zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) )
154
155         ! Ice albedo
156
157         CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), &
158                                 reshape( hsnif, (/jpi,jpj,1/) ), &
159                          zalb_cs, zalb_os )
160
161         SELECT CASE( ksbc )
162         CASE( jp_core , jp_purecpl )   ! CORE and COUPLED bulk formulations
163
164            ! albedo depends on cloud fraction because of non-linear spectral effects
165            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
166            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
167            ! (zalb_ice) is computed within the bulk routine
168
169         END SELECT
170
171         ! ... Sea-ice surface boundary conditions output from bulk formulae :
172         !     - utau_ice   ! surface ice stress i-component (I-point)   [N/m2]
173         !     - vtau_ice   ! surface ice stress j-component (I-point)   [N/m2]
174         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
175         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
176         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
177         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
178         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
179         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
180         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
181         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
182         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
183         !
184         SELECT CASE( ksbc )
185         CASE( jp_clio )           ! CLIO bulk formulation
186!           CALL blk_ice_clio( zsist, zalb_cs    , zalb_os    , zalb_ice   ,            &
187!              &                      utau_ice   , vtau_ice   , qns_ice    , qsr_ice,   &
188!              &                      qla_ice    , dqns_ice   , dqla_ice   ,            &
189!              &                      tprecip    , sprecip    ,                         &
190!              &                      fr1_i0     , fr2_i0     , cp_ice_msh , jpl  )
191            CALL blk_ice_clio_tau
192            CALL blk_ice_clio_flx( zsist, zalb_cs, zalb_os, zalb_ice )
193
194         CASE( jp_core )           ! CORE bulk formulation
195            CALL blk_ice_core_tau
196            CALL blk_ice_core_flx( zsist, zalb_ice )
197
198         CASE( jp_purecpl )            ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics)
199            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
200         END SELECT
201         
202         IF( ln_mixcpl) THEN
203            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
204            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
205            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
206         ENDIF
207
208         CALL iom_put( 'utau_ice', utau_ice )     ! Wind stress over ice along i-axis at I-point
209         CALL iom_put( 'vtau_ice', vtau_ice )     ! Wind stress over ice along j-axis at I-point
210
211         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
212            CALL prt_ctl_info( 'Ice Forcings ' )
213            CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip  : ', tab2d_2=sprecip , clinfo2=' Snow    : ' )
214            CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' )
215            CALL prt_ctl( tab2d_1=sst_m   ,clinfo1=' sbc_ice_lim: sst     : ', tab2d_2=sss_m   , clinfo2=' sss     : ' )
216            CALL prt_ctl( tab2d_1=u_oce   ,clinfo1=' sbc_ice_lim: u_io    : ', tab2d_2=v_oce   , clinfo2=' v_io    : ' )
217            CALL prt_ctl( tab2d_1=hsnif   ,clinfo1=' sbc_ice_lim: hsnif  1: ', tab2d_2=hicif   , clinfo2=' hicif   : ' )
218            CALL prt_ctl( tab2d_1=frld    ,clinfo1=' sbc_ice_lim: frld   1: ', tab2d_2=sist    , clinfo2=' sist    : ' )
219         ENDIF
220
221         ! ---------------- !
222         !  Ice model step  !
223         ! ---------------- !
224         numit = numit + nn_fsbc                           ! Ice model time step
225
226                           CALL lim_rst_opn_2  ( kt )  ! Open Ice restart file
227         IF( .NOT. lk_c1d ) THEN                       ! Ice dynamics & transport (except in 1D case)
228                           CALL lim_dyn_2      ( kt )      ! Ice dynamics    ( rheology/dynamics )
229                           CALL lim_trp_2      ( kt )      ! Ice transport   ( Advection/diffusion )
230           IF( ln_limdmp ) CALL lim_dmp_2      ( kt )      ! Ice damping
231           IF( ln_bdy    ) CALL bdy_ice_lim( kt ) ! bdy ice thermo
232         END IF
233         !                                             ! Ice surface fluxes in coupled mode
234         IF( ln_cpl ) THEN   ! pure coupled and mixed forced-coupled configurations
235            a_i(:,:,1)=fr_i
236            CALL sbc_cpl_ice_flx( frld,                                              &
237            !                                optional arguments, used only in 'mixed oce-ice' case
238            &                                             palbi=zalb_ice, psst=sst_m, pist=zsist )
239            sprecip(:,:) = - emp_ice(:,:)   ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.)
240         ENDIF
241                           CALL lim_thd_2      ( kt )      ! Ice thermodynamics
242                           CALL lim_sbc_flx_2  ( kt )      ! update surface ocean mass, heat & salt fluxes
243
244         IF(  .NOT. lk_mpp )THEN
245            IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 )   &
246            &              CALL lim_dia_2      ( kt )      ! Ice Diagnostics
247         ENDIF
248# if ! defined key_iomput
249                           CALL lim_wri_2      ( kt )      ! Ice outputs
250# endif
251         IF( lrst_ice  )   CALL lim_rst_write_2( kt )      ! Ice restart file
252         !
253# if defined key_agrif && defined key_lim2
254         IF( .NOT. Agrif_Root() )   CALL agrif_update_lim2( kt )
255# endif
256         !
257         CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
258         CALL wrk_dealloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
259         !
260      ENDIF                                    ! End sea-ice time step only
261      !
262      !                                        !--------------------------!
263      !                                        !  at all ocean time step  !
264      !                                        !--------------------------!
265      !                                               
266      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
267      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
268      IF( ln_limdyn    )   CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
269      !
270   END SUBROUTINE sbc_ice_lim_2
271
272#else
273   !!----------------------------------------------------------------------
274   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
275   !!----------------------------------------------------------------------
276CONTAINS
277   SUBROUTINE sbc_ice_lim_2 ( kt, ksbc )     ! Dummy routine
278      INTEGER, INTENT(in) ::   kt, ksbc   
279      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc
280   END SUBROUTINE sbc_ice_lim_2
281#endif
282
283   !!======================================================================
284END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.