New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp.F90 in branches/2016/v3_6_CMIP6_ice_diagnostics/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/v3_6_CMIP6_ice_diagnostics/NEMOGCM/NEMO/LIM_SRC_3/limtrp.F90 @ 8151

Last change on this file since 8151 was 8150, checked in by vancop, 7 years ago

SIMIP outputs, phase 2
  • Property svn:keywords set to Id
File size: 28.6 KB
Line 
1MODULE limtrp
2   !!======================================================================
3   !!                       ***  MODULE limtrp   ***
4   !! LIM transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History : LIM-2 ! 2000-01 (M.A. Morales Maqueda, H. Goosse, and T. Fichefet)  Original code
7   !!            3.0  ! 2005-11 (M. Vancoppenolle)   Multi-layer sea ice, salinity variations
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!----------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_trp      : advection/diffusion process of sea ice
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constant
17   USE dom_oce        ! ocean domain
18   USE sbc_oce        ! ocean surface boundary condition
19   USE dom_ice        ! ice domain
20   USE ice            ! ice variables
21   USE limadv         ! ice advection
22   USE limhdf         ! ice horizontal diffusion
23   USE limvar         !
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31   USE timing         ! Timing
32   USE limcons        ! conservation tests
33   USE limctl         ! control prints
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   lim_trp    ! called by sbcice_lim
39
40   INTEGER  ::   ncfl                 ! number of ice time step with CFL>1/2 
41
42   !! * Substitution
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE lim_trp( kt ) 
52      !!-------------------------------------------------------------------
53      !!                   ***  ROUTINE lim_trp ***
54      !!                   
55      !! ** purpose : advection/diffusion process of sea ice
56      !!
57      !! ** method  : variables included in the process are scalar,   
58      !!     other values are considered as second order.
59      !!     For advection, a second order Prather scheme is used. 
60      !!
61      !! ** action :
62      !!---------------------------------------------------------------------
63      INTEGER, INTENT(in) ::   kt           ! number of iteration
64      !
65      INTEGER  ::   ji, jj, jk, jm , jl, jt      ! dummy loop indices
66      INTEGER  ::   initad                  ! number of sub-timestep for the advection
67      REAL(wp) ::   zcfl , zusnit           !   -      -
68      CHARACTER(len=80) ::   cltmp
69      !
70      REAL(wp), POINTER, DIMENSION(:,:)      ::   zsm
71      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   z0ice, z0snw, z0ai, z0es , z0smi , z0oi
72      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   z0opw
73      REAL(wp), POINTER, DIMENSION(:,:,:,:)  ::   z0ei
74      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   zviold, zvsold, zsmvold  ! old ice volume...
75      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   zhimax                   ! old ice thickness
76      REAL(wp), POINTER, DIMENSION(:,:)      ::   zatold, zeiold, zesold   ! old concentration, enthalpies
77      REAL(wp), POINTER, DIMENSION(:,:,:)             ::   zhdfptab
78      REAL(wp) ::    zdv, zvi, zvs, zsmv, zes, zei
79      REAL(wp) ::    zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b
80      !!---------------------------------------------------------------------
81      INTEGER                                ::  ihdf_vars  = 6  !!Number of variables in which we apply horizontal diffusion
82                                                                   !!  inside limtrp for each ice category , not counting the
83                                                                   !!  variables corresponding to ice_layers
84      !!---------------------------------------------------------------------
85      IF( nn_timing == 1 )  CALL timing_start('limtrp')
86
87      CALL wrk_alloc( jpi,jpj,            zsm, zatold, zeiold, zesold )
88      CALL wrk_alloc( jpi,jpj,jpl,        z0ice, z0snw, z0ai, z0es , z0smi , z0oi )
89      CALL wrk_alloc( jpi,jpj,1,          z0opw )
90      CALL wrk_alloc( jpi,jpj,nlay_i,jpl, z0ei )
91      CALL wrk_alloc( jpi,jpj,jpl,        zhimax, zviold, zvsold, zsmvold )
92      CALL wrk_alloc( jpi,jpj,jpl*(ihdf_vars + nlay_i)+1,zhdfptab)
93
94      IF( numit == nstart .AND. lwp ) THEN
95         WRITE(numout,*)
96         IF( ln_limdyn ) THEN   ;   WRITE(numout,*) 'lim_trp : Ice transport '
97         ELSE                   ;   WRITE(numout,*) 'lim_trp : No ice advection as ln_limdyn = ', ln_limdyn
98         ENDIF
99         WRITE(numout,*) '~~~~~~~~~~~~'
100         ncfl = 0                ! nb of time step with CFL > 1/2
101      ENDIF
102
103      zsm(:,:) = e12t(:,:)
104
105      ! SIMIP diags
106      diag_dmtx_dyn(:,:) = 0._wp ; diag_dmty_dyn(:,:) = 0._wp
107     
108      !                             !-------------------------------------!
109      IF( ln_limdyn ) THEN          !   Advection of sea ice properties   !
110         !                          !-------------------------------------!
111
112         ! conservation test
113         IF( ln_limdiahsb )   CALL lim_cons_hsm(0, 'limtrp', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
114
115         ! mass and salt flux init
116         zviold(:,:,:)  = v_i(:,:,:)
117         zvsold(:,:,:)  = v_s(:,:,:)
118         zsmvold(:,:,:) = smv_i(:,:,:)
119         zeiold(:,:)    = SUM( SUM( e_i(:,:,1:nlay_i,:), dim=4 ), dim=3 ) 
120         zesold(:,:)    = SUM( SUM( e_s(:,:,1:nlay_s,:), dim=4 ), dim=3 ) 
121
122         !--- Thickness correction init. -------------------------------
123         zatold(:,:) = SUM( a_i(:,:,:), dim=3 )
124         DO jl = 1, jpl
125            DO jj = 1, jpj
126               DO ji = 1, jpi
127                  rswitch          = MAX( 0._wp , SIGN( 1._wp, a_i(ji,jj,jl) - epsi20 ) )
128                  ht_i  (ji,jj,jl) = v_i (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi20 ) * rswitch
129                  ht_s  (ji,jj,jl) = v_s (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi20 ) * rswitch
130               END DO
131            END DO
132         END DO
133         !---------------------------------------------------------------------
134         ! Record max of the surrounding ice thicknesses for correction
135         ! in case advection creates ice too thick.
136         !---------------------------------------------------------------------
137         zhimax(:,:,:) = ht_i(:,:,:) + ht_s(:,:,:)
138         DO jl = 1, jpl
139            DO jj = 2, jpjm1
140               DO ji = 2, jpim1
141                  zhimax(ji,jj,jl) = MAXVAL( ht_i(ji-1:ji+1,jj-1:jj+1,jl) + ht_s(ji-1:ji+1,jj-1:jj+1,jl) )
142               END DO
143            END DO
144            CALL lbc_lnk(zhimax(:,:,jl),'T',1.)
145         END DO
146         
147         !=============================!
148         !==      Prather scheme     ==!
149         !=============================!
150
151         ! If ice drift field is too fast, use an appropriate time step for advection.         
152         zcfl  =            MAXVAL( ABS( u_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )         ! CFL test for stability
153         zcfl  = MAX( zcfl, MAXVAL( ABS( v_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
154         IF(lk_mpp )   CALL mpp_max( zcfl )
155
156         IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
157         ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
158         ENDIF
159
160         IF( zcfl > 0.5_wp .AND. lwp )   ncfl = ncfl + 1
161!!         IF( lwp ) THEN
162!!            IF( ncfl > 0 ) THEN   
163!!               WRITE(cltmp,'(i6.1)') ncfl
164!!               CALL ctl_warn( 'lim_trp: ncfl= ', TRIM(cltmp), 'advective ice time-step using a split in sub-time-step ')
165!!            ELSE
166!!            !  WRITE(numout,*) 'lim_trp : CFL criterion for ice advection is always smaller than 1/2 '
167!!            ENDIF
168!!         ENDIF
169
170         !-------------------------
171         ! transported fields                                       
172         !-------------------------
173         z0opw(:,:,1) = ato_i(:,:) * e12t(:,:)             ! Open water area
174         DO jl = 1, jpl
175            z0snw (:,:,jl)  = v_s  (:,:,jl) * e12t(:,:)    ! Snow volume
176            z0ice(:,:,jl)   = v_i  (:,:,jl) * e12t(:,:)    ! Ice  volume
177            z0ai  (:,:,jl)  = a_i  (:,:,jl) * e12t(:,:)    ! Ice area
178            z0smi (:,:,jl)  = smv_i(:,:,jl) * e12t(:,:)    ! Salt content
179            z0oi (:,:,jl)   = oa_i (:,:,jl) * e12t(:,:)    ! Age content
180            z0es (:,:,jl)   = e_s  (:,:,1,jl) * e12t(:,:)  ! Snow heat content
181           DO jk = 1, nlay_i
182               z0ei  (:,:,jk,jl) = e_i  (:,:,jk,jl) * e12t(:,:) ! Ice  heat content
183            END DO
184         END DO
185
186
187         IF( MOD( ( kt - 1) / nn_fsbc , 2 ) == 0 ) THEN       !==  odd ice time step:  adv_x then adv_y  ==!
188            DO jt = 1, initad
189               CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0opw (:,:,1), sxopw(:,:),   &             !--- ice open water area
190                  &                                       sxxopw(:,:)  , syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
191               CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0opw (:,:,1), sxopw(:,:),   &
192                  &                                       sxxopw(:,:)  , syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
193               DO jl = 1, jpl
194                  ! SIMIP mass transport diags
195                  diag_dmtx_dyn(:,:) = diag_dmtx_dyn(:,:) - ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
196                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0ice (:,:,jl), sxice(:,:,jl),   &    !--- ice volume  ---
197                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
198                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0snw (:,:,jl), sxsn (:,:,jl),   &    !--- snow volume  ---
199                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
200                  diag_dmtx_dyn(:,:) = diag_dmtx_dyn(:,:) + ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
201
202                  diag_dmty_dyn(:,:) = diag_dmty_dyn(:,:) - ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
203                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0ice (:,:,jl), sxice(:,:,jl),   &    !--- ice volume
204                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
205                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0snw (:,:,jl), sxsn (:,:,jl),   &    !--- snow volume
206                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
207                  diag_dmty_dyn(:,:) = diag_dmty_dyn(:,:) + ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
208                  ! END SIMIP mass transport diags
209                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0smi (:,:,jl), sxsal(:,:,jl),   &    !--- ice salinity ---
210                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
211                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0smi (:,:,jl), sxsal(:,:,jl),   &
212                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
213                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0oi  (:,:,jl), sxage(:,:,jl),   &    !--- ice age      ---     
214                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
215                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0oi  (:,:,jl), sxage(:,:,jl),   &
216                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
217                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0ai  (:,:,jl), sxa  (:,:,jl),   &    !--- ice concentrations ---
218                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
219                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0ai  (:,:,jl), sxa  (:,:,jl),   & 
220                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
221                  CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0es  (:,:,jl), sxc0 (:,:,jl),   &    !--- snow heat contents ---
222                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
223                  CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0es  (:,:,jl), sxc0 (:,:,jl),   &
224                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
225                  DO jk = 1, nlay_i                                                                !--- ice heat contents ---
226                     CALL lim_adv_x( zusnit, u_ice, 1._wp, zsm, z0ei(:,:,jk,jl), sxe (:,:,jk,jl),   & 
227                        &                                       sxxe(:,:,jk,jl), sye (:,:,jk,jl),   &
228                        &                                       syye(:,:,jk,jl), sxye(:,:,jk,jl) )
229                     CALL lim_adv_y( zusnit, v_ice, 0._wp, zsm, z0ei(:,:,jk,jl), sxe (:,:,jk,jl),   & 
230                        &                                       sxxe(:,:,jk,jl), sye (:,:,jk,jl),   &
231                        &                                       syye(:,:,jk,jl), sxye(:,:,jk,jl) )
232                  END DO
233               END DO
234            END DO
235         ELSE
236            DO jt = 1, initad
237               CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0opw (:,:,1), sxopw(:,:),   &             !--- ice open water area
238                  &                                       sxxopw(:,:)  , syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
239               CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0opw (:,:,1), sxopw(:,:),   &
240                  &                                       sxxopw(:,:)  , syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
241               DO jl = 1, jpl
242                  ! SIMIP mass transport diags
243                  diag_dmty_dyn(:,:) = diag_dmty_dyn(:,:) - ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
244                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0ice (:,:,jl), sxice(:,:,jl),   &    !--- ice volume  ---
245                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
246                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0snw (:,:,jl), sxsn (:,:,jl),   &    !--- snow volume  ---
247                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
248                  diag_dmty_dyn(:,:) = diag_dmty_dyn(:,:) + ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
249
250                  diag_dmtx_dyn(:,:) = diag_dmtx_dyn(:,:) - ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
251                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0ice (:,:,jl), sxice(:,:,jl),   &
252                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
253                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0snw (:,:,jl), sxsn (:,:,jl),   &
254                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
255                  diag_dmtx_dyn(:,:) = diag_dmtx_dyn(:,:) + ( rhoic * z0ice(:,:,jl) + rhosn * z0snw(:,:,jl) )
256                  ! END SIMIP mass transport diags
257
258                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0smi (:,:,jl), sxsal(:,:,jl),   &    !--- ice salinity ---
259                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
260                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0smi (:,:,jl), sxsal(:,:,jl),   &
261                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
262                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0oi  (:,:,jl), sxage(:,:,jl),   &   !--- ice age      ---
263                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
264                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0oi  (:,:,jl), sxage(:,:,jl),   &
265                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
266                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0ai  (:,:,jl), sxa  (:,:,jl),   &   !--- ice concentrations ---
267                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
268                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0ai  (:,:,jl), sxa  (:,:,jl),   &
269                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
270                  CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0es  (:,:,jl), sxc0 (:,:,jl),   &  !--- snow heat contents ---
271                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
272                  CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0es  (:,:,jl), sxc0 (:,:,jl),   &
273                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
274                  DO jk = 1, nlay_i                                                           !--- ice heat contents ---
275                     CALL lim_adv_y( zusnit, v_ice, 1._wp, zsm, z0ei(:,:,jk,jl), sxe (:,:,jk,jl),   & 
276                        &                                       sxxe(:,:,jk,jl), sye (:,:,jk,jl),   &
277                        &                                       syye(:,:,jk,jl), sxye(:,:,jk,jl) )
278                     CALL lim_adv_x( zusnit, u_ice, 0._wp, zsm, z0ei(:,:,jk,jl), sxe (:,:,jk,jl),   & 
279                        &                                       sxxe(:,:,jk,jl), sye (:,:,jk,jl),   &
280                        &                                       syye(:,:,jk,jl), sxye(:,:,jk,jl) )
281                  END DO
282               END DO
283            END DO
284         ENDIF
285
286         ! SIMIP diags
287         diag_dmtx_dyn(:,:) = diag_dmtx_dyn(:,:) / rdt_ice 
288         diag_dmty_dyn(:,:) = diag_dmty_dyn(:,:) / rdt_ice
289
290         !-------------------------------------------
291         ! Recover the properties from their contents
292         !-------------------------------------------
293         ato_i(:,:) = z0opw(:,:,1) * r1_e12t(:,:)
294         DO jl = 1, jpl
295            v_i  (:,:,jl)   = z0ice(:,:,jl) * r1_e12t(:,:)
296            v_s  (:,:,jl)   = z0snw(:,:,jl) * r1_e12t(:,:)
297            smv_i(:,:,jl)   = z0smi(:,:,jl) * r1_e12t(:,:)
298            oa_i (:,:,jl)   = z0oi (:,:,jl) * r1_e12t(:,:)
299            a_i  (:,:,jl)   = z0ai (:,:,jl) * r1_e12t(:,:)
300            e_s  (:,:,1,jl) = z0es (:,:,jl) * r1_e12t(:,:)
301            DO jk = 1, nlay_i
302               e_i(:,:,jk,jl) = z0ei(:,:,jk,jl) * r1_e12t(:,:)
303            END DO
304         END DO
305
306         at_i(:,:) = a_i(:,:,1)      ! total ice fraction
307         DO jl = 2, jpl
308            at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
309         END DO
310
311         !------------------------------------------------------------------------------!
312         ! Diffusion of Ice fields                 
313         !------------------------------------------------------------------------------!
314         IF( nn_ahi0 /= -1 ) THEN
315
316            ! --- Prepare diffusion for variables with categories --- !
317            !     mask eddy diffusivity coefficient at ocean U- and V-points
318            jm=1
319            DO jl = 1, jpl
320               DO jj = 1, jpjm1                 ! NB: has not to be defined on jpj line and jpi row
321                  DO ji = 1 , fs_jpim1   ! vector opt.
322                     pahu3D(ji,jj,jl) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -a_i(ji  ,jj,  jl ) ) ) )   &
323                        &                * ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -a_i(ji+1,jj,  jl ) ) ) ) * ahiu(ji,jj)
324                     pahv3D(ji,jj,jl) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -a_i(ji,  jj,  jl ) ) ) )   &
325                        &                * ( 1._wp - MAX( 0._wp, SIGN( 1._wp,- a_i(ji,  jj+1,jl ) ) ) ) * ahiv(ji,jj)
326                  END DO
327               END DO
328               
329               zhdfptab(:,:,jm)= a_i  (:,:,  jl); jm = jm + 1   
330               zhdfptab(:,:,jm)= v_i  (:,:,  jl); jm = jm + 1
331               zhdfptab(:,:,jm)= v_s  (:,:,  jl); jm = jm + 1 
332               zhdfptab(:,:,jm)= smv_i(:,:,  jl); jm = jm + 1
333               zhdfptab(:,:,jm)= oa_i (:,:,  jl); jm = jm + 1
334               zhdfptab(:,:,jm)= e_s  (:,:,1,jl); jm = jm + 1
335               ! Sample of adding more variables to apply lim_hdf (ihdf_vars must be increased)
336               !   zhdfptab(:,:,jm) = variable_1 (:,:,1,jl); jm = jm + 1 
337               !   zhdfptab(:,:,jm) = variable_2 (:,:,1,jl); jm = jm + 1
338               DO jk = 1, nlay_i
339                  zhdfptab(:,:,jm)=e_i(:,:,jk,jl); jm= jm+1
340               END DO
341            END DO
342            !
343            ! --- Prepare diffusion for open water area --- !
344            !     mask eddy diffusivity coefficient at ocean U- and V-points
345            DO jj = 1, jpjm1                    ! NB: has not to be defined on jpj line and jpi row
346               DO ji = 1 , fs_jpim1   ! vector opt.
347                  pahu3D(ji,jj,jpl+1) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -at_i(ji  ,jj) ) ) )   &
348                     &                * ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -at_i(ji+1,jj) ) ) ) * ahiu(ji,jj)
349                  pahv3D(ji,jj,jpl+1) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -at_i(ji,jj  ) ) ) )   &
350                     &                * ( 1._wp - MAX( 0._wp, SIGN( 1._wp,- at_i(ji,jj+1) ) ) ) * ahiv(ji,jj)
351               END DO
352            END DO
353            !
354            zhdfptab(:,:,jm)= ato_i  (:,:);
355
356            ! --- Apply diffusion --- !
357            CALL lim_hdf( zhdfptab, ihdf_vars, jpl, nlay_i) 
358           
359            ! --- Recover properties --- !
360            jm=1
361            DO jl = 1, jpl
362               a_i  (:,:,  jl) = zhdfptab(:,:,jm); jm = jm + 1     
363               v_i  (:,:,  jl) = zhdfptab(:,:,jm); jm = jm + 1 
364               v_s  (:,:,  jl) = zhdfptab(:,:,jm); jm = jm + 1 
365               smv_i(:,:,  jl) = zhdfptab(:,:,jm); jm = jm + 1 
366               oa_i (:,:,  jl) = zhdfptab(:,:,jm); jm = jm + 1 
367               e_s  (:,:,1,jl) = zhdfptab(:,:,jm); jm = jm + 1 
368               ! Sample of adding more variables to apply lim_hdf---------
369               !   variable_1  (:,:,1,jl) = zhdfptab(:,:, jm  ) ; jm + 1
370               !   variable_2  (:,:,1,jl) = zhdfptab(:,:, jm  ) ; jm + 1
371               DO jk = 1, nlay_i
372                  e_i(:,:,jk,jl) = zhdfptab(:,:,jm);jm= jm + 1 
373               END DO
374            END DO
375            ato_i  (:,:) = zhdfptab(:,:,jm)
376
377         ENDIF
378         
379         ! --- diags ---
380         DO jj = 1, jpj
381            DO ji = 1, jpi
382               diag_trp_ei(ji,jj) = ( SUM( e_i(ji,jj,1:nlay_i,:) ) - zeiold(ji,jj) ) * r1_rdtice
383               diag_trp_es(ji,jj) = ( SUM( e_s(ji,jj,1:nlay_s,:) ) - zesold(ji,jj) ) * r1_rdtice
384
385               diag_trp_vi (ji,jj) = SUM(   v_i(ji,jj,:) -  zviold(ji,jj,:) ) * r1_rdtice
386               diag_trp_vs (ji,jj) = SUM(   v_s(ji,jj,:) -  zvsold(ji,jj,:) ) * r1_rdtice
387               diag_trp_smv(ji,jj) = SUM( smv_i(ji,jj,:) - zsmvold(ji,jj,:) ) * r1_rdtice
388
389               ! SIMIP diagnostics
390               diag_dms_dyn(ji,jj) = diag_dms_dyn(ji,jj) + rhosn * diag_trp_vs(ji,jj)
391               diag_dmi_dyn(ji,jj) = diag_dmi_dyn(ji,jj) + rhoic * diag_trp_vi(ji,jj)
392            END DO
393         END DO
394
395         ! zap small areas
396         CALL lim_var_zapsmall
397
398         !--- Thickness correction in case too high --------------------------------------------------------
399         DO jl = 1, jpl
400            DO jj = 1, jpj
401               DO ji = 1, jpi
402
403                  IF ( v_i(ji,jj,jl) > 0._wp ) THEN
404
405                     rswitch          = MAX( 0._wp , SIGN( 1._wp, a_i(ji,jj,jl) - epsi20 ) )
406                     ht_i  (ji,jj,jl) = v_i (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi20 ) * rswitch
407                     ht_s  (ji,jj,jl) = v_s (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi20 ) * rswitch
408                     
409                     zvi  = v_i  (ji,jj,jl)
410                     zvs  = v_s  (ji,jj,jl)
411                     zsmv = smv_i(ji,jj,jl)
412                     zes  = e_s  (ji,jj,1,jl)
413                     zei  = SUM( e_i(ji,jj,1:nlay_i,jl) )
414
415                     zdv  = v_i(ji,jj,jl) + v_s(ji,jj,jl) - zviold(ji,jj,jl) - zvsold(ji,jj,jl) 
416
417                     IF ( ( zdv >  0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) .AND. zatold(ji,jj) < 0.80 ) .OR. &
418                        & ( zdv <= 0.0 .AND. (ht_i(ji,jj,jl)+ht_s(ji,jj,jl)) > zhimax(ji,jj,jl) ) ) THEN
419
420                        rswitch        = MAX( 0._wp, SIGN( 1._wp, zhimax(ji,jj,jl) - epsi20 ) )
421                        a_i(ji,jj,jl)  = rswitch * ( v_i(ji,jj,jl) + v_s(ji,jj,jl) ) / MAX( zhimax(ji,jj,jl), epsi20 )
422
423                        ! small correction due to *rswitch for a_i
424                        v_i  (ji,jj,jl)        = rswitch * v_i  (ji,jj,jl)
425                        v_s  (ji,jj,jl)        = rswitch * v_s  (ji,jj,jl)
426                        smv_i(ji,jj,jl)        = rswitch * smv_i(ji,jj,jl)
427                        e_s(ji,jj,1,jl)        = rswitch * e_s(ji,jj,1,jl)
428                        e_i(ji,jj,1:nlay_i,jl) = rswitch * e_i(ji,jj,1:nlay_i,jl)
429
430                        ! Update mass fluxes
431                        wfx_res(ji,jj) = wfx_res(ji,jj) - ( v_i(ji,jj,jl) - zvi ) * rhoic * r1_rdtice
432                        wfx_snw(ji,jj) = wfx_snw(ji,jj) - ( v_s(ji,jj,jl) - zvs ) * rhosn * r1_rdtice
433                        sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsmv ) * rhoic * r1_rdtice 
434                        hfx_res(ji,jj) = hfx_res(ji,jj) + ( e_s(ji,jj,1,jl) - zes ) * r1_rdtice ! W.m-2 <0
435                        hfx_res(ji,jj) = hfx_res(ji,jj) + ( SUM( e_i(ji,jj,1:nlay_i,jl) ) - zei ) * r1_rdtice ! W.m-2 <0
436
437                     ENDIF
438
439                  ENDIF
440
441               END DO
442            END DO
443         END DO
444         ! -------------------------------------------------
445         
446         !--------------------------------------
447         ! Impose a_i < amax in mono-category
448         !--------------------------------------
449         !
450         IF ( ( nn_monocat == 2 ) .AND. ( jpl == 1 ) ) THEN ! simple conservative piling, comparable with LIM2
451            DO jj = 1, jpj
452               DO ji = 1, jpi
453                  a_i(ji,jj,1)  = MIN( a_i(ji,jj,1), rn_amax_2d(ji,jj) )
454               END DO
455            END DO
456         ENDIF
457
458         ! --- agglomerate variables -----------------
459         vt_i (:,:) = 0._wp
460         vt_s (:,:) = 0._wp
461         at_i (:,:) = 0._wp
462         DO jl = 1, jpl
463            DO jj = 1, jpj
464               DO ji = 1, jpi
465                  vt_i(ji,jj) = vt_i(ji,jj) + v_i(ji,jj,jl)
466                  vt_s(ji,jj) = vt_s(ji,jj) + v_s(ji,jj,jl)
467                  at_i(ji,jj) = at_i(ji,jj) + a_i(ji,jj,jl)
468               END DO
469            END DO
470         END DO
471
472         ! --- open water = 1 if at_i=0 --------------------------------
473         DO jj = 1, jpj
474            DO ji = 1, jpi
475               rswitch      = MAX( 0._wp , SIGN( 1._wp, - at_i(ji,jj) ) )
476               ato_i(ji,jj) = rswitch + (1._wp - rswitch ) * ato_i(ji,jj)
477            END DO
478         END DO     
479
480         ! conservation test
481         IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limtrp', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
482
483      ENDIF
484
485      ! -------------------------------------------------
486      ! control prints
487      ! -------------------------------------------------
488      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt,-1, ' - ice dyn & trp - ' )
489      !
490      CALL wrk_dealloc( jpi,jpj,            zsm, zatold, zeiold, zesold )
491      CALL wrk_dealloc( jpi,jpj,jpl,        z0ice, z0snw, z0ai, z0es , z0smi , z0oi )
492      CALL wrk_dealloc( jpi,jpj,1,          z0opw )
493      CALL wrk_dealloc( jpi,jpj,nlay_i,jpl, z0ei )
494      CALL wrk_dealloc( jpi,jpj,jpl,        zviold, zvsold, zhimax, zsmvold )
495      CALL wrk_dealloc( jpi,jpj,jpl*(ihdf_vars+nlay_i)+1,zhdfptab)
496      !
497      IF( nn_timing == 1 )  CALL timing_stop('limtrp')
498
499   END SUBROUTINE lim_trp
500
501#else
502   !!----------------------------------------------------------------------
503   !!   Default option         Empty Module                No sea-ice model
504   !!----------------------------------------------------------------------
505CONTAINS
506   SUBROUTINE lim_trp        ! Empty routine
507   END SUBROUTINE lim_trp
508#endif
509   !!======================================================================
510END MODULE limtrp
511
Note: See TracBrowser for help on using the repository browser.