source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zopt.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

File size: 19.4 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  optimisation
9   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improve light availability of nano & diat
10   !!----------------------------------------------------------------------
11#if defined  key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_opt       : light availability in the water column
16   !!----------------------------------------------------------------------
17   USE trc            ! tracer variables
18   USE oce_trc        ! tracer-ocean share variables
19   USE sms_pisces     ! Source Minus Sink of PISCES
20   USE iom            ! I/O manager
21   USE fldread         !  time interpolation
22   USE prtctl_trc      !  print control for debugging
23
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_opt        ! called in p4zbio.F90 module
29   PUBLIC   p4z_opt_init   ! called in trcsms_pisces.F90 module
30   PUBLIC   p4z_opt_alloc
31
32   !! * Shared module variables
33
34   LOGICAL  :: ln_varpar   !: boolean for variable PAR fraction
35   REAL(wp) :: parlux      !: Fraction of shortwave as PAR
36   REAL(wp) :: xparsw                 !: parlux/3
37   REAL(wp) :: xsi0r                 !:  1. /rn_si0
38
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_par      ! structure of input par
40   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
41   INTEGER  :: ntimes_par                ! number of time steps in a file
42   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:) :: par_varsw    !: PAR fraction of shortwave
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: enano, ediat   !: PAR for phyto, nano and diat
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: etot_ndcy      !: PAR over 24h in case of diurnal cycle
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emoy           !: averaged PAR in the mixed layer
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ekb, ekg, ekr  !: wavelength (Red-Green-Blue)
48
49   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
50
51   REAL(wp), DIMENSION(3,61), PUBLIC ::   xkrgb   !: tabulated attenuation coefficients for RGB absorption
52   
53   !!----------------------------------------------------------------------
54   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
55   !! $Id: p4zopt.F90 3160 2011-11-20 14:27:18Z cetlod $
56   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE p4z_opt( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_opt  ***
63      !!
64      !! ** Purpose :   Compute the light availability in the water column
65      !!              depending on the depth and the chlorophyll concentration
66      !!
67      !! ** Method  : - ???
68      !!---------------------------------------------------------------------
69      !
70      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
71      !
72      INTEGER  ::   ji, jj, jk
73      INTEGER  ::   irgb
74      REAL(wp) ::   zchl
75      REAL(wp) ::   zc0 , zc1 , zc2, zc3, z1_dep
76      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4
77      REAL(wp), POINTER, DIMENSION(:,:  ) :: zqsr100, zqsr_corr
78      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpar, ze0, ze1, ze2, ze3
79      !!---------------------------------------------------------------------
80      !
81      IF( nn_timing == 1 )  CALL timing_start('p4z_opt')
82      !
83      ! Allocate temporary workspace
84      CALL wrk_alloc( jpi, jpj,      zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4 )
85      CALL wrk_alloc( jpi, jpj,      zqsr100, zqsr_corr )
86      CALL wrk_alloc( jpi, jpj, jpk, zpar   , ze0, ze1, ze2, ze3 )
87
88      IF( knt == 1 .AND. ln_varpar ) CALL p4z_opt_sbc( kt )
89
90      !     Initialisation of variables used to compute PAR
91      !     -----------------------------------------------
92      ze1(:,:,:) = 0._wp
93      ze2(:,:,:) = 0._wp
94      ze3(:,:,:) = 0._wp
95      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
96      DO jk = 1, jpkm1                         !  --------------------------------------------------------
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               zchl = ( trb(ji,jj,jk,jpnch) + trb(ji,jj,jk,jpdch) + rtrn ) * 1.e6
100               zchl = MIN(  10. , MAX( 0.05, zchl )  )
101               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
102               !                                                         
103               ekb(ji,jj,jk) = xkrgb(1,irgb) * e3t_n(ji,jj,jk)
104               ekg(ji,jj,jk) = xkrgb(2,irgb) * e3t_n(ji,jj,jk)
105               ekr(ji,jj,jk) = xkrgb(3,irgb) * e3t_n(ji,jj,jk)
106            END DO
107         END DO
108      END DO
109      !                                        !* Photosynthetically Available Radiation (PAR)
110      !                                        !  --------------------------------------
111      IF( l_trcdm2dc ) THEN                     !  diurnal cycle
112         !
113         zqsr_corr(:,:) = qsr_mean(:,:) / ( 1. - fr_i(:,:) + rtrn )
114         !
115         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100 ) 
116         !
117         DO jk = 1, nksrp     
118            etot_ndcy(:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
119            enano    (:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
120            ediat    (:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
121         END DO
122         !
123         zqsr_corr(:,:) = qsr(:,:) / ( 1. - fr_i(:,:) + rtrn )
124         !
125         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3 ) 
126         !
127         DO jk = 1, nksrp     
128            etot(:,:,jk) =  ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk)
129         END DO
130         !
131      ELSE
132         !
133         zqsr_corr(:,:) = qsr(:,:) / ( 1. - fr_i(:,:) + rtrn )
134         !
135         CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3, pqsr100 = zqsr100  ) 
136         !
137         DO jk = 1, nksrp     
138            etot (:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
139            enano(:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
140            ediat(:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
141         END DO
142         etot_ndcy(:,:,:) =  etot(:,:,:) 
143      ENDIF
144
145
146      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
147         !                                     !  ------------------------
148         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3, pe0=ze0 )
149         !
150         etot3(:,:,1) =  qsr(:,:) * tmask(:,:,1)
151         DO jk = 2, nksrp + 1
152            etot3(:,:,jk) =  ( ze0(:,:,jk) + ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) ) * tmask(:,:,jk)
153         END DO
154         !                                     !  ------------------------
155      ENDIF
156      !                                        !* Euphotic depth and level
157      neln(:,:) = 1                            !  ------------------------
158      heup(:,:) = 300.
159
160      DO jk = 2, nksrp
161         DO jj = 1, jpj
162           DO ji = 1, jpi
163              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >=  zqsr100(ji,jj) )  THEN
164                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
165                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
166                 heup(ji,jj) = gdepw_n(ji,jj,jk+1)     ! Euphotic layer depth
167              ENDIF
168           END DO
169        END DO
170      END DO
171      !
172      heup(:,:) = MIN( 300., heup(:,:) )
173      !                                        !* mean light over the mixed layer
174      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
175      zetmp1 (:,:)   = 0.e0
176      zetmp2 (:,:)   = 0.e0
177      zetmp3 (:,:)   = 0.e0
178      zetmp4 (:,:)   = 0.e0
179
180      DO jk = 1, nksrp
181         DO jj = 1, jpj
182            DO ji = 1, jpi
183               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
184                  zetmp1 (ji,jj) = zetmp1 (ji,jj) + etot     (ji,jj,jk) * e3t_n(ji,jj,jk) ! remineralisation
185                  zetmp2 (ji,jj) = zetmp2 (ji,jj) + etot_ndcy(ji,jj,jk) * e3t_n(ji,jj,jk) ! production
186                  zetmp3 (ji,jj) = zetmp3 (ji,jj) + enano    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
187                  zetmp4 (ji,jj) = zetmp4 (ji,jj) + ediat    (ji,jj,jk) * e3t_n(ji,jj,jk) ! production
188                  zdepmoy(ji,jj) = zdepmoy(ji,jj) +                       e3t_n(ji,jj,jk)
189               ENDIF
190            END DO
191         END DO
192      END DO
193      !
194      emoy(:,:,:) = etot(:,:,:)       ! remineralisation
195      zpar(:,:,:) = etot_ndcy(:,:,:)  ! diagnostic : PAR with no diurnal cycle
196      !
197      DO jk = 1, nksrp
198         DO jj = 1, jpj
199            DO ji = 1, jpi
200               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
201                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
202                  emoy (ji,jj,jk) = zetmp1(ji,jj) * z1_dep
203                  zpar (ji,jj,jk) = zetmp2(ji,jj) * z1_dep
204                  enano(ji,jj,jk) = zetmp3(ji,jj) * z1_dep
205                  ediat(ji,jj,jk) = zetmp4(ji,jj) * z1_dep
206               ENDIF
207            END DO
208         END DO
209      END DO
210      !
211      IF( lk_iomput ) THEN
212        IF( knt == nrdttrc ) THEN
213           IF( iom_use( "Heup"  ) ) CALL iom_put( "Heup" , heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
214           IF( iom_use( "PARDM" ) ) CALL iom_put( "PARDM", zpar(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
215           IF( iom_use( "PAR"   ) ) CALL iom_put( "PAR"  , emoy(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
216        ENDIF
217      ENDIF
218      !
219      CALL wrk_dealloc( jpi, jpj,      zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4 )
220      CALL wrk_dealloc( jpi, jpj,      zqsr100, zqsr_corr )
221      CALL wrk_dealloc( jpi, jpj, jpk, zpar   ,  ze0, ze1, ze2, ze3 )
222      !
223      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt')
224      !
225   END SUBROUTINE p4z_opt
226
227   SUBROUTINE p4z_opt_par( kt, pqsr, pe1, pe2, pe3, pe0, pqsr100 ) 
228      !!----------------------------------------------------------------------
229      !!                  ***  routine p4z_opt_par  ***
230      !!
231      !! ** purpose :   compute PAR of each wavelength (Red-Green-Blue)
232      !!                for a given shortwave radiation
233      !!
234      !!----------------------------------------------------------------------
235      !! * arguments
236      INTEGER, INTENT(in)                                       ::  kt            !   ocean time-step
237      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in)              ::  pqsr          !   shortwave
238      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout)           ::  pe1 , pe2 , pe3   !  PAR ( R-G-B)
239      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout), OPTIONAL ::  pe0 
240      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(out)  , OPTIONAL  ::  pqsr100 
241      !! * local variables
242      INTEGER    ::   ji, jj, jk     ! dummy loop indices
243      REAL(wp), DIMENSION(jpi,jpj)     ::  zqsr          !   shortwave
244      !!----------------------------------------------------------------------
245
246      !  Real shortwave
247      IF( ln_varpar ) THEN  ;  zqsr(:,:) = par_varsw(:,:) * pqsr(:,:)
248      ELSE                  ;  zqsr(:,:) = xparsw         * pqsr(:,:)
249      ENDIF
250     
251      !  Light at the euphotic depth
252      IF( PRESENT( pqsr100 ) )  pqsr100(:,:) = 0.01 * 3. * zqsr(:,:)
253
254      IF( PRESENT( pe0 ) ) THEN     !  W-level
255         !
256         pe0(:,:,1) = pqsr(:,:) - 3. * zqsr(:,:)    !   ( 1 - 3 * alpha ) * q
257         pe1(:,:,1) = zqsr(:,:)         
258         pe2(:,:,1) = zqsr(:,:)
259         pe3(:,:,1) = zqsr(:,:)
260         !
261         DO jk = 2, nksrp + 1
262            DO jj = 1, jpj
263               DO ji = 1, jpi
264                  pe0(ji,jj,jk) = pe0(ji,jj,jk-1) * EXP( -e3t_n(ji,jj,jk-1) * xsi0r )
265                  pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -ekb(ji,jj,jk-1 ) )
266                  pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -ekg(ji,jj,jk-1 ) )
267                  pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -ekr(ji,jj,jk-1 ) )
268               END DO
269              !
270            END DO
271            !
272         END DO
273        !
274      ELSE   ! T- level
275        !
276        pe1(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekb(:,:,1) )
277        pe2(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekg(:,:,1) )
278        pe3(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekr(:,:,1) )
279        !
280        DO jk = 2, nksrp     
281           DO jj = 1, jpj
282              DO ji = 1, jpi
283                 pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -0.5 * ( ekb(ji,jj,jk-1) + ekb(ji,jj,jk) ) )
284                 pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -0.5 * ( ekg(ji,jj,jk-1) + ekg(ji,jj,jk) ) )
285                 pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -0.5 * ( ekr(ji,jj,jk-1) + ekr(ji,jj,jk) ) )
286              END DO
287           END DO
288        END DO   
289        !
290      ENDIF
291      !
292   END SUBROUTINE p4z_opt_par
293
294
295   SUBROUTINE p4z_opt_sbc( kt )
296      !!----------------------------------------------------------------------
297      !!                  ***  routine p4z_opt_sbc  ***
298      !!
299      !! ** purpose :   read and interpolate the variable PAR fraction
300      !!                of shortwave radiation
301      !!
302      !! ** method  :   read the files and interpolate the appropriate variables
303      !!
304      !! ** input   :   external netcdf files
305      !!
306      !!----------------------------------------------------------------------
307      !! * arguments
308      INTEGER ,                INTENT(in) ::   kt     ! ocean time step
309
310      !! * local declarations
311      INTEGER  :: ji,jj
312      REAL(wp) :: zcoef
313      !!---------------------------------------------------------------------
314      !
315      IF( nn_timing == 1 )  CALL timing_start('p4z_optsbc')
316      !
317      ! Compute par_varsw at nit000 or only if there is more than 1 time record in par coefficient file
318      IF( ln_varpar ) THEN
319         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_par > 1 ) ) THEN
320            CALL fld_read( kt, 1, sf_par )
321            par_varsw(:,:) = ( sf_par(1)%fnow(:,:,1) ) / 3.0
322         ENDIF
323      ENDIF
324      !
325      IF( nn_timing == 1 )  CALL timing_stop('p4z_optsbc')
326      !
327   END SUBROUTINE p4z_opt_sbc
328
329   SUBROUTINE p4z_opt_init
330      !!----------------------------------------------------------------------
331      !!                  ***  ROUTINE p4z_opt_init  ***
332      !!
333      !! ** Purpose :   Initialization of tabulated attenuation coef
334      !!                and of the percentage of PAR in Shortwave
335      !!
336      !! ** Input   :   external ascii and netcdf files
337      !!----------------------------------------------------------------------
338      !
339      INTEGER :: numpar
340      INTEGER :: ierr
341      INTEGER :: ios                 ! Local integer output status for namelist read
342      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
343      !
344      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
345      TYPE(FLD_N) ::   sn_par                ! informations about the fields to be read
346      !
347      NAMELIST/nampisopt/cn_dir, sn_par, ln_varpar, parlux
348
349      !!----------------------------------------------------------------------
350
351      IF( nn_timing == 1 )  CALL timing_start('p4z_opt_init')
352
353      REWIND( numnatp_ref )              ! Namelist nampisopt in reference namelist : Pisces attenuation coef. and PAR
354      READ  ( numnatp_ref, nampisopt, IOSTAT = ios, ERR = 901)
355901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in reference namelist', lwp )
356
357      REWIND( numnatp_cfg )              ! Namelist nampisopt in configuration namelist : Pisces attenuation coef. and PAR
358      READ  ( numnatp_cfg, nampisopt, IOSTAT = ios, ERR = 902 )
359902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in configuration namelist', lwp )
360      IF(lwm) WRITE ( numonp, nampisopt )
361
362      IF(lwp) THEN
363         WRITE(numout,*) ' '
364         WRITE(numout,*) ' namelist : nampisopt '
365         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
366         WRITE(numout,*) '    PAR as a variable fraction of SW     ln_varpar      = ', ln_varpar
367         WRITE(numout,*) '    Default value for the PAR fraction   parlux         = ', parlux
368      ENDIF
369      !
370      xparsw = parlux / 3.0
371      xsi0r  = 1.e0 / rn_si0
372      !
373      ! Variable PAR at the surface of the ocean
374      ! ----------------------------------------
375      IF( ln_varpar ) THEN
376         IF(lwp) WRITE(numout,*) '    initialize variable par fraction '
377         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
378         !
379         ALLOCATE( par_varsw(jpi,jpj) )
380         !
381         ALLOCATE( sf_par(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
382         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_opt_init: unable to allocate sf_par structure' )
383         !
384         CALL fld_fill( sf_par, (/ sn_par /), cn_dir, 'p4z_opt_init', 'Variable PAR fraction ', 'nampisopt' )
385                                   ALLOCATE( sf_par(1)%fnow(jpi,jpj,1)   )
386         IF( sn_par%ln_tint )      ALLOCATE( sf_par(1)%fdta(jpi,jpj,1,2) )
387
388         CALL iom_open (  TRIM( sn_par%clname ) , numpar )
389         CALL iom_gettime( numpar, zsteps, kntime=ntimes_par)  ! get number of record in file
390      ENDIF
391      !
392      CALL trc_oce_rgb( xkrgb )                  ! tabulated attenuation coefficients
393      nksrp = trc_oce_ext_lev( r_si2, 0.33e2 )     ! max level of light extinction (Blue Chl=0.01)
394      !
395      IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksrp, ' ref depth = ', gdepw_1d(nksrp+1), ' m'
396      !
397                         ekr      (:,:,:) = 0._wp
398                         ekb      (:,:,:) = 0._wp
399                         ekg      (:,:,:) = 0._wp
400                         etot     (:,:,:) = 0._wp
401                         etot_ndcy(:,:,:) = 0._wp
402                         enano    (:,:,:) = 0._wp
403                         ediat    (:,:,:) = 0._wp
404      IF( ln_qsr_bio )   etot3    (:,:,:) = 0._wp
405      !
406      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt_init')
407      !
408   END SUBROUTINE p4z_opt_init
409
410
411   INTEGER FUNCTION p4z_opt_alloc()
412      !!----------------------------------------------------------------------
413      !!                     ***  ROUTINE p4z_opt_alloc  ***
414      !!----------------------------------------------------------------------
415      ALLOCATE( ekb(jpi,jpj,jpk)      , ekr(jpi,jpj,jpk), ekg(jpi,jpj,jpk),   &
416        &       enano(jpi,jpj,jpk)    , ediat(jpi,jpj,jpk), &
417        &       etot_ndcy(jpi,jpj,jpk), emoy (jpi,jpj,jpk), STAT=p4z_opt_alloc ) 
418         !
419      IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.')
420      !
421   END FUNCTION p4z_opt_alloc
422
423#else
424   !!----------------------------------------------------------------------
425   !!  Dummy module :                                   No PISCES bio-model
426   !!----------------------------------------------------------------------
427CONTAINS
428   SUBROUTINE p4z_opt                   ! Empty routine
429   END SUBROUTINE p4z_opt
430#endif 
431
432   !!======================================================================
433END MODULE p4zopt
Note: See TracBrowser for help on using the repository browser.