New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcbc.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/TOP_SRC/trcbc.F90 @ 9134

Last change on this file since 9134 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

  • Property svn:keywords set to Id
File size: 22.7 KB
Line 
1MODULE trcbc
2   !!======================================================================
3   !!                     ***  MODULE  trcbc  ***
4   !! TOP :  module for passive tracer boundary conditions
5   !!=====================================================================
6   !! History :  3.5 !  2014 (M. Vichi, T. Lovato)  Original
7   !!            3.6 !  2015 (T . Lovato) Revision and BDY support
8   !!            4.0 !  2016 (T . Lovato) Include application of sbc and cbc
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP model
13   !!----------------------------------------------------------------------
14   !!   trc_bc       :  Apply tracer Boundary Conditions
15   !!----------------------------------------------------------------------
16   USE par_trc       !  passive tracers parameters
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE iom           !  I/O manager
20   USE lib_mpp       !  MPP library
21   USE fldread       !  read input fields
22   USE bdy_oce,  ONLY: ln_bdy, nb_bdy , idx_bdy, ln_coords_file, rn_time_dmp, rn_time_dmp_out
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_bc         ! called in trcstp.F90 or within TOP modules
28   PUBLIC   trc_bc_ini     ! called in trcini.F90
29
30   INTEGER  , SAVE, PUBLIC                             :: nb_trcobc    ! number of tracers with open BC
31   INTEGER  , SAVE, PUBLIC                             :: nb_trcsbc    ! number of tracers with surface BC
32   INTEGER  , SAVE, PUBLIC                             :: nb_trccbc    ! number of tracers with coastal BC
33   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indobc ! index of tracer with OBC data
34   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indsbc ! index of tracer with SBC data
35   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indcbc ! index of tracer with CBC data
36   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trsfac    ! multiplicative factor for SBC tracer values
37   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcsbc    ! structure of data input SBC (file informations, fields read)
38   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trcfac    ! multiplicative factor for CBC tracer values
39   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trccbc    ! structure of data input CBC (file informations, fields read)
40   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trofac    ! multiplicative factor for OBCtracer values
41   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET  :: sf_trcobc    ! structure of data input OBC (file informations, fields read)
42   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
43
44   !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2016)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE trc_bc_ini( ntrc )
54      !!----------------------------------------------------------------------
55      !!                   ***  ROUTINE trc_bc_ini  ***
56      !!                   
57      !! ** Purpose :   initialisation of passive tracer BC data
58      !!
59      !! ** Method  : - Read namtsd namelist
60      !!              - allocates passive tracer BC data structure
61      !!----------------------------------------------------------------------
62      INTEGER,INTENT(IN) :: ntrc                           ! number of tracers
63      INTEGER            :: jl, jn , ib, ibd, ii, ij, ik   ! dummy loop indices
64      INTEGER            :: ierr0, ierr1, ierr2, ierr3     ! temporary integers
65      INTEGER            :: ios                            ! Local integer output status for namelist read
66      INTEGER            :: nblen, igrd                    ! support arrays for BDY
67      CHARACTER(len=100) :: clndta, clntrc
68      !
69      CHARACTER(len=100) :: cn_dir_sbc, cn_dir_cbc, cn_dir_obc
70
71      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i  ! local array of namelist informations on the fields to read
72      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcobc    ! open
73      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcsbc    ! surface
74      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trccbc    ! coastal
75      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trofac    ! multiplicative factor for tracer values
76      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trsfac    ! multiplicative factor for tracer values
77      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trcfac    ! multiplicative factor for tracer values
78      !!
79      NAMELIST/namtrc_bc/ cn_dir_obc, sn_trcobc, rn_trofac, cn_dir_sbc, sn_trcsbc, rn_trsfac, & 
80                        & cn_dir_cbc, sn_trccbc, rn_trcfac, ln_rnf_ctl, rn_bc_time
81      NAMELIST/namtrc_bdy/ cn_trc_dflt, cn_trc, nn_trcdmp_bdy
82      !!----------------------------------------------------------------------
83      !
84      IF( lwp ) THEN
85         WRITE(numout,*) ' '
86         WRITE(numout,*) 'trc_bc_ini : Tracers Boundary Conditions (BC)'
87         WRITE(numout,*) '~~~~~~~~~~~ '
88      ENDIF
89      !  Initialisation and local array allocation
90      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0 
91      ALLOCATE( slf_i(ntrc), STAT=ierr0 )
92      IF( ierr0 > 0 ) THEN
93         CALL ctl_stop( 'trc_bc_ini: unable to allocate local slf_i' )   ;   RETURN
94      ENDIF
95
96      ! Compute the number of tracers to be initialised with open, surface and boundary data
97      ALLOCATE( n_trc_indobc(ntrc), STAT=ierr0 )
98      IF( ierr0 > 0 ) THEN
99         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indobc' )   ;   RETURN
100      ENDIF
101      nb_trcobc      = 0
102      n_trc_indobc(:) = 0
103      !
104      ALLOCATE( n_trc_indsbc(ntrc), STAT=ierr0 )
105      IF( ierr0 > 0 ) THEN
106         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indsbc' )   ;   RETURN
107      ENDIF
108      nb_trcsbc      = 0
109      n_trc_indsbc(:) = 0
110      !
111      ALLOCATE( n_trc_indcbc(ntrc), STAT=ierr0 )
112      IF( ierr0 > 0 ) THEN
113         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indcbc' )   ;   RETURN
114      ENDIF
115      nb_trccbc      = 0
116      n_trc_indcbc(:) = 0
117      !
118      ! Read Boundary Conditions Namelists
119      REWIND( numnat_ref )              ! Namelist namtrc_bc in reference namelist : Passive tracer data structure
120      READ  ( numnat_ref, namtrc_bc, IOSTAT = ios, ERR = 901)
121901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_bc in reference namelist', lwp )
122
123      REWIND( numnat_cfg )              ! Namelist namtrc_bc in configuration namelist : Passive tracer data structure
124      READ  ( numnat_cfg, namtrc_bc, IOSTAT = ios, ERR = 902 )
125902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_bc in configuration namelist', lwp )
126      IF(lwm) WRITE ( numont, namtrc_bc )
127
128      IF ( ln_bdy ) THEN
129         REWIND( numnat_ref )              ! Namelist namtrc_bdy in reference namelist : Passive tracer data structure
130         READ  ( numnat_ref, namtrc_bdy, IOSTAT = ios, ERR = 903)
131903      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_bdy in reference namelist', lwp )
132
133         REWIND( numnat_cfg )              ! Namelist namtrc_bdy in configuration namelist : Passive tracer data structure
134         READ  ( numnat_cfg, namtrc_bdy, IOSTAT = ios, ERR = 904 )
135904      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_bdy in configuration namelist', lwp )
136         IF(lwm) WRITE ( numont, namtrc_bdy )
137     
138         ! setup up preliminary informations for BDY structure
139         DO jn = 1, ntrc
140            DO ib = 1, nb_bdy
141               ! Set type of obc in BDY data structure (around here we may plug user override of obc type from nml)
142               IF ( ln_trc_obc(jn) ) THEN
143                  trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc(ib) )
144               ELSE
145                  trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc_dflt(ib) )
146               ENDIF
147               ! set damping use in BDY data structure
148               trcdta_bdy(jn,ib)%dmp = .false.
149               IF(nn_trcdmp_bdy(ib) .EQ. 1 .AND. ln_trc_obc(jn) ) trcdta_bdy(jn,ib)%dmp = .true.
150               IF(nn_trcdmp_bdy(ib) .EQ. 2 ) trcdta_bdy(jn,ib)%dmp = .true.
151               IF(trcdta_bdy(jn,ib)%cn_obc == 'frs' .AND. nn_trcdmp_bdy(ib) .NE. 0 )  &
152                   & CALL ctl_stop( 'Use FRS OR relaxation' )
153               IF (nn_trcdmp_bdy(ib) .LT. 0 .OR. nn_trcdmp_bdy(ib) .GT. 2)            &
154                   & CALL ctl_stop( 'Not a valid option for nn_trcdmp_bdy. Allowed: 0,1,2.' )
155            ENDDO
156         ENDDO
157      ELSE
158         ! Force all tracers OBC to false if bdy not used
159         ln_trc_obc = .false.
160      ENDIF
161
162      ! compose BC data indexes
163      DO jn = 1, ntrc
164         IF( ln_trc_obc(jn) ) THEN
165             nb_trcobc       = nb_trcobc + 1  ; n_trc_indobc(jn) = nb_trcobc
166         ENDIF
167         IF( ln_trc_sbc(jn) ) THEN
168             nb_trcsbc       = nb_trcsbc + 1  ; n_trc_indsbc(jn) = nb_trcsbc
169         ENDIF
170         IF( ln_trc_cbc(jn) ) THEN
171             nb_trccbc       = nb_trccbc + 1  ; n_trc_indcbc(jn) = nb_trccbc
172         ENDIF
173      ENDDO
174
175      ! Print summmary of Boundary Conditions
176      IF( lwp ) THEN
177         WRITE(numout,*) ' '
178         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with SURFACE BCs data:', nb_trcsbc
179         IF ( nb_trcsbc > 0 ) THEN
180            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
181            DO jn = 1, ntrc
182               IF ( ln_trc_sbc(jn) ) WRITE(numout,9001) jn, TRIM( sn_trcsbc(jn)%clvar ), 'SBC', rn_trsfac(jn)
183            ENDDO
184         ENDIF
185         WRITE(numout,'(2a)') '   SURFACE BC data repository : ', TRIM(cn_dir_sbc)
186
187         WRITE(numout,*) ' '
188         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with COASTAL BCs data:', nb_trccbc
189         IF( nb_trccbc > 0 ) THEN
190            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
191            DO jn = 1, ntrc
192               IF ( ln_trc_cbc(jn) ) WRITE(numout, 9001) jn, TRIM( sn_trccbc(jn)%clvar ), 'CBC', rn_trcfac(jn)
193            ENDDO
194         ENDIF
195         WRITE(numout,'(2a)') '   COASTAL BC data repository : ', TRIM(cn_dir_cbc)
196         IF( .NOT.ln_rnf .OR. .NOT.ln_linssh ) ln_rnf_ctl = .FALSE.
197         IF( ln_rnf_ctl )  WRITE(numout,'(a)') &
198              &            ' -> Remove runoff dilution effect on tracers with absent river load (ln_rnf_ctl = .TRUE.)'
199         WRITE(numout,*) ' '
200         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with OPEN BCs data:', nb_trcobc
201
202         IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
203            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact.   OBC Settings'
204            DO jn = 1, ntrc
205               IF (       ln_trc_obc(jn) )  WRITE(numout, 9001) jn, TRIM( sn_trcobc(jn)%clvar ), 'OBC', rn_trofac(jn), &
206                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
207               IF ( .NOT. ln_trc_obc(jn) )  WRITE(numout, 9002) jn, 'Set data to IC and use default condition'       , &
208                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
209            ENDDO
210            WRITE(numout,*) ' '
211            DO ib = 1, nb_bdy
212                IF(nn_trcdmp_bdy(ib) .EQ. 0) WRITE(numout,9003) '   Boundary ', ib, &
213                     &                                          ' -> NO damping of tracers'
214                IF(nn_trcdmp_bdy(ib) .EQ. 1) WRITE(numout,9003) '   Boundary ', ib, &
215                     &                                          ' -> damping ONLY for tracers with external data provided'
216                IF(nn_trcdmp_bdy(ib) .EQ. 2) WRITE(numout,9003) '   Boundary ', ib, &
217                     &                                          ' -> damping of ALL tracers'
218                IF(nn_trcdmp_bdy(ib) .GT. 0) THEN
219                   WRITE(numout,9003) '     USE damping parameters from nambdy for boundary ', ib,' : '
220                   WRITE(numout,'(a,f10.2,a)') '     - Inflow damping time scale  : ',rn_time_dmp(ib),' days'
221                   WRITE(numout,'(a,f10.2,a)') '     - Outflow damping time scale : ',rn_time_dmp_out(ib),' days'
222                ENDIF
223            ENDDO
224         ENDIF
225
226         WRITE(numout,'(2a)') '   OPEN BC data repository : ', TRIM(cn_dir_obc)
227      ENDIF
2289001  FORMAT(2x,i5, 3x, a15, 3x, a5, 6x, e11.3, 4x, 10a13)
2299002  FORMAT(2x,i5, 3x, a41, 3x, 10a13)
2309003  FORMAT(a, i5, a)
231
232      !
233      ! OPEN Lateral boundary conditions
234      IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
235         ALLOCATE ( sf_trcobc(nb_trcobc), rf_trofac(nb_trcobc), nbmap_ptr(nb_trcobc), STAT=ierr1 )
236         IF( ierr1 > 0 ) THEN
237            CALL ctl_stop( 'trc_bc_ini: unable to allocate sf_trcobc structure' )   ;   RETURN
238         ENDIF
239
240         igrd = 1                       ! Everything is at T-points here
241
242         DO jn = 1, ntrc
243            DO ib = 1, nb_bdy
244
245               nblen = idx_bdy(ib)%nblen(igrd)
246
247               IF ( ln_trc_obc(jn) ) THEN
248               ! Initialise from external data
249                  jl = n_trc_indobc(jn)
250                  slf_i(jl)    = sn_trcobc(jn)
251                  rf_trofac(jl) = rn_trofac(jn)
252                                               ALLOCATE( sf_trcobc(jl)%fnow(nblen,1,jpk)   , STAT=ierr2 )
253                  IF( sn_trcobc(jn)%ln_tint )  ALLOCATE( sf_trcobc(jl)%fdta(nblen,1,jpk,2) , STAT=ierr3 )
254                  IF( ierr2 + ierr3 > 0 ) THEN
255                    CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer OBC data arrays' )   ;   RETURN
256                  ENDIF
257                  trcdta_bdy(jn,ib)%trc => sf_trcobc(jl)%fnow(:,1,:)
258                  trcdta_bdy(jn,ib)%rn_fac = rf_trofac(jl)
259                  ! create OBC mapping array
260                  nbmap_ptr(jl)%ptr => idx_bdy(ib)%nbmap(:,igrd)
261                  nbmap_ptr(jl)%ll_unstruc = ln_coords_file(igrd)
262               ELSE
263               ! Initialise obc arrays from initial conditions
264                  ALLOCATE ( trcdta_bdy(jn,ib)%trc(nblen,jpk) )
265                  DO ibd = 1, nblen
266                     DO ik = 1, jpkm1
267                        ii = idx_bdy(ib)%nbi(ibd,igrd)
268                        ij = idx_bdy(ib)%nbj(ibd,igrd)
269                        trcdta_bdy(jn,ib)%trc(ibd,ik) = trn(ii,ij,ik,jn) * tmask(ii,ij,ik)
270                     END DO
271                  END DO
272                  trcdta_bdy(jn,ib)%rn_fac = 1._wp
273               ENDIF
274            ENDDO
275         ENDDO
276
277         CALL fld_fill( sf_trcobc, slf_i, cn_dir_obc, 'trc_bc_ini', 'Passive tracer OBC data', 'namtrc_bc' )
278      ENDIF
279
280      ! SURFACE Boundary conditions
281      IF( nb_trcsbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
282         ALLOCATE( sf_trcsbc(nb_trcsbc), rf_trsfac(nb_trcsbc), STAT=ierr1 )
283         IF( ierr1 > 0 ) THEN
284            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trcsbc structure' )   ;   RETURN
285         ENDIF
286         !
287         DO jn = 1, ntrc
288            IF( ln_trc_sbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
289               jl = n_trc_indsbc(jn)
290               slf_i(jl)    = sn_trcsbc(jn)
291               rf_trsfac(jl) = rn_trsfac(jn)
292                                            ALLOCATE( sf_trcsbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
293               IF( sn_trcsbc(jn)%ln_tint )  ALLOCATE( sf_trcsbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
294               IF( ierr2 + ierr3 > 0 ) THEN
295                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer SBC data arrays' )   ;   RETURN
296               ENDIF
297            ENDIF
298            !   
299         ENDDO
300         !                         ! fill sf_trcsbc with slf_i and control print
301         CALL fld_fill( sf_trcsbc, slf_i, cn_dir_sbc, 'trc_bc_ini', 'Passive tracer SBC data', 'namtrc_bc' )
302         !
303      ENDIF
304      !
305      ! COSTAL Boundary conditions
306      IF( nb_trccbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
307         ALLOCATE( sf_trccbc(nb_trccbc), rf_trcfac(nb_trccbc), STAT=ierr1 )
308         IF( ierr1 > 0 ) THEN
309            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trccbc structure' )   ;   RETURN
310         ENDIF
311         !
312         DO jn = 1, ntrc
313            IF( ln_trc_cbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
314               jl = n_trc_indcbc(jn)
315               slf_i(jl)    = sn_trccbc(jn)
316               rf_trcfac(jl) = rn_trcfac(jn)
317                                            ALLOCATE( sf_trccbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
318               IF( sn_trccbc(jn)%ln_tint )  ALLOCATE( sf_trccbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
319               IF( ierr2 + ierr3 > 0 ) THEN
320                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer CBC data arrays' )   ;   RETURN
321               ENDIF
322            ENDIF
323            !   
324         ENDDO
325         !                         ! fill sf_trccbc with slf_i and control print
326         CALL fld_fill( sf_trccbc, slf_i, cn_dir_cbc, 'trc_bc_ini', 'Passive tracer CBC data', 'namtrc_bc' )
327         !
328      ENDIF
329      !
330      DEALLOCATE( slf_i )          ! deallocate local field structure
331      !
332   END SUBROUTINE trc_bc_ini
333
334
335   SUBROUTINE trc_bc(kt, jit)
336      !!----------------------------------------------------------------------
337      !!                   ***  ROUTINE trc_bc  ***
338      !!
339      !! ** Purpose :  Apply Boundary Conditions data to tracers
340      !!
341      !! ** Method  :  1) Read BC inputs and update data structures using fldread
342      !!               2) Apply Boundary Conditions to tracers
343      !!             
344      !!----------------------------------------------------------------------
345      USE fldread
346      !!     
347      INTEGER, INTENT( in ) ::   kt              ! ocean time-step index
348      INTEGER, INTENT( in ), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
349      !!
350      INTEGER  :: ji, jj, jk, jn, jl             ! Loop index
351      REAL(wp) :: zfact, zrnf
352      !!---------------------------------------------------------------------
353      !
354      IF( ln_timing )   CALL timing_start('trc_bc')
355
356      IF( kt == nit000 .AND. lwp) THEN
357         WRITE(numout,*)
358         WRITE(numout,*) 'trc_bc : Surface boundary conditions for passive tracers.'
359         WRITE(numout,*) '~~~~~~~~~~~ '
360      ENDIF
361
362      ! 1. Update Boundary conditions data
363      IF ( PRESENT(jit) ) THEN 
364
365         ! OPEN boundary conditions (use time_offset=+1 as they are applied at the end of the step)
366         IF( nb_trcobc > 0 ) THEN
367           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
368           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trcobc, map=nbmap_ptr, kit=jit, kt_offset=+1)
369         ENDIF
370
371         ! SURFACE boundary conditions
372         IF( nb_trcsbc > 0 ) THEN
373           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
374           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trcsbc, kit=jit)
375         ENDIF
376
377         ! COASTAL boundary conditions
378         IF( nb_trccbc > 0 ) THEN
379           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
380           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trccbc, kit=jit)
381         ENDIF
382
383      ELSE
384
385         ! OPEN boundary conditions (use time_offset=+1 as they are applied at the end of the step)
386         IF( nb_trcobc > 0 ) THEN
387           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
388           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trcobc, map=nbmap_ptr, kt_offset=+1)
389         ENDIF
390
391         ! SURFACE boundary conditions
392         IF( nb_trcsbc > 0 ) THEN
393           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
394           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trcsbc)
395         ENDIF
396
397         ! COASTAL boundary conditions
398         IF( nb_trccbc > 0 ) THEN
399           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
400           CALL fld_read(kt=kt, kn_fsbc=1, sd=sf_trccbc)
401         ENDIF
402
403      ENDIF
404
405      ! 2. Apply Boundary conditions data
406      !
407      DO jn = 1 , jptra
408         !
409         ! Remove river dilution for tracers with absent river load
410         IF ( ln_rnf_ctl .AND. .NOT. ln_trc_cbc(jn) ) THEN
411            DO jj = 2, jpj
412               DO ji = fs_2, fs_jpim1
413                  DO jk = 1, nk_rnf(ji,jj)
414                     zrnf = (rnf(ji,jj) + rnf_b(ji,jj)) * 0.5_wp * r1_rau0 / h_rnf(ji,jj)
415                     tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)  + (trn(ji,jj,jk,jn) * zrnf)
416                  ENDDO
417               ENDDO
418            ENDDO
419         ENDIF
420         
421         ! OPEN boundary conditions: trcbdy is called in trcnxt !
422
423         ! SURFACE boundary conditions
424         IF (ln_trc_sbc(jn)) THEN
425            jl = n_trc_indsbc(jn)
426            DO jj = 2, jpj
427               DO ji = fs_2, fs_jpim1   ! vector opt.
428                  zfact = 1. / ( e3t_n(ji,jj,1) * rn_bc_time )
429                  tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + rf_trsfac(jl) * sf_trcsbc(jl)%fnow(ji,jj,1) * zfact
430               END DO
431            END DO
432         END IF
433
434         ! COASTAL boundary conditions
435         IF ( ln_rnf .AND. ln_trc_cbc(jn)) THEN
436            jl = n_trc_indcbc(jn)
437            DO jj = 2, jpj
438               DO ji = fs_2, fs_jpim1   ! vector opt.
439                  DO jk = 1, nk_rnf(ji,jj)
440                     zfact = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_bc_time ) 
441                     tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zfact
442                  ENDDO
443               END DO
444            END DO
445         END IF
446         !                                                       ! ===========
447      END DO                                                     ! tracer loop
448      !                                                          ! ===========
449      IF( ln_timing )   CALL timing_stop('trc_bc')
450      !
451   END SUBROUTINE trc_bc
452
453#else
454   !!----------------------------------------------------------------------
455   !!   Dummy module                              NO 3D passive tracer data
456   !!----------------------------------------------------------------------
457CONTAINS
458   SUBROUTINE trc_bc_ini( ntrc )        ! Empty routine
459      INTEGER,INTENT(IN) :: ntrc                           ! number of tracers
460      WRITE(*,*) 'trc_bc_ini: You should not have seen this print! error?', kt
461   END SUBROUTINE trc_bc_ini
462
463   SUBROUTINE trc_bc( kt )        ! Empty routine
464      WRITE(*,*) 'trc_bc: You should not have seen this print! error?', kt
465   END SUBROUTINE trc_bc
466#endif
467
468   !!======================================================================
469END MODULE trcbc
Note: See TracBrowser for help on using the repository browser.