New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/TRA/trazdf.F90 @ 9094

Last change on this file since 9094 was 9094, checked in by cetlod, 6 years ago

Use of lbclnk_multi in subdir LDF & TRA
  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_zdf( kt )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE tra_zdf  ***
49      !!
50      !! ** Purpose :   compute the vertical ocean tracer physics.
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
53      !
54      INTEGER  ::   jk   ! Dummy loop indices
55      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
56      !!---------------------------------------------------------------------
57      !
58      IF( ln_timing )   CALL timing_start('tra_zdf')
59      !
60      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dt =      rdt   ! at nit000, =   rdt (restarting with Euler time stepping)
61      ELSEIF( kt <= nit000 + 1           ) THEN   ;   r2dt = 2. * rdt   ! otherwise, = 2 rdt (leapfrog)
62      ENDIF
63      !
64      IF( l_trdtra )   THEN                  !* Save ta and sa trends
65         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
66         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
67         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
68      ENDIF
69      !
70      !                                      !* compute lateral mixing trend and add it to the general trend
71      CALL tra_zdf_imp( kt, nit000, 'TRA', r2dt, tsb, tsa, jpts ) 
72
73!!gm WHY here !   and I don't like that !
74      ! DRAKKAR SSS control {
75      ! JMM avoid negative salinities near river outlet ! Ugly fix
76      ! JMM : restore negative salinities to small salinities:
77      WHERE( tsa(:,:,:,jp_sal) < 0._wp )   tsa(:,:,:,jp_sal) = 0.1_wp
78!!gm
79
80      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
81         DO jk = 1, jpkm1
82            ztrdt(:,:,jk) = ( ( tsa(:,:,jk,jp_tem)*e3t_a(:,:,jk) - tsb(:,:,jk,jp_tem)*e3t_b(:,:,jk) ) &
83               &          / (e3t_n(:,:,jk)*r2dt) ) - ztrdt(:,:,jk)
84            ztrds(:,:,jk) = ( ( tsa(:,:,jk,jp_sal)*e3t_a(:,:,jk) - tsb(:,:,jk,jp_sal)*e3t_b(:,:,jk) ) &
85              &           / (e3t_n(:,:,jk)*r2dt) ) - ztrds(:,:,jk)
86         END DO
87!!gm this should be moved in trdtra.F90 and done on all trends
88         CALL lbc_lnk_multi( ztrdt, 'T', 1. , ztrds, 'T', 1. )
89!!gm
90         CALL trd_tra( kt, 'TRA', jp_tem, jptra_zdf, ztrdt )
91         CALL trd_tra( kt, 'TRA', jp_sal, jptra_zdf, ztrds )
92         DEALLOCATE( ztrdt , ztrds )
93      ENDIF
94      !                                          ! print mean trends (used for debugging)
95      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
96         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
97      !
98      IF( ln_timing )   CALL timing_stop('tra_zdf')
99      !
100   END SUBROUTINE tra_zdf
101
102 
103   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, ptb, pta, kjpt ) 
104      !!----------------------------------------------------------------------
105      !!                  ***  ROUTINE tra_zdf_imp  ***
106      !!
107      !! ** Purpose :   Compute the after tracer through a implicit computation
108      !!     of the vertical tracer diffusion (including the vertical component
109      !!     of lateral mixing (only for 2nd order operator, for fourth order
110      !!     it is already computed and add to the general trend in traldf)
111      !!
112      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
113      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
114      !!      It is computed using a backward time scheme (t=after field)
115      !!      which provide directly the after tracer field.
116      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
117      !!      Surface and bottom boundary conditions: no diffusive flux on
118      !!      both tracers (bottom, applied through the masked field avt).
119      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
120      !!
121      !! ** Action  : - pta  becomes the after tracer
122      !!---------------------------------------------------------------------
123      INTEGER                              , INTENT(in   ) ::   kt       ! ocean time-step index
124      INTEGER                              , INTENT(in   ) ::   kit000   ! first time step index
125      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
126      INTEGER                              , INTENT(in   ) ::   kjpt     ! number of tracers
127      REAL(wp)                             , INTENT(in   ) ::   p2dt     ! tracer time-step
128      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb      ! before and now tracer fields
129      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta      ! in: tracer trend ; out: after tracer field
130      !
131      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
132      REAL(wp) ::  zrhs             ! local scalars
133      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwi, zwt, zwd, zws
134      !!---------------------------------------------------------------------
135      !
136      IF( ln_timing )   CALL timing_start('tra_zdf_imp')
137      !
138      IF( kt == kit000 )  THEN
139         IF(lwp)WRITE(numout,*)
140         IF(lwp)WRITE(numout,*) 'tra_zdf_imp : implicit vertical mixing on ', cdtype
141         IF(lwp)WRITE(numout,*) '~~~~~~~~~~~ '
142      ENDIF
143      !                                               ! ============= !
144      DO jn = 1, kjpt                                 !  tracer loop  !
145         !                                            ! ============= !
146         !  Matrix construction
147         ! --------------------
148         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
149         !
150         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
151            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
152            !
153            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
154            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN   ;   zwt(:,:,2:jpk) = avt(:,:,2:jpk)
155            ELSE                                            ;   zwt(:,:,2:jpk) = avs(:,:,2:jpk)
156            ENDIF
157            zwt(:,:,1) = 0._wp
158            !
159            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
160               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
161                  DO jk = 2, jpkm1
162                     DO jj = 2, jpjm1
163                        DO ji = fs_2, fs_jpim1   ! vector opt.
164                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
165                        END DO
166                     END DO
167                  END DO
168               ELSE                          ! standard or triad iso-neutral operator
169                  DO jk = 2, jpkm1
170                     DO jj = 2, jpjm1
171                        DO ji = fs_2, fs_jpim1   ! vector opt.
172                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
173                        END DO
174                     END DO
175                  END DO
176               ENDIF
177            ENDIF
178            !
179            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
180            DO jk = 1, jpkm1
181               DO jj = 2, jpjm1
182                  DO ji = fs_2, fs_jpim1   ! vector opt.
183!!gm BUG  I think, use e3w_a instead of e3w_n, not sure of that
184                     zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w_n(ji,jj,jk  )
185                     zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w_n(ji,jj,jk+1)
186                     zwd(ji,jj,jk) = e3t_a(ji,jj,jk) - zwi(ji,jj,jk) - zws(ji,jj,jk)
187                 END DO
188               END DO
189            END DO
190            !
191            !! Matrix inversion from the first level
192            !!----------------------------------------------------------------------
193            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
194            !
195            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
196            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
197            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
198            !        (        ...               )( ...  ) ( ...  )
199            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
200            !
201            !   m is decomposed in the product of an upper and lower triangular matrix.
202            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
203            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
204            !   and "superior" (above diagonal) components of the tridiagonal system.
205            !   The solution will be in the 4d array pta.
206            !   The 3d array zwt is used as a work space array.
207            !   En route to the solution pta is used a to evaluate the rhs and then
208            !   used as a work space array: its value is modified.
209            !
210            DO jj = 2, jpjm1        !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k)
211               DO ji = fs_2, fs_jpim1            ! done one for all passive tracers (so included in the IF instruction)
212                  zwt(ji,jj,1) = zwd(ji,jj,1)
213               END DO
214            END DO
215            DO jk = 2, jpkm1
216               DO jj = 2, jpjm1
217                  DO ji = fs_2, fs_jpim1
218                     zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
219                  END DO
220               END DO
221            END DO
222            !
223         ENDIF 
224         !         
225         DO jj = 2, jpjm1           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
226            DO ji = fs_2, fs_jpim1
227               pta(ji,jj,1,jn) = e3t_b(ji,jj,1) * ptb(ji,jj,1,jn) + p2dt * e3t_n(ji,jj,1) * pta(ji,jj,1,jn)
228            END DO
229         END DO
230         DO jk = 2, jpkm1
231            DO jj = 2, jpjm1
232               DO ji = fs_2, fs_jpim1
233                  zrhs = e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * e3t_n(ji,jj,jk) * pta(ji,jj,jk,jn)   ! zrhs=right hand side
234                  pta(ji,jj,jk,jn) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pta(ji,jj,jk-1,jn)
235               END DO
236            END DO
237         END DO
238         !
239         DO jj = 2, jpjm1           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
240            DO ji = fs_2, fs_jpim1
241               pta(ji,jj,jpkm1,jn) = pta(ji,jj,jpkm1,jn) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
242            END DO
243         END DO
244         DO jk = jpk-2, 1, -1
245            DO jj = 2, jpjm1
246               DO ji = fs_2, fs_jpim1
247                  pta(ji,jj,jk,jn) = ( pta(ji,jj,jk,jn) - zws(ji,jj,jk) * pta(ji,jj,jk+1,jn) )   &
248                     &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
249               END DO
250            END DO
251         END DO
252         !                                            ! ================= !
253      END DO                                          !  end tracer loop  !
254      !                                               ! ================= !
255      !
256      IF( ln_timing )   CALL timing_stop('tra_zdf_imp')
257      !
258   END SUBROUTINE tra_zdf_imp
259
260   !!==============================================================================
261END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.