New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zflx.F90 @ 9125

Last change on this file since 9125 was 9125, checked in by timgraham, 6 years ago

Removed wrk_arrays from whole code. No change in SETTE results from this.
  • Property svn:keywords set to Id
File size: 18.4 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!----------------------------------------------------------------------
13   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
14   !!   p4z_flx_init  :   Read the namelist
15   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
16   !!----------------------------------------------------------------------
17   USE oce_trc                      !  shared variables between ocean and passive tracers
18   USE trc                          !  passive tracers common variables
19   USE sms_pisces                   !  PISCES Source Minus Sink variables
20   USE p4zche                       !  Chemical model
21   USE prtctl_trc                   !  print control for debugging
22   USE iom                          !  I/O manager
23   USE fldread                      !  read input fields
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_flx 
29   PUBLIC   p4z_flx_init 
30   PUBLIC   p4z_flx_alloc 
31
32   !                               !!** Namelist  nampisext  **
33   REAL(wp)          ::  atcco2     !: pre-industrial atmospheric [co2] (ppm)   
34   LOGICAL           ::  ln_co2int  !: flag to read in a file and interpolate atmospheric pco2 or not
35   CHARACTER(len=34) ::  clname     !: filename of pco2 values
36   INTEGER           ::  nn_offset  !: Offset model-data start year (default = 0)
37
38   !!  Variables related to reading atmospheric CO2 time history   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years
40   INTEGER  :: nmaxrec, numco2
41
42   !                               !!* nampisatm namelist (Atmospheric PRessure) *
43   LOGICAL, PUBLIC ::   ln_presatm     !: ref. pressure: global mean Patm (F) or a constant (F)
44   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
45
46   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) ::  patm      ! atmospheric pressure at kt                 [N/m2]
47   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::  sf_patm   ! structure of input fields (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::  sf_atmco2 ! structure of input fields (file informations, fields read)
49
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2   !: atmospheric pco2
51
52   REAL(wp) ::  xconv  = 0.01_wp / 3600._wp !: coefficients for conversion
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE p4z_flx ( kt, knt )
62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p4z_flx  ***
64      !!
65      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
66      !!
67      !! ** Method  :
68      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
69      !!              - Remove Wanninkhof chemical enhancement;
70      !!              - Add option for time-interpolation of atcco2.txt 
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) ::   kt, knt   !
74      !
75      INTEGER  ::   ji, jj, jm, iind, iindm1
76      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
77      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
78      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
79      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
80      REAL(wp) ::   zyr_dec, zdco2dt
81      CHARACTER (len=25) :: charout
82      REAL(wp), DIMENSION(jpi,jpj) :: zkgco2, zkgo2, zh2co3, zoflx,  zpco2atm 
83      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
84      !!---------------------------------------------------------------------
85      !
86      IF( ln_timing )   CALL timing_start('p4z_flx')
87      !
88
89      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
90      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
91      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
92
93      IF( kt /= nit000 .AND. .NOT.l_co2cpl .AND. knt == 1 ) CALL p4z_patm( kt )    ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
94
95      IF( ln_co2int .AND. .NOT.ln_presatmco2 .AND. .NOT.l_co2cpl ) THEN 
96         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
97         ! Caveats: First column of .txt must be in years, decimal  years preferably.
98         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
99         ! then the first atmospheric CO2 record read is at years(1)
100         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
101         jm = 1
102         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
103         iind = jm  ;   iindm1 = jm - 1
104         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
105         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
106         satmco2(:,:) = atcco2 
107      ENDIF
108
109      IF( l_co2cpl )   satmco2(:,:) = atm_co2(:,:)
110
111      DO jj = 1, jpj
112         DO ji = 1, jpi
113            ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
114            zfact = rhop(ji,jj,1) / 1000. + rtrn
115            zdic  = trb(ji,jj,1,jpdic)
116            zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
117            ! CALCULATE [H2CO3]
118            zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
119         END DO
120      END DO
121
122      ! --------------
123      ! COMPUTE FLUXES
124      ! --------------
125
126      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
127      ! -------------------------------------------
128
129      DO jj = 1, jpj
130         DO ji = 1, jpi
131            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
132            ztc2 = ztc * ztc
133            ztc3 = ztc * ztc2 
134            ztc4 = ztc2 * ztc2 
135            ! Compute the schmidt Number both O2 and CO2
136            zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
137            zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
138            !  wind speed
139            zws  = wndm(ji,jj) * wndm(ji,jj)
140            ! Compute the piston velocity for O2 and CO2
141            zkgwan = 0.251 * zws
142            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
143            ! compute gas exchange for CO2 and O2
144            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
145            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
146         END DO
147      END DO
148
149
150      DO jj = 1, jpj
151         DO ji = 1, jpi
152            ztkel = tempis(ji,jj,1) + 273.15
153            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
154            zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
155            zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
156            zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
157            zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
158            &           / ( 82.05736 * ztkel ))
159            zfco2 = zpco2atm(ji,jj) * zfugcoeff
160
161            ! Compute CO2 flux for the sea and air
162            zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
163            zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
164            oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
165            ! compute the trend
166            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / e3t_n(ji,jj,1) * tmask(ji,jj,1)
167
168            ! Compute O2 flux
169            zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
170            zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj)
171            zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
172            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_n(ji,jj,1)
173         END DO
174      END DO
175
176      t_oce_co2_flx     = glob_sum( oce_co2(:,:) )                    !  Total Flux of Carbon
177      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
178!      t_atm_co2_flx     = glob_sum( satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
179      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
180 
181      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
182         WRITE(charout, FMT="('flx ')")
183         CALL prt_ctl_trc_info(charout)
184         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
185      ENDIF
186
187      IF( lk_iomput .AND. knt == nrdttrc ) THEN
188         ALLOCATE( zw2d(jpi,jpj) ) 
189         IF( iom_use( "Cflx"  ) )  THEN
190            zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r
191            CALL iom_put( "Cflx"     , zw2d ) 
192         ENDIF
193         IF( iom_use( "Oflx"  ) )  THEN
194            zw2d(:,:) =  zoflx(:,:) * 1000 * tmask(:,:,1)
195            CALL iom_put( "Oflx" , zw2d )
196         ENDIF
197         IF( iom_use( "Kg"    ) )  THEN
198            zw2d(:,:) =  zkgco2(:,:) * tmask(:,:,1)
199            CALL iom_put( "Kg"   , zw2d )
200         ENDIF
201         IF( iom_use( "Dpco2" ) ) THEN
202           zw2d(:,:) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1)
203           CALL iom_put( "Dpco2" ,  zw2d )
204         ENDIF
205         IF( iom_use( "Dpo2" ) )  THEN
206           zw2d(:,:) = ( atcox * patm(:,:) - atcox * trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1)
207           CALL iom_put( "Dpo2"  , zw2d )
208         ENDIF
209         IF( iom_use( "tcflx" ) )  CALL iom_put( "tcflx"    , t_oce_co2_flx * rfact2r )   ! molC/s
210         CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum )      ! molC
211         !
212         DEALLOCATE( zw2d )
213      ENDIF
214      !
215      IF( ln_timing )   CALL timing_stop('p4z_flx')
216      !
217   END SUBROUTINE p4z_flx
218
219
220   SUBROUTINE p4z_flx_init
221      !!----------------------------------------------------------------------
222      !!                  ***  ROUTINE p4z_flx_init  ***
223      !!
224      !! ** Purpose :   Initialization of atmospheric conditions
225      !!
226      !! ** Method  :   Read the nampisext namelist and check the parameters
227      !!      called at the first timestep (nittrc000)
228      !! ** input   :   Namelist nampisext
229      !!----------------------------------------------------------------------
230      INTEGER ::   jm
231      INTEGER ::   ios   ! Local integer
232      !
233      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
234      !!----------------------------------------------------------------------
235      !
236
237      REWIND( numnatp_ref )              ! Namelist nampisext in reference namelist : Pisces atm. conditions
238      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
239901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp )
240
241      REWIND( numnatp_cfg )              ! Namelist nampisext in configuration namelist : Pisces atm. conditions
242      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
243902   IF( ios >  0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp )
244      IF(lwm) WRITE ( numonp, nampisext )
245      !
246      IF(lwp) THEN                         ! control print
247         WRITE(numout,*) ' '
248         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
249         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
250         WRITE(numout,*) '    Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int
251         WRITE(numout,*) ' '
252      ENDIF
253     IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
254         IF(lwp) THEN                         ! control print
255            WRITE(numout,*) '    Constant Atmospheric pCO2 value  atcco2    =', atcco2
256            WRITE(numout,*) ' '
257         ENDIF
258         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
259      ELSEIF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
260         IF(lwp)  THEN
261            WRITE(numout,*) '    Atmospheric pCO2 value  from file clname      =', TRIM( clname )
262            WRITE(numout,*) '    Offset model-data start year      nn_offset   =', nn_offset
263            WRITE(numout,*) ' '
264         ENDIF
265         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
266         jm = 0                      ! Count the number of record in co2 file
267         DO
268           READ(numco2,*,END=100) 
269           jm = jm + 1
270         END DO
271 100     nmaxrec = jm - 1 
272         ALLOCATE( years  (nmaxrec) )     ;      years  (:) = 0._wp
273         ALLOCATE( atcco2h(nmaxrec) )     ;      atcco2h(:) = 0._wp
274
275         REWIND(numco2)
276         DO jm = 1, nmaxrec          ! get  xCO2 data
277            READ(numco2, *)  years(jm), atcco2h(jm)
278            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
279         END DO
280         CLOSE(numco2)
281      ELSEIF( .NOT.ln_co2int .AND. ln_presatmco2 ) THEN
282         IF(lwp)  THEN
283            WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
284            WRITE(numout,*) ' '
285         ENDIF
286      ELSE
287         IF(lwp)  THEN
288            WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
289            WRITE(numout,*) ' '
290         ENDIF
291      ENDIF
292      !
293      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
294      t_oce_co2_flx = 0._wp
295      t_atm_co2_flx = 0._wp
296      !
297      CALL p4z_patm( nit000 )
298      !
299   END SUBROUTINE p4z_flx_init
300
301
302   SUBROUTINE p4z_patm( kt )
303      !!----------------------------------------------------------------------
304      !!                  ***  ROUTINE p4z_atm  ***
305      !!
306      !! ** Purpose :   Read and interpolate the external atmospheric sea-levl pressure
307      !! ** Method  :   Read the files and interpolate the appropriate variables
308      !!
309      !!----------------------------------------------------------------------
310      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
311      !
312      INTEGER            ::  ierr
313      INTEGER            ::  ios      ! Local integer output status for namelist read
314      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
315      TYPE(FLD_N)        ::  sn_patm  ! informations about the fields to be read
316      TYPE(FLD_N)        ::  sn_atmco2 ! informations about the fields to be read
317      !!
318      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
319      !!----------------------------------------------------------------------
320
321      !                                         ! ----------------------- !
322      IF( kt == nit000 ) THEN                   ! First call kt=nittrc000 !
323
324         REWIND( numnatp_ref )              ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file
325         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
326901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp )
327
328         REWIND( numnatp_cfg )              ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file
329         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
330902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp )
331         IF(lwm) WRITE ( numonp, nampisatm )
332         !
333         !
334         IF(lwp) THEN                                 !* control print
335            WRITE(numout,*)
336            WRITE(numout,*) '   Namelist nampisatm : Atmospheric Pressure as external forcing'
337            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm = ', ln_presatm
338            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs  ln_presatmco2 = ', ln_presatmco2
339            WRITE(numout,*)
340         ENDIF
341         !
342         IF( ln_presatm ) THEN
343            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
344            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
345            !
346            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
347                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
348            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
349         ENDIF
350         !                                         
351         IF( ln_presatmco2 ) THEN
352            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
353            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
354            !
355            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
356                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
357            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
358         ENDIF
359         !
360         IF( .NOT.ln_presatm )   patm(:,:) = 1.e0    ! Initialize patm if no reading from a file
361         !
362      ENDIF
363      !
364      IF( ln_presatm ) THEN
365         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
366         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
367      ENDIF
368      !
369      IF( ln_presatmco2 ) THEN
370         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
371         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
372      ELSE
373         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
374      ENDIF
375      !
376   END SUBROUTINE p4z_patm
377
378
379   INTEGER FUNCTION p4z_flx_alloc()
380      !!----------------------------------------------------------------------
381      !!                     ***  ROUTINE p4z_flx_alloc  ***
382      !!----------------------------------------------------------------------
383      ALLOCATE( satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
384      !
385      IF( p4z_flx_alloc /= 0 )   CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays')
386      !
387   END FUNCTION p4z_flx_alloc
388
389   !!======================================================================
390END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.