New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
albedo.F90 in branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC/albedo.F90 @ 8106

Last change on this file since 8106 was 8106, checked in by vancop, 7 years ago

Follow up on melt ponds and albedo
  • Property svn:keywords set to Id
File size: 21.5 KB
Line 
1MODULE albedo
2   !!======================================================================
3   !!                       ***  MODULE  albedo  ***
4   !! Ocean forcing:  bulk thermohaline forcing of the ocean (or ice)
5   !!=====================================================================
6   !! History :  8.0  ! 2001-04  (LIM 1.0)
7   !!   NEMO     1.0  ! 2003-07  (C. Ethe, G. Madec)  Optimization (old name:shine)
8   !!             -   ! 2004-11  (C. Talandier)  add albedo_init
9   !!             -   ! 2006-06  (M. Vancoppenolle) LIM 3.0
10   !!             -   ! 2006-08  (G. Madec)  cleaning for surface module
11   !!            3.6  ! 2016-01  (C. Rousset) new parameterization for sea ice albedo
12   !!            x.x  ! 2017-05  (M. Vancoppenolle, O. Lecomte) Melt ponds
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   albedo_ice    : albedo for   ice (clear and overcast skies)
17   !!   albedo_oce    : albedo for ocean (clear and overcast skies)
18   !!   albedo_init   : initialisation of albedo computation
19   !!----------------------------------------------------------------------
20   USE phycst         ! physical constants
21   USE in_out_manager ! I/O manager
22   USE lib_mpp        ! MPP library
23   USE wrk_nemo       ! work arrays
24   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   albedo_ice   ! routine called sbcice_lim.F90
30   PUBLIC   albedo_oce   ! routine called by ???
31
32   INTEGER  ::   albd_init = 0      !: control flag for initialization
33 
34   REAL(wp) ::   rmue     = 0.40    !  cosine of local solar altitude
35   REAL(wp) ::   ralb_oce = 0.066   ! ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001)
36   REAL(wp) ::   c1       = 0.05    ! snow thickness (only for nn_ice_alb=0)
37   REAL(wp) ::   c2       = 0.10    !  "        "
38   REAL(wp) ::   rcloud   = 0.06    ! cloud effect on albedo (only-for nn_ice_alb=0)
39 
40   !                             !!* namelist namsbc_alb
41   INTEGER  ::   nn_ice_alb
42   REAL(wp) ::   rn_alb_sdry, rn_alb_smlt, rn_alb_idry, rn_alb_imlt, rn_alb_dpnd
43
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pafrac_pnd, ph_pnd, ld_pnd, pa_ice_cs, pa_ice_os )
52      !!----------------------------------------------------------------------
53      !!               ***  ROUTINE albedo_ice  ***
54      !!         
55      !! ** Purpose :   Computation of the albedo of the snow/ice system
56      !!       
57      !! ** Method  :   Two schemes are available (from namelist parameter nn_ice_alb)
58      !!                  0: the scheme is that of Shine & Henderson-Sellers (JGR 1985) for clear-skies
59      !!                  1: the scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005)
60      !!                                                                           and Grenfell & Perovich (JGR 2004)
61      !!                  2: fractional surface-based formulation of scheme 1 (NEW)
62      !!                Description of scheme 1:
63      !!                  1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005)
64      !!                     which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999
65      !!                     0-5cm  : linear function of ice thickness
66      !!                     5-150cm: log    function of ice thickness
67      !!                     > 150cm: constant
68      !!                  2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004)
69      !!                     i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting
70      !!                  3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004)
71      !!                     i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law
72      !!                  4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice
73      !!
74      !! ** Note    :   The parameterization from Shine & Henderson-Sellers presents several misconstructions:
75      !!                  1) ice albedo when ice thick. tends to 0 is different than ocean albedo
76      !!                  2) for small ice thick. covered with some snow (<3cm?), albedo is larger
77      !!                     under melting conditions than under freezing conditions
78      !!                  3) the evolution of ice albedo as a function of ice thickness shows 
79      !!                     3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic
80      !!
81      !! References :   Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250.
82      !!                Brandt et al. 2005, J. Climate, vol 18
83      !!                Grenfell & Perovich 2004, JGR, vol 109
84      !!
85      !!----------------------------------------------------------------------
86      !!
87      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   pt_ice              !  ice surface temperature (Kelvin)
88      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_ice              !  sea-ice thickness
89      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_snw              !  snow depth
90      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   pafrac_pnd          !  melt pond relative fraction (per unit ice area)
91      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_pnd              !  melt pond depth
92      LOGICAL , INTENT(in   )                   ::   ld_pnd              !  melt ponds radiatively active or not
93      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_cs           !  albedo of ice under clear    sky
94      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_os           !  albedo of ice under overcast sky
95      !!
96      INTEGER  ::   ji, jj, jl                                           ! dummy loop indices
97      INTEGER  ::   ijpl                                                 ! number of ice categories (3rd dim of ice input arrays)
98      REAL(wp)                            ::   ralb_im, ralb_sf, ralb_sm, ralb_if, ralb_dp
99      REAL(wp)                            ::   zswitch, z1_c1, z1_c2
100      REAL(wp)                            ::   zhref_pnd                                 
101      REAL(wp)                            ::   zalb_sm, zalb_sf, zalb_st ! albedo of snow melting, freezing, total
102      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalb_it             ! intermediate variable & albedo of ice (snow free)
103      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_pnd                  ! ponded sea ice albedo
104      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_ice                  ! bare sea ice albedo
105      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_snw                  ! snow-covered sea ice albedo
106      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zafrac_snw                ! relative snow fraction
107      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zafrac_ice                ! relative ice fraction
108      !!
109      !!---------------------------------------------------------------------
110
111      WRITE(numout,*) ' albedo_ice '
112      WRITE(numout,*) ' ld_pnd     : ', ld_pnd
113      WRITE(numout,*) ' nn_ice_alb : ', nn_ice_alb
114
115      ijpl = SIZE( pt_ice, 3 )                     ! number of ice categories
116     
117      CALL wrk_alloc( jpi,jpj,ijpl, zalb, zalb_it )
118      CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw )
119      CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice )
120
121      IF( albd_init == 0 )   CALL albedo_init      ! initialization
122
123      ralb_sf = rn_alb_sdry    ! dry snow
124      ralb_sm = rn_alb_smlt    ! melting snow
125      ralb_if = rn_alb_idry    ! bare frozen ice
126      ralb_im = rn_alb_imlt    ! bare puddled ice (assumes implicit contribution of melt ponds)
127      ralb_dp = rn_alb_dpnd    ! deep pond albedo
128
129      !-----------------------------------------------------
130      !  Snow-free albedo (no ice thickness dependence yet)
131      !-----------------------------------------------------
132      !
133      ! Part common to nn_ice_alb = 0, 1, 2
134      !
135
136      zalb = ralb_if         
137      IF ( .NOT. ld_pnd ) THEN   !--- No melt ponds OR radiatively inactive melt ponds
138
139         ! Bare ice albedo is prescribed, with implicit assumption on pond fraction and depth
140         WHERE     ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ;  zalb = ralb_im  ;  END WHERE 
141                                                       ! !!! MV I think we could replace rt0_ice by rt0 and get rid of rt0
142
143      ENDIF
144
145      SELECT CASE ( nn_ice_alb )
146
147      !------------------------------------------
148      !  Shine and Henderson-Sellers (1985)
149      !------------------------------------------
150      ! NB: This parameterization is based on clear sky values
151
152      CASE( 0 )
153       
154         ! Thickness-dependent bare ice albedo
155         WHERE     ( 1.5  < ph_ice                     )  ;  zalb_it = zalb
156         ELSE WHERE( 1.0  < ph_ice .AND. ph_ice <= 1.5 )  ;  zalb_it = 0.472  + 2.0 * ( zalb - 0.472 ) * ( ph_ice - 1.0 )
157         ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.0 )  ;  zalb_it = 0.2467 + 0.7049 * ph_ice              &
158            &                                                                 - 0.8608 * ph_ice * ph_ice     &
159            &                                                                 + 0.3812 * ph_ice * ph_ice * ph_ice
160         ELSE WHERE                                       ;  zalb_it = 0.1    + 3.6    * ph_ice
161         END WHERE
162
163         IF ( ld_pnd ) THEN
164            ! Depth-dependent ponded ice albedo
165            zhref_pnd = 0.05        ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015)
166            zalb_pnd  = ralb_dp - ( ralb_dp - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) 
167
168            ! Snow-free ice albedo is a function of pond fraction
169            WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice )   ; zalb_it = zalb_it * ( 1. - pafrac_pnd  ) + zalb_pnd * pafrac_pnd ;   END WHERE
170         ENDIF 
171
172         ! Note that this way of coding things means that the thickness
173         ! dependence of bare ice albedo is also altering the ponded ice albedo
174         ! I'm not sure that this is valid, but at least, this maintains
175         ! consistency with previous formulation (see below)
176     
177         DO jl = 1, ijpl
178            DO jj = 1, jpj
179               DO ji = 1, jpi
180                  ! Freezing snow
181                  ! no effect of underlying ice layer IF snow thickness > c1. Albedo does not depend on snow thick if > c2
182                  !                                        !  freezing snow       
183                  zswitch   = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( ph_snw(ji,jj,jl) - c1 ) ) )
184                  zalb_sf   = ( 1._wp - zswitch ) * (  zalb_it(ji,jj,jl)  &
185                     &                           + ph_snw(ji,jj,jl) * ( ralb_sf - zalb_it(ji,jj,jl) ) / c1  )   &
186                     &        +         zswitch   * ralb_sf 
187
188                  ! Melting snow
189                  ! no effect of underlying ice layer. Albedo does not depend on snow thick IF > c2
190                  zswitch   = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c2 ) )
191                  zalb_sm = ( 1._wp - zswitch ) * ( ralb_im + ph_snw(ji,jj,jl) * ( ralb_sm - ralb_im ) / c2 )   &
192                      &     +         zswitch   *   ralb_sm 
193                   
194                  ! Snow albedo
195                  zswitch  =  MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) )   
196                  zalb_st  =  zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf
197               
198                  ! Surface albedo
199                  zswitch             = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) )
200                  pa_ice_cs(ji,jj,jl) = zswitch * zalb_st + ( 1._wp - zswitch ) * zalb_it(ji,jj,jl)
201
202               END DO
203            END DO
204         END DO
205
206         pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + rcloud       ! Oberhuber correction for overcast sky
207
208      !------------------------------------------
209      !  New parameterization (2016)
210      !------------------------------------------
211      ! NB: This parameterization is based on overcast skies values
212     
213      CASE( 1 ) 
214
215!         ! Reference (overcast sky) values
216!        ralb_sf = 0.85      ! dry snow
217!        ralb_sm = 0.75      ! melting snow
218!        ralb_if = 0.60      ! bare frozen ice
219!        ralb_dp = 0.36      ! ponded-ice overcast albedo (Lecomte et al, 2015)
220!                            ! early melt pnds 0.27, late melt ponds 0.14 Grenfell & Perovich
221! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved
222!         ralb_sf = 0.85       ! dry snow
223!         ralb_sm = 0.72       ! melting snow
224!         ralb_if = 0.65       ! bare frozen ice
225! Brandt et al 2005 (East Antarctica)
226!         ralb_sf = 0.87      ! dry snow
227!         ralb_sm = 0.82      ! melting snow
228!         ralb_if = 0.54      ! bare frozen ice
229!
230         ! Computation of snow-free ice albedo
231         z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) 
232         z1_c2 = 1. / 0.05
233
234         ! Accounting for the ice-thickness dependency
235         WHERE     ( 1.5  < ph_ice                     )        ;  zalb_it = zalb
236         ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 )        ;  zalb_it = zalb     + ( 0.18 - zalb     ) * z1_c1 *  &
237            &                                                                     ( LOG(1.5) - LOG(ph_ice) )
238         ELSE WHERE                                             ;  zalb_it = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice
239         END WHERE
240
241         IF ( ld_pnd ) THEN
242            ! Depth-dependent ponded ice albedo
243            zhref_pnd = 0.05        ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015)
244            zalb_pnd  = ralb_dp - ( ralb_dp - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) 
245
246            ! Snow-free ice albedo is weighted mean of ponded ice and bare ice contributions
247            WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice )   ;  zalb_it = zalb_it * ( 1. - pafrac_pnd  ) + zalb_pnd * pafrac_pnd ;  END WHERE
248         ENDIF
249
250         z1_c1 = 1. / 0.02
251         z1_c2 = 1. / 0.03
252         
253         ! Overcast sky surface albedo (accounting for snow, ice melt ponds)
254         DO jl = 1, ijpl
255            DO jj = 1, jpj
256               DO ji = 1, jpi
257
258                  ! Snow depth dependence of snow albedo
259                  zalb_sf = ralb_sf - ( ralb_sf - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c1 );
260                  zalb_sm = ralb_sm - ( ralb_sm - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c2 );
261
262                  ! Snow albedo (MV I guess we could use rt0 instead of rt0_snow)
263                  zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) )   
264                  zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf
265
266                  ! Surface albedo   
267                  zswitch             = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) )
268                  pa_ice_os(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch *  zalb_it(ji,jj,jl) 
269
270              END DO
271            END DO
272         END DO
273
274         ! Clear sky surface albedo
275         pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ); 
276
277      !---------------------------------------------------
278      !  Fractional surface-based parameterization (2017)
279      !---------------------------------------------------
280      CASE( 2 ) 
281 
282      ! MV: I propose this formulation that is more elegant, and more easy to expand towards
283      !     varying pond and snow fraction
284 
285          !-----------------------------------------
286          ! Snow, bare ice and ponded ice fractions
287          !-----------------------------------------
288          ! Specific fractions (zafrac) refer to relative area covered by snow within each ice category
289 
290          !--- Specific snow fraction (for now, prescribed)
291          WHERE     ( ph_snw > 0._wp     ) ;  zafrac_snw = 1.
292          ELSE WHERE                       ;  zafrac_snw = 0.
293          END WHERE
294 
295          !--- Specific ice fraction
296          zafrac_ice = 1. - zafrac_snw - pafrac_pnd
297!          WHERE     ( ph_ice > 1.0e-6_wp ) ;  zafrac_ice = 1. - zafrac_snw - pafrac_pnd
298!         ELSE WHERE                       ;  zafrac_ice = 0.
299!         ENDWHERE
300 
301          !--------------------------------------------------
302          ! Snow-covered, pond-covered, and bare ice albedos
303          !--------------------------------------------------
304          ! Bare ice albedo
305          z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) 
306          z1_c2 = 1. / 0.05
307          WHERE     ( 1.5  < ph_ice                     )  ;  zalb_ice = zalb
308          ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 )  ;  zalb_ice = zalb     + ( 0.18 - zalb     ) * z1_c1 *  &
309            &                                                                       ( LOG(1.5) - LOG(ph_ice) )
310          ELSE WHERE                                       ;  zalb_ice = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice
311          END WHERE
312
313          ! Snow-covered ice albedo (freezing, melting cases)
314          z1_c1 = 1. / 0.02
315          z1_c2 = 1. / 0.03
316         
317          WHERE( pt_ice < rt0_snow ) ; zalb_snw = ralb_sf - ( ralb_sf - zalb_ice ) * EXP( - ph_snw * z1_c1 );
318          ELSE WHERE                 ; zalb_snw = ralb_sm - ( ralb_sm - zalb_ice ) * EXP( - ph_snw * z1_c2 );
319          END WHERE
320
321          ! Depth-dependent ponded ice albedo
322          zhref_pnd = 0.05        ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015)
323          zalb_pnd  = ralb_dp - ( ralb_dp - zalb_ice ) * EXP( - ph_pnd / zhref_pnd ) 
324
325          ! Surface albedo is weighted mean of snow, ponds and bare ice contributions
326          pa_ice_os = zafrac_snw * zalb_snw  +  pafrac_pnd * zalb_pnd  +  zafrac_ice * zalb_ice
327         
328          pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 )
329
330      END SELECT
331     
332      CALL wrk_dealloc( jpi,jpj,ijpl, zalb, zalb_it )
333      CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw )
334      CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice )
335      !
336   END SUBROUTINE albedo_ice
337
338
339   SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs )
340      !!----------------------------------------------------------------------
341      !!               ***  ROUTINE albedo_oce  ***
342      !!
343      !! ** Purpose :   Computation of the albedo of the ocean
344      !!----------------------------------------------------------------------
345      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pa_oce_os   !  albedo of ocean under overcast sky
346      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pa_oce_cs   !  albedo of ocean under clear sky
347      !!
348      REAL(wp) :: zcoef 
349      !!----------------------------------------------------------------------
350      !
351      zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 )   ! Parameterization of Briegled and Ramanathan, 1982
352      pa_oce_cs(:,:) = zcoef 
353      pa_oce_os(:,:) = 0.06                       ! Parameterization of Kondratyev, 1969 and Payne, 1972
354      !
355   END SUBROUTINE albedo_oce
356
357
358   SUBROUTINE albedo_init
359      !!----------------------------------------------------------------------
360      !!                 ***  ROUTINE albedo_init  ***
361      !!
362      !! ** Purpose :   initializations for the albedo parameters
363      !!
364      !! ** Method  :   Read the namelist namsbc_alb
365      !!----------------------------------------------------------------------
366      INTEGER  ::   ios                 ! Local integer output status for namelist read
367      NAMELIST/namsbc_alb/ nn_ice_alb, rn_alb_sdry, rn_alb_smlt, rn_alb_idry , rn_alb_imlt, rn_alb_dpnd
368      !!----------------------------------------------------------------------
369      !
370      albd_init = 1                     ! indicate that the initialization has been done
371      !
372      REWIND( numnam_ref )              ! Namelist namsbc_alb in reference namelist : Albedo parameters
373      READ  ( numnam_ref, namsbc_alb, IOSTAT = ios, ERR = 901)
374901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in reference namelist', lwp )
375
376      REWIND( numnam_cfg )              ! Namelist namsbc_alb in configuration namelist : Albedo parameters
377      READ  ( numnam_cfg, namsbc_alb, IOSTAT = ios, ERR = 902 )
378902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in configuration namelist', lwp )
379      IF(lwm) WRITE ( numond, namsbc_alb )
380      !
381      IF(lwp) THEN                      ! Control print
382         WRITE(numout,*)
383         WRITE(numout,*) 'albedo : set albedo parameters'
384         WRITE(numout,*) '~~~~~~~'
385         WRITE(numout,*) '   Namelist namsbc_alb : albedo '
386         WRITE(numout,*) '      choose the albedo parameterization                  nn_ice_alb = ', nn_ice_alb
387         WRITE(numout,*) '      albedo of dry snow                                  rn_alb_sdry = ', rn_alb_sdry
388         WRITE(numout,*) '      albedo of melting snow                              rn_alb_smlt = ', rn_alb_smlt
389         WRITE(numout,*) '      albedo of dry ice                                   rn_alb_idry = ', rn_alb_idry
390         WRITE(numout,*) '      albedo of bare ice                                  rn_alb_imlt = ', rn_alb_imlt
391         WRITE(numout,*) '      albedo of ponded ice                                rn_alb_dpnd = ', rn_alb_dpnd
392      ENDIF
393      !
394   END SUBROUTINE albedo_init
395
396   !!======================================================================
397END MODULE albedo
Note: See TracBrowser for help on using the repository browser.