New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2016/dev_r6711_SIMPLIF_6_aerobulk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6711_SIMPLIF_6_aerobulk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 6723

Last change on this file since 6723 was 6723, checked in by gm, 8 years ago

#1751 - branch SIMPLIF_6_aerobulk: add aerobulk package including NCAR, COARE and ECMWF bulk
  • Property svn:keywords set to Id
File size: 28.4 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!----------------------------------------------------------------------
23   USE oce            ! ocean dynamics and tracers
24   USE dom_oce        ! ocean space and time domain
25   USE phycst         ! physical constants
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE trc_oce        ! shared ocean-passive tracers variables
28   USE sbc_ice        ! Surface boundary condition: ice fields
29   USE sbcdcy         ! surface boundary condition: diurnal cycle
30   USE sbcssm         ! surface boundary condition: sea-surface mean variables
31   USE sbcana         ! surface boundary condition: analytical formulation
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim     ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2   ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
38   USE sbccpl         ! surface boundary condition: coupled florulation
39   USE cpl_oasis3     ! OASIS routines for coupling
40   USE sbcssr         ! surface boundary condition: sea surface restoring
41   USE sbcrnf         ! surface boundary condition: runoffs
42   USE sbcisf         ! surface boundary condition: ice shelf
43   USE sbcfwb         ! surface boundary condition: freshwater budget
44   USE closea         ! closed sea
45   USE icbstp         ! Icebergs
46   USE traqsr         ! active tracers: light penetration
47   USE sbcwave        ! Wave module
48   USE bdy_par        ! Require lk_bdy
49   !
50   USE prtctl         ! Print control                    (prt_ctl routine)
51   USE iom            ! IOM library
52   USE in_out_manager ! I/O manager
53   USE lib_mpp        ! MPP library
54   USE timing         ! Timing
55
56   USE diurnal_bulk, ONLY:   ln_diurnal_only
57
58   IMPLICIT NONE
59   PRIVATE
60
61   PUBLIC   sbc        ! routine called by step.F90
62   PUBLIC   sbc_init   ! routine called by opa.F90
63
64   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
65
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 4.0 , NEMO-consortium (2016)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   SUBROUTINE sbc_init
74      !!---------------------------------------------------------------------
75      !!                    ***  ROUTINE sbc_init ***
76      !!
77      !! ** Purpose :   Initialisation of the ocean surface boundary computation
78      !!
79      !! ** Method  :   Read the namsbc namelist and set derived parameters
80      !!                Call init routines for all other SBC modules that have one
81      !!
82      !! ** Action  : - read namsbc parameters
83      !!              - nsbc: type of sbc
84      !!----------------------------------------------------------------------
85      INTEGER ::   icpt   ! local integer
86      !!
87      NAMELIST/namsbc/ nn_fsbc  , ln_ana   , ln_flx, ln_blk, ln_cpl   , ln_mixcpl,        &
88         &             nn_components      , nn_limflx  ,                                  &
89         &             ln_traqsr, ln_dm2dc ,                                              &
90         &             nn_ice   , nn_ice_embd,                                            &
91         &             ln_rnf   , ln_ssr   , ln_isf   , nn_fwb    , ln_apr_dyn,           &
92         &             ln_wave  ,                                                         &
93         &             nn_lsm
94      INTEGER  ::   ios
95      INTEGER  ::   ierr, ierr0, ierr1, ierr2, ierr3, jpm
96      LOGICAL  ::   ll_purecpl
97      !!----------------------------------------------------------------------
98      !
99      IF(lwp) THEN
100         WRITE(numout,*)
101         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
102         WRITE(numout,*) '~~~~~~~~ '
103      ENDIF
104      !
105      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
106      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
107901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
108      !
109      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
110      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
111902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
112      IF(lwm) WRITE( numond, namsbc )
113      !
114      !                          ! overwrite namelist parameter using CPP key information
115      IF( Agrif_Root() ) THEN                ! AGRIF zoom
116         IF( lk_lim2 )   nn_ice      = 2
117         IF( lk_lim3 )   nn_ice      = 3
118         IF( lk_cice )   nn_ice      = 4
119      ENDIF
120      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
121         ln_ana      = .TRUE.
122         nn_ice      =   0
123      ENDIF
124      !
125      IF(lwp) THEN               ! Control print
126         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
127         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
128         WRITE(numout,*) '           Type of air-sea fluxes : '
129         WRITE(numout,*) '              analytical formulation                     ln_ana        = ', ln_ana
130         WRITE(numout,*) '              flux       formulation                     ln_flx        = ', ln_flx
131         WRITE(numout,*) '              bulk       formulation                     ln_blk        = ', ln_blk
132         WRITE(numout,*) '           Type of coupling (Ocean/Ice/Atmosphere) : '
133         WRITE(numout,*) '              ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
134         WRITE(numout,*) '              forced-coupled mixed formulation           ln_mixcpl     = ', ln_mixcpl
135         WRITE(numout,*) '              OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
136         WRITE(numout,*) '              components of your executable              nn_components = ', nn_components
137         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx     = ', nn_limflx
138         WRITE(numout,*) '           Sea-ice : '
139         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
140         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd   = ', nn_ice_embd
141         WRITE(numout,*) '           Misc. options of sbc : '
142         WRITE(numout,*) '              Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
143         WRITE(numout,*) '                 daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
144         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
145         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
146         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
147         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf        = ', ln_rnf
148         WRITE(numout,*) '              iceshelf formulation                       ln_isf        = ', ln_isf
149         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea     = ', nn_closea
150         WRITE(numout,*) '              nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
151         WRITE(numout,*) '              surface wave                               ln_wave       = ', ln_wave
152      ENDIF
153      !
154      IF(lwp) THEN
155         WRITE(numout,*)
156         SELECT CASE ( nn_limflx )        ! LIM3 Multi-category heat flux formulation
157         CASE ( -1 )   ;   WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
158         CASE ( 0  )   ;   WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
159         CASE ( 1  )   ;   WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
160         CASE ( 2  )   ;   WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
161         END SELECT
162      ENDIF
163      !
164      IF( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis )   &
165         &      CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
166      IF( nn_components == jp_iam_opa .AND. ln_cpl )   &
167         &      CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' )
168      IF( nn_components == jp_iam_opa .AND. ln_mixcpl )   &
169         &      CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
170      IF( ln_cpl .AND. .NOT. lk_oasis )    &
171         &      CALL ctl_stop( 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' )
172      IF( ln_mixcpl .AND. .NOT. lk_oasis )    &
173         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' )
174      IF( ln_mixcpl .AND. .NOT. ln_cpl )    &
175         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' )
176      IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo )    &
177         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' )
178
179      !                              ! allocate sbc arrays
180      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
181
182      !                          ! Checks:
183      IF( .NOT. ln_isf ) THEN                      ! variable initialisation if no ice shelf
184         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
185         fwfisf  (:,:)   = 0.0_wp ; fwfisf_b  (:,:)   = 0.0_wp
186         risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp
187      END IF
188      IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! no ice in the domain, ice fraction is always zero
189
190      sfx(:,:) = 0._wp                             ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
191      !                                            ! only if sea-ice is present
192
193      fmmflx(:,:) = 0._wp                          ! freezing-melting array initialisation
194
195      taum(:,:) = 0._wp                            ! Initialise taum for use in gls in case of reduced restart
196
197      !                                            ! restartability
198      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk .OR. ln_cpl ) )   &
199         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
200      IF( nn_ice == 4 .AND. .NOT.( ln_blk .OR. ln_cpl ) )   &
201         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk or ln_cpl' )
202      IF( nn_ice == 4 .AND. lk_agrif )   &
203         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
204      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
205         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
206      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
207         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
208      IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
209         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
210      IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) )   &
211         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
212
213      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
214
215      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
216         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or the bulk formulation' )
217
218      !                          ! Choice of the Surface Boudary Condition (set nsbc)
219      ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl
220      !
221      icpt = 0
222      IF( ln_ana          ) THEN   ;   nsbc = jp_ana     ; icpt = icpt + 1   ;   ENDIF       ! analytical           formulation
223      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
224      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
225      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
226      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                        ;   ENDIF       ! GYRE analytical      formulation
227      IF( nn_components == jp_iam_opa )   &
228         &                  THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
229      !
230      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init: choose ONE and only ONE sbc option' )
231      !
232      IF(lwp) THEN
233         WRITE(numout,*)
234         SELECT CASE( nsbc )
235         CASE( jp_gyre    )   ;   WRITE(numout,*) '   GYRE analytical formulation'
236         CASE( jp_ana     )   ;   WRITE(numout,*) '   analytical formulation'
237         CASE( jp_flx     )   ;   WRITE(numout,*) '   flux formulation'
238         CASE( jp_blk     )   ;   WRITE(numout,*) '   bulk formulation'
239         CASE( jp_purecpl )   ;   WRITE(numout,*) '   pure coupled formulation'
240         CASE( jp_none    )   ;   WRITE(numout,*) '   OPA coupled to SAS via oasis'
241            IF( ln_mixcpl )       WRITE(numout,*) '       + forced-coupled mixed formulation'
242         END SELECT
243         IF( nn_components/= jp_iam_nemo )  &
244            &                     WRITE(numout,*) '       + OASIS coupled SAS'
245      ENDIF
246      !
247      IF( lk_oasis )   CALL sbc_cpl_init (nn_ice)   ! OASIS initialisation. must be done before: (1) first time step
248      !                                             !                                            (2) the use of nn_fsbc
249      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
250      !     sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
251      IF( nn_components /= jp_iam_nemo ) THEN
252         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
253         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
254         !
255         IF(lwp)THEN
256            WRITE(numout,*)
257            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
258            WRITE(numout,*)
259         ENDIF
260      ENDIF
261      !
262      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
263          MOD( nstock             , nn_fsbc) /= 0 ) THEN
264         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
265            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
266         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
267      ENDIF
268      !
269      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
270         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
271      !
272      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
273         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
274      !
275                          CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
276      !
277      IF( ln_ssr      )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
278      !
279                          CALL sbc_rnf_init               ! Runof initialisation
280      !
281      IF( nn_ice == 3 )   CALL sbc_lim_init               ! LIM3 initialisation
282      !
283      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
284      !
285   END SUBROUTINE sbc_init
286
287
288   SUBROUTINE sbc( kt )
289      !!---------------------------------------------------------------------
290      !!                    ***  ROUTINE sbc  ***
291      !!
292      !! ** Purpose :   provide at each time-step the ocean surface boundary
293      !!                condition (momentum, heat and freshwater fluxes)
294      !!
295      !! ** Method  :   blah blah  to be written ?????????
296      !!                CAUTION : never mask the surface stress field (tke sbc)
297      !!
298      !! ** Action  : - set the ocean surface boundary condition at before and now
299      !!                time step, i.e.
300      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
301      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
302      !!              - updte the ice fraction : fr_i
303      !!----------------------------------------------------------------------
304      INTEGER, INTENT(in) ::   kt   ! ocean time step
305      !
306      LOGICAL ::   ll_sas, ll_opa   ! local logical
307      !!---------------------------------------------------------------------
308      !
309      IF( nn_timing == 1 )  CALL timing_start('sbc')
310      !
311      !                                            ! ---------------------------------------- !
312      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
313         !                                         ! ---------------------------------------- !
314         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
315         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
316         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
317         emp_b (:,:) = emp (:,:)
318         sfx_b (:,:) = sfx (:,:)
319         IF ( ln_rnf ) THEN
320            rnf_b    (:,:  ) = rnf    (:,:  )
321            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
322         ENDIF
323      ENDIF
324      !                                            ! ---------------------------------------- !
325      !                                            !        forcing field computation         !
326      !                                            ! ---------------------------------------- !
327      !
328      ll_sas = nn_components == jp_iam_sas               ! component flags
329      ll_opa = nn_components == jp_iam_opa
330      !
331      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
332      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
333
334      !
335      !                                            !==  sbc formulation  ==!
336      !                                                   
337      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
338      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
339      CASE( jp_gyre    )   ;   CALL sbc_gyre  ( kt )                     ! analytical formulation : GYRE configuration
340      CASE( jp_ana     )   ;   CALL sbc_ana   ( kt )                     ! analytical formulation : uniform sbc
341      CASE( jp_flx     )   ;   CALL sbc_flx   ( kt )                     ! flux formulation
342      CASE( jp_blk     )
343         IF( ll_sas    )       CALL sbc_cpl_rcv( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
344                               CALL sbc_blk    ( kt )                    ! bulk formulation for the ocean
345                               !
346      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
347      CASE( jp_none    )
348         IF( ll_opa    )       CALL sbc_cpl_rcv( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
349      END SELECT
350
351      IF( ln_mixcpl )          CALL sbc_cpl_rcv( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
352
353      !
354      !                                            !==  Misc. Options  ==!
355      !
356      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
357      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
358      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
359      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
360      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
361      END SELECT
362
363      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
364
365      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
366
367      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
368
369      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
370
371      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
372
373      ! treatment of closed sea in the model domain   (update freshwater fluxes)
374      ! Should not be ran if ln_diurnal_only
375      IF( .NOT.(ln_diurnal_only) .AND. (nn_closea == 1) )   CALL sbc_clo( kt )
376
377!RBbug do not understand why see ticket 667
378!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
379      CALL lbc_lnk( emp, 'T', 1. )
380      !
381      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
382         !                                             ! ---------------------------------------- !
383         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
384            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
385            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
386            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
387            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
388            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
389            ! The 3D heat content due to qsr forcing is treated in traqsr
390            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
391            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
392            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
393            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
394               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
395            ELSE
396               sfx_b (:,:) = sfx(:,:)
397            ENDIF
398         ELSE                                                   !* no restart: set from nit000 values
399            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
400            utau_b(:,:) = utau(:,:)
401            vtau_b(:,:) = vtau(:,:)
402            qns_b (:,:) = qns (:,:)
403            emp_b (:,:) = emp (:,:)
404            sfx_b (:,:) = sfx (:,:)
405         ENDIF
406      ENDIF
407      !                                                ! ---------------------------------------- !
408      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
409         !                                             ! ---------------------------------------- !
410         IF(lwp) WRITE(numout,*)
411         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
412            &                    'at it= ', kt,' date= ', ndastp
413         IF(lwp) WRITE(numout,*) '~~~~'
414         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
415         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
416         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
417         ! The 3D heat content due to qsr forcing is treated in traqsr
418         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
419         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
420         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
421      ENDIF
422      !                                                ! ---------------------------------------- !
423      !                                                !        Outputs and control print         !
424      !                                                ! ---------------------------------------- !
425      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
426         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
427         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
428         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
429         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
430         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
431         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
432         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
433         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
434         CALL iom_put( "taum"  , taum       )                   ! wind stress module
435         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
436      ENDIF
437      !
438      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
439      CALL iom_put( "vtau", vtau )   ! j-wind stress
440      !
441      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
442         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
443         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
444         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 )
445         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
446         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
447         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
448         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
449         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
450         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
451            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
452      ENDIF
453
454      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
455      !
456      IF( nn_timing == 1 )  CALL timing_stop('sbc')
457      !
458   END SUBROUTINE sbc
459
460
461   SUBROUTINE sbc_final
462      !!---------------------------------------------------------------------
463      !!                    ***  ROUTINE sbc_final  ***
464      !!
465      !! ** Purpose :   Finalize CICE (if used)
466      !!---------------------------------------------------------------------
467      !
468      IF( nn_ice == 4 )   CALL cice_sbc_final
469      !
470   END SUBROUTINE sbc_final
471
472   !!======================================================================
473END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.