| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.6 ! 2015-12 (A. Ryan) Original code (from OPA_SRC/) |
|---|
| 7 | !! 4.0 ! 2016-11 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 12 | !! nemo_init : initialization of the NEMO system |
|---|
| 13 | !! nemo_ctl : initialisation of the contol print |
|---|
| 14 | !! nemo_closefile: close remaining open files |
|---|
| 15 | !! nemo_alloc : dynamical allocation |
|---|
| 16 | !! nemo_partition: calculate MPP domain decomposition |
|---|
| 17 | !! factorise : calculate the factors of the no. of MPI processes |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 20 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 21 | USE istate ! initial state setting (istate_init routine) |
|---|
| 22 | USE phycst ! physical constant (par_cst routine) |
|---|
| 23 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 24 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 25 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
|---|
| 26 | #if defined key_nemocice_decomp |
|---|
| 27 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 28 | #endif |
|---|
| 29 | ! ! Stand Alone Observation operator modules |
|---|
| 30 | USE sao_data |
|---|
| 31 | USE sao_intp |
|---|
| 32 | ! |
|---|
| 33 | USE lib_mpp ! distributed memory computing |
|---|
| 34 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 35 | USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges |
|---|
| 36 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 37 | #if defined key_iomput |
|---|
| 38 | USE xios ! xIOserver |
|---|
| 39 | #endif |
|---|
| 40 | |
|---|
| 41 | IMPLICIT NONE |
|---|
| 42 | PRIVATE |
|---|
| 43 | |
|---|
| 44 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 45 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 46 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 47 | |
|---|
| 48 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 49 | |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | !! NEMO/OPA 4.0 , NEMO Consortium (2016) |
|---|
| 52 | !! $Id$ |
|---|
| 53 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | CONTAINS |
|---|
| 56 | |
|---|
| 57 | SUBROUTINE nemo_gcm |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | !! *** SUBROUTINE offline_obs_oper *** |
|---|
| 60 | !! |
|---|
| 61 | !! ** Purpose : To use NEMO components to interpolate model fields |
|---|
| 62 | !! to observation space. |
|---|
| 63 | !! |
|---|
| 64 | !! ** Method : 1. Initialise NEMO |
|---|
| 65 | !! 2. Initialise offline obs_oper |
|---|
| 66 | !! 3. Cycle through match ups |
|---|
| 67 | !! 4. Write results to file |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | ! |
|---|
| 70 | CALL nemo_init ! Initialise NEMO |
|---|
| 71 | ! |
|---|
| 72 | CALL sao_data_init ! Initialise Stand Alone Observation operator data |
|---|
| 73 | ! |
|---|
| 74 | CALL dia_obs_init ! Initialise obs_operator |
|---|
| 75 | ! |
|---|
| 76 | CALL sao_interp ! Interpolate to observation space |
|---|
| 77 | ! |
|---|
| 78 | CALL dia_obs_wri ! Pipe to output files |
|---|
| 79 | ! |
|---|
| 80 | CALL dia_obs_dealloc ! Reset the obs_oper between |
|---|
| 81 | ! |
|---|
| 82 | IF(lk_mpp) CALL mppstop ! Safely stop MPI (end mpp communications) |
|---|
| 83 | ! |
|---|
| 84 | END SUBROUTINE nemo_gcm |
|---|
| 85 | |
|---|
| 86 | |
|---|
| 87 | SUBROUTINE nemo_init |
|---|
| 88 | !!---------------------------------------------------------------------- |
|---|
| 89 | !! *** ROUTINE nemo_init *** |
|---|
| 90 | !! |
|---|
| 91 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 92 | !!---------------------------------------------------------------------- |
|---|
| 93 | INTEGER :: ji ! dummy loop indices |
|---|
| 94 | INTEGER :: ios, ilocal_comm ! local integer |
|---|
| 95 | CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam |
|---|
| 96 | ! |
|---|
| 97 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
|---|
| 98 | & nn_isplt , nn_jsplt, nn_jctls, nn_jctle, & |
|---|
| 99 | & ln_timing, ln_diacfl |
|---|
| 100 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | ! |
|---|
| 103 | cltxt = '' |
|---|
| 104 | cltxt2 = '' |
|---|
| 105 | clnam = '' |
|---|
| 106 | cxios_context = 'nemo' |
|---|
| 107 | ! |
|---|
| 108 | ! ! Open reference namelist and configuration namelist files |
|---|
| 109 | CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
|---|
| 110 | CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
|---|
| 111 | ! |
|---|
| 112 | REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints |
|---|
| 113 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 114 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. ) |
|---|
| 115 | ! |
|---|
| 116 | REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist |
|---|
| 117 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 118 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. ) |
|---|
| 119 | ! |
|---|
| 120 | REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints |
|---|
| 121 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 122 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. ) |
|---|
| 123 | |
|---|
| 124 | REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark |
|---|
| 125 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 126 | 904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. ) |
|---|
| 127 | |
|---|
| 128 | ! !--------------------------! |
|---|
| 129 | ! ! Set global domain size ! (control print return in cltxt2) |
|---|
| 130 | ! !--------------------------! |
|---|
| 131 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 132 | CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
|---|
| 133 | ! |
|---|
| 134 | ELSE ! user-defined namelist |
|---|
| 135 | CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
|---|
| 136 | ENDIF |
|---|
| 137 | ! |
|---|
| 138 | jpk = jpkglo |
|---|
| 139 | ! |
|---|
| 140 | #if defined key_agrif |
|---|
| 141 | IF( .NOT. Agrif_Root() ) THEN ! AGRIF children: specific setting (cf. agrif_user.F90) |
|---|
| 142 | jpiglo = nbcellsx + 2 + 2*nbghostcells |
|---|
| 143 | jpjglo = nbcellsy + 2 + 2*nbghostcells |
|---|
| 144 | jpi = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci |
|---|
| 145 | jpj = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj |
|---|
| 146 | nperio = 0 |
|---|
| 147 | jperio = 0 |
|---|
| 148 | ln_use_jattr = .false. |
|---|
| 149 | ENDIF |
|---|
| 150 | #endif |
|---|
| 151 | ! |
|---|
| 152 | ! !--------------------------------------------! |
|---|
| 153 | ! ! set communicator & select the local node ! |
|---|
| 154 | ! ! NB: mynode also opens output.namelist.dyn ! |
|---|
| 155 | ! ! on unit number numond on first proc ! |
|---|
| 156 | ! !--------------------------------------------! |
|---|
| 157 | #if defined key_iomput |
|---|
| 158 | IF( Agrif_Root() ) THEN |
|---|
| 159 | IF( lk_oasis ) THEN |
|---|
| 160 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 161 | CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios |
|---|
| 162 | ELSE |
|---|
| 163 | CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 164 | ENDIF |
|---|
| 165 | ENDIF |
|---|
| 166 | ! Nodes selection (control print return in cltxt) |
|---|
| 167 | narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) |
|---|
| 168 | #else |
|---|
| 169 | IF( lk_oasis ) THEN |
|---|
| 170 | IF( Agrif_Root() ) THEN |
|---|
| 171 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 172 | ENDIF |
|---|
| 173 | ! Nodes selection (control print return in cltxt) |
|---|
| 174 | narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) |
|---|
| 175 | ELSE |
|---|
| 176 | ilocal_comm = 0 |
|---|
| 177 | ! Nodes selection (control print return in cltxt) |
|---|
| 178 | narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop ) |
|---|
| 179 | ENDIF |
|---|
| 180 | #endif |
|---|
| 181 | |
|---|
| 182 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
|---|
| 183 | |
|---|
| 184 | lwm = (narea == 1) ! control of output namelists |
|---|
| 185 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
|---|
| 186 | |
|---|
| 187 | IF(lwm) THEN |
|---|
| 188 | ! write merged namelists from earlier to output namelist now that the |
|---|
| 189 | ! file has been opened in call to mynode. nammpp has already been |
|---|
| 190 | ! written in mynode (if lk_mpp_mpi) |
|---|
| 191 | WRITE( numond, namctl ) |
|---|
| 192 | WRITE( numond, namcfg ) |
|---|
| 193 | IF( .NOT.ln_read_cfg ) THEN |
|---|
| 194 | DO ji = 1, SIZE(clnam) |
|---|
| 195 | IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print |
|---|
| 196 | END DO |
|---|
| 197 | ENDIF |
|---|
| 198 | ENDIF |
|---|
| 199 | |
|---|
| 200 | ! If dimensions of processor grid weren't specified in the namelist file |
|---|
| 201 | ! then we calculate them here now that we have our communicator size |
|---|
| 202 | IF( jpni < 1 .OR. jpnj < 1 ) THEN |
|---|
| 203 | #if defined key_mpp_mpi |
|---|
| 204 | IF( Agrif_Root() ) CALL nemo_partition( mppsize ) |
|---|
| 205 | #else |
|---|
| 206 | jpni = 1 |
|---|
| 207 | jpnj = 1 |
|---|
| 208 | jpnij = jpni*jpnj |
|---|
| 209 | #endif |
|---|
| 210 | ENDIF |
|---|
| 211 | |
|---|
| 212 | IF( Agrif_Root() ) THEN ! AGRIF mother: specific setting from jpni and jpnj |
|---|
| 213 | #if defined key_nemocice_decomp |
|---|
| 214 | jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
|---|
| 215 | jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
|---|
| 216 | #else |
|---|
| 217 | jpi = ( jpiglo -2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
|---|
| 218 | jpj = ( jpjglo -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
|---|
| 219 | #endif |
|---|
| 220 | ENDIF |
|---|
| 221 | |
|---|
| 222 | !!gm ??? why here it has already been done in line 301 ! |
|---|
| 223 | jpk = jpkglo ! third dim |
|---|
| 224 | !!gm end |
|---|
| 225 | jpim1 = jpi-1 ! inner domain indices |
|---|
| 226 | jpjm1 = jpj-1 ! " " |
|---|
| 227 | jpkm1 = jpk-1 ! " " |
|---|
| 228 | jpij = jpi*jpj ! jpi x j |
|---|
| 229 | |
|---|
| 230 | IF(lwp) THEN ! open listing units |
|---|
| 231 | ! |
|---|
| 232 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
|---|
| 233 | ! |
|---|
| 234 | WRITE(numout,*) |
|---|
| 235 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
|---|
| 236 | WRITE(numout,*) ' NEMO team' |
|---|
| 237 | WRITE(numout,*) ' Stand Alone Observation operator' |
|---|
| 238 | WRITE(numout,*) ' NEMO version 3.7 (2015) ' |
|---|
| 239 | WRITE(numout,*) |
|---|
| 240 | WRITE(numout,*) |
|---|
| 241 | DO ji = 1, SIZE(cltxt) |
|---|
| 242 | IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
|---|
| 243 | END DO |
|---|
| 244 | WRITE(numout,*) |
|---|
| 245 | WRITE(numout,*) |
|---|
| 246 | DO ji = 1, SIZE(cltxt2) |
|---|
| 247 | IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) cltxt2(ji) ! control print of domain size |
|---|
| 248 | END DO |
|---|
| 249 | ! |
|---|
| 250 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 251 | ! |
|---|
| 252 | ENDIF |
|---|
| 253 | |
|---|
| 254 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 255 | CALL nemo_alloc() |
|---|
| 256 | |
|---|
| 257 | ! !-------------------------------! |
|---|
| 258 | ! ! NEMO general initialization ! |
|---|
| 259 | ! !-------------------------------! |
|---|
| 260 | |
|---|
| 261 | CALL nemo_ctl ! Control prints & Benchmark |
|---|
| 262 | |
|---|
| 263 | ! ! Domain decomposition |
|---|
| 264 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
|---|
| 265 | ELSE ; CALL mpp_init2 ! eliminate land processors |
|---|
| 266 | ENDIF |
|---|
| 267 | ! |
|---|
| 268 | IF( ln_timing ) CALL timing_init ! timing by routine |
|---|
| 269 | ! |
|---|
| 270 | ! ! General initialization |
|---|
| 271 | CALL phy_cst ! Physical constants |
|---|
| 272 | CALL eos_init ! Equation of state |
|---|
| 273 | CALL dom_init ! Domain |
|---|
| 274 | |
|---|
| 275 | IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined) |
|---|
| 276 | |
|---|
| 277 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
|---|
| 278 | |
|---|
| 279 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
|---|
| 280 | END SUBROUTINE nemo_init |
|---|
| 281 | |
|---|
| 282 | |
|---|
| 283 | SUBROUTINE nemo_ctl |
|---|
| 284 | !!---------------------------------------------------------------------- |
|---|
| 285 | !! *** ROUTINE nemo_ctl *** |
|---|
| 286 | !! |
|---|
| 287 | !! ** Purpose : control print setting |
|---|
| 288 | !! |
|---|
| 289 | !! ** Method : - print namctl information and check some consistencies |
|---|
| 290 | !!---------------------------------------------------------------------- |
|---|
| 291 | ! |
|---|
| 292 | IF(lwp) THEN ! control print |
|---|
| 293 | WRITE(numout,*) |
|---|
| 294 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 295 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 296 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 297 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
|---|
| 298 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
|---|
| 299 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
|---|
| 300 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
|---|
| 301 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
|---|
| 302 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
|---|
| 303 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
|---|
| 304 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
|---|
| 305 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 306 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 307 | ENDIF |
|---|
| 308 | ! |
|---|
| 309 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
|---|
| 310 | nictls = nn_ictls |
|---|
| 311 | nictle = nn_ictle |
|---|
| 312 | njctls = nn_jctls |
|---|
| 313 | njctle = nn_jctle |
|---|
| 314 | isplt = nn_isplt |
|---|
| 315 | jsplt = nn_jsplt |
|---|
| 316 | |
|---|
| 317 | IF(lwp) THEN ! control print |
|---|
| 318 | WRITE(numout,*) |
|---|
| 319 | WRITE(numout,*) 'namcfg : configuration initialization through namelist read' |
|---|
| 320 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 321 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 322 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 323 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 324 | WRITE(numout,*) ' write configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 325 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 326 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 327 | ENDIF |
|---|
| 328 | ! ! Parameter control |
|---|
| 329 | ! |
|---|
| 330 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
|---|
| 331 | IF( lk_mpp .AND. jpnij > 1 ) THEN |
|---|
| 332 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
|---|
| 333 | ELSE |
|---|
| 334 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
|---|
| 335 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
|---|
| 336 | & ' - the print control will be done over the whole domain' ) |
|---|
| 337 | ENDIF |
|---|
| 338 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
|---|
| 339 | ENDIF |
|---|
| 340 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
|---|
| 341 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
|---|
| 342 | ! |
|---|
| 343 | ! ! indices used for the SUM control |
|---|
| 344 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
|---|
| 345 | lsp_area = .FALSE. |
|---|
| 346 | ELSE ! print control done over a specific area |
|---|
| 347 | lsp_area = .TRUE. |
|---|
| 348 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
|---|
| 349 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
|---|
| 350 | nictls = 1 |
|---|
| 351 | ENDIF |
|---|
| 352 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
|---|
| 353 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
|---|
| 354 | nictle = jpiglo |
|---|
| 355 | ENDIF |
|---|
| 356 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
|---|
| 357 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
|---|
| 358 | njctls = 1 |
|---|
| 359 | ENDIF |
|---|
| 360 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
|---|
| 361 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
|---|
| 362 | njctle = jpjglo |
|---|
| 363 | ENDIF |
|---|
| 364 | ENDIF |
|---|
| 365 | ENDIF |
|---|
| 366 | ! |
|---|
| 367 | IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', & |
|---|
| 368 | & 'f2003 standard. ' , & |
|---|
| 369 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 370 | ! |
|---|
| 371 | END SUBROUTINE nemo_ctl |
|---|
| 372 | |
|---|
| 373 | |
|---|
| 374 | SUBROUTINE nemo_closefile |
|---|
| 375 | !!---------------------------------------------------------------------- |
|---|
| 376 | !! *** ROUTINE nemo_closefile *** |
|---|
| 377 | !! |
|---|
| 378 | !! ** Purpose : Close the files |
|---|
| 379 | !!---------------------------------------------------------------------- |
|---|
| 380 | ! |
|---|
| 381 | IF( lk_mpp ) CALL mppsync |
|---|
| 382 | ! |
|---|
| 383 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 384 | ! |
|---|
| 385 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 386 | IF( numsol /= -1 ) CLOSE( numsol ) ! solver file |
|---|
| 387 | IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist |
|---|
| 388 | IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist |
|---|
| 389 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 390 | IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist |
|---|
| 391 | IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist |
|---|
| 392 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 393 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 394 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 395 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 396 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 397 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 398 | ! |
|---|
| 399 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 400 | ! |
|---|
| 401 | END SUBROUTINE nemo_closefile |
|---|
| 402 | |
|---|
| 403 | |
|---|
| 404 | SUBROUTINE nemo_alloc |
|---|
| 405 | !!---------------------------------------------------------------------- |
|---|
| 406 | !! *** ROUTINE nemo_alloc *** |
|---|
| 407 | !! |
|---|
| 408 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 409 | !! |
|---|
| 410 | !! ** Method : |
|---|
| 411 | !!---------------------------------------------------------------------- |
|---|
| 412 | USE diawri , ONLY: dia_wri_alloc |
|---|
| 413 | USE dom_oce , ONLY: dom_oce_alloc |
|---|
| 414 | ! |
|---|
| 415 | INTEGER :: ierr |
|---|
| 416 | !!---------------------------------------------------------------------- |
|---|
| 417 | ! |
|---|
| 418 | ierr = oce_alloc () ! ocean |
|---|
| 419 | ierr = ierr + dia_wri_alloc () |
|---|
| 420 | ierr = ierr + dom_oce_alloc () ! ocean domain |
|---|
| 421 | ! |
|---|
| 422 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
|---|
| 423 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' ) |
|---|
| 424 | ! |
|---|
| 425 | END SUBROUTINE nemo_alloc |
|---|
| 426 | |
|---|
| 427 | |
|---|
| 428 | SUBROUTINE nemo_partition( num_pes ) |
|---|
| 429 | !!---------------------------------------------------------------------- |
|---|
| 430 | !! *** ROUTINE nemo_partition *** |
|---|
| 431 | !! |
|---|
| 432 | !! ** Purpose : |
|---|
| 433 | !! |
|---|
| 434 | !! ** Method : |
|---|
| 435 | !!---------------------------------------------------------------------- |
|---|
| 436 | INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have |
|---|
| 437 | ! |
|---|
| 438 | INTEGER, PARAMETER :: nfactmax = 20 |
|---|
| 439 | INTEGER :: nfact ! The no. of factors returned |
|---|
| 440 | INTEGER :: ierr ! Error flag |
|---|
| 441 | INTEGER :: ji |
|---|
| 442 | INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value |
|---|
| 443 | INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors |
|---|
| 444 | !!---------------------------------------------------------------------- |
|---|
| 445 | ! |
|---|
| 446 | ierr = 0 |
|---|
| 447 | ! |
|---|
| 448 | CALL factorise( ifact, nfactmax, nfact, num_pes, ierr ) |
|---|
| 449 | ! |
|---|
| 450 | IF( nfact <= 1 ) THEN |
|---|
| 451 | WRITE (numout, *) 'WARNING: factorisation of number of PEs failed' |
|---|
| 452 | WRITE (numout, *) ' : using grid of ',num_pes,' x 1' |
|---|
| 453 | jpnj = 1 |
|---|
| 454 | jpni = num_pes |
|---|
| 455 | ELSE |
|---|
| 456 | ! Search through factors for the pair that are closest in value |
|---|
| 457 | mindiff = 1000000 |
|---|
| 458 | imin = 1 |
|---|
| 459 | DO ji = 1, nfact-1, 2 |
|---|
| 460 | idiff = ABS( ifact(ji) - ifact(ji+1) ) |
|---|
| 461 | IF( idiff < mindiff ) THEN |
|---|
| 462 | mindiff = idiff |
|---|
| 463 | imin = ji |
|---|
| 464 | ENDIF |
|---|
| 465 | END DO |
|---|
| 466 | jpnj = ifact(imin) |
|---|
| 467 | jpni = ifact(imin + 1) |
|---|
| 468 | ENDIF |
|---|
| 469 | ! |
|---|
| 470 | jpnij = jpni*jpnj |
|---|
| 471 | ! |
|---|
| 472 | END SUBROUTINE nemo_partition |
|---|
| 473 | |
|---|
| 474 | |
|---|
| 475 | SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr ) |
|---|
| 476 | !!---------------------------------------------------------------------- |
|---|
| 477 | !! *** ROUTINE factorise *** |
|---|
| 478 | !! |
|---|
| 479 | !! ** Purpose : return the prime factors of n. |
|---|
| 480 | !! knfax factors are returned in array kfax which is of |
|---|
| 481 | !! maximum dimension kmaxfax. |
|---|
| 482 | !! ** Method : |
|---|
| 483 | !!---------------------------------------------------------------------- |
|---|
| 484 | INTEGER , INTENT(in ) :: kn, kmaxfax |
|---|
| 485 | INTEGER , INTENT( out) :: kerr, knfax |
|---|
| 486 | INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax |
|---|
| 487 | ! |
|---|
| 488 | INTEGER :: ifac, jl, inu |
|---|
| 489 | INTEGER, PARAMETER :: ntest = 14 |
|---|
| 490 | INTEGER, DIMENSION(ntest) :: ilfax |
|---|
| 491 | !!---------------------------------------------------------------------- |
|---|
| 492 | ! |
|---|
| 493 | ! lfax contains the set of allowed factors. |
|---|
| 494 | ilfax(:) = (/(2**jl,jl=ntest,1,-1)/) |
|---|
| 495 | ! |
|---|
| 496 | ! Clear the error flag and initialise output vars |
|---|
| 497 | kerr = 0 |
|---|
| 498 | kfax = 1 |
|---|
| 499 | knfax = 0 |
|---|
| 500 | ! |
|---|
| 501 | ! Find the factors of n. |
|---|
| 502 | IF( kn == 1 ) GOTO 20 |
|---|
| 503 | |
|---|
| 504 | ! nu holds the unfactorised part of the number. |
|---|
| 505 | ! knfax holds the number of factors found. |
|---|
| 506 | ! l points to the allowed factor list. |
|---|
| 507 | ! ifac holds the current factor. |
|---|
| 508 | ! |
|---|
| 509 | inu = kn |
|---|
| 510 | knfax = 0 |
|---|
| 511 | ! |
|---|
| 512 | DO jl = ntest, 1, -1 |
|---|
| 513 | ! |
|---|
| 514 | ifac = ilfax(jl) |
|---|
| 515 | IF( ifac > inu ) CYCLE |
|---|
| 516 | |
|---|
| 517 | ! Test whether the factor will divide. |
|---|
| 518 | |
|---|
| 519 | IF( MOD(inu,ifac) == 0 ) THEN |
|---|
| 520 | ! |
|---|
| 521 | knfax = knfax + 1 ! Add the factor to the list |
|---|
| 522 | IF( knfax > kmaxfax ) THEN |
|---|
| 523 | kerr = 6 |
|---|
| 524 | write (*,*) 'FACTOR: insufficient space in factor array ', knfax |
|---|
| 525 | return |
|---|
| 526 | ENDIF |
|---|
| 527 | kfax(knfax) = ifac |
|---|
| 528 | ! Store the other factor that goes with this one |
|---|
| 529 | knfax = knfax + 1 |
|---|
| 530 | kfax(knfax) = inu / ifac |
|---|
| 531 | !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax) |
|---|
| 532 | ENDIF |
|---|
| 533 | ! |
|---|
| 534 | END DO |
|---|
| 535 | ! |
|---|
| 536 | 20 CONTINUE ! Label 20 is the exit point from the factor search loop. |
|---|
| 537 | ! |
|---|
| 538 | END SUBROUTINE factorise |
|---|
| 539 | |
|---|
| 540 | #if defined key_mpp_mpi |
|---|
| 541 | |
|---|
| 542 | SUBROUTINE nemo_northcomms |
|---|
| 543 | !!---------------------------------------------------------------------- |
|---|
| 544 | !! *** ROUTINE nemo_northcomms *** |
|---|
| 545 | !! ** Purpose : Setup for north fold exchanges with explicit |
|---|
| 546 | !! point-to-point messaging |
|---|
| 547 | !! |
|---|
| 548 | !! ** Method : Initialization of the northern neighbours lists. |
|---|
| 549 | !!---------------------------------------------------------------------- |
|---|
| 550 | !! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) |
|---|
| 551 | !! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC) |
|---|
| 552 | !!---------------------------------------------------------------------- |
|---|
| 553 | INTEGER :: sxM, dxM, sxT, dxT, jn |
|---|
| 554 | INTEGER :: njmppmax |
|---|
| 555 | !!---------------------------------------------------------------------- |
|---|
| 556 | ! |
|---|
| 557 | njmppmax = MAXVAL( njmppt ) |
|---|
| 558 | ! |
|---|
| 559 | !initializes the north-fold communication variables |
|---|
| 560 | isendto(:) = 0 |
|---|
| 561 | nsndto = 0 |
|---|
| 562 | ! |
|---|
| 563 | !if I am a process in the north |
|---|
| 564 | IF ( njmpp == njmppmax ) THEN |
|---|
| 565 | !sxM is the first point (in the global domain) needed to compute the |
|---|
| 566 | !north-fold for the current process |
|---|
| 567 | sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1 |
|---|
| 568 | !dxM is the last point (in the global domain) needed to compute the |
|---|
| 569 | !north-fold for the current process |
|---|
| 570 | dxM = jpiglo - nimppt(narea) + 2 |
|---|
| 571 | |
|---|
| 572 | !loop over the other north-fold processes to find the processes |
|---|
| 573 | !managing the points belonging to the sxT-dxT range |
|---|
| 574 | |
|---|
| 575 | DO jn = 1, jpni |
|---|
| 576 | !sxT is the first point (in the global domain) of the jn |
|---|
| 577 | !process |
|---|
| 578 | sxT = nfiimpp(jn, jpnj) |
|---|
| 579 | !dxT is the last point (in the global domain) of the jn |
|---|
| 580 | !process |
|---|
| 581 | dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1 |
|---|
| 582 | IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN |
|---|
| 583 | nsndto = nsndto + 1 |
|---|
| 584 | isendto(nsndto) = jn |
|---|
| 585 | ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN |
|---|
| 586 | nsndto = nsndto + 1 |
|---|
| 587 | isendto(nsndto) = jn |
|---|
| 588 | ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN |
|---|
| 589 | nsndto = nsndto + 1 |
|---|
| 590 | isendto(nsndto) = jn |
|---|
| 591 | ENDIF |
|---|
| 592 | END DO |
|---|
| 593 | nfsloop = 1 |
|---|
| 594 | nfeloop = nlci |
|---|
| 595 | DO jn = 2,jpni-1 |
|---|
| 596 | IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN |
|---|
| 597 | IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN |
|---|
| 598 | nfsloop = nldi |
|---|
| 599 | ENDIF |
|---|
| 600 | IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN |
|---|
| 601 | nfeloop = nlei |
|---|
| 602 | ENDIF |
|---|
| 603 | ENDIF |
|---|
| 604 | END DO |
|---|
| 605 | |
|---|
| 606 | ENDIF |
|---|
| 607 | l_north_nogather = .TRUE. |
|---|
| 608 | END SUBROUTINE nemo_northcomms |
|---|
| 609 | |
|---|
| 610 | #else |
|---|
| 611 | SUBROUTINE nemo_northcomms ! Dummy routine |
|---|
| 612 | WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?' |
|---|
| 613 | END SUBROUTINE nemo_northcomms |
|---|
| 614 | #endif |
|---|
| 615 | |
|---|
| 616 | !!====================================================================== |
|---|
| 617 | END MODULE nemogcm |
|---|
| 618 | |
|---|
