New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 9076

Last change on this file since 9076 was 9019, checked in by timgraham, 7 years ago

Merge of dev_CNRS_2017 into branch
  • Property svn:keywords set to Id
File size: 7.3 KB
RevLine 
[643]1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
[1566]7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
[643]9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
[6140]12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
[643]13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
[4990]16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
[643]19   USE in_out_manager ! I/O manager
[2715]20   USE lib_mpp        ! MPP library
[1129]21   USE prtctl         ! Print control
[4990]22   USE timing         ! Timing
[643]23
24   IMPLICIT NONE
25   PRIVATE
26
[1566]27   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
[643]28
29   !! * Substitutions
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
[9019]32   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
[1152]33   !! $Id$
[2715]34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[643]35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the now momentum advection trend in flux form
[1566]43      !!              and the general trend of the momentum equation.
[643]44      !!
45      !! ** Method  :   Trend evaluated using now fields (centered in time)
46      !!
[1566]47      !! ** Action  :   (ua,va) updated with the now vorticity term trend
[643]48      !!----------------------------------------------------------------------
[1566]49      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
[2715]50      !
[1566]51      INTEGER  ::   ji, jj, jk   ! dummy loop indices
[9019]52      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfu_t, zfu_f, zfu_uw, zfu
53      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfv_t, zfv_f, zfv_vw, zfv, zfw
[643]54      !!----------------------------------------------------------------------
[3294]55      !
[9019]56      IF( ln_timing )   CALL timing_start('dyn_adv_cen2')
[3294]57      !
[2715]58      IF( kt == nit000 .AND. lwp ) THEN
59         WRITE(numout,*)
60         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
61         WRITE(numout,*) '~~~~~~~~~~~~'
[643]62      ENDIF
[3294]63      !
[6140]64      IF( l_trddyn ) THEN           ! trends: store the input trends
[1129]65         zfu_uw(:,:,:) = ua(:,:,:)
66         zfv_vw(:,:,:) = va(:,:,:)
67      ENDIF
[6140]68      !
69      !                             !==  Horizontal advection  ==!
70      !
71      DO jk = 1, jpkm1                    ! horizontal transport
72         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u_n(:,:,jk) * un(:,:,jk)
73         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
74         DO jj = 1, jpjm1                 ! horizontal momentum fluxes (at T- and F-point)
[643]75            DO ji = 1, fs_jpim1   ! vector opt.
[6140]76               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
77               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
78               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
79               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
[643]80            END DO
81         END DO
[6140]82         DO jj = 2, jpjm1                 ! divergence of horizontal momentum fluxes
[643]83            DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]84               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
85                  &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
86               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
87                  &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[643]88            END DO
89         END DO
[1566]90      END DO
91      !
[6140]92      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
[1129]93         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
94         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
[4990]95         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
[1129]96         zfu_t(:,:,:) = ua(:,:,:)
97         zfv_t(:,:,:) = va(:,:,:)
98      ENDIF
[1566]99      !
[6140]100      !                             !==  Vertical advection  ==!
101      !
102      DO jj = 2, jpjm1                    ! surface/bottom advective fluxes set to zero
103         DO ji = fs_2, fs_jpim1
104            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(jj,jj,jpk) = 0._wp
105            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(jj,jj, 1 ) = 0._wp
106         END DO
107      END DO
108      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
109         DO jj = 2, jpjm1
110            DO ji = fs_2, fs_jpim1
111               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji+1,jj) * wn(ji+1,jj,1) ) * un(ji,jj,1)
112               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji,jj+1) * wn(ji,jj+1,1) ) * vn(ji,jj,1)
[643]113            END DO
[6140]114         END DO
115      ENDIF
116      DO jk = 2, jpkm1                    ! interior advective fluxes
[6750]117         DO jj = 2, jpj                       ! 1/4 * Vertical transport
118            DO ji = 2, jpi
[6140]119               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
120            END DO
121         END DO
122         DO jj = 2, jpjm1
123            DO ji = fs_2, fs_jpim1   ! vector opt.
124               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
125               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
126            END DO
127         END DO
[643]128      END DO
[6140]129      DO jk = 1, jpkm1                    ! divergence of vertical momentum flux divergence
[643]130         DO jj = 2, jpjm1 
131            DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]132               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
133               va(ji,jj,jk) = va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[643]134            END DO
135         END DO
136      END DO
[1566]137      !
[6140]138      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
[1129]139         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
140         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
[4990]141         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
[1129]142      ENDIF
[6140]143      !                                   ! Control print
[1129]144      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
145         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
146      !
[9019]147      IF( ln_timing )   CALL timing_stop('dyn_adv_cen2')
[2715]148      !
[643]149   END SUBROUTINE dyn_adv_cen2
150
151   !!==============================================================================
152END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.