New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2016/v3_6_CMIP6_ice_diagnostics/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/v3_6_CMIP6_ice_diagnostics/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8158

Last change on this file since 8158 was 8158, checked in by vancop, 7 years ago

SIMIP outputs, phase 2, commit#5
  • Property svn:keywords set to Id
File size: 39.4 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! LIM thermodynamic sea-ice variables
28   USE dom_ice        ! LIM sea-ice domain
29   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
30   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
31   USE limthd_sal     ! LIM: thermodynamics, ice salinity
32   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
33   USE limthd_lac     ! LIM-3 lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! LIM: 1D <==> 2D transformation
36   USE limvar         ! LIM: sea-ice variables
37   USE lbclnk         ! lateral boundary condition - MPP links
38   USE lib_mpp        ! MPP library
39   USE wrk_nemo       ! work arrays
40   USE in_out_manager ! I/O manager
41   USE prtctl         ! Print control
42   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
43   USE timing         ! Timing
44   USE limcons        ! conservation tests
45   USE limctl
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd         ! called by limstp module
51   PUBLIC   lim_thd_init    ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !!
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      INTEGER  :: ii, ij           ! temporary dummy loop index
87      REAL(wp) :: zfric_u, zqld, zqfr
88      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      !
92      !!-------------------------------------------------------------------
93
94      IF( nn_timing == 1 )  CALL timing_start('limthd')
95
96      ! conservation test
97      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
98
99      CALL lim_var_glo2eqv
100      !------------------------------------------------------------------------!
101      ! 1) Initialization of some variables                                    !
102      !------------------------------------------------------------------------!
103      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
104
105      !--------------------
106      ! 1.2) Heat content   
107      !--------------------
108      ! Change the units of heat content; from J/m2 to J/m3
109      DO jl = 1, jpl
110         DO jk = 1, nlay_i
111            DO jj = 1, jpj
112               DO ji = 1, jpi
113                  !0 if no ice and 1 if yes
114                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
115                  !Energy of melting q(S,T) [J.m-3]
116                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
117               END DO
118            END DO
119         END DO
120         DO jk = 1, nlay_s
121            DO jj = 1, jpj
122               DO ji = 1, jpi
123                  !0 if no ice and 1 if yes
124                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
125                  !Energy of melting q(S,T) [J.m-3]
126                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
127               END DO
128            END DO
129         END DO
130      END DO
131
132      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
133      !-----------------------------------------------------------------------------!
134      DO jj = 1, jpj
135         DO ji = 1, jpi
136            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
137            !
138            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
139            !           !  practically no "direct lateral ablation"
140            !           
141            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
142            !           !  temperature and turbulent mixing (McPhee, 1992)
143            !
144            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
145            zqld =  tmask(ji,jj,1) * rdt_ice *  &
146               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
147
148            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
149            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
150
151            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
152            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
153            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
154
155            !-> MV
156            !-> the following line makes hfxtur often crazily negative
157            !-> if sst is warmer than freezing, evt is fine
158            !-> but if sst is super-cooled, fhtur = 0 and zqfr > 0
159            !-> so fhtur becomes - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 )
160            !-> if at_i is small, fhtur can be big
161            !-> an we will impose the ice to give energy to the ocean to absorb all super cooling!
162            !-> makes very high values for small ice concentrations, and grows ice vertically very rapidly
163            !-> eg 5th category in hudson bay
164            !-> should check after 10 years, but within a year fhtur is too negative
165            !-> that may help to build up towers
166            ! could we test to put this energy in zqld
167            ! zqfr_pos kept in fhtur
168            ! zqfr_neg added to zqld
169            ! zqfr_pos = MAX( tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0. )
170            ! zqfr_neg = MIN( tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0. )
171            ! fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_pos * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
172            ! how do we deal with qlead ?
173
174
175            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
176            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
177            !                        the freezing point, so that we do not have SST < T_freeze
178            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
179
180            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
181            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
182
183            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
184            IF( zqld > 0._wp ) THEN
185               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
186               qlead(ji,jj) = 0._wp
187            ELSE
188               fhld (ji,jj) = 0._wp
189            ENDIF
190            !
191            ! -----------------------------------------
192            ! Net heat flux on top of ice-ocean [W.m-2]
193            ! -----------------------------------------
194            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
195
196            ! -----------------------------------------------------------------------------
197            ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
198            ! -----------------------------------------------------------------------------
199            !     First  step here              :  non solar + precip - qlead - qturb
200            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
201            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
202            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
203               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
204               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
205               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
206                                                                                   !    (fhld should be 0 while bott growth)
207         END DO
208      END DO
209
210      !------------------------------------------------------------------------------!
211      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
212      !------------------------------------------------------------------------------!
213
214      DO jl = 1, jpl      !loop over ice categories
215
216         IF( kt == nit000 .AND. lwp ) THEN
217            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
218            WRITE(numout,*) ' ~~~~~~~~'
219         ENDIF
220
221         nbpb = 0
222         DO jj = 1, jpj
223            DO ji = 1, jpi
224               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
225                  nbpb      = nbpb  + 1
226                  npb(nbpb) = (jj - 1) * jpi + ji
227               ENDIF
228            END DO
229         END DO
230
231         ! debug point to follow
232         jiindex_1d = 0
233         IF( ln_icectl ) THEN
234            DO ji = mi0(iiceprt), mi1(iiceprt)
235               DO jj = mj0(jiceprt), mj1(jiceprt)
236                  jiindex_1d = (jj - 1) * jpi + ji
237                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
238               END DO
239            END DO
240         ENDIF
241
242         !------------------------------------------------------------------------------!
243         ! 4) Thermodynamic computation
244         !------------------------------------------------------------------------------!
245
246         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
247
248         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
249
250            !-------------------------!
251            ! --- Move to 1D arrays ---
252            !-------------------------!
253            CALL lim_thd_1d2d( nbpb, jl, 1 )
254
255            !--------------------------------------!
256            ! --- Ice/Snow Temperature profile --- !
257            !--------------------------------------!
258            CALL lim_thd_dif( 1, nbpb )
259
260            !---------------------------------!
261            ! --- Ice/Snow thickness ---      !
262            !---------------------------------!
263            CALL lim_thd_dh( 1, nbpb )   
264
265            ! --- Ice enthalpy remapping --- !
266            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
267                                           
268            !---------------------------------!
269            ! --- Ice salinity ---            !
270            !---------------------------------!
271            CALL lim_thd_sal( 1, nbpb )   
272
273            !---------------------------------!
274            ! --- temperature update ---      !
275            !---------------------------------!
276            CALL lim_thd_temp( 1, nbpb )
277
278            !------------------------------------!
279            ! --- lateral melting if monocat --- !
280            !------------------------------------!
281            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
282               CALL lim_thd_lam( 1, nbpb )
283            END IF
284
285            !-------------------------!
286            ! --- Move to 2D arrays ---
287            !-------------------------!
288            CALL lim_thd_1d2d( nbpb, jl, 2 )
289
290            !
291            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
292         ENDIF
293         !
294      END DO !jl
295
296      !------------------------------------------------------------------------------!
297      ! 5) Global variables, diagnostics
298      !------------------------------------------------------------------------------!
299
300      !------------------------
301      ! Ice heat content             
302      !------------------------
303      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
304      DO jl = 1, jpl
305         DO jk = 1, nlay_i
306            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
307         END DO
308      END DO
309
310      !------------------------
311      ! Snow heat content             
312      !------------------------
313      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
314      DO jl = 1, jpl
315         DO jk = 1, nlay_s
316            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
317         END DO
318      END DO
319 
320      !----------------------------------
321      ! Change thickness to volume
322      !----------------------------------
323      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
324      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
325      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
326
327      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
328      DO jl  = 1, jpl
329         DO jj = 1, jpj
330            DO ji = 1, jpi
331               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
332               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
333            END DO
334         END DO
335      END DO
336
337      CALL lim_var_zapsmall
338
339      !--------------------------------------------
340      ! Diagnostic thermodynamic growth rates
341      !--------------------------------------------
342      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
343
344      IF(ln_ctl) THEN            ! Control print
345         CALL prt_ctl_info(' ')
346         CALL prt_ctl_info(' - Cell values : ')
347         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
348         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
349         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
350         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
351         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
352         DO jl = 1, jpl
353            CALL prt_ctl_info(' ')
354            CALL prt_ctl_info(' - Category : ', ivar1=jl)
355            CALL prt_ctl_info('   ~~~~~~~~~~')
356            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
357            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
358            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
359            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
360            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
361            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
362            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
363            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
364            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
365            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
366            DO jk = 1, nlay_i
367               CALL prt_ctl_info(' ')
368               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
369               CALL prt_ctl_info('   ~~~~~~~')
370               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
371               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
372            END DO
373         END DO
374      ENDIF
375      !
376      !
377      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
378
379      !------------------------------------------------------------------------------|
380      !  6) Transport of ice between thickness categories.                           |
381      !------------------------------------------------------------------------------|
382      ! Given thermodynamic growth rates, transport ice between thickness categories.
383      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
384
385      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
386
387      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
388
389      !------------------------------------------------------------------------------|
390      !  7) Add frazil ice growing in leads.
391      !------------------------------------------------------------------------------|
392      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
393
394      CALL lim_thd_lac
395     
396      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
397
398      ! Control print
399      IF(ln_ctl) THEN
400         CALL lim_var_glo2eqv
401
402         CALL prt_ctl_info(' ')
403         CALL prt_ctl_info(' - Cell values : ')
404         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
405         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
406         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
407         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
408         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
409         DO jl = 1, jpl
410            CALL prt_ctl_info(' ')
411            CALL prt_ctl_info(' - Category : ', ivar1=jl)
412            CALL prt_ctl_info('   ~~~~~~~~~~')
413            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
414            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
415            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
416            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
417            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
418            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
419            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
420            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
421            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
422            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
423            DO jk = 1, nlay_i
424               CALL prt_ctl_info(' ')
425               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
426               CALL prt_ctl_info('   ~~~~~~~')
427               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
428               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
429            END DO
430         END DO
431      ENDIF
432      !
433      IF( nn_timing == 1 )  CALL timing_stop('limthd')
434
435   END SUBROUTINE lim_thd 
436
437 
438   SUBROUTINE lim_thd_temp( kideb, kiut )
439      !!-----------------------------------------------------------------------
440      !!                   ***  ROUTINE lim_thd_temp ***
441      !!                 
442      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
443      !!
444      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
445      !!-------------------------------------------------------------------
446      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
447      !!
448      INTEGER  ::   ji, jk   ! dummy loop indices
449      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
450      !!-------------------------------------------------------------------
451      ! Recover ice temperature
452      DO jk = 1, nlay_i
453         DO ji = kideb, kiut
454            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
455            ! Conversion q(S,T) -> T (second order equation)
456            zaaa          =  cpic
457            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
458            zccc          =  lfus * ( ztmelts - rt0 )
459            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
460            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
461           
462            ! mask temperature
463            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
464            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
465         END DO
466      END DO
467
468   END SUBROUTINE lim_thd_temp
469
470   SUBROUTINE lim_thd_lam( kideb, kiut )
471      !!-----------------------------------------------------------------------
472      !!                   ***  ROUTINE lim_thd_lam ***
473      !!                 
474      !! ** Purpose :   Lateral melting in case monocategory
475      !!                          ( dA = A/2h dh )
476      !!-----------------------------------------------------------------------
477      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
478      INTEGER             ::   ji                 ! dummy loop indices
479      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
480      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
481      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
482
483      DO ji = kideb, kiut
484         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
485         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
486            zvi          = a_i_1d(ji) * ht_i_1d(ji)
487            zvs          = a_i_1d(ji) * ht_s_1d(ji)
488            ! lateral melting = concentration change
489            zhi_bef     = ht_i_1d(ji) - zdh_mel
490            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
491            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
492            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
493            ! adjust thickness
494            ht_i_1d(ji) = zvi / a_i_1d(ji)           
495            ht_s_1d(ji) = zvs / a_i_1d(ji)           
496            ! retrieve total concentration
497            at_i_1d(ji) = a_i_1d(ji)
498         END IF
499      END DO
500     
501   END SUBROUTINE lim_thd_lam
502
503   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
504      !!-----------------------------------------------------------------------
505      !!                   ***  ROUTINE lim_thd_1d2d ***
506      !!                 
507      !! ** Purpose :   move arrays from 1d to 2d and the reverse
508      !!-----------------------------------------------------------------------
509      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
510                                        ! 2= from 1D to 2D
511      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
512      INTEGER, INTENT(in) ::   jl       ! ice cat
513      INTEGER             ::   jk       ! dummy loop indices
514
515      SELECT CASE( kn )
516
517      CASE( 1 )
518
519         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
520         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
521         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
522         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
523         
524         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
525         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
526         DO jk = 1, nlay_s
527            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
528            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
529         END DO
530         DO jk = 1, nlay_i
531            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
532            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
533            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
534         END DO
535         
536         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
537         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
538         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
539         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
540         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
541         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
542         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
543         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
544         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
545         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
546         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
547         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
548         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
549         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
550         
551         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
552         CALL tab_2d_1d( nbpb, wfx_snw_sum_1d(1:nbpb), wfx_snw_sum  , jpi, jpj, npb(1:nbpb) )
553         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
554         CALL tab_2d_1d( nbpb, wfx_snw_sub_1d(1:nbpb), wfx_snw_sub  , jpi, jpj, npb(1:nbpb) )
555         CALL tab_2d_1d( nbpb, wfx_ice_sub_1d(1:nbpb), wfx_ice_sub  , jpi, jpj, npb(1:nbpb) )
556         
557         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
558         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
559         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
560         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
561         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
562         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
563         
564         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
565         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
566         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
567         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
568         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
569         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
570         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
571 
572         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
573         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
574         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
575         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
576         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
577         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
578         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
579         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
580         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
581         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
582         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
583         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
584         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
585
586         ! SIMIP diagnostics
587         CALL tab_2d_1d( nbpb, diag_fc_bo_1d   (1:nbpb), diag_fc_bo  , jpi, jpj, npb(1:nbpb) )
588         CALL tab_2d_1d( nbpb, diag_fc_su_1d   (1:nbpb), diag_fc_su  , jpi, jpj, npb(1:nbpb) )
589
590      CASE( 2 )
591
592         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
593         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
594         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
595         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
596         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
597         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
598         DO jk = 1, nlay_s
599            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
600            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
601         END DO
602         DO jk = 1, nlay_i
603            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
604            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
605            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
606         END DO
607         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
608         
609         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
610         CALL tab_1d_2d( nbpb, wfx_snw_sum   , npb, wfx_snw_sum_1d(1:nbpb),jpi, jpj )
611         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
612         CALL tab_1d_2d( nbpb, wfx_snw_sub   , npb, wfx_snw_sub_1d(1:nbpb), jpi, jpj )
613         CALL tab_1d_2d( nbpb, wfx_ice_sub   , npb, wfx_ice_sub_1d(1:nbpb), jpi, jpj )
614         
615         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
616         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
617         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
618         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
619         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
620         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
621         
622         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
623         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
624         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
625         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
626         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
627         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
628         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
629 
630         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
631         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
632         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
633         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
634         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
635         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
636         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
637         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
638         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
639         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
640         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
641         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
642         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
643         !
644         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
645         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
646
647         ! SIMIP diagnostics         
648         CALL tab_1d_2d( nbpb, t_si(:,:,jl)   , npb, t_si_1d    (1:nbpb)     , jpi, jpj )
649         CALL tab_1d_2d( nbpb, diag_fc_bo     , npb, diag_fc_bo_1d(1:nbpb)   , jpi, jpj )
650         CALL tab_1d_2d( nbpb, diag_fc_su     , npb, diag_fc_su_1d(1:nbpb)   , jpi, jpj )
651      END SELECT
652
653   END SUBROUTINE lim_thd_1d2d
654
655
656   SUBROUTINE lim_thd_init
657      !!-----------------------------------------------------------------------
658      !!                   ***  ROUTINE lim_thd_init ***
659      !!                 
660      !! ** Purpose :   Physical constants and parameters linked to the ice
661      !!              thermodynamics
662      !!
663      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
664      !!              parameter values called at the first timestep (nit000)
665      !!
666      !! ** input   :   Namelist namicether
667      !!-------------------------------------------------------------------
668      INTEGER  ::   ios                 ! Local integer output status for namelist read
669      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
670         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,         &
671         &                rn_cdsn, nn_monocat, ln_it_qnsice
672      !!-------------------------------------------------------------------
673      !
674      IF(lwp) THEN
675         WRITE(numout,*)
676         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
677         WRITE(numout,*) '~~~~~~~'
678      ENDIF
679      !
680      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
681      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
682901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
683
684      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
685      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
686902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
687      IF(lwm) WRITE ( numoni, namicethd )
688      !
689      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
690         nn_monocat = 0
691         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
692      ENDIF
693
694      !
695      IF(lwp) THEN                          ! control print
696         WRITE(numout,*)
697         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
698         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
699         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
700         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
701         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
702         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
703         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
704         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
705         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
706         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
707         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
708         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
709         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
710         WRITE(numout,*)'      thermal conductivity of the snow                        rn_cdsn      = ', rn_cdsn
711         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
712         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
713         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
714      ENDIF
715      !
716   END SUBROUTINE lim_thd_init
717
718#else
719   !!----------------------------------------------------------------------
720   !!   Default option         Dummy module          NO  LIM3 sea-ice model
721   !!----------------------------------------------------------------------
722#endif
723
724   !!======================================================================
725END MODULE limthd
Note: See TracBrowser for help on using the repository browser.