| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and active tracers |
|---|
| 18 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 19 | USE dom_oce ! ocean space domain variables |
|---|
| 20 | USE phycst ! physical constant |
|---|
| 21 | USE eosbn2 ! Equation Of State |
|---|
| 22 | USE sbcmod ! ln_rnf |
|---|
| 23 | USE sbcrnf ! River runoff |
|---|
| 24 | USE sbcisf ! Ice shelf |
|---|
| 25 | USE iscplini ! Ice sheet coupling |
|---|
| 26 | USE traqsr ! solar radiation penetration |
|---|
| 27 | USE trd_oce ! trends: ocean variables |
|---|
| 28 | USE trdtra ! trends manager: tracers |
|---|
| 29 | #if defined key_asminc |
|---|
| 30 | USE asminc ! Assimilation increment |
|---|
| 31 | #endif |
|---|
| 32 | ! |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE prtctl ! Print control |
|---|
| 35 | USE iom ! xIOS server |
|---|
| 36 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 37 | USE wrk_nemo ! Memory Allocation |
|---|
| 38 | USE timing ! Timing |
|---|
| 39 | USE wet_dry, ONLY : ll_wd, rn_wdmin1, r_rn_wdmin1 ! Wetting and drying |
|---|
| 40 | |
|---|
| 41 | IMPLICIT NONE |
|---|
| 42 | PRIVATE |
|---|
| 43 | |
|---|
| 44 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 45 | |
|---|
| 46 | !! * Substitutions |
|---|
| 47 | # include "vectopt_loop_substitute.h90" |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 50 | !! $Id$ |
|---|
| 51 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | CONTAINS |
|---|
| 54 | |
|---|
| 55 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! *** ROUTINE tra_sbc *** |
|---|
| 58 | !! |
|---|
| 59 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 60 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 61 | !! and add it to the general trend of tracer equations. |
|---|
| 62 | !! |
|---|
| 63 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 64 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 65 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 66 | !! The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe, |
|---|
| 67 | !! they are simply added to the tracer trend (tsa). |
|---|
| 68 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 69 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 70 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 71 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 72 | !! |
|---|
| 73 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 74 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 77 | ! |
|---|
| 78 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 79 | INTEGER :: ikt, ikb ! local integers |
|---|
| 80 | REAL(wp) :: zfact, z1_e3t, zdep, ztim ! local scalar |
|---|
| 81 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt, ztrds |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | ! |
|---|
| 84 | IF( nn_timing == 1 ) CALL timing_start('tra_sbc') |
|---|
| 85 | ! |
|---|
| 86 | IF( kt == nit000 ) THEN |
|---|
| 87 | IF(lwp) WRITE(numout,*) |
|---|
| 88 | IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 89 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 90 | ENDIF |
|---|
| 91 | ! |
|---|
| 92 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 93 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) |
|---|
| 94 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 95 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 96 | ENDIF |
|---|
| 97 | ! |
|---|
| 98 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 99 | IF( .NOT.ln_traqsr ) THEN ! no solar radiation penetration |
|---|
| 100 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 101 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 102 | ENDIF |
|---|
| 103 | |
|---|
| 104 | !---------------------------------------- |
|---|
| 105 | ! EMP, SFX and QNS effects |
|---|
| 106 | !---------------------------------------- |
|---|
| 107 | ! !== Set before sbc tracer content fields ==! |
|---|
| 108 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 109 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 110 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 111 | IF(lwp) WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 112 | zfact = 0.5_wp |
|---|
| 113 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 114 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) ) ! before heat content sbc trend |
|---|
| 115 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) ) ! before salt content sbc trend |
|---|
| 116 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 117 | zfact = 1._wp |
|---|
| 118 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 119 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 120 | ENDIF |
|---|
| 121 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 122 | zfact = 0.5_wp |
|---|
| 123 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 124 | ENDIF |
|---|
| 125 | ! !== Now sbc tracer content fields ==! |
|---|
| 126 | DO jj = 2, jpj |
|---|
| 127 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 128 | IF ( ll_wd ) THEN ! If near WAD point limit the flux for now |
|---|
| 129 | IF ( sshn(ji,jj) + ht_0(ji,jj) > 2._wp * rn_wdmin1 ) THEN |
|---|
| 130 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 131 | ELSE IF ( sshn(ji,jj) + ht_0(ji,jj) > rn_wdmin1 ) THEN |
|---|
| 132 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) * (tanh(5._wp*( ( sshn(ji,jj) + ht_0(ji,jj) - rn_wdmin1 )*r_rn_wdmin1)) ) |
|---|
| 133 | ELSE |
|---|
| 134 | sbc_tsc(ji,jj,jp_tem) = 0._wp |
|---|
| 135 | ENDIF |
|---|
| 136 | ELSE |
|---|
| 137 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 138 | ENDIF |
|---|
| 139 | |
|---|
| 140 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 141 | END DO |
|---|
| 142 | END DO |
|---|
| 143 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 144 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 145 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 146 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 147 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 148 | END DO |
|---|
| 149 | END DO !==>> output c./d. term |
|---|
| 150 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 151 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 155 | DO jj = 2, jpj |
|---|
| 156 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 157 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 158 | END DO |
|---|
| 159 | END DO |
|---|
| 160 | END DO |
|---|
| 161 | ! |
|---|
| 162 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 163 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) ) |
|---|
| 164 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) ) |
|---|
| 165 | ENDIF |
|---|
| 166 | ! |
|---|
| 167 | !---------------------------------------- |
|---|
| 168 | ! Ice Shelf effects (ISF) |
|---|
| 169 | ! tbl treated as in Losh (2008) JGR |
|---|
| 170 | !---------------------------------------- |
|---|
| 171 | ! |
|---|
| 172 | !!gm BUG ? Why no differences between non-linear and linear free surface ? |
|---|
| 173 | !!gm probably taken into account in r1_hisf_tbl : to be verified |
|---|
| 174 | IF( ln_isf ) THEN |
|---|
| 175 | zfact = 0.5_wp |
|---|
| 176 | DO jj = 2, jpj |
|---|
| 177 | DO ji = fs_2, fs_jpim1 |
|---|
| 178 | ! |
|---|
| 179 | ikt = misfkt(ji,jj) |
|---|
| 180 | ikb = misfkb(ji,jj) |
|---|
| 181 | ! |
|---|
| 182 | ! level fully include in the ice shelf boundary layer |
|---|
| 183 | ! sign - because fwf sign of evapo (rnf sign of precip) |
|---|
| 184 | DO jk = ikt, ikb - 1 |
|---|
| 185 | ! compute trend |
|---|
| 186 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 187 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 188 | & * r1_hisf_tbl(ji,jj) |
|---|
| 189 | END DO |
|---|
| 190 | |
|---|
| 191 | ! level partially include in ice shelf boundary layer |
|---|
| 192 | ! compute trend |
|---|
| 193 | tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem) & |
|---|
| 194 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 195 | & * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 196 | |
|---|
| 197 | END DO |
|---|
| 198 | END DO |
|---|
| 199 | END IF |
|---|
| 200 | ! |
|---|
| 201 | !---------------------------------------- |
|---|
| 202 | ! River Runoff effects |
|---|
| 203 | !---------------------------------------- |
|---|
| 204 | ! |
|---|
| 205 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 206 | zfact = 0.5_wp |
|---|
| 207 | DO jj = 2, jpj |
|---|
| 208 | DO ji = fs_2, fs_jpim1 |
|---|
| 209 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 210 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 211 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 212 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 213 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 214 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 215 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 216 | END DO |
|---|
| 217 | ENDIF |
|---|
| 218 | END DO |
|---|
| 219 | END DO |
|---|
| 220 | ENDIF |
|---|
| 221 | |
|---|
| 222 | IF( iom_use('rnf_x_sst') ) CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) ) ! runoff term on sst |
|---|
| 223 | IF( iom_use('rnf_x_sss') ) CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) ) ! runoff term on sss |
|---|
| 224 | |
|---|
| 225 | #if defined key_asminc |
|---|
| 226 | ! |
|---|
| 227 | !---------------------------------------- |
|---|
| 228 | ! Assmilation effects |
|---|
| 229 | !---------------------------------------- |
|---|
| 230 | ! |
|---|
| 231 | IF( ln_sshinc ) THEN ! input of heat and salt due to assimilation |
|---|
| 232 | ! |
|---|
| 233 | IF( ln_linssh ) THEN |
|---|
| 234 | DO jj = 2, jpj |
|---|
| 235 | DO ji = fs_2, fs_jpim1 |
|---|
| 236 | ztim = ssh_iau(ji,jj) / e3t_n(ji,jj,1) |
|---|
| 237 | tsa(ji,jj,1,jp_tem) = tsa(ji,jj,1,jp_tem) + tsn(ji,jj,1,jp_tem) * ztim |
|---|
| 238 | tsa(ji,jj,1,jp_sal) = tsa(ji,jj,1,jp_sal) + tsn(ji,jj,1,jp_sal) * ztim |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | ELSE |
|---|
| 242 | DO jj = 2, jpj |
|---|
| 243 | DO ji = fs_2, fs_jpim1 |
|---|
| 244 | ztim = ssh_iau(ji,jj) / ( ht_n(ji,jj) + 1. - ssmask(ji, jj) ) |
|---|
| 245 | tsa(ji,jj,:,jp_tem) = tsa(ji,jj,:,jp_tem) + tsn(ji,jj,:,jp_tem) * ztim |
|---|
| 246 | tsa(ji,jj,:,jp_sal) = tsa(ji,jj,:,jp_sal) + tsn(ji,jj,:,jp_sal) * ztim |
|---|
| 247 | END DO |
|---|
| 248 | END DO |
|---|
| 249 | ENDIF |
|---|
| 250 | ! |
|---|
| 251 | ENDIF |
|---|
| 252 | ! |
|---|
| 253 | #endif |
|---|
| 254 | |
|---|
| 255 | ! |
|---|
| 256 | !---------------------------------------- |
|---|
| 257 | ! Ice Sheet coupling imbalance correction to have conservation |
|---|
| 258 | !---------------------------------------- |
|---|
| 259 | ! |
|---|
| 260 | IF( ln_iscpl .AND. ln_hsb) THEN ! input of heat and salt due to river runoff |
|---|
| 261 | DO jk = 1,jpk |
|---|
| 262 | DO jj = 2, jpj |
|---|
| 263 | DO ji = fs_2, fs_jpim1 |
|---|
| 264 | zdep = 1._wp / e3t_n(ji,jj,jk) |
|---|
| 265 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem) & |
|---|
| 266 | & * zdep |
|---|
| 267 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal) & |
|---|
| 268 | & * zdep |
|---|
| 269 | END DO |
|---|
| 270 | END DO |
|---|
| 271 | END DO |
|---|
| 272 | ENDIF |
|---|
| 273 | |
|---|
| 274 | IF( l_trdtra ) THEN ! save the horizontal diffusive trends for further diagnostics |
|---|
| 275 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 276 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 277 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 278 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 279 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) |
|---|
| 280 | ENDIF |
|---|
| 281 | ! |
|---|
| 282 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 283 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 284 | ! |
|---|
| 285 | IF( nn_timing == 1 ) CALL timing_stop('tra_sbc') |
|---|
| 286 | ! |
|---|
| 287 | END SUBROUTINE tra_sbc |
|---|
| 288 | |
|---|
| 289 | !!====================================================================== |
|---|
| 290 | END MODULE trasbc |
|---|
