New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 7293

Last change on this file since 7293 was 7293, checked in by vancop, 7 years ago
Commit infrastructure for melt pond impletation
Property svn:keywords set to `Id`
File size: 35.6 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26
27	USE sbc_oce ! Surface boundary condition: ocean fields
28	USE sbc_ice ! Surface boundary condition: ice fields
29	USE sbcblk_core ! Surface boundary condition: CORE bulk
30	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
31	USE sbccpl ! Surface boundary condition: coupled interface
32	USE sbcana ! Surface boundary condition: analytic formulation
33	USE albedo ! ocean & ice albedo
34
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49
50	! MV MP 2016
51	USE limmp
52	! END MV MP 2016
53
54	USE limistate ! LIM initial state
55	USE limthd_sal ! LIM ice thermodynamics: salinity
56
57	USE c1d ! 1D vertical configuration
58	USE lbclnk ! lateral boundary condition - MPP link
59	USE lib_mpp ! MPP library
60	USE wrk_nemo ! work arrays
61	USE timing ! Timing
62	USE iom ! I/O manager library
63	USE in_out_manager ! I/O manager
64	USE prtctl ! Print control
65	USE lib_fortran !
66	USE limctl
67
68	#if defined key_bdy
69	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
70	#endif
71	# if defined key_agrif
72	USE agrif_ice
73	USE agrif_lim3_update
74	USE agrif_lim3_interp
75	# endif
76
77	IMPLICIT NONE
78	PRIVATE
79
80	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
81	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
82
83	!! * Substitutions
84	# include "domzgr_substitute.h90"
85	# include "vectopt_loop_substitute.h90"
86	!!----------------------------------------------------------------------
87	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
88	!! $Id$
89	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
90	!!----------------------------------------------------------------------
91	CONTAINS
92
93	!!======================================================================
94
95	SUBROUTINE sbc_ice_lim( kt, kblk )
96	!!---------------------------------------------------------------------
97	!! * ROUTINE sbc_ice_lim *
98	!!
99	!! ** Purpose : update the ocean surface boundary condition via the
100	!! Louvain la Neuve Sea Ice Model time stepping
101	!!
102	!! ** Method : ice model time stepping
103	!! - call the ice dynamics routine
104	!! - call the ice advection/diffusion routine
105	!! - call the ice thermodynamics routine
106	!! - call the routine that computes mass and
107	!! heat fluxes at the ice/ocean interface
108	!! - save the outputs
109	!! - save the outputs for restart when necessary
110	!!
111	!! ** Action : - time evolution of the LIM sea-ice model
112	!! - update all sbc variables below sea-ice:
113	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
114	!!---------------------------------------------------------------------
115	INTEGER, INTENT(in) :: kt ! ocean time step
116	INTEGER, INTENT(in) :: kblk ! type of bulk (=1 ANALYTIC, =3 CLIO, =4 CORE, =5 COUPLED)
117	!!
118	INTEGER :: jl ! dummy loop index
119	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
120	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
121	!!----------------------------------------------------------------------
122
123	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
124
125	! clem: it is important to initialize agrif_lim3 variables here and not in sbc_lim_init
126	# if defined key_agrif
127	IF( kt == nit000 ) THEN
128	IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim3
129	ENDIF
130	# endif
131
132	!-----------------------!
133	! --- Ice time step --- !
134	!-----------------------!
135	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
136
137	# if defined key_agrif
138	IF( .NOT. Agrif_Root() ) lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
139	# endif
140
141	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
142	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
143	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
144
145	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
146	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
147	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
148
149	! Mask sea ice surface temperature (set to rt0 over land)
150	DO jl = 1, jpl
151	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
152	END DO
153	!
154	!------------------------------------------------!
155	! --- Dynamical coupling with the atmosphere --- !
156	!------------------------------------------------!
157	! It provides the following fields:
158	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
159	!-----------------------------------------------------------------
160	SELECT CASE( kblk )
161	CASE( jp_ana ) ; CALL ana_ice_tau ! analytic formulation
162	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
163	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
164	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
165	END SELECT
166
167	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
168	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
169	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
170	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
171	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
172	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
173	ENDIF
174
175	!-------------------------------------------------------!
176	! --- ice dynamics and transport (except in 1D case) ---!
177	!-------------------------------------------------------!
178	numit = numit + nn_fsbc ! Ice model time step
179	!
180	CALL sbc_lim_bef ! Store previous ice values
181	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
182	CALL lim_rst_opn( kt ) ! Open Ice restart file
183	!
184	! --- zap this if no ice dynamics --- !
185	IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
186	!
187	IF( nn_limdyn /= 0 ) THEN ! -- Ice dynamics
188	CALL lim_dyn( kt ) ! rheology
189	ELSE
190	u_ice(:,:) = rn_uice * umask(:,:,1) ! or prescribed velocity
191	v_ice(:,:) = rn_vice * vmask(:,:,1)
192	ENDIF
193	CALL lim_trp( kt ) ! -- Ice transport (Advection/diffusion)
194	IF( nn_limdyn == 2 .AND. nn_monocat /= 2 ) & ! -- Mechanical redistribution (ridging/rafting)
195	& CALL lim_itd_me
196	IF( nn_limdyn == 2 ) CALL lim_update1( kt ) ! -- Corrections
197	!
198	ENDIF
199
200	! ---
201	#if defined key_agrif
202	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
203	#endif
204	#if defined key_bdy
205	IF( ln_limthd ) CALL bdy_ice_lim( kt ) ! -- bdy ice thermo
206	#endif
207
208	! previous lead fraction and ice volume for flux calculations
209	CALL sbc_lim_bef
210	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
211	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
212	!
213	pfrld(:,:) = 1._wp - at_i(:,:)
214	phicif(:,:) = vt_i(:,:)
215
216	!------------------------------------------------------!
217	! --- Thermodynamical coupling with the atmosphere --- !
218	!------------------------------------------------------!
219	! It provides the following fields:
220	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
221	! qla_ice : latent heat flux over ice (T-point) [W/m2]
222	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
223	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
224	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
225	!----------------------------------------------------------------------------------------
226	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
227
228	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
229	SELECT CASE( kblk )
230
231	CASE( jp_ana ) ! analytic formulation
232	CALL ana_ice_flx
233
234	CASE( jp_clio ) ! CLIO bulk formulation
235	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
236	! (alb_ice) is computed within the bulk routine
237	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
238	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
239	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
240
241	CASE( jp_core ) ! CORE bulk formulation
242	! albedo depends on cloud fraction because of non-linear spectral effects
243	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
244	CALL blk_ice_core_flx( t_su, alb_ice )
245	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
246	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
247
248	CASE ( jp_purecpl ) ! Coupled formulation
249	! albedo depends on cloud fraction because of non-linear spectral effects
250	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
251	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
252	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
253
254	END SELECT
255
256	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
257
258	!----------------------------!
259	! --- ice thermodynamics --- !
260	!----------------------------!
261	! --- zap this if no ice thermo --- !
262	IF( ln_limthd ) CALL lim_thd( kt ) ! -- Ice thermodynamics
263	IF( ln_limthd ) CALL lim_update2( kt ) ! -- Corrections
264	! ---
265	# if defined key_agrif
266	IF( .NOT. Agrif_Root() ) CALL agrif_update_lim3( kt )
267	# endif
268	CALL lim_var_glo2eqv ! necessary calls (at least for coupling)
269	CALL lim_var_agg( 2 ) ! necessary calls (at least for coupling)
270	!
271	# if defined key_agrif
272	!! IF( .NOT. Agrif_Root() ) CALL Agrif_ChildGrid_To_ParentGrid() ! clem: should be called at the update frequency only (cf agrif_lim3_update)
273	# endif
274	CALL lim_sbc_flx( kt ) ! -- Update surface ocean mass, heat and salt fluxes
275	# if defined key_agrif
276	!! IF( .NOT. Agrif_Root() ) CALL Agrif_ParentGrid_To_ChildGrid() ! clem: should be called at the update frequency only (cf agrif_lim3_update)
277	# endif
278	IF( ln_limdiahsb ) CALL lim_diahsb( kt ) ! -- Diagnostics and outputs
279	!
280	CALL lim_wri( 1 ) ! -- Ice outputs
281	!
282	IF( kt == nit000 .AND. ln_rstart ) &
283	& CALL iom_close( numrir ) ! close input ice restart file
284	!
285	IF( lrst_ice ) CALL lim_rst_write( kt ) ! -- Ice restart file
286	!
287	IF( ln_limctl ) CALL lim_ctl( kt ) ! alerts in case of model crash
288	!
289	ENDIF ! End sea-ice time step only
290
291	!-------------------------!
292	! --- Ocean time step --- !
293	!-------------------------!
294	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
295	! using before instantaneous surf. currents
296	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
297	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
298	!
299	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
300	!
301	END SUBROUTINE sbc_ice_lim
302
303
304	SUBROUTINE sbc_lim_init
305	!!----------------------------------------------------------------------
306	!! * ROUTINE sbc_lim_init *
307	!!
308	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
309	!!----------------------------------------------------------------------
310	INTEGER :: ierr
311	INTEGER :: ji, jj
312	!!----------------------------------------------------------------------
313	IF(lwp) WRITE(numout,*)
314	IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition'
315	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
316	!
317	! Open the reference and configuration namelist files and namelist output file
318	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
319	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
320	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
321
322	CALL ice_run ! set some ice run parameters
323	!
324	! ! Allocate the ice arrays
325	ierr = ice_alloc () ! ice variables
326	ierr = ierr + sbc_ice_alloc () ! surface forcing
327	ierr = ierr + thd_ice_alloc () ! thermodynamics
328	IF( ln_limdyn ) ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
329	!
330	IF( lk_mpp ) CALL mpp_sum( ierr )
331	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
332	!
333	CALL lim_dyn_init ! set ice dynamics parameters
334	!
335	CALL lim_itd_init ! ice thickness distribution initialization
336	!
337	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
338	!
339	CALL lim_thd_init ! set ice thermodynics parameters
340	!
341	CALL lim_thd_sal_init ! set ice salinity parameters
342
343	! MV MP 2016
344	CALL lim_mp_init ! set melt ponds parameters
345	! END MV MP 2016
346
347	IF( ln_limdyn ) CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
348	! ! Initial sea-ice state
349	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
350	numit = 0
351	numit = nit000 - 1
352	CALL lim_istate
353	ELSE ! start from a restart file
354	CALL lim_rst_read
355	numit = nit000 - 1
356	ENDIF
357	CALL lim_var_agg(2)
358	CALL lim_var_glo2eqv
359	!
360	CALL lim_sbc_init ! ice surface boundary condition
361	!
362	IF( ln_limdiahsb) CALL lim_diahsb_init ! initialization for diags
363	!
364	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
365	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
366	!
367	DO jj = 1, jpj
368	DO ji = 1, jpi
369	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
370	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
371	ENDIF
372	ENDDO
373	ENDDO
374	!
375	nstart = numit + nn_fsbc
376	nitrun = nitend - nit000 + 1
377	nlast = numit + nitrun
378	!
379	IF( nstock == 0 ) nstock = nlast + 1
380	!
381	!
382	END SUBROUTINE sbc_lim_init
383
384
385	SUBROUTINE ice_run
386	!!-------------------------------------------------------------------
387	!! * ROUTINE ice_run *
388	!!
389	!! ** Purpose : Definition some run parameter for ice model
390	!!
391	!! ** Method : Read the namicerun namelist and check the parameter
392	!! values called at the first timestep (nit000)
393	!!
394	!! ** input : Namelist namicerun
395	!!-------------------------------------------------------------------
396	INTEGER :: ios ! Local integer output status for namelist read
397	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir, &
398	& cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice
399	NAMELIST/namicediag/ ln_limdiachk, ln_limdiahsb, ln_limctl, iiceprt, jiceprt
400	!!-------------------------------------------------------------------
401	!
402	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
403	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
404	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
405
406	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
407	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
408	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
409	IF(lwm) WRITE ( numoni, namicerun )
410	!
411	REWIND( numnam_ice_ref ) ! Namelist namicediag in reference namelist : Parameters for ice
412	READ ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
413	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
414
415	REWIND( numnam_ice_cfg ) ! Namelist namicediag in configuration namelist : Parameters for ice
416	READ ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
417	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
418	IF(lwm) WRITE ( numoni, namicediag )
419	!
420	IF(lwp) THEN ! control print
421	WRITE(numout,*)
422	WRITE(numout,*) 'ice_run : ice share~d parameters for dynamics/advection/thermo of sea-ice'
423	WRITE(numout,*) ' ~~~~~~'
424	WRITE(numout,*) ' number of ice categories = ', jpl
425	WRITE(numout,*) ' number of ice layers = ', nlay_i
426	WRITE(numout,*) ' number of snow layers = ', nlay_s
427	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
428	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
429	WRITE(numout,*) ' Ice thermodynamics (T) or not (F) ln_limthd = ', ln_limthd
430	WRITE(numout,*) ' Ice dynamics (T) or not (F) ln_limdyn = ', ln_limdyn
431	WRITE(numout,*) ' (ln_limdyn=T) Ice dynamics switch nn_limdyn = ', nn_limdyn
432	WRITE(numout,*) ' 2: total'
433	WRITE(numout,*) ' 1: advection only (no diffusion, no ridging/rafting)'
434	WRITE(numout,*) ' 0: advection only (as 1 + prescribed velocity, bypass rheology)'
435	WRITE(numout,*) ' (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0) = ', rn_uice
436	WRITE(numout,*) ' (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0) = ', rn_vice
437	WRITE(numout,*)
438	WRITE(numout,*) '...and ice diagnostics'
439	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
440	WRITE(numout,*) ' Diagnose online heat/mass/salt budget ln_limdiachk = ', ln_limdiachk
441	WRITE(numout,*) ' Output heat/mass/salt budget ln_limdiahsb = ', ln_limdiahsb
442	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_limctl
443	WRITE(numout,*) ' i-index for control prints (ln_limctl=true) = ', iiceprt
444	WRITE(numout,*) ' j-index for control prints (ln_limctl=true) = ', jiceprt
445	ENDIF
446	!
447	! sea-ice timestep and inverse
448	rdt_ice = REAL(nn_fsbc) * rdt
449	r1_rdtice = 1._wp / rdt_ice
450
451	! inverse of nlay_i and nlay_s
452	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
453	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
454	!
455	#if defined key_bdy
456	IF( lwp .AND. ln_limdiachk ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
457	#endif
458	!
459	IF( lwp ) WRITE(numout,*) ' ice timestep rdt_ice = ', rdt_ice
460	!
461	END SUBROUTINE ice_run
462
463
464	SUBROUTINE lim_itd_init
465	!!------------------------------------------------------------------
466	!! * ROUTINE lim_itd_init *
467	!!
468	!! ** Purpose : Initializes the ice thickness distribution
469	!! ** Method : ...
470	!! ** input : Namelist namiceitd
471	!!-------------------------------------------------------------------
472	INTEGER :: ios ! Local integer output status for namelist read
473	NAMELIST/namiceitd/ nn_catbnd, rn_himean
474	!
475	INTEGER :: jl ! dummy loop index
476	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
477	REAL(wp) :: zhmax, znum, zden, zalpha !
478	!!------------------------------------------------------------------
479	!
480	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
481	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
482	905 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
483
484	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
485	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
486	906 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
487	IF(lwm) WRITE ( numoni, namiceitd )
488	!
489	IF(lwp) THEN ! control print
490	WRITE(numout,*)
491	WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
492	WRITE(numout,*) '~~~~~~~~~~~~'
493	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
494	WRITE(numout,*) ' mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
495	ENDIF
496
497	!----------------------------------
498	!- Thickness categories boundaries
499	!----------------------------------
500	hi_max(:) = 0._wp
501
502	SELECT CASE ( nn_catbnd )
503	!----------------------
504	CASE (1) ! tanh function (CICE)
505	!----------------------
506	zc1 = 3._wp / REAL( jpl, wp )
507	zc2 = 10._wp * zc1
508	zc3 = 3._wp
509
510	DO jl = 1, jpl
511	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
512	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
513	END DO
514
515	!----------------------
516	CASE (2) ! h^(-alpha) function
517	!----------------------
518	zalpha = 0.05 ! exponent of the transform function
519
520	zhmax = 3.*rn_himean
521
522	DO jl = 1, jpl
523	znum = jpl * ( zhmax+1 )**zalpha
524	zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
525	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
526	END DO
527
528	END SELECT
529
530	DO jl = 1, jpl
531	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
532	END DO
533
534	! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
535	hi_max(jpl) = 99._wp
536
537	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
538	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
539	!
540	END SUBROUTINE lim_itd_init
541
542
543	SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
544	!!---------------------------------------------------------------------
545	!! * ROUTINE ice_lim_flx *
546	!!
547	!! ** Purpose : update the ice surface boundary condition by averaging and / or
548	!! redistributing fluxes on ice categories
549	!!
550	!! ** Method : average then redistribute
551	!!
552	!! ** Action :
553	!!---------------------------------------------------------------------
554	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
555	! =1 average and redistribute ; =2 redistribute
556	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
557	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
558	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
559	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
560	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
561	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
562	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
563	!
564	INTEGER :: jl ! dummy loop index
565	!
566	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
567	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
568	!
569	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
570	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
571	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
572	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
573	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
574	!!----------------------------------------------------------------------
575
576	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
577	!
578	!
579	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
580	CASE( 0 , 1 )
581	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
582	!
583	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
584	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
585	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
586	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
587	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
588	DO jl = 1, jpl
589	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
590	pdevap_ice(:,:,jl) = z_devap_m(:,:)
591	END DO
592	!
593	DO jl = 1, jpl
594	pqns_ice (:,:,jl) = z_qns_m(:,:)
595	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
596	pevap_ice(:,:,jl) = z_evap_m(:,:)
597	END DO
598	!
599	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
600	END SELECT
601
602	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
603	CASE( 1 , 2 )
604	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
605	!
606	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
607	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
608	DO jl = 1, jpl
609	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
610	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
611	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
612	END DO
613	!
614	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
615	END SELECT
616	!
617	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
618	!
619	END SUBROUTINE ice_lim_flx
620
621	SUBROUTINE sbc_lim_bef
622	!!----------------------------------------------------------------------
623	!! * ROUTINE sbc_lim_bef *
624	!!
625	!! ** purpose : store ice variables at "before" time step
626	!!----------------------------------------------------------------------
627	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
628	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
629	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
630	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
631	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
632	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
633	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
634	u_ice_b(:,:) = u_ice(:,:)
635	v_ice_b(:,:) = v_ice(:,:)
636	at_i_b (:,:) = SUM( a_i_b(:,:,:), dim=3 )
637
638	END SUBROUTINE sbc_lim_bef
639
640	SUBROUTINE sbc_lim_diag0
641	!!----------------------------------------------------------------------
642	!! * ROUTINE sbc_lim_diag0 *
643	!!
644	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
645	!! of the time step
646	!!----------------------------------------------------------------------
647	sfx (:,:) = 0._wp ;
648	sfx_bri(:,:) = 0._wp ; sfx_lam(:,:) = 0._wp
649	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
650	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
651	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
652	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
653
654	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
655	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
656	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
657	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
658	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
659	wfx_spr(:,:) = 0._wp ; wfx_lam(:,:) = 0._wp
660
661	hfx_thd(:,:) = 0._wp ;
662	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
663	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
664	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
665	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
666	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
667	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
668	hfx_err_dif(:,:) = 0._wp
669	wfx_err_sub(:,:) = 0._wp
670
671	afx_tot(:,:) = 0._wp ;
672	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
673
674	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
675	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
676
677	tau_icebfr(:,:) = 0._wp; ! landfast ice param only (clem: important to keep the init here)
678
679	END SUBROUTINE sbc_lim_diag0
680
681
682	FUNCTION fice_cell_ave ( ptab )
683	!!--------------------------------------------------------------------------
684	!! * Compute average over categories, for grid cell (ice covered and free ocean)
685	!!--------------------------------------------------------------------------
686	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
687	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
688	INTEGER :: jl ! Dummy loop index
689
690	fice_cell_ave (:,:) = 0.0_wp
691	DO jl = 1, jpl
692	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
693	END DO
694
695	END FUNCTION fice_cell_ave
696
697
698	FUNCTION fice_ice_ave ( ptab )
699	!!--------------------------------------------------------------------------
700	!! * Compute average over categories, for ice covered part of grid cell
701	!!--------------------------------------------------------------------------
702	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
703	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
704
705	fice_ice_ave (:,:) = 0.0_wp
706	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
707
708	END FUNCTION fice_ice_ave
709
710
711	#else
712	!!----------------------------------------------------------------------
713	!! Default option Dummy module NO LIM 3.0 sea-ice model
714	!!----------------------------------------------------------------------
715	CONTAINS
716	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
717	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
718	END SUBROUTINE sbc_ice_lim
719	SUBROUTINE sbc_lim_init ! Dummy routine
720	END SUBROUTINE sbc_lim_init
721	#endif
722
723	!!======================================================================
724	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: