source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsms.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

File size: 25.5 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4zsms         :  Time loop of passive tracers sms
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE trcdta
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zbio          !  Biological model
20   USE p4zche          !  Chemical model
21   USE p4zlys          !  Calcite saturation
22   USE p4zflx          !  Gas exchange
23   USE p4zsbc          !  External source of nutrients
24   USE p4zsed          !  Sedimentation
25   USE p4zint          !  time interpolation
26   USE p4zrem          !  remineralisation
27   USE iom             !  I/O manager
28   USE trd_oce         !  Ocean trends variables
29   USE trdtrc          !  TOP trends variables
30   USE sedmodel        !  Sediment model
31   USE prtctl_trc      !  print control for debugging
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
37   PUBLIC   p4z_sms        ! called in p4zsms.F90
38
39   REAL(wp) :: alkbudget, no3budget, silbudget, ferbudget, po4budget
40   REAL(wp) :: xfact1, xfact2, xfact3
41   INTEGER ::  numco2, numnut, numnit  !: logical unit for co2 budget
42
43   !!* Array used to indicate negative tracer values
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     !: ???
45
46
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
49   !! $Id: p4zsms.F90 3320 2012-03-05 16:37:52Z cetlod $
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE p4z_sms( kt )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_sms  ***
58      !!
59      !! ** Purpose :   Managment of the call to Biological sources and sinks
60      !!              routines of PISCES bio-model
61      !!
62      !! ** Method  : - at each new day ...
63      !!              - several calls of bio and sed ???
64      !!              - ...
65      !!---------------------------------------------------------------------
66      !
67      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
68      !!
69      INTEGER ::   ji, jj, jk, jnt, jn, jl
70      REAL(wp) ::  ztra
71      CHARACTER (len=25) :: charout
72      !!---------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('p4z_sms')
75      !
76      IF( kt == nittrc000 ) THEN
77        !
78        ALLOCATE( xnegtr(jpi,jpj,jpk) )
79        !
80        CALL p4z_che                              ! initialize the chemical constants
81        !
82        IF( .NOT. ln_rsttr ) THEN  ;   CALL p4z_ph_ini   !  set PH at kt=nit000
83        ELSE                       ;   CALL p4z_rst( nittrc000, 'READ' )  !* read or initialize all required fields
84        ENDIF
85        !
86      ENDIF
87      !
88      IF( ln_pisdmp .AND. MOD( kt - nn_dttrc, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt )      ! Relaxation of some tracers
89      !
90      !                                                                    !   set time step size (Euler/Leapfrog)
91      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN   ;    rfact = rdttrc     !  at nittrc000
92      ELSEIF( kt <= nittrc000 + nn_dttrc )                          THEN   ;    rfact = 2. * rdttrc   ! at nittrc000 or nittrc000+nn_dttrc (Leapfrog)
93      ENDIF
94      !
95      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + nn_dttrc ) ) THEN
96         rfactr  = 1. / rfact
97         rfact2  = rfact / FLOAT( nrdttrc )
98         rfact2r = 1. / rfact2
99         xstep = rfact2 / rday         ! Time step duration for biology
100         IF(lwp) WRITE(numout,*) 
101         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdt
102         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
103         IF(lwp) WRITE(numout,*)
104      ENDIF
105
106      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN
107         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
108            trb(:,:,:,jn) = trn(:,:,:,jn)
109         END DO
110      ENDIF
111      !
112      IF( ndayflxtr /= nday_year ) THEN      ! New days
113         !
114         ndayflxtr = nday_year
115
116         IF(lwp) write(numout,*)
117         IF(lwp) write(numout,*) ' New chemical constants and various rates for biogeochemistry at new day : ', nday_year
118         IF(lwp) write(numout,*) '~~~~~~'
119
120         CALL p4z_che              ! computation of chemical constants
121         CALL p4z_int( kt )        ! computation of various rates for biogeochemistry
122         !
123      ENDIF
124
125      IF( ll_sbc ) CALL p4z_sbc( kt )   ! external sources of nutrients
126
127      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
128         !
129         CALL p4z_bio( kt, jnt )   ! Biology
130         CALL p4z_lys( kt, jnt )   ! Compute CaCO3 saturation
131         CALL p4z_sed( kt, jnt )   ! Surface and Bottom boundary conditions
132         CALL p4z_flx( kt, jnt )   ! Compute surface fluxes
133         !
134         xnegtr(:,:,:) = 1.e0
135         DO jn = jp_pcs0, jp_pcs1
136            DO jk = 1, jpk
137               DO jj = 1, jpj
138                  DO ji = 1, jpi
139                     IF( ( trb(ji,jj,jk,jn) + tra(ji,jj,jk,jn) ) < 0.e0 ) THEN
140                        ztra             = ABS( trb(ji,jj,jk,jn) ) / ( ABS( tra(ji,jj,jk,jn) ) + rtrn )
141                        xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
142                     ENDIF
143                 END DO
144               END DO
145            END DO
146         END DO
147         !                                ! where at least 1 tracer concentration becomes negative
148         !                                !
149         DO jn = jp_pcs0, jp_pcs1
150           trb(:,:,:,jn) = trb(:,:,:,jn) + xnegtr(:,:,:) * tra(:,:,:,jn)
151         END DO
152        !
153         DO jn = jp_pcs0, jp_pcs1
154            tra(:,:,:,jn) = 0._wp
155         END DO
156         !
157         IF( ln_top_euler ) THEN
158            DO jn = jp_pcs0, jp_pcs1
159               trn(:,:,:,jn) = trb(:,:,:,jn)
160            END DO
161         ENDIF
162      END DO
163
164      !
165      IF( l_trdtrc ) THEN
166         DO jn = jp_pcs0, jp_pcs1
167           CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
168         END DO
169      END IF
170      !
171      IF( lk_sed ) THEN 
172         !
173         CALL sed_model( kt )     !  Main program of Sediment model
174         !
175         DO jn = jp_pcs0, jp_pcs1
176           CALL lbc_lnk( trb(:,:,:,jn), 'T', 1. )
177         END DO
178         !
179      ENDIF
180      !
181      IF( lrst_trc )  CALL p4z_rst( kt, 'WRITE' )  !* Write PISCES informations in restart file
182      !
183
184      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt ) ! Mass conservation checking
185
186      IF ( lwm .AND. kt == nittrc000 ) CALL FLUSH    ( numonp )     ! flush output namelist PISCES
187      IF( nn_timing == 1 )  CALL timing_stop('p4z_sms')
188      !
189      !
190   END SUBROUTINE p4z_sms
191
192   SUBROUTINE p4z_sms_init
193      !!----------------------------------------------------------------------
194      !!                     ***  p4z_sms_init  *** 
195      !!
196      !! ** Purpose :   read PISCES namelist
197      !!
198      !! ** input   :   file 'namelist.trc.s' containing the following
199      !!             namelist: natext, natbio, natsms
200      !!----------------------------------------------------------------------
201      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, niter1max, niter2max
202      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
203      NAMELIST/nampismass/ ln_check_mass
204      INTEGER :: ios                 ! Local integer output status for namelist read
205      !!----------------------------------------------------------------------
206
207      REWIND( numnatp_ref )              ! Namelist nampisbio in reference namelist : Pisces variables
208      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
209901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisbio in reference namelist', lwp )
210
211      REWIND( numnatp_cfg )              ! Namelist nampisbio in configuration namelist : Pisces variables
212      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
213902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisbio in configuration namelist', lwp )
214      IF(lwm) WRITE ( numonp, nampisbio )
215
216      IF(lwp) THEN                         ! control print
217         WRITE(numout,*) ' Namelist : nampisbio'
218         WRITE(numout,*) '    frequence pour la biologie                nrdttrc   =', nrdttrc
219         WRITE(numout,*) '    POC sinking speed                         wsbio     =', wsbio
220         WRITE(numout,*) '    half saturation constant for mortality    xkmort    =', xkmort
221         WRITE(numout,*) '    Fe/C in zooplankton                       ferat3    =', ferat3
222         WRITE(numout,*) '    Big particles sinking speed               wsbio2    =', wsbio2
223         WRITE(numout,*) '    Maximum number of iterations for POC      niter1max =', niter1max
224         WRITE(numout,*) '    Maximum number of iterations for GOC      niter2max =', niter2max
225      ENDIF
226
227      REWIND( numnatp_ref )              ! Namelist nampisdmp in reference namelist : Pisces damping
228      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
229905   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisdmp in reference namelist', lwp )
230
231      REWIND( numnatp_cfg )              ! Namelist nampisdmp in configuration namelist : Pisces damping
232      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
233906   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisdmp in configuration namelist', lwp )
234      IF(lwm) WRITE ( numonp, nampisdmp )
235
236      IF(lwp) THEN                         ! control print
237         WRITE(numout,*)
238         WRITE(numout,*) ' Namelist : nampisdmp'
239         WRITE(numout,*) '    Relaxation of tracer to glodap mean value             ln_pisdmp      =', ln_pisdmp
240         WRITE(numout,*) '    Frequency of Relaxation                               nn_pisdmp      =', nn_pisdmp
241         WRITE(numout,*) ' '
242      ENDIF
243
244      REWIND( numnatp_ref )              ! Namelist nampismass in reference namelist : Pisces mass conservation check
245      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
246907   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismass in reference namelist', lwp )
247
248      REWIND( numnatp_cfg )              ! Namelist nampismass in configuration namelist : Pisces mass conservation check
249      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
250908   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismass in configuration namelist', lwp )
251      IF(lwm) WRITE ( numonp, nampismass )
252
253      IF(lwp) THEN                         ! control print
254         WRITE(numout,*) ' '
255         WRITE(numout,*) ' Namelist parameter for mass conservation checking'
256         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
257         WRITE(numout,*) '    Flag to check mass conservation of NO3/Si/TALK ln_check_mass = ', ln_check_mass
258      ENDIF
259
260   END SUBROUTINE p4z_sms_init
261
262   SUBROUTINE p4z_ph_ini
263      !!---------------------------------------------------------------------
264      !!                   ***  ROUTINE p4z_ini_ph  ***
265      !!
266      !!  ** Purpose : Initialization of chemical variables of the carbon cycle
267      !!---------------------------------------------------------------------
268      INTEGER  ::  ji, jj, jk
269      REAL(wp) ::  zcaralk, zbicarb, zco3
270      REAL(wp) ::  ztmas, ztmas1
271      !!---------------------------------------------------------------------
272
273      ! Set PH from  total alkalinity, borat (???), akb3 (???) and ak23 (???)
274      ! --------------------------------------------------------
275      DO jk = 1, jpk
276         DO jj = 1, jpj
277            DO ji = 1, jpi
278               ztmas   = tmask(ji,jj,jk)
279               ztmas1  = 1. - tmask(ji,jj,jk)
280               zcaralk = trb(ji,jj,jk,jptal) - borat(ji,jj,jk) / (  1. + 1.E-8 / ( rtrn + akb3(ji,jj,jk) )  )
281               zco3    = ( zcaralk - trb(ji,jj,jk,jpdic) ) * ztmas + 0.5e-3 * ztmas1
282               zbicarb = ( 2. * trb(ji,jj,jk,jpdic) - zcaralk )
283               hi(ji,jj,jk) = ( ak23(ji,jj,jk) * zbicarb / zco3 ) * ztmas + 1.e-9 * ztmas1
284            END DO
285         END DO
286     END DO
287     !
288   END SUBROUTINE p4z_ph_ini
289
290   SUBROUTINE p4z_rst( kt, cdrw )
291      !!---------------------------------------------------------------------
292      !!                   ***  ROUTINE p4z_rst  ***
293      !!
294      !!  ** Purpose : Read or write variables in restart file:
295      !!
296      !!  WRITE(READ) mode:
297      !!       kt        : number of time step since the begining of the experiment at the
298      !!                   end of the current(previous) run
299      !!---------------------------------------------------------------------
300      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
301      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
302      !
303      INTEGER  ::  ji, jj, jk
304      REAL(wp) ::  zcaralk, zbicarb, zco3
305      REAL(wp) ::  ztmas, ztmas1
306      !!---------------------------------------------------------------------
307
308      IF( TRIM(cdrw) == 'READ' ) THEN
309         !
310         IF(lwp) WRITE(numout,*)
311         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
312         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
313         !
314         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
315            CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:)  )
316         ELSE
317!            hi(:,:,:) = 1.e-9
318            CALL p4z_ph_ini
319         ENDIF
320         CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) )
321         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
322            CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
323         ELSE
324            xksimax(:,:) = xksi(:,:)
325         ENDIF
326         !
327         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
328            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum  )
329         ELSE
330            t_oce_co2_flx_cum = 0._wp
331         ENDIF
332         !
333      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
334         IF( kt == nitrst ) THEN
335            IF(lwp) WRITE(numout,*)
336            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
337            IF(lwp) WRITE(numout,*) '~~~~~~~'
338         ENDIF
339         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) )
340         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) )
341         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) )
342         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum )
343      ENDIF
344      !
345   END SUBROUTINE p4z_rst
346
347   SUBROUTINE p4z_dmp( kt )
348      !!----------------------------------------------------------------------
349      !!                    ***  p4z_dmp  ***
350      !!
351      !! ** purpose  : Relaxation of some tracers
352      !!----------------------------------------------------------------------
353      !
354      INTEGER, INTENT( in )  ::     kt ! time step
355      !
356      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
357      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
358      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
359      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
360      !
361      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
362      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
363      !!---------------------------------------------------------------------
364
365
366      IF(lwp)  WRITE(numout,*)
367      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
368      IF(lwp)  WRITE(numout,*)
369
370      IF( cp_cfg == "orca" .AND. .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
371         !                                                    ! --------------------------- !
372         ! set total alkalinity, phosphate, nitrate & silicate
373         zarea          = 1._wp / glob_sum( cvol(:,:,:) ) * 1e6             
374
375         zalksumn = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
376         zpo4sumn = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
377         zno3sumn = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
378         zsilsumn = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
379 
380         IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
381         trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksumn
382
383         IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
384         trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sumn
385
386         IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
387         trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sumn
388
389         IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
390         trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsumn )
391         !
392         !
393         IF( .NOT. ln_top_euler ) THEN
394            zalksumb = glob_sum( trb(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
395            zpo4sumb = glob_sum( trb(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
396            zno3sumb = glob_sum( trb(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
397            zsilsumb = glob_sum( trb(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
398 
399            IF(lwp) WRITE(numout,*) ' '
400            IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
401            trb(:,:,:,jptal) = trb(:,:,:,jptal) * alkmean / zalksumb
402
403            IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
404            trb(:,:,:,jppo4) = trb(:,:,:,jppo4) * po4mean / zpo4sumb
405
406            IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
407            trb(:,:,:,jpno3) = trb(:,:,:,jpno3) * no3mean / zno3sumb
408
409            IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
410            trb(:,:,:,jpsil) = MIN( 400.e-6,trb(:,:,:,jpsil) * silmean / zsilsumb )
411        ENDIF
412        !
413      ENDIF
414        !
415   END SUBROUTINE p4z_dmp
416
417
418   SUBROUTINE p4z_chk_mass( kt )
419      !!----------------------------------------------------------------------
420      !!                  ***  ROUTINE p4z_chk_mass  ***
421      !!
422      !! ** Purpose :  Mass conservation check
423      !!
424      !!---------------------------------------------------------------------
425      !
426      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
427      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
428      CHARACTER(LEN=100)   ::   cltxt
429      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zvol
430      INTEGER :: jk
431      !!----------------------------------------------------------------------
432
433      !
434      !!---------------------------------------------------------------------
435
436      IF( kt == nittrc000 ) THEN
437         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
438            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
439            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
440            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
441            xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
442            xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
443            xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
444            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
445            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
446            IF( lwp ) WRITE(numnut,*) 
447         ENDIF
448      ENDIF
449
450      !
451      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
452         !   Compute the budget of NO3, ALK, Si, Fer
453         no3budget = glob_sum( (   trn(:,:,:,jpno3) + trn(:,:,:,jpnh4)  &
454            &                    + trn(:,:,:,jpphy) + trn(:,:,:,jpdia)  &
455            &                    + trn(:,:,:,jpzoo) + trn(:,:,:,jpmes)  &
456            &                    + trn(:,:,:,jppoc)                     &
457            &                    + trn(:,:,:,jpgoc)                     &
458            &                    + trn(:,:,:,jpdoc)                     ) * cvol(:,:,:)  )
459         !
460         no3budget = no3budget / areatot
461         CALL iom_put( "pno3tot", no3budget )
462      ENDIF
463      !
464      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
465         po4budget = glob_sum( (   trn(:,:,:,jppo4)                     &
466            &                    + trn(:,:,:,jpphy) + trn(:,:,:,jpdia)  &
467            &                    + trn(:,:,:,jpzoo) + trn(:,:,:,jpmes)  &
468            &                    + trn(:,:,:,jppoc)                     &
469            &                    + trn(:,:,:,jpgoc)                     &
470            &                    + trn(:,:,:,jpdoc)                     ) * cvol(:,:,:)  )
471         po4budget = po4budget / areatot
472         CALL iom_put( "ppo4tot", po4budget )
473      ENDIF
474      !
475      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
476         silbudget = glob_sum( (   trn(:,:,:,jpsil) + trn(:,:,:,jpgsi)  &
477            &                    + trn(:,:,:,jpdsi)                     ) * cvol(:,:,:)  )
478         !
479         silbudget = silbudget / areatot
480         CALL iom_put( "psiltot", silbudget )
481      ENDIF
482      !
483      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
484         alkbudget = glob_sum( (   trn(:,:,:,jpno3) * rno3              &
485            &                    + trn(:,:,:,jptal)                     &
486            &                    + trn(:,:,:,jpcal) * 2.                ) * cvol(:,:,:)  )
487         !
488         alkbudget = alkbudget / areatot
489         CALL iom_put( "palktot", alkbudget )
490      ENDIF
491      !
492      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
493         ferbudget = glob_sum( (   trn(:,:,:,jpfer) + trn(:,:,:,jpnfe)  &
494            &                    + trn(:,:,:,jpdfe)                     &
495            &                    + trn(:,:,:,jpbfe)                     &
496            &                    + trn(:,:,:,jpsfe)                     &
497            &                    + trn(:,:,:,jpzoo) * ferat3            &
498            &                    + trn(:,:,:,jpmes) * ferat3            ) * cvol(:,:,:)  )
499         !
500         ferbudget = ferbudget / areatot
501         CALL iom_put( "pfertot", ferbudget )
502      ENDIF
503      !
504
505      ! Global budget of N SMS : denitrification in the water column and in the sediment
506      !                          nitrogen fixation by the diazotrophs
507      ! --------------------------------------------------------------------------------
508      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
509         znitrpottot  = glob_sum ( nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
510         CALL iom_put( "tnfix"  , znitrpottot * 1.e+3 * rno3 )  ! Global  nitrogen fixation molC/l  to molN/m3
511      ENDIF
512      !
513      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
514         zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
515         CALL iom_put( "tdenit"  , zrdenittot * 1.e+3 * rno3 )  ! Total denitrification molC/l to molN/m3
516      ENDIF
517      !
518      IF( iom_use( "Sdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
519         zsdenittot   = glob_sum ( sdenit(:,:) * e1e2t(:,:) )
520         CALL iom_put( "Sdenit", sdenit(:,:) * xfact3 * tmask(:,:,1) )  ! Nitrate reduction in the sediments
521      ENDIF
522
523      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
524         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( e1e2t(:,:) )
525         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
526         tpp            = tpp           * 1000. * xfact1
527         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
528         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
529         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
530             &                                no3budget * rno3 * 1.e+06, &
531             &                                po4budget * po4r * 1.e+06, &
532             &                                silbudget        * 1.e+06, &
533             &                                ferbudget        * 1.e+09
534         !
535         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
536         &                             zrdenittot  * xfact2  , &
537         &                             zsdenittot  * xfact2
538
539      ENDIF
540      !
541 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
542 9100  FORMAT(i8,5e18.10)
543 9200  FORMAT(i8,3f10.5)
544
545       !
546   END SUBROUTINE p4z_chk_mass
547
548#else
549   !!======================================================================
550   !!  Dummy module :                                   No PISCES bio-model
551   !!======================================================================
552CONTAINS
553   SUBROUTINE p4z_sms( kt )                   ! Empty routine
554      INTEGER, INTENT( in ) ::   kt
555      WRITE(*,*) 'p4z_sms: You should not have seen this print! error?', kt
556   END SUBROUTINE p4z_sms
557#endif 
558
559   !!======================================================================
560END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.