New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 7158

Last change on this file since 7158 was 7158, checked in by clem, 7 years ago
debug branch
Property svn:keywords set to `Id`
File size: 35.4 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26
27	USE sbc_oce ! Surface boundary condition: ocean fields
28	USE sbc_ice ! Surface boundary condition: ice fields
29	USE sbcblk_core ! Surface boundary condition: CORE bulk
30	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
31	USE sbccpl ! Surface boundary condition: coupled interface
32	USE sbcana ! Surface boundary condition: analytic formulation
33	USE albedo ! ocean & ice albedo
34
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49
50	USE limistate ! LIM initial state
51	USE limthd_sal ! LIM ice thermodynamics: salinity
52
53	USE c1d ! 1D vertical configuration
54	USE lbclnk ! lateral boundary condition - MPP link
55	USE lib_mpp ! MPP library
56	USE wrk_nemo ! work arrays
57	USE timing ! Timing
58	USE iom ! I/O manager library
59	USE in_out_manager ! I/O manager
60	USE prtctl ! Print control
61	USE lib_fortran !
62	USE limctl
63
64	#if defined key_bdy
65	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
66	#endif
67	# if defined key_agrif
68	USE agrif_ice
69	USE agrif_lim3_update
70	USE agrif_lim3_interp
71	# endif
72
73	IMPLICIT NONE
74	PRIVATE
75
76	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
77	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
78
79	!! * Substitutions
80	# include "domzgr_substitute.h90"
81	# include "vectopt_loop_substitute.h90"
82	!!----------------------------------------------------------------------
83	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
84	!! $Id$
85	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
86	!!----------------------------------------------------------------------
87	CONTAINS
88
89	!!======================================================================
90
91	SUBROUTINE sbc_ice_lim( kt, kblk )
92	!!---------------------------------------------------------------------
93	!! * ROUTINE sbc_ice_lim *
94	!!
95	!! ** Purpose : update the ocean surface boundary condition via the
96	!! Louvain la Neuve Sea Ice Model time stepping
97	!!
98	!! ** Method : ice model time stepping
99	!! - call the ice dynamics routine
100	!! - call the ice advection/diffusion routine
101	!! - call the ice thermodynamics routine
102	!! - call the routine that computes mass and
103	!! heat fluxes at the ice/ocean interface
104	!! - save the outputs
105	!! - save the outputs for restart when necessary
106	!!
107	!! ** Action : - time evolution of the LIM sea-ice model
108	!! - update all sbc variables below sea-ice:
109	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
110	!!---------------------------------------------------------------------
111	INTEGER, INTENT(in) :: kt ! ocean time step
112	INTEGER, INTENT(in) :: kblk ! type of bulk (=1 ANALYTIC, =3 CLIO, =4 CORE, =5 COUPLED)
113	!!
114	INTEGER :: jl ! dummy loop index
115	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
116	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
117	!!----------------------------------------------------------------------
118
119	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
120
121	! clem: it is important to initialize agrif_lim3 variables here and not in sbc_lim_init
122	# if defined key_agrif
123	IF( kt == nit000 ) THEN
124	IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim3
125	ENDIF
126	# endif
127
128	!-----------------------!
129	! --- Ice time step --- !
130	!-----------------------!
131	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
132
133	# if defined key_agrif
134	IF( .NOT. Agrif_Root() ) lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
135	# endif
136
137	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
138	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
139	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
140
141	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
142	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
143	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144
145	! Mask sea ice surface temperature (set to rt0 over land)
146	DO jl = 1, jpl
147	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
148	END DO
149	!
150	!------------------------------------------------!
151	! --- Dynamical coupling with the atmosphere --- !
152	!------------------------------------------------!
153	! It provides the following fields:
154	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
155	!-----------------------------------------------------------------
156	SELECT CASE( kblk )
157	CASE( jp_ana ) ; CALL ana_ice_tau ! analytic formulation
158	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
159	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
160	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
161	END SELECT
162
163	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
164	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
165	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
166	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
167	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
168	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
169	ENDIF
170
171	!-------------------------------------------------------!
172	! --- ice dynamics and transport (except in 1D case) ---!
173	!-------------------------------------------------------!
174	numit = numit + nn_fsbc ! Ice model time step
175	!
176	CALL sbc_lim_bef ! Store previous ice values
177	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
178	CALL lim_rst_opn( kt ) ! Open Ice restart file
179	!
180	! --- zap this if no ice dynamics --- !
181	IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
182	!
183	IF( nn_limdyn /= 0 ) THEN ! -- Ice dynamics
184	CALL lim_dyn( kt ) ! rheology
185	ELSE
186	u_ice(:,:) = rn_uice * umask(:,:,1) ! or prescribed velocity
187	v_ice(:,:) = rn_vice * vmask(:,:,1)
188	ENDIF
189	CALL lim_trp( kt ) ! -- Ice transport (Advection/diffusion)
190	IF( nn_limdyn == 2 .AND. nn_monocat /= 2 ) & ! -- Mechanical redistribution (ridging/rafting)
191	& CALL lim_itd_me
192	IF( nn_limdyn == 2 ) CALL lim_update1( kt ) ! -- Corrections
193	!
194	ENDIF
195
196	! ---
197	#if defined key_agrif
198	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
199	#endif
200	#if defined key_bdy
201	IF( ln_limthd ) CALL bdy_ice_lim( kt ) ! -- bdy ice thermo
202	#endif
203
204	! previous lead fraction and ice volume for flux calculations
205	CALL sbc_lim_bef
206	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
207	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
208	!
209	pfrld(:,:) = 1._wp - at_i(:,:)
210	phicif(:,:) = vt_i(:,:)
211
212	!------------------------------------------------------!
213	! --- Thermodynamical coupling with the atmosphere --- !
214	!------------------------------------------------------!
215	! It provides the following fields:
216	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
217	! qla_ice : latent heat flux over ice (T-point) [W/m2]
218	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
219	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
220	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
221	!----------------------------------------------------------------------------------------
222	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
223
224	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
225	SELECT CASE( kblk )
226
227	CASE( jp_ana ) ! analytic formulation
228	CALL ana_ice_flx
229
230	CASE( jp_clio ) ! CLIO bulk formulation
231	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
232	! (alb_ice) is computed within the bulk routine
233	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
234	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
235	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
236
237	CASE( jp_core ) ! CORE bulk formulation
238	! albedo depends on cloud fraction because of non-linear spectral effects
239	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
240	CALL blk_ice_core_flx( t_su, alb_ice )
241	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
242	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
243
244	CASE ( jp_purecpl ) ! Coupled formulation
245	! albedo depends on cloud fraction because of non-linear spectral effects
246	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
247	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
248	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
249
250	END SELECT
251
252	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
253
254	!----------------------------!
255	! --- ice thermodynamics --- !
256	!----------------------------!
257	! --- zap this if no ice thermo --- !
258	IF( ln_limthd ) CALL lim_thd( kt ) ! -- Ice thermodynamics
259	IF( ln_limthd ) CALL lim_update2( kt ) ! -- Corrections
260	! ---
261	# if defined key_agrif
262	IF( .NOT. Agrif_Root() ) CALL agrif_update_lim3( kt )
263	# endif
264	CALL lim_var_glo2eqv ! necessary calls (at least for coupling)
265	CALL lim_var_agg( 2 ) ! necessary calls (at least for coupling)
266	!
267	# if defined key_agrif
268	!! IF( .NOT. Agrif_Root() ) CALL Agrif_ChildGrid_To_ParentGrid() ! clem: should be called at the update frequency only (cf agrif_lim3_update)
269	# endif
270	CALL lim_sbc_flx( kt ) ! -- Update surface ocean mass, heat and salt fluxes
271	# if defined key_agrif
272	!! IF( .NOT. Agrif_Root() ) CALL Agrif_ParentGrid_To_ChildGrid() ! clem: should be called at the update frequency only (cf agrif_lim3_update)
273	# endif
274	IF( ln_limdiahsb ) CALL lim_diahsb( kt ) ! -- Diagnostics and outputs
275	!
276	CALL lim_wri( 1 ) ! -- Ice outputs
277	!
278	IF( kt == nit000 .AND. ln_rstart ) &
279	& CALL iom_close( numrir ) ! close input ice restart file
280	!
281	IF( lrst_ice ) CALL lim_rst_write( kt ) ! -- Ice restart file
282	!
283	IF( ln_limctl ) CALL lim_ctl( kt ) ! alerts in case of model crash
284	!
285	ENDIF ! End sea-ice time step only
286
287	!-------------------------!
288	! --- Ocean time step --- !
289	!-------------------------!
290	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
291	! using before instantaneous surf. currents
292	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
293	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
294	!
295	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
296	!
297	END SUBROUTINE sbc_ice_lim
298
299
300	SUBROUTINE sbc_lim_init
301	!!----------------------------------------------------------------------
302	!! * ROUTINE sbc_lim_init *
303	!!
304	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
305	!!----------------------------------------------------------------------
306	INTEGER :: ierr
307	INTEGER :: ji, jj
308	!!----------------------------------------------------------------------
309	IF(lwp) WRITE(numout,*)
310	IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition'
311	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
312	!
313	! Open the reference and configuration namelist files and namelist output file
314	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
315	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
316	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
317
318	CALL ice_run ! set some ice run parameters
319	!
320	! ! Allocate the ice arrays
321	ierr = ice_alloc () ! ice variables
322	ierr = ierr + sbc_ice_alloc () ! surface forcing
323	ierr = ierr + thd_ice_alloc () ! thermodynamics
324	IF( ln_limdyn ) ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
325	!
326	IF( lk_mpp ) CALL mpp_sum( ierr )
327	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
328	!
329	CALL lim_dyn_init ! set ice dynamics parameters
330	!
331	CALL lim_itd_init ! ice thickness distribution initialization
332	!
333	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
334	!
335	CALL lim_thd_init ! set ice thermodynics parameters
336	!
337	CALL lim_thd_sal_init ! set ice salinity parameters
338	!
339	IF( ln_limdyn ) CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
340	! ! Initial sea-ice state
341	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
342	numit = 0
343	numit = nit000 - 1
344	CALL lim_istate
345	ELSE ! start from a restart file
346	CALL lim_rst_read
347	numit = nit000 - 1
348	ENDIF
349	CALL lim_var_agg(2)
350	CALL lim_var_glo2eqv
351	!
352	CALL lim_sbc_init ! ice surface boundary condition
353	!
354	IF( ln_limdiahsb) CALL lim_diahsb_init ! initialization for diags
355	!
356	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
357	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
358	!
359	DO jj = 1, jpj
360	DO ji = 1, jpi
361	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
362	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
363	ENDIF
364	ENDDO
365	ENDDO
366	!
367	nstart = numit + nn_fsbc
368	nitrun = nitend - nit000 + 1
369	nlast = numit + nitrun
370	!
371	IF( nstock == 0 ) nstock = nlast + 1
372	!
373	!
374	END SUBROUTINE sbc_lim_init
375
376
377	SUBROUTINE ice_run
378	!!-------------------------------------------------------------------
379	!! * ROUTINE ice_run *
380	!!
381	!! ** Purpose : Definition some run parameter for ice model
382	!!
383	!! ** Method : Read the namicerun namelist and check the parameter
384	!! values called at the first timestep (nit000)
385	!!
386	!! ** input : Namelist namicerun
387	!!-------------------------------------------------------------------
388	INTEGER :: ios ! Local integer output status for namelist read
389	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir, &
390	& cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice
391	NAMELIST/namicediag/ ln_limdiachk, ln_limdiahsb, ln_limctl, iiceprt, jiceprt
392	!!-------------------------------------------------------------------
393	!
394	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
395	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
396	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
397
398	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
399	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
400	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
401	IF(lwm) WRITE ( numoni, namicerun )
402	!
403	REWIND( numnam_ice_ref ) ! Namelist namicediag in reference namelist : Parameters for ice
404	READ ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
405	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
406
407	REWIND( numnam_ice_cfg ) ! Namelist namicediag in configuration namelist : Parameters for ice
408	READ ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
409	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
410	IF(lwm) WRITE ( numoni, namicediag )
411	!
412	IF(lwp) THEN ! control print
413	WRITE(numout,*)
414	WRITE(numout,*) 'ice_run : ice share~d parameters for dynamics/advection/thermo of sea-ice'
415	WRITE(numout,*) ' ~~~~~~'
416	WRITE(numout,*) ' number of ice categories = ', jpl
417	WRITE(numout,*) ' number of ice layers = ', nlay_i
418	WRITE(numout,*) ' number of snow layers = ', nlay_s
419	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
420	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
421	WRITE(numout,*) ' Ice thermodynamics (T) or not (F) ln_limthd = ', ln_limthd
422	WRITE(numout,*) ' Ice dynamics (T) or not (F) ln_limdyn = ', ln_limdyn
423	WRITE(numout,*) ' (ln_limdyn=T) Ice dynamics switch nn_limdyn = ', nn_limdyn
424	WRITE(numout,*) ' 2: total'
425	WRITE(numout,*) ' 1: advection only (no diffusion, no ridging/rafting)'
426	WRITE(numout,*) ' 0: advection only (as 1 + prescribed velocity, bypass rheology)'
427	WRITE(numout,*) ' (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0) = ', rn_uice
428	WRITE(numout,*) ' (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0) = ', rn_vice
429	WRITE(numout,*)
430	WRITE(numout,*) '...and ice diagnostics'
431	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
432	WRITE(numout,*) ' Diagnose online heat/mass/salt budget ln_limdiachk = ', ln_limdiachk
433	WRITE(numout,*) ' Output heat/mass/salt budget ln_limdiahsb = ', ln_limdiahsb
434	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_limctl
435	WRITE(numout,*) ' i-index for control prints (ln_limctl=true) = ', iiceprt
436	WRITE(numout,*) ' j-index for control prints (ln_limctl=true) = ', jiceprt
437	ENDIF
438	!
439	! sea-ice timestep and inverse
440	rdt_ice = REAL(nn_fsbc) * rdt
441	r1_rdtice = 1._wp / rdt_ice
442
443	! inverse of nlay_i and nlay_s
444	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
445	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
446	!
447	#if defined key_bdy
448	IF( lwp .AND. ln_limdiachk ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
449	#endif
450	!
451	IF( lwp ) WRITE(numout,*) ' ice timestep rdt_ice = ', rdt_ice
452	!
453	END SUBROUTINE ice_run
454
455
456	SUBROUTINE lim_itd_init
457	!!------------------------------------------------------------------
458	!! * ROUTINE lim_itd_init *
459	!!
460	!! ** Purpose : Initializes the ice thickness distribution
461	!! ** Method : ...
462	!! ** input : Namelist namiceitd
463	!!-------------------------------------------------------------------
464	INTEGER :: ios ! Local integer output status for namelist read
465	NAMELIST/namiceitd/ nn_catbnd, rn_himean
466	!
467	INTEGER :: jl ! dummy loop index
468	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
469	REAL(wp) :: zhmax, znum, zden, zalpha !
470	!!------------------------------------------------------------------
471	!
472	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
473	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
474	905 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
475
476	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
477	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
478	906 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
479	IF(lwm) WRITE ( numoni, namiceitd )
480	!
481	IF(lwp) THEN ! control print
482	WRITE(numout,*)
483	WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
484	WRITE(numout,*) '~~~~~~~~~~~~'
485	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
486	WRITE(numout,*) ' mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
487	ENDIF
488
489	!----------------------------------
490	!- Thickness categories boundaries
491	!----------------------------------
492	hi_max(:) = 0._wp
493
494	SELECT CASE ( nn_catbnd )
495	!----------------------
496	CASE (1) ! tanh function (CICE)
497	!----------------------
498	zc1 = 3._wp / REAL( jpl, wp )
499	zc2 = 10._wp * zc1
500	zc3 = 3._wp
501
502	DO jl = 1, jpl
503	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
504	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
505	END DO
506
507	!----------------------
508	CASE (2) ! h^(-alpha) function
509	!----------------------
510	zalpha = 0.05 ! exponent of the transform function
511
512	zhmax = 3.*rn_himean
513
514	DO jl = 1, jpl
515	znum = jpl * ( zhmax+1 )**zalpha
516	zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
517	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
518	END DO
519
520	END SELECT
521
522	DO jl = 1, jpl
523	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
524	END DO
525
526	! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
527	hi_max(jpl) = 99._wp
528
529	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
530	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
531	!
532	END SUBROUTINE lim_itd_init
533
534
535	SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
536	!!---------------------------------------------------------------------
537	!! * ROUTINE ice_lim_flx *
538	!!
539	!! ** Purpose : update the ice surface boundary condition by averaging and / or
540	!! redistributing fluxes on ice categories
541	!!
542	!! ** Method : average then redistribute
543	!!
544	!! ** Action :
545	!!---------------------------------------------------------------------
546	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
547	! =1 average and redistribute ; =2 redistribute
548	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
549	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
550	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
551	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
552	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
553	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
554	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
555	!
556	INTEGER :: jl ! dummy loop index
557	!
558	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
559	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
560	!
561	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
562	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
563	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
564	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
565	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
566	!!----------------------------------------------------------------------
567
568	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
569	!
570	!
571	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
572	CASE( 0 , 1 )
573	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
574	!
575	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
576	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
577	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
578	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
579	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
580	DO jl = 1, jpl
581	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
582	pdevap_ice(:,:,jl) = z_devap_m(:,:)
583	END DO
584	!
585	DO jl = 1, jpl
586	pqns_ice (:,:,jl) = z_qns_m(:,:)
587	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
588	pevap_ice(:,:,jl) = z_evap_m(:,:)
589	END DO
590	!
591	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
592	END SELECT
593
594	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
595	CASE( 1 , 2 )
596	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
597	!
598	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
599	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
600	DO jl = 1, jpl
601	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
602	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
603	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
604	END DO
605	!
606	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
607	END SELECT
608	!
609	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
610	!
611	END SUBROUTINE ice_lim_flx
612
613	SUBROUTINE sbc_lim_bef
614	!!----------------------------------------------------------------------
615	!! * ROUTINE sbc_lim_bef *
616	!!
617	!! ** purpose : store ice variables at "before" time step
618	!!----------------------------------------------------------------------
619	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
620	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
621	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
622	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
623	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
624	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
625	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
626	u_ice_b(:,:) = u_ice(:,:)
627	v_ice_b(:,:) = v_ice(:,:)
628	at_i_b (:,:) = SUM( a_i_b(:,:,:), dim=3 )
629
630	END SUBROUTINE sbc_lim_bef
631
632	SUBROUTINE sbc_lim_diag0
633	!!----------------------------------------------------------------------
634	!! * ROUTINE sbc_lim_diag0 *
635	!!
636	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
637	!! of the time step
638	!!----------------------------------------------------------------------
639	sfx (:,:) = 0._wp ;
640	sfx_bri(:,:) = 0._wp ; sfx_lam(:,:) = 0._wp
641	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
642	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
643	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
644	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
645
646	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
647	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
648	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
649	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
650	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
651	wfx_spr(:,:) = 0._wp ; wfx_lam(:,:) = 0._wp
652
653	hfx_thd(:,:) = 0._wp ;
654	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
655	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
656	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
657	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
658	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
659	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
660	hfx_err_dif(:,:) = 0._wp
661	wfx_err_sub(:,:) = 0._wp
662
663	afx_tot(:,:) = 0._wp ;
664	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
665
666	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
667	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
668
669	tau_icebfr(:,:) = 0._wp; ! landfast ice param only (clem: important to keep the init here)
670
671	END SUBROUTINE sbc_lim_diag0
672
673
674	FUNCTION fice_cell_ave ( ptab )
675	!!--------------------------------------------------------------------------
676	!! * Compute average over categories, for grid cell (ice covered and free ocean)
677	!!--------------------------------------------------------------------------
678	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
679	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
680	INTEGER :: jl ! Dummy loop index
681
682	fice_cell_ave (:,:) = 0.0_wp
683	DO jl = 1, jpl
684	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
685	END DO
686
687	END FUNCTION fice_cell_ave
688
689
690	FUNCTION fice_ice_ave ( ptab )
691	!!--------------------------------------------------------------------------
692	!! * Compute average over categories, for ice covered part of grid cell
693	!!--------------------------------------------------------------------------
694	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
695	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
696
697	fice_ice_ave (:,:) = 0.0_wp
698	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
699
700	END FUNCTION fice_ice_ave
701
702
703	#else
704	!!----------------------------------------------------------------------
705	!! Default option Dummy module NO LIM 3.0 sea-ice model
706	!!----------------------------------------------------------------------
707	CONTAINS
708	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
709	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
710	END SUBROUTINE sbc_ice_lim
711	SUBROUTINE sbc_lim_init ! Dummy routine
712	END SUBROUTINE sbc_lim_init
713	#endif
714
715	!!======================================================================
716	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: