New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago

Merge of dev_CNRS_2017 into branch
  • Property svn:keywords set to Id
File size: 19.8 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constants
19   USE oce            ! ocean variables
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE zdf_oce,  ONLY : ln_zdfswm
22   USE bdy_oce        ! open boundary condition variables
23   USE domvvl         ! domain: variable volume layers
24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE fldread        ! read input fields
29   USE wrk_nemo       !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wstrf  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
47
48   INTEGER ::   jpfld    ! number of files to read for stokes drift
49   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
50   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
51   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
52   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !: 
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
65
66   !! * Substitutions
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE sbc_stokes( )
76      !!---------------------------------------------------------------------
77      !!                     ***  ROUTINE sbc_stokes  ***
78      !!
79      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
80      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
81      !!
82      !! ** Method  : - Calculate Stokes transport speed
83      !!              - Calculate horizontal divergence
84      !!              - Integrate the horizontal divergenze from the bottom
85      !! ** action 
86      !!---------------------------------------------------------------------
87      INTEGER  ::   jj, ji, jk   ! dummy loop argument
88      INTEGER  ::   ik           ! local integer
89      REAL(wp) ::  ztransp, zfac, zsp0
90      REAL(wp) ::  zdepth, zsqrt_depth,  zexp_depth, z_two_thirds, zsqrtpi !sqrt of pi
91      REAL(wp) ::  zbot_u, zbot_v, zkb_u, zkb_v, zke3_u, zke3_v, zda_u, zda_v
92      REAL(wp) ::  zstokes_psi_u_bot, zstokes_psi_v_bot
93      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
94      REAL(wp), DIMENSION(:,:)  , POINTER ::   zstokes_psi_u_top, zstokes_psi_v_top   ! 2D workspace
95      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
96      !!---------------------------------------------------------------------
97      !
98      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
99      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
100      CALL wrk_alloc( jpi,jpj,       zstokes_psi_u_top, zstokes_psi_v_top)
101      !
102      !
103      zsqrtpi = SQRT(rpi)
104      z_two_thirds = 2.0_wp / 3.0_wp
105      zfac =  2.0_wp * rpi / 16.0_wp
106      DO jj = 1, jpj                ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
107         DO ji = 1, jpi
108               ! Stokes drift velocity estimated from Hs and Tmean
109               ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj) , 0.0000001_wp )
110               ! Stokes surface speed
111               zsp0 = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj) )
112               tsd2d(ji,jj) = zsp0
113               ! Wavenumber scale
114               zk_t(ji,jj) =  (1.0_wp-2.0_wp/3.0_wp)*zsp0/MAX(2.0_wp*ztransp,0.0000001_wp)
115         END DO
116      END DO
117      !
118      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
119         DO ji = 1, jpim1
120            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
121            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
122            !
123            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
124            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
125         END DO
126      END DO
127      !
128      !                       !==  horizontal Stokes Drift 3D velocity  ==!
129      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
130         DO ji = 1, jpim1
131            zstokes_psi_u_top(ji,jj) = 0._wp
132            zstokes_psi_v_top(ji,jj) = 0._wp
133         END DO
134      END DO
135
136      DO jk = 1, jpkm1
137         DO jj = 2, jpjm1
138            DO ji = 2, jpim1
139               zbot_u = 0.5_wp * ( gdepw_n(ji,jj,jk+1) + gdepw_n(ji+1,jj,jk+1) )
140               zbot_v = 0.5_wp * ( gdepw_n(ji,jj,jk+1) + gdepw_n(ji,jj+1,jk+1) )
141               zkb_u = 2.0_wp * zk_u(ji,jj) * zbot_u     ! 2k * bottom depth
142               zkb_v = 2.0_wp * zk_v(ji,jj) * zbot_v     ! 2k * bottom depth
143               !
144               zke3_u = MAX(1.e-8_wp, 2.0_wp * zk_u(ji,jj) * e3u_n(ji,jj,jk))     ! 2k * thickness
145               zke3_v = MAX(1.e-8_wp, 2.0_wp * zk_v(ji,jj) * e3v_n(ji,jj,jk))     ! 2k * thickness
146
147               ! Depth attenuation .... do u component first..
148               zdepth=zkb_u
149               zsqrt_depth = SQRT(zdepth)
150               zexp_depth = EXP(-zdepth)
151               zstokes_psi_u_bot = 1.0_wp - zexp_depth  &
152                    & - z_two_thirds*(zsqrtpi*zsqrt_depth*zdepth*ERFC(zsqrt_depth) &
153                    &                  + 1.0_wp - (1.0_wp + zdepth)*zexp_depth)
154               zda_u = (zstokes_psi_u_bot - zstokes_psi_u_top(ji,jj))/zke3_u
155               zstokes_psi_u_top(ji,jj) = zstokes_psi_u_bot
156
157               !         ... and then v component
158               zdepth=zkb_v
159               zsqrt_depth = SQRT(zdepth)
160               zexp_depth = EXP(-zdepth)
161               zstokes_psi_v_bot = 1.0_wp - zexp_depth  &
162                    & - z_two_thirds*(zsqrtpi*zsqrt_depth*zdepth*ERFC(zsqrt_depth) &
163                    &                  + 1.0_wp - (1.0_wp + zdepth)*zexp_depth)
164               zda_v = (zstokes_psi_v_bot - zstokes_psi_v_top(ji,jj))/zke3_v
165               zstokes_psi_v_top(ji,jj) = zstokes_psi_v_bot
166              !
167               usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
168               vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
169            END DO
170         END DO
171      END DO   
172      CALL lbc_lnk( usd(:,:,:), 'U', -1. )
173      CALL lbc_lnk( vsd(:,:,:), 'V', -1. )
174
175
176      !
177      !                       !==  vertical Stokes Drift 3D velocity  ==!
178      !
179      DO jk = 1, jpkm1               ! Horizontal e3*divergence
180         DO jj = 2, jpj
181            DO ji = fs_2, jpi
182               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji  ,jj,jk)    &
183                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
184                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
185                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e1e2t(ji,jj)
186            END DO
187         END DO
188      END DO
189      !
190#if defined key_agrif
191      IF( .NOT. Agrif_Root() ) THEN
192         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh( 2:nbghostcells+1,:        ,:) = 0._wp      ! west
193         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh( nlci-nbghostcells:nlci-1,:,:) = 0._wp      ! east
194         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh( :,2:nbghostcells+1        ,:) = 0._wp      ! south
195         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh( :,nlcj-nbghostcells:nlcj-1,:) = 0._wp      ! north
196      ENDIF
197#endif
198      !
199      CALL lbc_lnk( ze3divh, 'T', 1. )
200      !
201      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
202      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
203      ENDIF
204      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
205         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
206      END DO
207      !
208      IF( ln_bdy ) THEN
209         DO jk = 1, jpkm1
210            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
211         END DO
212      ENDIF
213      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
214      div_sd(:,:) = 0._wp
215      DO jk = 1, jpkm1                                 !
216        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
217      END DO
218      !
219      CALL iom_put( "ustokes",  usd  )
220      CALL iom_put( "vstokes",  vsd  )
221      CALL iom_put( "wstokes",  wsd  )
222      !
223      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
224      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
225      CALL wrk_dealloc( jpi,jpj,       zstokes_psi_u_top, zstokes_psi_v_top)
226      !
227   END SUBROUTINE sbc_stokes
228
229
230   SUBROUTINE sbc_wave( kt )
231      !!---------------------------------------------------------------------
232      !!                     ***  ROUTINE sbc_wave  ***
233      !!
234      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
235      !!
236      !! ** Method  : - Read namelist namsbc_wave
237      !!              - Read Cd_n10 fields in netcdf files
238      !!              - Read stokes drift 2d in netcdf files
239      !!              - Read wave number in netcdf files
240      !!              - Compute 3d stokes drift using Breivik et al.,2014
241      !!                formulation
242      !! ** action 
243      !!---------------------------------------------------------------------
244      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
245      !!---------------------------------------------------------------------
246      !
247      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
248         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
249         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
250      ENDIF
251
252      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
253         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
254         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
255      ENDIF
256
257      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
258         !
259         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
260            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
261            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
262            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
263            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
264            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
265         ENDIF
266         !
267         ! Read also wave number if needed, so that it is available in coupling routines
268         IF( ln_zdfswm .AND. .NOT.cpl_wnum ) THEN
269            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
270            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
271         ENDIF
272           
273         !                                         !==  Computation of the 3d Stokes Drift  ==!
274         !
275         IF( jpfld == 4 )   CALL sbc_stokes()            ! Calculate only if required fields are read
276         !                                               ! In coupled wave model-NEMO case the call is done after coupling
277         !
278      ENDIF
279      !
280   END SUBROUTINE sbc_wave
281
282
283   SUBROUTINE sbc_wave_init
284      !!---------------------------------------------------------------------
285      !!                     ***  ROUTINE sbc_wave_init  ***
286      !!
287      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
288      !!
289      !! ** Method  : - Read namelist namsbc_wave
290      !!              - Read Cd_n10 fields in netcdf files
291      !!              - Read stokes drift 2d in netcdf files
292      !!              - Read wave number in netcdf files
293      !!              - Compute 3d stokes drift using Breivik et al.,2014
294      !!                formulation
295      !! ** action 
296      !!---------------------------------------------------------------------
297      INTEGER ::   ierror, ios   ! local integer
298      INTEGER ::   ifpr
299      !!
300      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
301      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
302      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
303                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
304      !
305      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc
306      !!---------------------------------------------------------------------
307      !
308      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
309      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
310901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
311         
312      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
313      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
314902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
315      IF(lwm) WRITE ( numond, namsbc_wave )
316      !
317      IF( ln_cdgw ) THEN
318         IF( .NOT. cpl_wdrag ) THEN
319            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
320            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
321            !
322                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
323            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
324            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
325         ENDIF
326         ALLOCATE( cdn_wave(jpi,jpj) )
327      ENDIF
328
329      IF( ln_tauoc ) THEN
330         IF( .NOT. cpl_wstrf ) THEN
331            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
332            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
333            !
334                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
335            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
336            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
337         ENDIF
338         ALLOCATE( tauoc_wave(jpi,jpj) )
339      ENDIF
340
341      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
342         jpfld=0
343         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
344         IF( .NOT. cpl_sdrftx ) THEN
345            jpfld  = jpfld + 1
346            jp_usd = jpfld
347         ENDIF
348         IF( .NOT. cpl_sdrfty ) THEN
349            jpfld  = jpfld + 1
350            jp_vsd = jpfld
351         ENDIF
352         IF( .NOT. cpl_hsig ) THEN
353            jpfld  = jpfld + 1
354            jp_hsw = jpfld
355         ENDIF
356         IF( .NOT. cpl_wper ) THEN
357            jpfld  = jpfld + 1
358            jp_wmp = jpfld
359         ENDIF
360
361         ! Read from file only the non-coupled fields
362         IF( jpfld > 0 ) THEN
363            ALLOCATE( slf_i(jpfld) )
364            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
365            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
366            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
367            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
368            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
369            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
370            !
371            DO ifpr= 1, jpfld
372               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
373               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
374            END DO
375            !
376            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
377         ENDIF
378         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
379         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
380         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
381         ALLOCATE( div_sd(jpi,jpj) )
382         ALLOCATE( tsd2d (jpi,jpj) )
383
384         ut0sd(:,:) = 0._wp
385         vt0sd(:,:) = 0._wp
386         hsw(:,:) = 0._wp
387         wmp(:,:) = 0._wp
388
389         usd(:,:,:) = 0._wp
390         vsd(:,:,:) = 0._wp
391         wsd(:,:,:) = 0._wp
392         ! Wave number needed only if ln_zdfswm=T
393         IF( .NOT. cpl_wnum ) THEN
394            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
395            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
396                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
397            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
398            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
399         ENDIF
400         ALLOCATE( wnum(jpi,jpj) )
401      ENDIF
402      !
403   END SUBROUTINE sbc_wave_init
404
405   !!======================================================================
406END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.