source: branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/TRA/trazdf.F90 @ 7953

Last change on this file since 7953 was 7953, checked in by gm, 3 years ago

#1880 (HPC-09): add zdfphy (the ZDF manager) + remove all key_…

  • Property svn:keywords set to Id
File size: 7.2 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  ! 2005-11  (G. Madec)  Original code
7   !!            3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
12   !!   tra_zdf_init  : initialisation of the computation
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trazdf_exp     ! vertical diffusion: explicit (tra_zdf_exp routine)
23   USE trazdf_imp     ! vertical diffusion: implicit (tra_zdf_imp routine)
24   USE trd_oce        ! trends: ocean variables
25   USE trdtra         ! trends: tracer trend manager
26   !
27   USE in_out_manager ! I/O manager
28   USE prtctl         ! Print control
29   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp        ! MPP library
31   USE wrk_nemo       ! Memory allocation
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_zdf        ! routine called by step.F90
38   PUBLIC   tra_zdf_init   ! routine called by nemogcm.F90
39
40   INTEGER ::   nzdf = 0   ! type vertical diffusion algorithm used (defined from ln_zdf...  namlist logicals)
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_zdf( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_zdf  ***
54      !!
55      !! ** Purpose :   compute the vertical ocean tracer physics.
56      !!---------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
58      !
59      INTEGER  ::   jk                   ! Dummy loop indices
60      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdt, ztrds   ! 3D workspace
61      !!---------------------------------------------------------------------
62      !
63      IF( nn_timing == 1 )  CALL timing_start('tra_zdf')
64      !
65      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
66         r2dt =  rdt                          ! = rdt (restarting with Euler time stepping)
67      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
68         r2dt = 2. * rdt                      ! = 2 rdt (leapfrog)
69      ENDIF
70      !
71      IF( l_trdtra )   THEN                    !* Save ta and sa trends
72         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
73         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
74         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
75      ENDIF
76      !
77      SELECT CASE ( nzdf )                       ! compute lateral mixing trend and add it to the general trend
78      CASE ( 0 )    ;    CALL tra_zdf_exp( kt, nit000, 'TRA', r2dt, nn_zdfexp, tsb, tsa, jpts )  !   explicit scheme
79      CASE ( 1 )    ;    CALL tra_zdf_imp( kt, nit000, 'TRA', r2dt,            tsb, tsa, jpts )  !   implicit scheme
80      END SELECT
81!!gm WHY here !   and I don't like that !
82      ! DRAKKAR SSS control {
83      ! JMM avoid negative salinities near river outlet ! Ugly fix
84      ! JMM : restore negative salinities to small salinities:
85      WHERE( tsa(:,:,:,jp_sal) < 0._wp )   tsa(:,:,:,jp_sal) = 0.1_wp
86!!gm
87
88      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
89         DO jk = 1, jpkm1
90            ztrdt(:,:,jk) = ( ( tsa(:,:,jk,jp_tem) - tsb(:,:,jk,jp_tem) ) / r2dt ) - ztrdt(:,:,jk)
91            ztrds(:,:,jk) = ( ( tsa(:,:,jk,jp_sal) - tsb(:,:,jk,jp_sal) ) / r2dt ) - ztrds(:,:,jk)
92         END DO
93!!gm this should be moved in trdtra.F90 and done on all trends
94         CALL lbc_lnk( ztrdt, 'T', 1. )
95         CALL lbc_lnk( ztrds, 'T', 1. )
96!!gm
97         CALL trd_tra( kt, 'TRA', jp_tem, jptra_zdf, ztrdt )
98         CALL trd_tra( kt, 'TRA', jp_sal, jptra_zdf, ztrds )
99         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
100      ENDIF
101      !                                          ! print mean trends (used for debugging)
102      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
103         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
104      !
105      IF( nn_timing == 1 )  CALL timing_stop('tra_zdf')
106      !
107   END SUBROUTINE tra_zdf
108
109
110   SUBROUTINE tra_zdf_init
111      !!----------------------------------------------------------------------
112      !!                 ***  ROUTINE tra_zdf_init  ***
113      !!
114      !! ** Purpose :   Choose the vertical mixing scheme
115      !!
116      !! ** Method  :   Set nzdf from ln_zdfexp
117      !!      nzdf = 0   explicit (time-splitting) scheme (ln_zdfexp=T)
118      !!           = 1   implicit (euler backward) scheme (ln_zdfexp=F)
119      !!      NB: rotation of lateral mixing operator or TKE & GLS schemes,
120      !!          an implicit scheme is required.
121      !!----------------------------------------------------------------------
122      USE zdftke
123      USE zdfgls
124      !!----------------------------------------------------------------------
125      !
126      ! Choice from ln_zdfexp (namzdf namelist variable read in zdfphy module)
127      IF( ln_zdfexp ) THEN   ;   nzdf = 0           ! use explicit scheme
128      ELSE                   ;   nzdf = 1           ! use implicit scheme
129      ENDIF
130      !
131      ! Force implicit schemes
132      IF( ln_zdftke .OR. ln_zdfgls   )   nzdf = 1   ! TKE, or GLS physics
133      IF( ln_traldf_iso              )   nzdf = 1   ! iso-neutral lateral physics
134      IF( ln_traldf_hor .AND. ln_sco )   nzdf = 1   ! horizontal lateral physics in s-coordinate
135      IF( ln_zdfexp .AND. nzdf == 1 )   CALL ctl_stop( 'tra_zdf : If using the rotation of lateral mixing operator',   &
136            &                         ' GLS or TKE scheme, the implicit scheme is required, set ln_zdfexp = .false.' )
137            !
138      IF(lwp) THEN
139         WRITE(numout,*)
140         WRITE(numout,*) 'tra_zdf_init : vertical tracer physics scheme'
141         WRITE(numout,*) '~~~~~~~~~~~'
142         IF( nzdf ==  0 )   WRITE(numout,*) '      ===>>   Explicit time-splitting scheme'
143         IF( nzdf ==  1 )   WRITE(numout,*) '      ===>>   Implicit (euler backward) scheme'
144      ENDIF
145      !
146   END SUBROUTINE tra_zdf_init
147
148   !!==============================================================================
149END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.