New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
agrif_lim3_update.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/NST_SRC – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/NST_SRC/agrif_lim3_update.F90 @ 6746

Last change on this file since 6746 was 6746, checked in by clem, 8 years ago

landfast ice parameterization + update from trunk + removing useless dom_ice.F90 and limmsh.F90 and limwri_dimg.h90
File size: 8.6 KB
Line 
1#define TWO_WAY
2
3MODULE agrif_lim3_update
4   !!=====================================================================================
5   !!                       ***  MODULE agrif_lim3_update ***
6   !! Nesting module :  update surface ocean boundary condition over ice from a child grid
7   !! Sea-Ice model  :  LIM 3.6 Sea ice model time-stepping
8   !!=====================================================================================
9   !! History :  2.0   !  04-2008  (F. Dupont)  initial version
10   !!            3.4   !  08-2012  (R. Benshila, C. Herbaut) update and EVP
11   !!            3.6   !  05-2016  (C. Rousset)  Add LIM3 compatibility
12   !!----------------------------------------------------------------------
13#if defined key_agrif && defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'  :                                 LIM 3.6 sea-ice model
16   !!   'key_agrif' :                                 AGRIF library
17   !!----------------------------------------------------------------------
18   !!   agrif_update_lim3  : update sea-ice on boundaries or total
19   !!                        child domain for velocities and ice properties
20   !!   update_tra_ice     : sea-ice properties
21   !!   update_u_ice       : zonal      ice velocity
22   !!   update_v_ice       : meridional ice velocity
23   !!----------------------------------------------------------------------
24   USE dom_oce
25   USE sbc_oce
26   USE agrif_oce
27   USE ice
28   USE agrif_ice 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC agrif_update_lim3
34
35   !!----------------------------------------------------------------------
36   !! NEMO/NST 3.6 , LOCEAN-IPSL (2016)
37   !! $Id: agrif_lim3_update.F90 6204 2016-01-04 13:47:06Z cetlod $
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40
41CONTAINS
42
43   SUBROUTINE agrif_update_lim3( kt )
44      !!----------------------------------------------------------------------
45      !!                     *** ROUTINE agrif_update_lim3 ***
46      !! ** Method  :   Call the hydrostaticupdate pressure at the boundary or the entire domain
47      !!
48      !! ** Action : - Update (u_ice,v_ice) and ice tracers
49      !!----------------------------------------------------------------------
50      INTEGER, INTENT(in) :: kt
51      !!
52      !!----------------------------------------------------------------------
53      !
54      IF( ( Agrif_NbStepint() .NE. (Agrif_irhot()-1) ) .AND. (kt /= 0) )  RETURN  ! do not update if nb of child time steps differ from time refinement
55                                                                                  ! i.e. update only at the parent time step
56
57      Agrif_UseSpecialValueInUpdate = .TRUE.
58      Agrif_SpecialValueFineGrid = -9999.
59# if defined TWO_WAY
60      IF( MOD(nbcline,nbclineupdate) == 0) THEN ! update the whole basin at each nbclineupdate (=nn_cln_update) baroclinic parent time steps
61                                                ! nbcline is incremented (+1) at the end of each parent time step from 0 (1st time step)
62                                                ! clem: j'ai l'impression qu'il y a un decalage de 1 mais selon rachid c ok
63         CALL Agrif_Update_Variable( tra_ice_id , procname = update_tra_ice  )
64         CALL Agrif_Update_Variable( u_ice_id   , procname = update_u_ice    )
65         CALL Agrif_Update_Variable( v_ice_id   , procname = update_v_ice    )
66      ELSE                                      ! update only the boundaries
67                                                ! defined par locupdate
68         CALL Agrif_Update_Variable( tra_ice_id , locupdate=(/0,2/), procname = update_tra_ice  )
69         CALL Agrif_Update_Variable( u_ice_id   , locupdate=(/0,1/), procname = update_u_ice    )
70         CALL Agrif_Update_Variable( v_ice_id   , locupdate=(/0,1/), procname = update_v_ice    )
71      ENDIF
72# endif
73      Agrif_UseSpecialValueInUpdate = .FALSE.
74      !
75   END SUBROUTINE agrif_update_lim3
76
77
78   !!------------------
79   !! Local subroutines
80   !!------------------
81   SUBROUTINE update_tra_ice( ptab, i1, i2, j1, j2, k1, k2, before )
82      !!-----------------------------------------------------------------------
83      !!                        *** ROUTINE update_tra_ice ***
84      !! ** Method  : Compute the mass properties on the fine grid and recover
85      !!              the properties per mass on the coarse grid
86      !!-----------------------------------------------------------------------
87      INTEGER , INTENT(in) :: i1, i2, j1, j2, k1, k2
88      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2), INTENT(inout) :: ptab
89      LOGICAL , INTENT(in) :: before
90      !!
91      INTEGER  :: jk, jl, jm
92      !!-----------------------------------------------------------------------
93      ! clem: it is ok not to multiply by e1 e2 since we conserve tracers here (cf ce qui est fait dans opa).
94      IF( before ) THEN
95         jm = 1
96         DO jl = 1, jpl
97            ptab(:,:,jm) = a_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
98            ptab(:,:,jm) = v_i  (i1:i2,j1:j2,jl) ; jm = jm + 1
99            ptab(:,:,jm) = v_s  (i1:i2,j1:j2,jl) ; jm = jm + 1
100            ptab(:,:,jm) = smv_i(i1:i2,j1:j2,jl) ; jm = jm + 1
101            ptab(:,:,jm) = oa_i (i1:i2,j1:j2,jl) ; jm = jm + 1
102            DO jk = 1, nlay_s
103               ptab(:,:,jm) = e_s(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
104            ENDDO
105            DO jk = 1, nlay_i
106               ptab(:,:,jm) = e_i(i1:i2,j1:j2,jk,jl) ; jm = jm + 1
107            ENDDO
108         ENDDO
109
110         DO jk = k1, k2
111            WHERE( tmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:,jk) = -9999.
112         ENDDO
113                 
114      ELSE
115         jm = 1
116         DO jl = 1, jpl
117            a_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
118            v_i  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
119            v_s  (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
120            smv_i(i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
121            oa_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
122            DO jk = 1, nlay_s
123               e_s(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
124            ENDDO
125            DO jk = 1, nlay_i
126               e_i(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1
127            ENDDO
128         ENDDO
129
130      ENDIF
131      !
132   END SUBROUTINE update_tra_ice
133
134
135   SUBROUTINE update_u_ice( ptab, i1, i2, j1, j2, before )
136      !!-----------------------------------------------------------------------
137      !!                        *** ROUTINE update_u_ice ***
138      !! ** Method  : Update the fluxes and recover the properties (C-grid)
139      !!-----------------------------------------------------------------------
140      INTEGER , INTENT(in) :: i1, i2, j1, j2
141      REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) :: ptab
142      LOGICAL , INTENT(in) :: before
143      !!
144      REAL(wp) :: zrhoy
145      !!-----------------------------------------------------------------------
146      !
147      IF( before ) THEN
148         zrhoy = Agrif_Rhoy()
149         ptab(:,:) = e2u(i1:i2,j1:j2) * u_ice(i1:i2,j1:j2) * zrhoy
150         WHERE( umask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
151      ELSE
152         u_ice(i1:i2,j1:j2) = ptab(:,:) / e2u(i1:i2,j1:j2) * umask(i1:i2,j1:j2,1)
153      ENDIF
154      !
155   END SUBROUTINE update_u_ice
156
157
158   SUBROUTINE update_v_ice( ptab, i1, i2, j1, j2, before )
159      !!-----------------------------------------------------------------------
160      !!                    *** ROUTINE update_v_ice ***
161      !! ** Method  : Update the fluxes and recover the properties (C-grid)
162      !!-----------------------------------------------------------------------
163      INTEGER , INTENT(in) :: i1,i2,j1,j2
164      REAL(wp), DIMENSION(i1:i2,j1:j2),  INTENT(inout) :: ptab
165      LOGICAL , INTENT(in) :: before
166      !!
167      REAL(wp) :: zrhox
168      !!-----------------------------------------------------------------------
169      !
170      IF( before ) THEN
171         zrhox = Agrif_Rhox()
172         ptab(:,:) = e1v(i1:i2,j1:j2) * v_ice(i1:i2,j1:j2) * zrhox
173         WHERE( vmask(i1:i2,j1:j2,1) == 0. )  ptab(:,:) = -9999.
174      ELSE
175         v_ice(i1:i2,j1:j2) = ptab(:,:) / e1v(i1:i2,j1:j2) * vmask(i1:i2,j1:j2,1)
176      ENDIF
177      !
178   END SUBROUTINE update_v_ice
179
180#else
181CONTAINS
182   SUBROUTINE agrif_lim3_update_empty
183      !!---------------------------------------------
184      !!   *** ROUTINE agrif_lim3_update_empty ***
185      !!---------------------------------------------
186      WRITE(*,*)  'agrif_lim3_update : You should not have seen this print! error?'
187   END SUBROUTINE agrif_lim3_update_empty
188#endif
189END MODULE agrif_lim3_update
Note: See TracBrowser for help on using the repository browser.