New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlim.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlim.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
File size: 15.1 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10   !!   p4z_lim        :   Compute the nutrients limitation terms
11   !!   p4z_lim_init   :   Read the namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! Shared ocean-passive tracers variables
14   USE trc             ! Tracers defined
15   USE sms_pisces      ! PISCES variables
16   USE p4zopt          ! Optical
17   USE iom             !  I/O manager
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC p4z_lim   
23   PUBLIC p4z_lim_init   
24
25   !! * Shared module variables
26   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
27   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
28   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for phyto 
29   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
30   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
31   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
32   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
33   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
34   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
35   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
36   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
37   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
38   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
39   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
40   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
41   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
42   REAL(wp), PUBLIC ::  oxymin      !:  half saturation constant for anoxia
43   REAL(wp), PUBLIC ::  qnfelim     !:  optimal Fe quota for nanophyto
44   REAL(wp), PUBLIC ::  qdfelim     !:  optimal Fe quota for diatoms
45   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
46
47   ! Coefficient for iron limitation
48   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
49   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
50   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zlim.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p4z_lim( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_lim  ***
63      !!
64      !! ** Purpose :   Compute the co-limitations by the various nutrients
65      !!              for the various phytoplankton species
66      !!
67      !! ** Method  : - ???
68      !!---------------------------------------------------------------------
69      !
70      INTEGER, INTENT(in)  :: kt, knt
71      !
72      INTEGER  ::   ji, jj, jk
73      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
74      REAL(wp) ::   zconcd, zconcd2, zconcn, zconcn2
75      REAL(wp) ::   z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2
76      REAL(wp) ::   zdenom, zratio, zironmin
77      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('p4z_lim')
81      !
82      DO jk = 1, jpkm1
83         DO jj = 1, jpj
84            DO ji = 1, jpi
85               
86               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
87               !-------------------------------------
88               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
89               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
90               zferlim = MIN( zferlim, 7e-11 )
91               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
92
93               ! Computation of a variable Ks for iron on diatoms taking into account
94               ! that increasing biomass is made of generally bigger cells
95               !------------------------------------------------
96               zconcd   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
97               zconcd2  = trb(ji,jj,jk,jpdia) - zconcd
98               zconcn   = MAX( 0.e0 , trb(ji,jj,jk,jpphy) - xsizephy )
99               zconcn2  = trb(ji,jj,jk,jpphy) - zconcn
100               z1_trbphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
101               z1_trbdia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
102
103               concdfe(ji,jj,jk) = MAX( concdfer, ( zconcd2 * concdfer + concdfer * xsizerd * zconcd ) * z1_trbdia )
104               zconc1d           = MAX( concdno3, ( zconcd2 * concdno3 + concdno3 * xsizerd * zconcd ) * z1_trbdia )
105               zconc1dnh4        = MAX( concdnh4, ( zconcd2 * concdnh4 + concdnh4 * xsizerd * zconcd ) * z1_trbdia )
106
107               concnfe(ji,jj,jk) = MAX( concnfer, ( zconcn2 * concnfer + concnfer * xsizern * zconcn ) * z1_trbphy )
108               zconc0n           = MAX( concnno3, ( zconcn2 * concnno3 + concnno3 * xsizern * zconcn ) * z1_trbphy )
109               zconc0nnh4        = MAX( concnnh4, ( zconcn2 * concnnh4 + concnnh4 * xsizern * zconcn ) * z1_trbphy )
110
111               ! Michaelis-Menten Limitation term for nutrients Small bacteria
112               ! -------------------------------------------------------------
113               zdenom = 1. /  ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) )
114               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom
115               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom
116               !
117               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
118               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 )
119               zlim3    = trb(ji,jj,jk,jpfer) / ( concbfe + trb(ji,jj,jk,jpfer) )
120               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
121               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
122               xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
123
124               ! Michaelis-Menten Limitation term for nutrients Small flagellates
125               ! -----------------------------------------------
126               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) )
127               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
128               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n    * zdenom
129               !
130               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
131               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 )
132               zratio   = trb(ji,jj,jk,jpnfe) * z1_trbphy 
133               zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
134               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
135               xnanopo4(ji,jj,jk) = zlim2
136               xlimnfe (ji,jj,jk) = MIN( 1., zlim3 )
137               xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
138               !
139               !   Michaelis-Menten Limitation term for nutrients Diatoms
140               !   ----------------------------------------------
141               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) )
142               xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
143               xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d    * zdenom
144               !
145               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
146               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4  )
147               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
148               zratio   = trb(ji,jj,jk,jpdfe) * z1_trbdia
149               zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
150               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
151               xdiatpo4(ji,jj,jk) = zlim2
152               xlimdfe (ji,jj,jk) = MIN( 1., zlim4 )
153               xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
154               xlimsi  (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 )
155           END DO
156         END DO
157      END DO
158
159      ! Compute the fraction of nanophytoplankton that is made of calcifiers
160      ! --------------------------------------------------------------------
161      DO jk = 1, jpkm1
162         DO jj = 1, jpj
163            DO ji = 1, jpi
164               zlim1 =  ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 )    &
165                  &   / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) 
166               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 )
167               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11   )
168               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
169               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
170               zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) 
171               zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) 
172
173               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
174                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
175                  &                       * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
176                  &                       * zetot1 * zetot2               &
177                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
178                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
179               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
180               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
181            END DO
182         END DO
183      END DO
184      !
185      DO jk = 1, jpkm1
186         DO jj = 1, jpj
187            DO ji = 1, jpi
188               ! denitrification factor computed from O2 levels
189               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
190                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
191               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
192            END DO
193         END DO
194      END DO
195      !
196      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
197        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
198        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
199        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
200        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
201        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
202      ENDIF
203      !
204      IF( nn_timing == 1 )  CALL timing_stop('p4z_lim')
205      !
206   END SUBROUTINE p4z_lim
207
208   SUBROUTINE p4z_lim_init
209
210      !!----------------------------------------------------------------------
211      !!                  ***  ROUTINE p4z_lim_init  ***
212      !!
213      !! ** Purpose :   Initialization of nutrient limitation parameters
214      !!
215      !! ** Method  :   Read the nampislim namelist and check the parameters
216      !!      called at the first timestep (nittrc000)
217      !!
218      !! ** input   :   Namelist nampislim
219      !!
220      !!----------------------------------------------------------------------
221
222      NAMELIST/nampislim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe,   &
223         &                concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd,          & 
224         &                xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r, oxymin
225      INTEGER :: ios                 ! Local integer output status for namelist read
226
227      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
228      READ  ( numnatp_ref, nampislim, IOSTAT = ios, ERR = 901)
229901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp )
230
231      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
232      READ  ( numnatp_cfg, nampislim, IOSTAT = ios, ERR = 902 )
233902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp )
234      IF(lwm) WRITE ( numonp, nampislim )
235
236      IF(lwp) THEN                         ! control print
237         WRITE(numout,*) ' '
238         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim'
239         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
240         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
241         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
242         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
243         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
244         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
245         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
246         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
247         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
248         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
249         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
250         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
251         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
252         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
253         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
254         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
255         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
256         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
257         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin   =' , oxymin
258         WRITE(numout,*) '    optimal Fe quota for nano.               qnfelim   = ', qnfelim
259         WRITE(numout,*) '    Optimal Fe quota for diatoms             qdfelim   = ', qdfelim
260      ENDIF
261      !
262      nitrfac (:,:,:) = 0._wp
263      !
264   END SUBROUTINE p4z_lim_init
265
266   !!======================================================================
267END MODULE p4zlim
Note: See TracBrowser for help on using the repository browser.