New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_algo_ecmwf.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_algo_ecmwf.F90 @ 9124

Last change on this file since 9124 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

File size: 20.6 KB
Line 
1MODULE sbcblk_algo_ecmwf
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_algo_ecmwf  ***
4   !! Computes turbulent components of surface fluxes
5   !!         according to the method in IFS of the ECMWF model
6   !!
7   !!   * bulk transfer coefficients C_D, C_E and C_H
8   !!   * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed
9   !!   * the effective bulk wind speed at 10m U_blk
10   !!   => all these are used in bulk formulas in sbcblk.F90
11   !!
12   !!    Using the bulk formulation/param. of IFS of ECMWF (cycle 31r2)
13   !!         based on IFS doc (avaible online on the ECMWF's website)
14   !!
15   !!
16   !!       Routine turb_ecmwf maintained and developed in AeroBulk
17   !!                     (http://aerobulk.sourceforge.net/)
18   !!
19   !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
20   !!----------------------------------------------------------------------
21   !! History :  4.0  !  2016-02  (L.Brodeau)   Original code
22   !!----------------------------------------------------------------------
23
24   !!----------------------------------------------------------------------
25   !!   turb_ecmwf  : computes the bulk turbulent transfer coefficients
26   !!                   adjusts t_air and q_air from zt to zu m
27   !!                   returns the effective bulk wind speed at 10m
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE iom             ! I/O manager library
33   USE lib_mpp         ! distribued memory computing library
34   USE wrk_nemo        ! work arrays
35   USE in_out_manager  ! I/O manager
36   USE prtctl          ! Print control
37   USE sbcwave, ONLY   :  cdn_wave ! wave module
38#if defined key_lim3 || defined key_cice
39   USE sbc_ice         ! Surface boundary condition: ice fields
40#endif
41   USE lib_fortran     ! to use key_nosignedzero
42
43   USE sbc_oce         ! Surface boundary condition: ocean fields
44
45   IMPLICIT NONE
46   PRIVATE
47
48   PUBLIC ::   TURB_ECMWF   ! called by sbcblk.F90
49
50   !                   !! ECMWF own values for given constants, taken form IFS documentation...
51   REAL(wp), PARAMETER ::   charn0 = 0.018    ! Charnock constant (pretty high value here !!!
52   !                                          !    =>  Usually 0.011 for moderate winds)
53   REAL(wp), PARAMETER ::   zi0     = 1000.   ! scale height of the atmospheric boundary layer...1
54   REAL(wp), PARAMETER ::   Beta0    = 1.     ! gustiness parameter ( = 1.25 in COAREv3)
55   REAL(wp), PARAMETER ::   rctv0    = 0.608  ! constant to obtain virtual temperature...
56   REAL(wp), PARAMETER ::   Cp_dry = 1005.0   ! Specic heat of dry air, constant pressure      [J/K/kg]
57   REAL(wp), PARAMETER ::   Cp_vap = 1860.0   ! Specic heat of water vapor, constant pressure  [J/K/kg]
58   REAL(wp), PARAMETER ::   alpha_M = 0.11    ! For roughness length (smooth surface term)
59   REAL(wp), PARAMETER ::   alpha_H = 0.40    ! (Chapter 3, p.34, IFS doc Cy31r1)
60   REAL(wp), PARAMETER ::   alpha_Q = 0.62    !
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE TURB_ECMWF( zt, zu, sst, t_zt, ssq , q_zt , U_zu,   &
65      &                   Cd, Ch, Ce , t_zu, q_zu, U_blk,         &
66      &                   Cdn, Chn, Cen                           )
67      !!----------------------------------------------------------------------------------
68      !!                      ***  ROUTINE  turb_ecmwf  ***
69      !!
70      !!            2015: L. Brodeau (brodeau@gmail.com)
71      !!
72      !! ** Purpose :   Computes turbulent transfert coefficients of surface
73      !!                fluxes according to IFS doc. (cycle 31)
74      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
75      !!
76      !! ** Method : Monin Obukhov Similarity Theory
77      !!
78      !! INPUT :
79      !! -------
80      !!    *  zt   : height for temperature and spec. hum. of air            [m]
81      !!    *  zu   : height for wind speed (generally 10m)                   [m]
82      !!    *  U_zu : scalar wind speed at 10m                                [m/s]
83      !!    *  sst  : SST                                                     [K]
84      !!    *  t_zt : potential air temperature at zt                         [K]
85      !!    *  ssq  : specific humidity at saturation at SST                  [kg/kg]
86      !!    *  q_zt : specific humidity of air at zt                          [kg/kg]
87      !!
88      !!
89      !! OUTPUT :
90      !! --------
91      !!    *  Cd     : drag coefficient
92      !!    *  Ch     : sensible heat coefficient
93      !!    *  Ce     : evaporation coefficient
94      !!    *  t_zu   : pot. air temperature adjusted at wind height zu       [K]
95      !!    *  q_zu   : specific humidity of air        //                    [kg/kg]
96      !!    *  U_blk  : bulk wind at 10m                                      [m/s]
97      !!
98      !!
99      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
100      !!----------------------------------------------------------------------------------
101      REAL(wp), INTENT(in   )                     ::   zt       ! height for t_zt and q_zt                    [m]
102      REAL(wp), INTENT(in   )                     ::   zu       ! height for U_zu                             [m]
103      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature                [Kelvin]
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   t_zt     ! potential air temperature              [Kelvin]
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   ssq      ! sea surface specific humidity           [kg/kg]
106      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                   [kg/kg]
107      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   U_zu     ! relative wind module at zu                [m/s]
108      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
109      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
110      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
111      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   t_zu     ! pot. air temp. adjusted at zu               [K]
112      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. humidity adjusted at zu           [kg/kg]
113      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   U_blk    ! bulk wind at 10m                          [m/s]
114      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cdn, Chn, Cen ! neutral transfer coefficients
115      !
116      INTEGER :: j_itt
117      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at same height as U
118      INTEGER , PARAMETER ::   nb_itt = 4       ! number of itterations
119      !
120      REAL(wp), DIMENSION(:,:), POINTER  ::   u_star, t_star, q_star,   &
121         &  dt_zu, dq_zu,    &
122         &  znu_a,           & !: Nu_air, Viscosity of air
123         &  Linv,            & !: 1/L (inverse of Monin Obukhov length...
124         &  z0, z0t, z0q
125      REAL(wp), DIMENSION(:,:), POINTER ::   func_m, func_h
126      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
127      !!----------------------------------------------------------------------------------
128      !
129      CALL wrk_alloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
130      CALL wrk_alloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
131      !
132      ! Identical first gess as in COARE, with IFS parameter values though
133      !
134      l_zt_equal_zu = .FALSE.
135      IF( ABS(zu - zt) < 0.01 )   l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
136
137
138      !! First guess of temperature and humidity at height zu:
139      t_zu = MAX( t_zt , 0.0  )   ! who knows what's given on masked-continental regions...
140      q_zu = MAX( q_zt , 1.e-6)   !               "
141
142      !! Pot. temp. difference (and we don't want it to be 0!)
143      dt_zu = t_zu - sst   ;   dt_zu = SIGN( MAX(ABS(dt_zu),1.e-6), dt_zu )
144      dq_zu = q_zu - ssq   ;   dq_zu = SIGN( MAX(ABS(dq_zu),1.e-9), dq_zu )
145
146      znu_a = visc_air(t_zt) ! Air viscosity (m^2/s) at zt given from temperature in (K)
147
148      ztmp2 = 0.5 * 0.5  ! initial guess for wind gustiness contribution
149      U_blk = SQRT(U_zu*U_zu + ztmp2)
150
151      ! z0     = 0.0001
152      ztmp2   = 10000.     ! optimization: ztmp2 == 1/z0
153      ztmp0   = LOG(zu*ztmp2)
154      ztmp1   = LOG(10.*ztmp2)
155      u_star = 0.035*U_blk*ztmp1/ztmp0       ! (u* = 0.035*Un10)
156
157      z0     = charn0*u_star*u_star/grav + 0.11*znu_a/u_star
158      z0t    = 0.1*EXP(vkarmn/(0.00115/(vkarmn/ztmp1)))   !  WARNING: 1/z0t !
159
160      Cd     = (vkarmn/ztmp0)**2    ! first guess of Cd
161
162      ztmp0 = vkarmn*vkarmn/LOG(zt*z0t)/Cd
163
164      ztmp2 = Ri_bulk( zu, t_zu, dt_zu, q_zu, dq_zu, U_blk )   ! Ribu = Bulk Richardson number
165
166      !! First estimate of zeta_u, depending on the stability, ie sign of Ribu (ztmp2):
167      ztmp1 = 0.5 + SIGN( 0.5 , ztmp2 )
168      func_m = ztmp0*ztmp2 ! temporary array !!
169      !!             Ribu < 0                                 Ribu > 0   Beta = 1.25
170      func_h = (1.-ztmp1)*(func_m/(1.+ztmp2/(-zu/(zi0*0.004*Beta0**3)))) &  ! temporary array !!! func_h == zeta_u
171         &  +     ztmp1*(func_m*(1. + 27./9.*ztmp2/ztmp0))
172
173      !! First guess M-O stability dependent scaling params.(u*,t*,q*) to estimate z0 and z/L
174      ztmp0   =        vkarmn/(LOG(zu*z0t) - psi_h_ecmwf(func_h))
175
176      u_star = U_blk*vkarmn/(LOG(zu) - LOG(z0)  - psi_m_ecmwf(func_h))
177      t_star = dt_zu*ztmp0
178      q_star = dq_zu*ztmp0
179
180      ! What's need to be done if zt /= zu:
181      IF( .NOT. l_zt_equal_zu ) THEN
182         !
183         !! First update of values at zu (or zt for wind)
184         ztmp0 = psi_h_ecmwf(func_h) - psi_h_ecmwf(zt*func_h/zu)    ! zt*func_h/zu == zeta_t
185         ztmp1 = log(zt/zu) + ztmp0
186         t_zu = t_zt - t_star/vkarmn*ztmp1
187         q_zu = q_zt - q_star/vkarmn*ztmp1
188         q_zu = (0.5 + sign(0.5,q_zu))*q_zu !Makes it impossible to have negative humidity :
189
190         dt_zu = t_zu - sst  ; dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
191         dq_zu = q_zu - ssq  ; dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
192         !
193      ENDIF
194
195
196      !! => that was same first guess as in COARE...
197
198
199      !! First guess of inverse of Monin-Obukov length (1/L) :
200      ztmp0 = (1. + rctv0*q_zu)  ! the factor to apply to temp. to get virt. temp...
201      Linv  =  grav*vkarmn*(t_star*ztmp0 + rctv0*t_zu*q_star) / ( u_star*u_star * t_zu*ztmp0 )
202
203      !! Functions such as  u* = U_blk*vkarmn/func_m
204      ztmp1 = zu + z0
205      ztmp0 = ztmp1*Linv
206      func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0*Linv)
207      func_h = LOG(ztmp1*z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(1./z0t*Linv)
208
209
210      !! ITERATION BLOCK
211      !! ***************
212
213      DO j_itt = 1, nb_itt
214
215         !! Bulk Richardson Number at z=zu (Eq. 3.25)
216         ztmp0 = Ri_bulk(zu, t_zu, dt_zu, q_zu, dq_zu, U_blk)
217
218         !! New estimate of the inverse of the Monin-Obukhon length (Linv == zeta/zu) :
219         Linv = ztmp0*func_m*func_m/func_h / zu     ! From Eq. 3.23, Chap.3, p.33, IFS doc - Cy31r1
220
221         !! Update func_m with new Linv:
222         ztmp1 = zu + z0
223         func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp1*Linv) + psi_m_ecmwf(z0*Linv)
224
225         !! Need to update roughness lengthes:
226         u_star = U_blk*vkarmn/func_m
227         ztmp2  = u_star*u_star
228         ztmp1  = znu_a/u_star
229         z0    = alpha_M*ztmp1 + charn0*ztmp2/grav
230         z0t    = alpha_H*ztmp1                              ! eq.3.26, Chap.3, p.34, IFS doc - Cy31r1
231         z0q    = alpha_Q*ztmp1
232
233         !! Update wind at 10m taking into acount convection-related wind gustiness:
234         ! Only true when unstable (L<0) => when ztmp0 < 0 => - !!!
235         ztmp2 = ztmp2 * (MAX(-zi0*Linv/vkarmn,0.))**(2./3.) ! => w*^2  (combining Eq. 3.8 and 3.18, hap.3, IFS doc - Cy31r1)
236         !! => equivalent using Beta=1 (gustiness parameter, 1.25 for COARE, also zi0=600 in COARE..)
237         U_blk = MAX(sqrt(U_zu*U_zu + ztmp2), 0.2)              ! eq.3.17, Chap.3, p.32, IFS doc - Cy31r1
238         ! => 0.2 prevents U_blk to be 0 in stable case when U_zu=0.
239
240
241         !! Need to update "theta" and "q" at zu in case they are given at different heights
242         !! as well the air-sea differences:
243         IF( .NOT. l_zt_equal_zu ) THEN
244
245            !! Arrays func_m and func_h are free for a while so using them as temporary arrays...
246            func_h = psi_h_ecmwf((zu+z0)*Linv) ! temporary array !!!
247            func_m = psi_h_ecmwf((zt+z0)*Linv) ! temporary array !!!
248
249            ztmp2  = psi_h_ecmwf(z0t*Linv)
250            ztmp0  = func_h - ztmp2
251            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0t) - ztmp0)
252            t_star = dt_zu*ztmp1
253            ztmp2  = ztmp0 - func_m + ztmp2
254            ztmp1  = LOG(zt/zu) + ztmp2
255            t_zu   = t_zt - t_star/vkarmn*ztmp1
256
257            ztmp2  = psi_h_ecmwf(z0q*Linv)
258            ztmp0  = func_h - ztmp2
259            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0q) - ztmp0)
260            q_star = dq_zu*ztmp1
261            ztmp2  = ztmp0 - func_m + ztmp2
262            ztmp1  = log(zt/zu) + ztmp2
263            q_zu   = q_zt - q_star/vkarmn*ztmp1
264
265            dt_zu = t_zu - sst ;  dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
266            dq_zu = q_zu - ssq ;  dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
267
268         END IF
269
270         !! Updating because of updated z0 and z0t and new Linv...
271         ztmp1 = zu + z0
272         ztmp0 = ztmp1*Linv
273         func_m = log(ztmp1) - LOG(z0 ) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0 *Linv)
274         func_h = log(ztmp1) - LOG(z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(z0t*Linv)
275
276      END DO
277
278      Cd = vkarmn*vkarmn/(func_m*func_m)
279      Ch = vkarmn*vkarmn/(func_m*func_h)
280      ztmp1 = log((zu + z0)/z0q) - psi_h_ecmwf((zu + z0)*Linv) + psi_h_ecmwf(z0q*Linv)   ! func_q
281      Ce = vkarmn*vkarmn/(func_m*ztmp1)
282
283      ztmp1 = zu + z0
284      Cdn = vkarmn*vkarmn / (log(ztmp1/z0 )*log(ztmp1/z0 ))
285      Chn = vkarmn*vkarmn / (log(ztmp1/z0t)*log(ztmp1/z0t))
286      Cen = vkarmn*vkarmn / (log(ztmp1/z0q)*log(ztmp1/z0q))
287
288      CALL wrk_dealloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
289      CALL wrk_dealloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
290      !
291   END SUBROUTINE TURB_ECMWF
292
293
294   FUNCTION psi_m_ecmwf( pzeta )
295      !!----------------------------------------------------------------------------------
296      !! Universal profile stability function for momentum
297      !!     ECMWF / as in IFS cy31r1 documentation, available online
298      !!     at ecmwf.int
299      !!
300      !! pzeta : stability paramenter, z/L where z is altitude measurement
301      !!         and L is M-O length
302      !!
303      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
304      !!----------------------------------------------------------------------------------
305      REAL(wp), DIMENSION(jpi,jpj) :: psi_m_ecmwf
306      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
307      !
308      INTEGER  ::   ji, jj    ! dummy loop indices
309      REAL(wp) :: zzeta, zx, ztmp, psi_unst, psi_stab, stab
310      !!----------------------------------------------------------------------------------
311      !
312      DO jj = 1, jpj
313         DO ji = 1, jpi
314            !
315            zzeta = MIN( pzeta(ji,jj) , 5. ) !! Very stable conditions (L positif and big!):
316            !
317            ! Unstable (Paulson 1970):
318            !   eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
319            zx = SQRT(ABS(1. - 16.*zzeta))
320            ztmp = 1. + SQRT(zx)
321            ztmp = ztmp*ztmp
322            psi_unst = LOG( 0.125*ztmp*(1. + zx) )   &
323               &       -2.*ATAN( SQRT(zx) ) + 0.5*rpi
324            !
325            ! Unstable:
326            ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
327            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) &
328               &       - zzeta - 2./3.*5./0.35
329            !
330            ! Combining:
331            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
332            !
333            psi_m_ecmwf(ji,jj) = (1. - stab) * psi_unst & ! (zzeta < 0) Unstable
334               &                +      stab  * psi_stab   ! (zzeta > 0) Stable
335            !
336         END DO
337      END DO
338      !
339   END FUNCTION psi_m_ecmwf
340
341   
342   FUNCTION psi_h_ecmwf( pzeta )
343      !!----------------------------------------------------------------------------------
344      !! Universal profile stability function for temperature and humidity
345      !!     ECMWF / as in IFS cy31r1 documentation, available online
346      !!     at ecmwf.int
347      !!
348      !! pzeta : stability paramenter, z/L where z is altitude measurement
349      !!         and L is M-O length
350      !!
351      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
352      !!----------------------------------------------------------------------------------
353      REAL(wp), DIMENSION(jpi,jpj) :: psi_h_ecmwf
354      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
355      !
356      INTEGER  ::   ji, jj     ! dummy loop indices
357      REAL(wp) ::  zzeta, zx, psi_unst, psi_stab, stab
358      !!----------------------------------------------------------------------------------
359      !
360      DO jj = 1, jpj
361         DO ji = 1, jpi
362            !
363            zzeta = MIN(pzeta(ji,jj) , 5.)   ! Very stable conditions (L positif and big!):
364            !
365            zx  = ABS(1. - 16.*zzeta)**.25        ! this is actually (1/phi_m)**2  !!!
366            !                                     ! eq.3.19, Chap.3, p.33, IFS doc - Cy31r1
367            ! Unstable (Paulson 1970) :
368            psi_unst = 2.*LOG(0.5*(1. + zx*zx))   ! eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
369            !
370            ! Stable:
371            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) & ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
372               &       - ABS(1. + 2./3.*zzeta)**1.5 - 2./3.*5./0.35 + 1. 
373            ! LB: added ABS() to avoid NaN values when unstable, which contaminates the unstable solution...
374            !
375            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
376            !
377            !
378            psi_h_ecmwf(ji,jj) = (1. - stab) * psi_unst &   ! (zzeta < 0) Unstable
379               &                +    stab    * psi_stab     ! (zzeta > 0) Stable
380            !
381         END DO
382      END DO
383      !
384   END FUNCTION psi_h_ecmwf
385
386
387   FUNCTION Ri_bulk( pz, ptz, pdt, pqz, pdq, pub )
388      !!----------------------------------------------------------------------------------
389      !! Bulk Richardson number (Eq. 3.25 IFS doc)
390      !!
391      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
392      !!----------------------------------------------------------------------------------
393      REAL(wp), DIMENSION(jpi,jpj) ::   Ri_bulk   !
394      !
395      REAL(wp)                    , INTENT(in) ::   pz    ! height above the sea        [m]
396      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptz   ! air temperature at pz m     [K]
397      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdt   ! ptz - sst                   [K]
398      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pqz   ! air temperature at pz m [kg/kg]
399      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdq   ! pqz - ssq               [kg/kg]
400      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pub   ! bulk wind speed           [m/s]
401      !!----------------------------------------------------------------------------------
402      !
403      Ri_bulk =   grav*pz/(pub*pub)                                          &
404         &      * ( pdt/(ptz - 0.5_wp*(pdt + grav*pz/(Cp_dry+Cp_vap*pqz)))   &
405         &          + rctv0*pdq )
406      !
407   END FUNCTION Ri_bulk
408
409
410   FUNCTION visc_air(ptak)
411      !!----------------------------------------------------------------------------------
412      !! Air kinetic viscosity (m^2/s) given from temperature in degrees...
413      !!
414      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
415      !!----------------------------------------------------------------------------------
416      REAL(wp), DIMENSION(jpi,jpj)             ::   visc_air   !
417      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptak       ! air temperature in (K)
418      !
419      INTEGER  ::   ji, jj      ! dummy loop indices
420      REAL(wp) ::   ztc, ztc2   ! local scalar
421      !!----------------------------------------------------------------------------------
422      !
423      DO jj = 1, jpj
424         DO ji = 1, jpi
425            ztc  = ptak(ji,jj) - rt0   ! air temp, in deg. C
426            ztc2 = ztc*ztc
427            visc_air(ji,jj) = 1.326e-5*(1. + 6.542E-3*ztc + 8.301e-6*ztc2 - 4.84e-9*ztc2*ztc)
428         END DO
429      END DO
430      !
431   END FUNCTION visc_air
432
433   !!======================================================================
434END MODULE sbcblk_algo_ecmwf
Note: See TracBrowser for help on using the repository browser.