source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OCE_SRC/SBC/sbcmod.F90 @ 9580

Last change on this file since 9580 was 9570, checked in by nicolasmartin, 3 years ago

Global renaming for core routines (./NEMO)

  • Folders
    • LIM_SRC_3 → ICE_SRC
    • OPA_SRC → OCE_SRC
  • CPP key: key_lim3 → key_si3
  • Modules, (sub)routines and variables names
    • MPI: mpi_comm_opa → mpi_comm_oce, MPI_COMM_OPA → MPI_COMM_OCE, mpi_init_opa → mpi_init_oce
    • AGRIF: agrif_opa_* → agrif_oce_*, agrif_lim3_* → agrif_si3_* and few more
    • TOP-PISCES: p.zlim → p.zice, namp.zlim → namp.zice
  • Comments
    • NEMO/OPA → NEMO/OCE
    • ESIM|LIM3 → SI3
  • Property svn:keywords set to Id
File size: 32.3 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35#if defined key_si3
36   USE icestp         ! surface boundary condition: LIM 3.0 sea-ice model
37#endif
38   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
39   USE sbcisf         ! surface boundary condition: ice-shelf
40   USE sbccpl         ! surface boundary condition: coupled formulation
41   USE cpl_oasis3     ! OASIS routines for coupling
42   USE sbcssr         ! surface boundary condition: sea surface restoring
43   USE sbcrnf         ! surface boundary condition: runoffs
44   USE sbcapr         ! surface boundary condition: atmo pressure
45   USE sbcisf         ! surface boundary condition: ice shelf
46   USE sbcfwb         ! surface boundary condition: freshwater budget
47   USE icbstp         ! Icebergs
48   USE traqsr         ! active tracers: light penetration
49   USE sbcwave        ! Wave module
50   USE bdy_oce   , ONLY: ln_bdy
51   USE usrdef_sbc     ! user defined: surface boundary condition
52   USE closea         ! closed sea
53   !
54   USE prtctl         ! Print control                    (prt_ctl routine)
55   USE iom            ! IOM library
56   USE in_out_manager ! I/O manager
57   USE lib_mpp        ! MPP library
58   USE timing         ! Timing
59   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
60
61   IMPLICIT NONE
62   PRIVATE
63
64   PUBLIC   sbc        ! routine called by step.F90
65   PUBLIC   sbc_init   ! routine called by opa.F90
66
67   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OCE 4.0 , NEMO-consortium (2016)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE sbc_init
77      !!---------------------------------------------------------------------
78      !!                    ***  ROUTINE sbc_init ***
79      !!
80      !! ** Purpose :   Initialisation of the ocean surface boundary computation
81      !!
82      !! ** Method  :   Read the namsbc namelist and set derived parameters
83      !!                Call init routines for all other SBC modules that have one
84      !!
85      !! ** Action  : - read namsbc parameters
86      !!              - nsbc: type of sbc
87      !!----------------------------------------------------------------------
88      INTEGER ::   ios, icpt                         ! local integer
89      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
90      !!
91      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
92         &             ln_usr   , ln_flx   , ln_blk       ,                          &
93         &             ln_cpl   , ln_mixcpl, nn_components,                          &
94         &             nn_ice   , ln_ice_embd,                                       &
95         &             ln_traqsr, ln_dm2dc ,                                         &
96         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
97         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor   ,     &
98         &             ln_tauw  , nn_lsm, nn_sdrift
99      !!----------------------------------------------------------------------
100      !
101      IF(lwp) THEN
102         WRITE(numout,*)
103         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
104         WRITE(numout,*) '~~~~~~~~ '
105      ENDIF
106      !
107      !                       !**  read Surface Module namelist
108      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
109      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
110901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
111      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
112      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
113902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
114      IF(lwm) WRITE( numond, namsbc )
115      !
116      !                             !* overwrite namelist parameter using CPP key information
117#if defined key_agrif
118      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
119         IF( lk_lim3 )   nn_ice      = 2
120         IF( lk_cice )   nn_ice      = 3
121      ENDIF
122#else
123      IF( lk_lim3 )   nn_ice      = 2
124      IF( lk_cice )   nn_ice      = 3
125#endif
126      !
127      IF(lwp) THEN                  !* Control print
128         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
129         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
130         WRITE(numout,*) '      Type of air-sea fluxes : '
131         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
132         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
133         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
134         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
135         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
136         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
137!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
138         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
139         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
140         WRITE(numout,*) '      Sea-ice : '
141         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
142         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
143         WRITE(numout,*) '      Misc. options of sbc : '
144         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
145         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
146         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
147         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
148         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
149         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
150         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
151         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
152         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
153         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
154         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
155         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
156         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
157         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
158         WRITE(numout,*) '               neutral drag coefficient (CORE, MFS) ln_cdgw       = ', ln_cdgw
159      ENDIF
160      !
161      IF( ln_sdw ) THEN
162         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
163            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
164      ENDIF
165      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
166      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
167      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
168      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
169      IF( ln_tauwoc .AND. ln_tauw ) &
170         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
171                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
172      IF( ln_tauwoc ) &
173         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
174      IF( ln_tauw ) &
175         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
176                              'This will override any other specification of the ocean stress' )
177      !
178      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
179         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
180         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
181         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
182      ENDIF
183      !                       !**  check option consistency
184      !
185      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
186      SELECT CASE( nn_components )
187      CASE( jp_iam_nemo )
188         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
189      CASE( jp_iam_opa  )
190         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
191         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
192         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
193         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
194      CASE( jp_iam_sas  )
195         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
196         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
197         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
198      CASE DEFAULT
199         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
200      END SELECT
201      !                             !* coupled options
202      IF( ln_cpl ) THEN
203         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
204            &                                  '           required to defined key_oasis3' )
205      ENDIF
206      IF( ln_mixcpl ) THEN
207         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
208            &                                  '           required to defined key_oasis3' )
209         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
210         IF( nn_components /= jp_iam_nemo )    &
211            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
212            &                                   '          not yet working with sas-opa coupling via oasis' )
213      ENDIF
214      !                             !* sea-ice
215      SELECT CASE( nn_ice )
216      CASE( 0 )                        !- no ice in the domain
217      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
218      CASE( 2 )                        !- LIM3 ice model
219      CASE( 3 )                        !- CICE ice model
220         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
221         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
222      CASE DEFAULT                     !- not supported
223      END SELECT
224      !
225      !                       !**  allocate and set required variables
226      !
227      !                             !* allocate sbc arrays
228      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
229#if ! defined key_si3 && ! defined key_cice
230      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
231#endif
232      !
233      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
234         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
235         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
236         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
237      END IF
238      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
239         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
240      ENDIF
241      !
242      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
243      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
244
245      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
246
247      !                          ! Choice of the Surface Boudary Condition (set nsbc)
248      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
249         nday_qsr = -1   ! allow initialization at the 1st call
250         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
251            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
252      ENDIF
253      !                             !* Choice of the Surface Boudary Condition
254      !                             (set nsbc)
255      !
256      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
257      ll_opa      = nn_components == jp_iam_opa
258      ll_not_nemo = nn_components /= jp_iam_nemo
259      icpt = 0
260      !
261      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
262      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
263      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
264      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
265      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
266      !
267      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
268      !
269      IF(lwp) THEN                     !- print the choice of surface flux formulation
270         WRITE(numout,*)
271         SELECT CASE( nsbc )
272         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
273         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
274         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
275         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
276!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
277         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
278            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
279         END SELECT
280         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
281      ENDIF
282      !
283      !                             !* OASIS initialization
284      !
285      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
286      !                                              !                      (2) the use of nn_fsbc
287      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
288      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
289      IF( nn_components /= jp_iam_nemo ) THEN
290         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
291         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
292         !
293         IF(lwp)THEN
294            WRITE(numout,*)
295            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
296            WRITE(numout,*)
297         ENDIF
298      ENDIF
299      !
300      !                             !* check consistency between model timeline and nn_fsbc
301      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
302          MOD( nstock             , nn_fsbc) /= 0 ) THEN
303         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
304            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
305         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
306      ENDIF
307      !
308      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
309         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
310      !
311      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
312         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
313      !
314   
315      !                       !**  associated modules : initialization
316      !
317                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
318      !
319      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
320
321      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
322      !
323      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
324      !
325                          CALL sbc_rnf_init            ! Runof initialization
326      !
327      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
328      !
329#if defined key_si3
330      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
331                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
332      ELSEIF( nn_ice == 2 ) THEN
333                          CALL ice_init                ! ICE initialization
334      ENDIF
335#endif
336      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
337      !
338      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
339      !
340      IF( lwxios ) THEN
341         CALL iom_set_rstw_var_active('utau_b')
342         CALL iom_set_rstw_var_active('vtau_b')
343         CALL iom_set_rstw_var_active('qns_b')
344         ! The 3D heat content due to qsr forcing is treated in traqsr
345         ! CALL iom_set_rstw_var_active('qsr_b')
346         CALL iom_set_rstw_var_active('emp_b')
347         CALL iom_set_rstw_var_active('sfx_b')
348      ENDIF
349
350   END SUBROUTINE sbc_init
351
352
353   SUBROUTINE sbc( kt )
354      !!---------------------------------------------------------------------
355      !!                    ***  ROUTINE sbc  ***
356      !!
357      !! ** Purpose :   provide at each time-step the ocean surface boundary
358      !!                condition (momentum, heat and freshwater fluxes)
359      !!
360      !! ** Method  :   blah blah  to be written ?????????
361      !!                CAUTION : never mask the surface stress field (tke sbc)
362      !!
363      !! ** Action  : - set the ocean surface boundary condition at before and now
364      !!                time step, i.e.
365      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
366      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
367      !!              - updte the ice fraction : fr_i
368      !!----------------------------------------------------------------------
369      INTEGER, INTENT(in) ::   kt   ! ocean time step
370      !
371      LOGICAL ::   ll_sas, ll_opa   ! local logical
372      !!---------------------------------------------------------------------
373      !
374      IF( ln_timing )   CALL timing_start('sbc')
375      !
376      !                                            ! ---------------------------------------- !
377      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
378         !                                         ! ---------------------------------------- !
379         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
380         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
381         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
382         emp_b (:,:) = emp (:,:)
383         sfx_b (:,:) = sfx (:,:)
384         IF ( ln_rnf ) THEN
385            rnf_b    (:,:  ) = rnf    (:,:  )
386            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
387         ENDIF
388         IF( ln_isf )  THEN
389            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
390            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
391         ENDIF
392        !
393      ENDIF
394      !                                            ! ---------------------------------------- !
395      !                                            !        forcing field computation         !
396      !                                            ! ---------------------------------------- !
397      !
398      ll_sas = nn_components == jp_iam_sas               ! component flags
399      ll_opa = nn_components == jp_iam_opa
400      !
401      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
402      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
403
404      !
405      !                                            !==  sbc formulation  ==!
406      !                                                   
407      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
408      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
409      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
410      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
411      CASE( jp_blk     )
412         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
413                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
414                               !
415      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
416      CASE( jp_none    )
417         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
418      END SELECT
419      !
420      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
421      !
422      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
423      !
424      !                                            !==  Misc. Options  ==!
425      !
426      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
427      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
428#if defined key_si3
429      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! LIM-3 ice model
430#endif
431      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
432      END SELECT
433
434      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
435
436      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
437
438      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
439
440      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
441
442      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
443
444      ! Special treatment of freshwater fluxes over closed seas in the model domain
445      ! Should not be run if ln_diurnal_only
446      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
447
448!!$!RBbug do not understand why see ticket 667
449!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
450!!$      CALL lbc_lnk( emp, 'T', 1. )
451      !
452      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
453         !                                             ! ---------------------------------------- !
454         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
455            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
456            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
457            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
458            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
459            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios  )   ! before non solar heat flux (T-point)
460            ! The 3D heat content due to qsr forcing is treated in traqsr
461            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
462            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
463            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
464            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
465               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
466            ELSE
467               sfx_b (:,:) = sfx(:,:)
468            ENDIF
469         ELSE                                                   !* no restart: set from nit000 values
470            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
471            utau_b(:,:) = utau(:,:)
472            vtau_b(:,:) = vtau(:,:)
473            qns_b (:,:) = qns (:,:)
474            emp_b (:,:) = emp (:,:)
475            sfx_b (:,:) = sfx (:,:)
476         ENDIF
477      ENDIF
478      !                                                ! ---------------------------------------- !
479      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
480         !                                             ! ---------------------------------------- !
481         IF(lwp) WRITE(numout,*)
482         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
483            &                    'at it= ', kt,' date= ', ndastp
484         IF(lwp) WRITE(numout,*) '~~~~'
485         IF( lwxios ) CALL iom_swap(      cwxios_context          )
486         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
487         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
488         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
489         ! The 3D heat content due to qsr forcing is treated in traqsr
490         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
491         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
492         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
493         IF( lwxios ) CALL iom_swap(      cxios_context          )
494      ENDIF
495      !                                                ! ---------------------------------------- !
496      !                                                !        Outputs and control print         !
497      !                                                ! ---------------------------------------- !
498      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
499         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
500         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
501         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
502         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
503         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
504         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
505         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
506         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
507         CALL iom_put( "taum"  , taum       )                   ! wind stress module
508         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
509      ENDIF
510      !
511      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
512      CALL iom_put( "vtau", vtau )   ! j-wind stress
513      !
514      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
515         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask )
516         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask )
517         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask )
518         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
519         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
520         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
521         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
522         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
523         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
524            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
525      ENDIF
526
527      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
528      !
529      IF( ln_timing )   CALL timing_stop('sbc')
530      !
531   END SUBROUTINE sbc
532
533
534   SUBROUTINE sbc_final
535      !!---------------------------------------------------------------------
536      !!                    ***  ROUTINE sbc_final  ***
537      !!
538      !! ** Purpose :   Finalize CICE (if used)
539      !!---------------------------------------------------------------------
540      !
541      IF( nn_ice == 3 )   CALL cice_sbc_final
542      !
543   END SUBROUTINE sbc_final
544
545   !!======================================================================
546END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.