New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/SAS_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/SAS_SRC/sbcssm.F90 @ 9124

Last change on this file since 9124 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

  • Property svn:keywords set to Id
File size: 15.7 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :
7   !!   NEMO         3.4  ! 2012-03 First version by S. Alderson
8   !!                     !         Heavily derived from Christian's dtadyn routine
9   !!                     !         in OFF_SRC
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_ssm_init : initialization, namelist read, and SAVEs control
14   !!   sbc_ssm      : Interpolation of the fields
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers variables
17   USE c1d             ! 1D configuration: lk_c1d
18   USE dom_oce         ! ocean domain: variables
19   USE zdf_oce         ! ocean vertical physics: variables
20   USE sbc_oce         ! surface module: variables
21   USE phycst          ! physical constants
22   USE eosbn2          ! equation of state - Brunt Vaisala frequency
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
25   !
26   USE in_out_manager  ! I/O manager
27   USE iom             ! I/O library
28   USE lib_mpp         ! distributed memory computing library
29   USE prtctl          ! print control
30   USE fldread         ! read input fields
31   USE timing          ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   sbc_ssm_init   ! called by sbc_init
37   PUBLIC   sbc_ssm        ! called by sbc
38
39   CHARACTER(len=100)   ::   cn_dir        !: Root directory for location of ssm files
40   LOGICAL              ::   ln_3d_uve     !: specify whether input velocity data is 3D
41   LOGICAL              ::   ln_read_frq   !: specify whether we must read frq or not
42   LOGICAL              ::   l_sasread     !: Ice intilisation: read a file (.TRUE.) or anaytical initilaistion in namelist &namsbc_sas
43   LOGICAL              ::   l_initdone = .false.
44   INTEGER     ::   nfld_3d
45   INTEGER     ::   nfld_2d
46
47   INTEGER     ::   jf_tem         ! index of temperature
48   INTEGER     ::   jf_sal         ! index of salinity
49   INTEGER     ::   jf_usp         ! index of u velocity component
50   INTEGER     ::   jf_vsp         ! index of v velocity component
51   INTEGER     ::   jf_ssh         ! index of sea surface height
52   INTEGER     ::   jf_e3t         ! index of first T level thickness
53   INTEGER     ::   jf_frq         ! index of fraction of qsr absorbed in the 1st T level
54
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d  ! structure of input fields (file information, fields read)
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d  ! structure of input fields (file information, fields read)
57
58   !!----------------------------------------------------------------------
59   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE sbc_ssm( kt )
66      !!----------------------------------------------------------------------
67      !!                  ***  ROUTINE sbc_ssm  ***
68      !!
69      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
70      !!               for an off-line simulation using surface processes only
71      !!
72      !! ** Method : calculates the position of data
73      !!             - interpolates data if needed
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      !
77      INTEGER  ::   ji, jj     ! dummy loop indices
78      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
79      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
80      !!----------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start( 'sbc_ssm')
83     
84      IF ( l_sasread ) THEN
85         IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d )      !==   read data at kt time step   ==!
86         IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d )      !==   read data at kt time step   ==!
87         !
88         IF( ln_3d_uve ) THEN
89            IF( .NOT. ln_linssh ) THEN
90               e3t_m(:,:) = sf_ssm_3d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor
91            ELSE
92               e3t_m(:,:) = e3t_0(:,:,1)                                 ! vertical scale factor
93            ENDIF
94            ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
95            ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
96         ELSE
97            IF( .NOT. ln_linssh ) THEN
98               e3t_m(:,:) = sf_ssm_2d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor
99            ELSE
100               e3t_m(:,:) = e3t_0(:,:,1)                                 ! vertical scale factor
101            ENDIF
102            ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
103            ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
104         ENDIF
105         !
106         sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1)    ! temperature
107         sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1)    ! salinity
108         ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1)    ! sea surface height
109         IF( ln_read_frq ) THEN
110            frq_m(:,:) = sf_ssm_2d(jf_frq)%fnow(:,:,1) * tmask(:,:,1) ! solar penetration
111         ELSE
112            frq_m(:,:) = 1._wp
113         ENDIF
114      ELSE
115         sss_m(:,:) = 35._wp                             ! =35. to obtain a physical value for the freezing point
116         CALL eos_fzp( sss_m(:,:), sst_m(:,:) )          ! sst_m is set at the freezing point
117         ssu_m(:,:) = 0._wp
118         ssv_m(:,:) = 0._wp
119         ssh_m(:,:) = 0._wp
120         IF( .NOT. ln_linssh ) e3t_m(:,:) = e3t_0(:,:,1) !clem: necessary at least for sas2D
121         frq_m(:,:) = 1._wp                              !              - -
122         sshn (:,:) = 0._wp                              !              - -
123      ENDIF
124     
125      IF ( nn_ice == 1 ) THEN
126         tsn(:,:,1,jp_tem) = sst_m(:,:)
127         tsn(:,:,1,jp_sal) = sss_m(:,:)
128         tsb(:,:,1,jp_tem) = sst_m(:,:)
129         tsb(:,:,1,jp_sal) = sss_m(:,:)
130      ENDIF
131      ub (:,:,1) = ssu_m(:,:)
132      vb (:,:,1) = ssv_m(:,:)
133 
134      IF(ln_ctl) THEN                  ! print control
135         CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m   - : ', mask1=tmask, ovlap=1   )
136         CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m   - : ', mask1=tmask, ovlap=1   )
137         CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m   - : ', mask1=umask, ovlap=1   )
138         CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m   - : ', mask1=vmask, ovlap=1   )
139         CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m   - : ', mask1=tmask, ovlap=1   )
140         IF( .NOT.ln_linssh )   CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' e3t_m   - : ', mask1=tmask, ovlap=1   )
141         IF( ln_read_frq    )   CALL prt_ctl(tab2d_1=frq_m, clinfo1=' frq_m   - : ', mask1=tmask, ovlap=1   )
142      ENDIF
143      !
144      IF( l_initdone ) THEN          !   Mean value at each nn_fsbc time-step   !
145         CALL iom_put( 'ssu_m', ssu_m )
146         CALL iom_put( 'ssv_m', ssv_m )
147         CALL iom_put( 'sst_m', sst_m )
148         CALL iom_put( 'sss_m', sss_m )
149         CALL iom_put( 'ssh_m', ssh_m )
150         IF( .NOT.ln_linssh )   CALL iom_put( 'e3t_m', e3t_m )
151         IF( ln_read_frq    )   CALL iom_put( 'frq_m', frq_m )
152      ENDIF
153      !
154      IF( ln_timing )   CALL timing_stop( 'sbc_ssm')
155      !
156   END SUBROUTINE sbc_ssm
157
158
159   SUBROUTINE sbc_ssm_init
160      !!----------------------------------------------------------------------
161      !!                  ***  ROUTINE sbc_ssm_init  ***
162      !!
163      !! ** Purpose :   Initialisation of the dynamical data     
164      !! ** Method  : - read the data namsbc_ssm namelist
165      !!
166      !! ** Action  : - read parameters
167      !!----------------------------------------------------------------------
168      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
169      INTEGER  :: ifpr                               ! dummy loop indice
170      INTEGER  :: inum, idv, idimv, jpm              ! local integer
171      INTEGER  ::   ios                              ! Local integer output status for namelist read
172      !!
173      CHARACTER(len=100)                     ::  cn_dir       ! Root directory for location of core files
174      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_3d       ! array of namelist information on the fields to read
175      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_2d       ! array of namelist information on the fields to read
176      TYPE(FLD_N) :: sn_tem, sn_sal                     ! information about the fields to be read
177      TYPE(FLD_N) :: sn_usp, sn_vsp
178      TYPE(FLD_N) :: sn_ssh, sn_e3t, sn_frq
179      !
180      NAMELIST/namsbc_sas/l_sasread, cn_dir, ln_3d_uve, ln_read_frq, sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh, sn_e3t, sn_frq
181      !!----------------------------------------------------------------------
182
183      IF( ln_rstart .AND. nn_components == jp_iam_sas ) RETURN
184     
185      REWIND( numnam_ref )              ! Namelist namsbc_sas in reference namelist : Input fields
186      READ  ( numnam_ref, namsbc_sas, IOSTAT = ios, ERR = 901)
187901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in reference namelist', lwp )
188
189      REWIND( numnam_cfg )              ! Namelist namsbc_sas in configuration namelist : Input fields
190      READ  ( numnam_cfg, namsbc_sas, IOSTAT = ios, ERR = 902 )
191902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in configuration namelist', lwp )
192      IF(lwm) WRITE ( numond, namsbc_sas )
193
194      !                                         ! store namelist information in an array
195      !                                         ! Control print
196      IF(lwp) THEN
197         WRITE(numout,*)
198         WRITE(numout,*) 'sbc_sas : standalone surface scheme '
199         WRITE(numout,*) '~~~~~~~~~~~ '
200         WRITE(numout,*) '   Namelist namsbc_sas'
201         WRITE(numout,*) '      Initialisation using an input file  = ',l_sasread 
202         WRITE(numout,*) '      Are we supplying a 3D u,v and e3 field                             ln_3d_uve   = ', ln_3d_uve
203         WRITE(numout,*) '      Are we reading frq (fraction of qsr absorbed in the 1st T level)   ln_read_frq = ', ln_read_frq
204         WRITE(numout,*)
205      ENDIF
206      !
207      !! switch off stuff that isn't sensible with a standalone module
208      !! note that we need sbc_ssm called first in sbc
209      !
210      IF( ln_apr_dyn ) THEN
211         IF( lwp ) WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
212         ln_apr_dyn = .FALSE.
213      ENDIF
214      IF( ln_rnf ) THEN
215         IF( lwp ) WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
216         ln_rnf = .FALSE.
217      ENDIF
218      IF( ln_ssr ) THEN
219         IF( lwp ) WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
220         ln_ssr = .FALSE.
221      ENDIF
222      IF( nn_fwb > 0 ) THEN
223         IF( lwp ) WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
224         nn_fwb = 0
225      ENDIF
226      IF( nn_closea > 0 ) THEN
227         IF( lwp ) WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
228         nn_closea = 0
229      ENDIF
230      IF (l_sasread) THEN
231      !
232      !! following code is a bit messy, but distinguishes between when u,v are 3d arrays and
233      !! when we have other 3d arrays that we need to read in
234      !! so if a new field is added i.e. jf_new, just give it the next integer in sequence
235      !! for the corresponding dimension (currently if ln_3d_uve is true, 4 for 2d and 3 for 3d,
236      !! alternatively if ln_3d_uve is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d,
237      !! and the rest of the logic should still work
238      !
239      jf_tem = 1 ; jf_sal = 2 ; jf_ssh = 3 ; jf_frq = 4   ! default 2D fields index
240      !
241      IF( ln_3d_uve ) THEN
242         jf_usp = 1 ; jf_vsp = 2 ; jf_e3t = 3      ! define 3D fields index
243         nfld_3d  = 2 + COUNT( (/.NOT.ln_linssh/) )        ! number of 3D fields to read
244         nfld_2d  = 3 + COUNT( (/ln_read_frq/) )   ! number of 2D fields to read
245      ELSE
246         jf_usp = 4 ; jf_vsp = 5 ; jf_e3t = 6 ; jf_frq = 6 + COUNT( (/.NOT.ln_linssh/) )   ! update 2D fields index
247         nfld_3d  = 0                                                              ! no 3D fields to read
248         nfld_2d  = 5 + COUNT( (/.NOT.ln_linssh/) ) + COUNT( (/ln_read_frq/) )             ! number of 2D fields to read
249      ENDIF
250
251      IF( nfld_3d > 0 ) THEN
252         ALLOCATE( slf_3d(nfld_3d), STAT=ierr )         ! set slf structure
253         IF( ierr > 0 ) THEN
254            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' )   ;   RETURN
255         ENDIF
256         slf_3d(jf_usp) = sn_usp
257         slf_3d(jf_vsp) = sn_vsp
258         IF( .NOT.ln_linssh )   slf_3d(jf_e3t) = sn_e3t
259      ENDIF
260
261      IF( nfld_2d > 0 ) THEN
262         ALLOCATE( slf_2d(nfld_2d), STAT=ierr )         ! set slf structure
263         IF( ierr > 0 ) THEN
264            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' )   ;   RETURN
265         ENDIF
266         slf_2d(jf_tem) = sn_tem ; slf_2d(jf_sal) = sn_sal ; slf_2d(jf_ssh) = sn_ssh
267         IF( ln_read_frq )   slf_2d(jf_frq) = sn_frq
268         IF( .NOT. ln_3d_uve ) THEN
269            slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp
270            IF( .NOT.ln_linssh )   slf_2d(jf_e3t) = sn_e3t
271         ENDIF
272      ENDIF
273      !
274      ierr1 = 0    ! default definition if slf_?d(ifpr)%ln_tint = .false.
275      IF( nfld_3d > 0 ) THEN
276         ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr )         ! set sf structure
277         IF( ierr > 0 ) THEN
278            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' )   ;   RETURN
279         ENDIF
280         DO ifpr = 1, nfld_3d
281                                       ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk)    , STAT=ierr0 )
282            IF( slf_3d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2)  , STAT=ierr1 )
283            IF( ierr0 + ierr1 > 0 ) THEN
284               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' )   ;   RETURN
285            ENDIF
286         END DO
287         !                                         ! fill sf with slf_i and control print
288         CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' )
289      ENDIF
290
291      IF( nfld_2d > 0 ) THEN
292         ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr )         ! set sf structure
293         IF( ierr > 0 ) THEN
294            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' )   ;   RETURN
295         ENDIF
296         DO ifpr = 1, nfld_2d
297                                       ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
298            IF( slf_2d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
299            IF( ierr0 + ierr1 > 0 ) THEN
300               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' )   ;   RETURN
301            ENDIF
302         END DO
303         !
304         CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' )
305      ENDIF
306      !
307      ! finally tidy up
308
309      IF( nfld_3d > 0 ) DEALLOCATE( slf_3d, STAT=ierr )
310      IF( nfld_2d > 0 ) DEALLOCATE( slf_2d, STAT=ierr )
311
312   ENDIF
313 
314      CALL sbc_ssm( nit000 )   ! need to define ss?_m arrays used in iceistate
315      l_initdone = .TRUE.
316      !
317   END SUBROUTINE sbc_ssm_init
318
319   !!======================================================================
320END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.