source: branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfphy.F90 @ 8915

Last change on this file since 8915 was 8915, checked in by acc, 3 years ago

Branch 2017/dev_r7881_ENHANCE09_RK3. Remove call to osm_rst from zdfphy.F90. OSMOSIS requires the wn field and its restart must be written after wn has been updated later in step.F90

File size: 18.4 KB
Line 
1MODULE zdfphy
2   !!======================================================================
3   !!                      ***  MODULE  zdfphy  ***
4   !! Vertical ocean physics :   manager of all vertical physics packages
5   !!======================================================================
6   !! History :  4.0  !  2017-04  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   zdf_phy_init  : initialization of all vertical physics packages
11   !!   zdf_phy       : upadate at each time-step the vertical mixing coeff.
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE zdf_oce        ! vertical physics: shared variables         
15   USE zdfdrg         ! vertical physics: top/bottom drag coef.
16   USE zdfsh2         ! vertical physics: shear production term of TKE
17   USE zdfric         ! vertical physics: RIChardson dependent vertical mixing   
18   USE zdftke         ! vertical physics: TKE vertical mixing
19   USE zdfgls         ! vertical physics: GLS vertical mixing
20   USE zdfosm         ! vertical physics: OSMOSIS vertical mixing
21   USE zdfddm         ! vertical physics: double diffusion mixing     
22   USE zdfevd         ! vertical physics: convection via enhanced vertical diffusion 
23   USE zdfiwm         ! vertical physics: internal wave-induced mixing 
24   USE zdfswm         ! vertical physics: surface  wave-induced mixing
25   USE zdfmxl         ! vertical physics: mixed layer
26   USE tranpc         ! convection: non penetrative adjustment
27   USE trc_oce        ! variables shared between passive tracer & ocean           
28   USE sbc_oce        ! surface module (only for nn_isf in the option compatibility test)
29   USE sbcrnf         ! surface boundary condition: runoff variables
30#if defined key_agrif
31   USE agrif_opa_interp   ! interpavm
32#endif
33   !
34   USE in_out_manager ! I/O manager
35   USE iom            ! IOM library
36   USE lbclnk         ! lateral boundary conditions
37   USE lib_mpp        ! distribued memory computing
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   zdf_phy_init  ! called by nemogcm.F90
44   PUBLIC   zdf_phy       ! called by step.F90
45
46   INTEGER ::   nzdf_phy   ! type of vertical closure used
47   !                       ! associated indicators
48   INTEGER, PARAMETER ::   np_CST = 1   ! Constant Kz
49   INTEGER, PARAMETER ::   np_RIC = 2   ! Richardson number dependent Kz
50   INTEGER, PARAMETER ::   np_TKE = 3   ! Turbulente Kinetic Eenergy closure scheme for Kz
51   INTEGER, PARAMETER ::   np_GLS = 4   ! Generic Length Scale closure scheme for Kz
52   INTEGER, PARAMETER ::   np_OSM = 5   ! OSMOSIS-OBL closure scheme for Kz
53
54   LOGICAL ::   l_zdfsh2   ! shear production term flag (=F for CST, =T otherwise (i.e. TKE, GLS, RIC))
55
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
58   !! $Id: zdfphy.F90 8160 2017-06-10 07:31:34Z gm $
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE zdf_phy_init
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE zdf_phy_init  ***
66      !!
67      !! ** Purpose :   initializations of the vertical ocean physics
68      !!
69      !! ** Method  :   Read namelist namzdf, control logicals
70      !!                set horizontal shape and vertical profile of background mixing coef.
71      !!----------------------------------------------------------------------
72      INTEGER ::   jk            ! dummy loop indices
73      INTEGER ::   ioptio, ios   ! local integers
74      !!
75      NAMELIST/namzdf/ ln_zdfcst, ln_zdfric, ln_zdftke, ln_zdfgls,   &     ! type of closure scheme
76         &             ln_zdfosm,                                    &     ! type of closure scheme
77         &             ln_zdfevd, nn_evdm, rn_evd ,                  &     ! convection : evd
78         &             ln_zdfnpc, nn_npc , nn_npcp,                  &     ! convection : npc
79         &             ln_zdfddm, rn_avts, rn_hsbfr,                 &     ! double diffusion
80         &             ln_zdfswm,                                    &     ! surface  wave-induced mixing
81         &             ln_zdfiwm,                                    &     ! internal  -      -      -
82         &             rn_avm0, rn_avt0, nn_avb, nn_havtb                  ! coefficients
83      !!----------------------------------------------------------------------
84      !
85      IF( ln_timing )   CALL timing_start('zdf_phy_init')
86      !
87      !                           !==  Namelist  ==!
88      REWIND( numnam_ref )              ! Namelist namzdf in reference namelist : Vertical mixing parameters
89      READ  ( numnam_ref, namzdf, IOSTAT = ios, ERR = 901)
90901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf in reference namelist', lwp )
91      !
92      REWIND( numnam_cfg )              ! Namelist namzdf in reference namelist : Vertical mixing parameters
93      READ  ( numnam_cfg, namzdf, IOSTAT = ios, ERR = 902 )
94902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf in configuration namelist', lwp )
95      IF(lwm)   WRITE ( numond, namzdf )
96      !
97      IF(lwp) THEN                      ! Parameter print
98         WRITE(numout,*)
99         WRITE(numout,*) 'zdf_phy_init: vertical physics'
100         WRITE(numout,*) '~~~~~~~~~~~~'
101         WRITE(numout,*) '   Namelist namzdf : set vertical mixing mixing parameters'
102         WRITE(numout,*) '      vertical closure scheme'
103         WRITE(numout,*) '         constant vertical mixing coefficient    ln_zdfcst = ', ln_zdfcst
104         WRITE(numout,*) '         Richardson number dependent closure     ln_zdfric = ', ln_zdfric
105         WRITE(numout,*) '         Turbulent Kinetic Energy closure (TKE)  ln_zdftke = ', ln_zdftke
106         WRITE(numout,*) '         Generic Length Scale closure (GLS)      ln_zdfgls = ', ln_zdfgls
107         WRITE(numout,*) '         OSMOSIS-OBL closure (OSM)               ln_zdfosm = ', ln_zdfosm
108         WRITE(numout,*) '      convection: '
109         WRITE(numout,*) '         enhanced vertical diffusion             ln_zdfevd = ', ln_zdfevd
110         WRITE(numout,*) '            applied on momentum (=1/0)             nn_evdm = ', nn_evdm
111         WRITE(numout,*) '            vertical coefficient for evd           rn_evd  = ', rn_evd
112         WRITE(numout,*) '         non-penetrative convection (npc)        ln_zdfnpc = ', ln_zdfnpc
113         WRITE(numout,*) '            npc call  frequency                    nn_npc  = ', nn_npc
114         WRITE(numout,*) '            npc print frequency                    nn_npcp = ', nn_npcp
115         WRITE(numout,*) '      double diffusive mixing                    ln_zdfddm = ', ln_zdfddm
116         WRITE(numout,*) '         maximum avs for dd mixing                 rn_avts = ', rn_avts
117         WRITE(numout,*) '         heat/salt buoyancy flux ratio             rn_hsbfr= ', rn_hsbfr
118         WRITE(numout,*) '      gravity wave-induced mixing'
119         WRITE(numout,*) '         surface  wave (Qiao et al 2010)         ln_zdfswm = ', ln_zdfswm                                          ! surface wave induced mixing
120         WRITE(numout,*) '         internal wave (de Lavergne et al 2017)  ln_zdfiwm = ', ln_zdfiwm
121         WRITE(numout,*) '      coefficients : '
122         WRITE(numout,*) '         vertical eddy viscosity                 rn_avm0   = ', rn_avm0
123         WRITE(numout,*) '         vertical eddy diffusivity               rn_avt0   = ', rn_avt0
124         WRITE(numout,*) '         constant background or profile          nn_avb    = ', nn_avb
125         WRITE(numout,*) '         horizontal variation for avtb           nn_havtb  = ', nn_havtb
126      ENDIF
127
128      !                          !==  Background eddy viscosity and diffusivity  ==!
129      IF( nn_avb == 0 ) THEN             ! Define avmb, avtb from namelist parameter
130         avmb(:) = rn_avm0
131         avtb(:) = rn_avt0                     
132      ELSE                               ! Background profile of avt (fit a theoretical/observational profile (Krauss 1990)
133         avmb(:) = rn_avm0
134         avtb(:) = rn_avt0 + ( 3.e-4_wp - 2._wp * rn_avt0 ) * 1.e-4_wp * gdepw_1d(:)   ! m2/s
135         IF(ln_sco .AND. lwp)   CALL ctl_warn( 'avtb profile not valid in sco' )
136      ENDIF
137      !                                  ! 2D shape of the avtb
138      avtb_2d(:,:) = 1._wp                   ! uniform
139      !
140      IF( nn_havtb == 1 ) THEN               ! decrease avtb by a factor of ten in the equatorial band
141           !                                 !   -15S -5S : linear decrease from avt0 to avt0/10.
142           !                                 !   -5S  +5N : cst value avt0/10.
143           !                                 !    5N  15N : linear increase from avt0/10, to avt0
144           WHERE(-15. <= gphit .AND. gphit < -5 )   avtb_2d = (1.  - 0.09 * (gphit + 15.))
145           WHERE( -5. <= gphit .AND. gphit <  5 )   avtb_2d =  0.1
146           WHERE(  5. <= gphit .AND. gphit < 15 )   avtb_2d = (0.1 + 0.09 * (gphit -  5.))
147      ENDIF
148      !
149      DO jk = 1, jpk                      ! set turbulent closure Kz to the background value (avt_k, avm_k)
150         avt_k(:,:,jk) = avtb_2d(:,:) * avtb(jk) * wmask (:,:,jk)
151         avm_k(:,:,jk) =                avmb(jk) * wmask (:,:,jk)
152      END DO
153!!gm  to be tested only the 1st & last levels
154!      avt  (:,:, 1 ) = 0._wp   ;   avs(:,:, 1 ) = 0._wp   ;   avm  (:,:, 1 ) = 0._wp
155!      avt  (:,:,jpk) = 0._wp   ;   avs(:,:,jpk) = 0._wp   ;   avm  (:,:,jpk) = 0._wp
156!!gm
157      avt  (:,:,:) = 0._wp   ;   avs(:,:,:) = 0._wp   ;   avm  (:,:,:) = 0._wp
158
159      !                          !==  Convection  ==!
160      !
161      IF( ln_zdfnpc .AND. ln_zdfevd )   CALL ctl_stop( 'zdf_phy_init: chose between ln_zdfnpc and ln_zdfevd' )
162      IF( ln_zdfosm .AND. ln_zdfevd )   CALL ctl_stop( 'zdf_phy_init: chose between ln_zdfosm and ln_zdfevd' )
163      IF( lk_top    .AND. ln_zdfnpc )   CALL ctl_stop( 'zdf_phy_init: npc scheme is not working with key_top' )
164      !IF( lk_top    .AND. ln_zdfosm )   CALL ctl_stop( 'zdf_phy_init: osmosis scheme is not working with key_top' )
165      IF(lwp) THEN
166         WRITE(numout,*)
167         IF    ( ln_zdfnpc ) THEN  ;   WRITE(numout,*) '      convection: use non penetrative convective scheme'
168         ELSEIF( ln_zdfevd ) THEN  ;   WRITE(numout,*) '      convection: use enhanced vertical diffusion scheme'
169         ELSE                      ;   WRITE(numout,*) '      convection: no specific scheme used'
170         ENDIF
171      ENDIF
172
173      IF(lwp) THEN               !==  Double Diffusion Mixing parameterization  ==!   (ddm)
174         WRITE(numout,*)
175         IF( ln_zdfddm ) THEN   ;   WRITE(numout,*) '      use double diffusive mixing: avs /= avt'
176         ELSE                   ;   WRITE(numout,*) '      No  double diffusive mixing: avs = avt'
177         ENDIF
178      ENDIF
179
180      !                          !==  type of vertical turbulent closure  ==!    (set nzdf_phy)
181      ioptio = 0 
182      IF( ln_zdfcst ) THEN   ;   ioptio = ioptio + 1   ;    nzdf_phy = np_CST   ;   ENDIF
183      IF( ln_zdfric ) THEN   ;   ioptio = ioptio + 1   ;    nzdf_phy = np_RIC   ;   CALL zdf_ric_init   ;   ENDIF
184      IF( ln_zdftke ) THEN   ;   ioptio = ioptio + 1   ;    nzdf_phy = np_TKE   ;   CALL zdf_tke_init   ;   ENDIF
185      IF( ln_zdfgls ) THEN   ;   ioptio = ioptio + 1   ;    nzdf_phy = np_GLS   ;   CALL zdf_gls_init   ;   ENDIF
186      IF( ln_zdfosm ) THEN   ;   ioptio = ioptio + 1   ;    nzdf_phy = np_OSM   ;   CALL zdf_osm_init   ;   ENDIF
187      !
188      IF( ioptio /= 1 )    CALL ctl_stop( 'zdf_phy_init: one and only one vertical diffusion option has to be defined ' )
189      IF( ln_isfcav ) THEN
190      IF( ln_zdfric .OR. ln_zdfgls )    CALL ctl_stop( 'zdf_phy_init: zdfric and zdfgls never tested with ice shelves cavities ' )
191      ENDIF
192      !                                ! shear production term flag
193      IF( ln_zdfcst ) THEN   ;   l_zdfsh2 = .FALSE.
194      ELSE                   ;   l_zdfsh2 = .TRUE.
195      ENDIF
196
197      !                          !== gravity wave-driven mixing  ==!
198      IF( ln_zdfiwm )   CALL zdf_iwm_init       ! internal wave-driven mixing
199      IF( ln_zdfswm )   CALL zdf_swm_init       ! surface  wave-driven mixing
200
201      !                          !== top/bottom friction  ==!
202      CALL zdf_drg_init
203      !
204      !                          !== time-stepping  ==!
205      ! Check/update of time stepping done in dynzdf_init/trazdf_init
206      !!gm move it here ?
207      !
208      IF( ln_timing )   CALL timing_stop('zdf_phy_init')
209      !
210   END SUBROUTINE zdf_phy_init
211
212
213   SUBROUTINE zdf_phy( kt )
214      !!----------------------------------------------------------------------
215      !!                     ***  ROUTINE zdf_phy  ***
216      !!
217      !! ** Purpose :  Update ocean physics at each time-step
218      !!
219      !! ** Method  :
220      !!
221      !! ** Action  :   avm, avt vertical eddy viscosity and diffusivity at w-points
222      !!                nmld ??? mixed layer depth in level and meters   <<<<====verifier !
223      !!                bottom stress.....                               <<<<====verifier !
224      !!----------------------------------------------------------------------
225      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
226      !
227      INTEGER ::   ji, jj, jk   ! dummy loop indice
228      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zsh2   ! shear production
229      !! ---------------------------------------------------------------------
230      !
231      IF( ln_timing )   CALL timing_start('zdf_phy')
232      !
233      IF( l_zdfdrg ) THEN     !==  update top/bottom drag  ==!   (non-linear cases)
234         !
235         !                       !* bottom drag
236         CALL zdf_drg( kt, mbkt    , r_Cdmin_bot, r_Cdmax_bot,   &   ! <<== in
237            &              r_z0_bot,   r_ke0_bot,    rCd0_bot,   &
238            &                                        rCdU_bot  )     ! ==>> out : bottom drag [m/s]
239         IF( ln_isfcav ) THEN    !* top drag   (ocean cavities)
240            CALL zdf_drg( kt, mikt    , r_Cdmin_top, r_Cdmax_top,   &   ! <<== in
241               &              r_z0_top,   r_ke0_top,    rCd0_top,   &
242               &                                        rCdU_top  )     ! ==>> out : bottom drag [m/s]
243         ENDIF
244      ENDIF
245      !
246      !                       !==  Kz from chosen turbulent closure  ==!   (avm_k, avt_k)
247      !
248      IF( l_zdfsh2 )   &         !* shear production at w-points (energy conserving form)
249         CALL zdf_sh2( ub, vb, un, vn, avm_k,   &     ! <<== in
250            &                           zsh2    )     ! ==>> out : shear production
251      !
252      SELECT CASE ( nzdf_phy )                  !* Vertical eddy viscosity and diffusivity coefficients at w-points
253      CASE( np_RIC )   ;   CALL zdf_ric( kt, gdept_n, zsh2, avm_k, avt_k )    ! Richardson number dependent Kz
254      CASE( np_TKE )   ;   CALL zdf_tke( kt         , zsh2, avm_k, avt_k )    ! TKE closure scheme for Kz
255      CASE( np_GLS )   ;   CALL zdf_gls( kt         , zsh2, avm_k, avt_k )    ! GLS closure scheme for Kz
256      CASE( np_OSM )   ;   CALL zdf_osm( kt               , avm_k, avt_k )    ! OSMOSIS closure scheme for Kz
257!     CASE( np_CST )                                  ! Constant Kz (reset avt, avm to the background value)
258!         ! avt_k and avm_k set one for all at initialisation phase
259!!gm         avt(2:jpim1,2:jpjm1,1:jpkm1) = rn_avt0 * wmask(2:jpim1,2:jpjm1,1:jpkm1)
260!!gm         avm(2:jpim1,2:jpjm1,1:jpkm1) = rn_avm0 * wmask(2:jpim1,2:jpjm1,1:jpkm1)
261      END SELECT
262     
263      !                          !==  ocean Kz  ==!   (avt, avs, avm)
264      !
265      !                                         !* start from turbulent closure values
266      avt(:,:,2:jpkm1) = avt_k(:,:,2:jpkm1)
267      avm(:,:,2:jpkm1) = avm_k(:,:,2:jpkm1)
268      !
269      IF( ln_rnf_mouth ) THEN                   !* increase diffusivity at rivers mouths
270         DO jk = 2, nkrnf
271            avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * wmask(:,:,jk)
272         END DO
273      ENDIF
274      !
275      IF( ln_zdfevd )   CALL zdf_evd( kt, avm, avt )  !* convection: enhanced vertical eddy diffusivity
276      !
277      !                                         !* double diffusive mixing
278      IF( ln_zdfddm ) THEN                            ! update avt and compute avs
279                        CALL zdf_ddm( kt, avm, avt, avs )
280      ELSE                                            ! same mixing on all tracers
281         avs(2:jpim1,2:jpjm1,1:jpkm1) = avt(2:jpim1,2:jpjm1,1:jpkm1)
282      ENDIF
283      !
284      !                                         !* wave-induced mixing
285      IF( ln_zdfswm )   CALL zdf_swm( kt, avm, avt, avs )   ! surface  wave (Qiao et al. 2004)
286      IF( ln_zdfiwm )   CALL zdf_iwm( kt, avm, avt, avs )   ! internal wave (de Lavergne et al 2017)
287
288#if defined key_agrif 
289      ! interpolation parent grid => child grid for avm_k ( ex : at west border: update column 1 and 2)
290      IF( l_zdfsh2 )   CALL Agrif_avm
291#endif
292
293      !                                         !* Lateral boundary conditions (sign unchanged)
294      IF( l_zdfsh2 ) THEN
295         CALL lbc_lnk( avm_k, 'W', 1. )               ! needed to compute the shear production term
296         CALL lbc_lnk( avt_k, 'W', 1. )               !!gm a priori useless ==>> to be tested
297      ENDIF
298      CALL lbc_lnk( avm  , 'W', 1. )                  ! needed to compute avm at u- and v-points
299      CALL lbc_lnk( avt  , 'W', 1. )                  !!gm  a priori only avm_k and avm are required
300      CALL lbc_lnk( avs  , 'W', 1. )                  !!gm  for calculation, kept here for output only
301      !
302      IF( l_zdfdrg ) THEN     ! drag  have been updated (non-linear cases)
303         IF( ln_isfcav )   CALL lbc_lnk( rCdU_top, 'T', 1. )   ! top    drag
304                           CALL lbc_lnk( rCdU_bot, 'T', 1. )   ! bottom drag
305      ENDIF
306      !
307      CALL zdf_mxl( kt )                        !* mixed layer depth, and level
308      !
309      IF( lrst_oce ) THEN                       !* write TKE, GLS or RIC fields in the restart file
310         IF( ln_zdftke )   CALL tke_rst( kt, 'WRITE' )
311         IF( ln_zdfgls )   CALL gls_rst( kt, 'WRITE' )
312         IF( ln_zdfric )   CALL ric_rst( kt, 'WRITE' ) 
313         ! NB. OSMOSIS restart (osm_rst) will be called in step.F90 after wn has been updated
314      ENDIF
315      !
316      IF( ln_timing )   CALL timing_stop('zdf_phy')
317      !
318   END SUBROUTINE zdf_phy
319
320   !!======================================================================
321END MODULE zdfphy
Note: See TracBrowser for help on using the repository browser.