New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfiwm.F90 in branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2017/dev_r7881_HPC09_ZDF/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfiwm.F90 @ 7990

Last change on this file since 7990 was 7990, checked in by gm, 7 years ago

#1880 (HPC-09): OPA remove avmu, avmv from zdf modules + move CALL tke(gls)_rst & gls_rst in zdftke(gls) + rename zdftmx and zdfqiao
  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   USE prtctl         ! Print control
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O Manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! work arrays
29   USE timing         ! Timing
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   zdf_iwm         ! called in step module
36   PUBLIC   zdf_iwm_init    ! called in nemogcm module
37   PUBLIC   zdf_iwm_alloc   ! called in nemogcm module
38
39   !                       !!* Namelist  namzdf_iwm : internal wave-driven mixing *
40   INTEGER  ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
41   LOGICAL  ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
42   LOGICAL  ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
43
44   REAL(wp) ::  r1_6 = 1._wp / 6._wp
45
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ebot_iwm     ! power available from high-mode wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   epyc_iwm     ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ecri_iwm     ! power available from low-mode, critical slope wave breaking (W/m2)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hbot_iwm     ! WKB decay scale for high-mode energy dissipation (m)
50   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hcri_iwm     ! decay scale for low-mode critical slope dissipation (m)
51   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   emix_iwm     ! local energy density available for mixing (W/kg)
52   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   bflx_iwm     ! buoyancy flux Kz * N^2 (W/kg)
53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   pcmap_iwm    ! vertically integrated buoyancy flux (W/m2)
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_ratio    ! S/T diffusivity ratio (only for ln_tsdiff=T)
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_wave     ! Internal wave-induced diffusivity
56
57   !! * Substitutions
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   INTEGER FUNCTION zdf_iwm_alloc()
67      !!----------------------------------------------------------------------
68      !!                ***  FUNCTION zdf_iwm_alloc  ***
69      !!----------------------------------------------------------------------
70      ALLOCATE(     ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj)    ,   &
71      &             hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj),  emix_iwm(jpi,jpj,jpk),   &
72      &         bflx_iwm(jpi,jpj,jpk), pcmap_iwm(jpi,jpj), zav_ratio(jpi,jpj,jpk),   & 
73      &         zav_wave(jpi,jpj,jpk), STAT=zdf_iwm_alloc     )
74      !
75      IF( lk_mpp             )   CALL mpp_sum ( zdf_iwm_alloc )
76      IF( zdf_iwm_alloc /= 0 )   CALL ctl_warn('zdf_iwm_alloc: failed to allocate arrays')
77   END FUNCTION zdf_iwm_alloc
78
79
80   SUBROUTINE zdf_iwm( kt )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE zdf_iwm  ***
83      !!                   
84      !! ** Purpose :   add to the vertical mixing coefficients the effect of
85      !!              breaking internal waves.
86      !!
87      !! ** Method  : - internal wave-driven vertical mixing is given by:
88      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = emix_iwm /( Nu * N^2 )  )
89      !!              where emix_iwm is the 3D space distribution of the wave-breaking
90      !!              energy and Nu the molecular kinematic viscosity.
91      !!              The function f(Reb) is linear (constant mixing efficiency)
92      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
93      !!
94      !!              - Compute emix_iwm, the 3D power density that allows to compute
95      !!              Reb and therefrom the wave-induced vertical diffusivity.
96      !!              This is divided into three components:
97      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
98      !!                     emix_iwm(z) = ( ecri_iwm / rau0 ) * EXP( -(H-z)/hcri_iwm )
99      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
100      !!              where hcri_iwm is the characteristic length scale of the bottom
101      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
102      !!                 2. Pycnocline-intensified low-mode dissipation
103      !!                     emix_iwm(z) = ( epyc_iwm / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
104      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
105      !!              where epyc_iwm is a map of available power, and nn_zpyc
106      !!              is the chosen stratification-dependence of the internal wave
107      !!              energy dissipation.
108      !!                 3. WKB-height dependent high mode dissipation
109      !!                     emix_iwm(z) = ( ebot_iwm / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
110      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w(z) )
111      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
112      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
113      !!              WKB-stretched height above bottom defined as
114      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
115      !!                                 / SUM( sqrt(rn2(z'))    * e3w(z')    )
116      !!
117      !!              - update the model vertical eddy viscosity and diffusivity:
118      !!                     avt  = avt  +    av_wave
119      !!                     avm  = avm  +    av_wave
120      !!
121      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
122      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
123      !!
124      !! ** Action  : - Define emix_iwm used to compute internal wave-induced mixing
125      !!              - avt, avs, avm, increased by internal wave-driven mixing   
126      !!
127      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
128      !!----------------------------------------------------------------------
129      INTEGER, INTENT(in) ::   kt   ! ocean time-step
130      !
131      INTEGER  ::   ji, jj, jk   ! dummy loop indices
132      REAL(wp) ::   ztpc         ! scalar workspace
133      REAL(wp), DIMENSION(:,:)  , POINTER ::  zfact     ! Used for vertical structure
134      REAL(wp), DIMENSION(:,:)  , POINTER ::  zhdep     ! Ocean depth
135      REAL(wp), DIMENSION(:,:,:), POINTER ::  zwkb      ! WKB-stretched height above bottom
136      REAL(wp), DIMENSION(:,:,:), POINTER ::  zweight   ! Weight for high mode vertical distribution
137      REAL(wp), DIMENSION(:,:,:), POINTER ::  znu_t     ! Molecular kinematic viscosity (T grid)
138      REAL(wp), DIMENSION(:,:,:), POINTER ::  znu_w     ! Molecular kinematic viscosity (W grid)
139      REAL(wp), DIMENSION(:,:,:), POINTER ::  zReb      ! Turbulence intensity parameter
140      !!----------------------------------------------------------------------
141      !
142      IF( nn_timing == 1 )   CALL timing_start('zdf_iwm')
143      !
144      CALL wrk_alloc( jpi,jpj,       zfact, zhdep )
145      CALL wrk_alloc( jpi,jpj,jpk,   zwkb, zweight, znu_t, znu_w, zReb )
146
147      !                          ! ----------------------------- !
148      !                          !  Internal wave-driven mixing  !  (compute zav_wave)
149      !                          ! ----------------------------- !
150      !                             
151      !                        !* Critical slope mixing: distribute energy over the time-varying ocean depth,
152      !                                                 using an exponential decay from the seafloor.
153      DO jj = 1, jpj                ! part independent of the level
154         DO ji = 1, jpi
155            zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
156            zfact(ji,jj) = rau0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
157            IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
158         END DO
159      END DO
160
161      DO jk = 2, jpkm1              ! complete with the level-dependent part
162         emix_iwm(:,:,jk) = zfact(:,:) * (  EXP( ( gde3w_n(:,:,jk  ) - zhdep(:,:) ) / hcri_iwm(:,:) )                      &
163            &                             - EXP( ( gde3w_n(:,:,jk-1) - zhdep(:,:) ) / hcri_iwm(:,:) )  ) * wmask(:,:,jk)   &
164!!gm delta(gde3w_n) = e3t_n  !!  Please verify the grid-point position w versus t-point
165            &                          / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
166      END DO
167
168      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
169      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
170      !
171      SELECT CASE ( nn_zpyc )
172      !
173      CASE ( 1 )               ! Dissipation scales as N (recommended)
174         !
175         zfact(:,:) = 0._wp
176         DO jk = 2, jpkm1              ! part independent of the level
177            zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
178         END DO
179         !
180         DO jj = 1, jpj
181            DO ji = 1, jpi
182               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
183            END DO
184         END DO
185         !
186         DO jk = 2, jpkm1              ! complete with the level-dependent part
187            emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zfact(:,:) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
188         END DO
189         !
190      CASE ( 2 )               ! Dissipation scales as N^2
191         !
192         zfact(:,:) = 0._wp
193         DO jk = 2, jpkm1              ! part independent of the level
194            zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
195         END DO
196         !
197         DO jj= 1, jpj
198            DO ji = 1, jpi
199               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
200            END DO
201         END DO
202         !
203         DO jk = 2, jpkm1              ! complete with the level-dependent part
204            emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
205         END DO
206         !
207      END SELECT
208
209      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
210      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
211      !
212      zwkb(:,:,:) = 0._wp
213      zfact(:,:) = 0._wp
214      DO jk = 2, jpkm1
215         zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
216         zwkb(:,:,jk) = zfact(:,:)
217      END DO
218      !
219      DO jk = 2, jpkm1
220         DO jj = 1, jpj
221            DO ji = 1, jpi
222               IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
223                  &                                     * tmask(ji,jj,jk) / zfact(ji,jj)
224            END DO
225         END DO
226      END DO
227      zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1)
228      !
229      zweight(:,:,:) = 0._wp
230      DO jk = 2, jpkm1
231         zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_iwm(:,:) * wmask(:,:,jk)                    &
232            &   * (  EXP( -zwkb(:,:,jk) / hbot_iwm(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_iwm(:,:) )  )
233      END DO
234      !
235      zfact(:,:) = 0._wp
236      DO jk = 2, jpkm1              ! part independent of the level
237         zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
238      END DO
239      !
240      DO jj = 1, jpj
241         DO ji = 1, jpi
242            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
243         END DO
244      END DO
245      !
246      DO jk = 2, jpkm1              ! complete with the level-dependent part
247         emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk)   &
248            &                                / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
249      END DO
250      !
251      ! Calculate molecular kinematic viscosity
252      znu_t(:,:,:) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem)  &
253         &                                  + 0.02305_wp * tsn(:,:,:,jp_sal)  ) * tmask(:,:,:) * r1_rau0
254      DO jk = 2, jpkm1
255         znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
256      END DO
257      !
258      ! Calculate turbulence intensity parameter Reb
259      DO jk = 2, jpkm1
260         zReb(:,:,jk) = emix_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
261      END DO
262      !
263      ! Define internal wave-induced diffusivity
264      DO jk = 2, jpkm1
265         zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
266      END DO
267      !
268      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
269         DO jk = 2, jpkm1              ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
270            DO jj = 1, jpj
271               DO ji = 1, jpi
272                  IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
273                     zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
274                  ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
275                     zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
276                  ENDIF
277               END DO
278            END DO
279         END DO
280      ENDIF
281      !
282      DO jk = 2, jpkm1                 ! Bound diffusivity by molecular value and 100 cm2/s
283         zav_wave(:,:,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp  ) * wmask(:,:,jk)
284      END DO
285      !
286      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
287         ztpc = 0._wp
288!!gm used of glosum 3D....
289         DO jk = 2, jpkm1
290            DO jj = 1, jpj
291               DO ji = 1, jpi
292                  ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj)   &
293                     &         * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
294               END DO
295            END DO
296         END DO
297         IF( lk_mpp )   CALL mpp_sum( ztpc )
298         ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing
299         !
300         IF(lwp) THEN
301            WRITE(numout,*)
302            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
303            WRITE(numout,*) '~~~~~~~ '
304            WRITE(numout,*)
305            WRITE(numout,*) '      Total power consumption by av_wave: ztpc =  ', ztpc * 1.e-12_wp, 'TW'
306         ENDIF
307      ENDIF
308
309      !                          ! ----------------------- !
310      !                          !   Update  mixing coefs  !                         
311      !                          ! ----------------------- !
312      !     
313      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
314         DO jk = 2, jpkm1              ! Calculate S/T diffusivity ratio as a function of Reb
315            DO jj = 1, jpj
316               DO ji = 1, jpi
317                  zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp *                                                                  &
318                      &   TANH(    0.92_wp * (   LOG10(  MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 )  ) - 0.60_wp   )    )   &
319                      &                 ) * wmask(ji,jj,jk)
320               END DO
321            END DO
322         END DO
323         CALL iom_put( "av_ratio", zav_ratio )
324         DO jk = 2, jpkm1           !* update momentum & tracer diffusivity with wave-driven mixing
325            avs(:,:,jk) = avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
326            avt(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
327            avm(:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
328         END DO
329         !
330      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
331         DO jk = 2, jpkm1
332            avs(:,:,jk) = avs(:,:,jk) + zav_wave(:,:,jk)
333            avt(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
334            avm(:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
335         END DO
336      ENDIF
337
338      !                             !* output internal wave-driven mixing coefficient
339      CALL iom_put( "av_wave", zav_wave )
340                                    !* output useful diagnostics: N^2, Kz * N^2 (bflx_iwm),
341                                    !  vertical integral of rau0 * Kz * N^2 (pcmap_iwm), energy density (emix_iwm)
342      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
343         bflx_iwm(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
344         pcmap_iwm(:,:) = 0._wp
345         DO jk = 2, jpkm1
346            pcmap_iwm(:,:) = pcmap_iwm(:,:) + e3w_n(:,:,jk) * bflx_iwm(:,:,jk) * wmask(:,:,jk)
347         END DO
348         pcmap_iwm(:,:) = rau0 * pcmap_iwm(:,:)
349         CALL iom_put( "bflx_iwm", bflx_iwm )
350         CALL iom_put( "pcmap_iwm", pcmap_iwm )
351      ENDIF
352      CALL iom_put( "bn2", rn2 )
353      CALL iom_put( "emix_iwm", emix_iwm )
354     
355      CALL wrk_dealloc( jpi,jpj,       zfact, zhdep )
356      CALL wrk_dealloc( jpi,jpj,jpk,   zwkb, zweight, znu_t, znu_w, zReb )
357
358      IF(ln_ctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
359      !
360      IF( nn_timing == 1 )   CALL timing_stop('zdf_iwm')
361      !
362   END SUBROUTINE zdf_iwm
363
364
365   SUBROUTINE zdf_iwm_init
366      !!----------------------------------------------------------------------
367      !!                  ***  ROUTINE zdf_iwm_init  ***
368      !!                     
369      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
370      !!              of input power maps and decay length scales in netcdf files.
371      !!
372      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
373      !!
374      !!              - Read the input data in NetCDF files :
375      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
376      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
377      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
378      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
379      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
380      !!
381      !! ** input   : - Namlist namzdf_iwm
382      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
383      !!              decay_scale_bot.nc decay_scale_cri.nc
384      !!
385      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
386      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
387      !!
388      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
389      !!              de Lavergne et al. in prep., 2017
390      !!----------------------------------------------------------------------
391      INTEGER  ::   ji, jj, jk   ! dummy loop indices
392      INTEGER  ::   inum         ! local integer
393      INTEGER  ::   ios
394      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
395      !!
396      NAMELIST/namzdf_iwm_new/ nn_zpyc, ln_mevar, ln_tsdiff
397      !!----------------------------------------------------------------------
398      !
399      IF( nn_timing == 1 )  CALL timing_start('zdf_iwm_init')
400      !
401      REWIND( numnam_ref )              ! Namelist namzdf_iwm in reference namelist : Wave-driven mixing
402      READ  ( numnam_ref, namzdf_iwm_new, IOSTAT = ios, ERR = 901)
403901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist', lwp )
404      !
405      REWIND( numnam_cfg )              ! Namelist namzdf_iwm in configuration namelist : Wave-driven mixing
406      READ  ( numnam_cfg, namzdf_iwm_new, IOSTAT = ios, ERR = 902 )
407902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist', lwp )
408      IF(lwm) WRITE ( numond, namzdf_iwm_new )
409      !
410      IF(lwp) THEN                  ! Control print
411         WRITE(numout,*)
412         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
413         WRITE(numout,*) '~~~~~~~~~~~~'
414         WRITE(numout,*) '   Namelist namzdf_iwm_new : set wave-driven mixing parameters'
415         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
416         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
417         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
418      ENDIF
419     
420      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
421      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
422      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
423      avmb(:) = 1.4e-6_wp        ! viscous molecular value
424      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
425      avtb_2d(:,:) = 1.e0_wp     ! uniform
426      IF(lwp) THEN                  ! Control print
427         WRITE(numout,*)
428         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
429            &               'the viscous molecular value & a very small diffusive value, resp.'
430      ENDIF
431           
432      !                             ! allocate iwm arrays
433      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
434      !
435      !                             ! read necessary fields
436      CALL iom_open('mixing_power_bot',inum)       ! energy flux for high-mode wave breaking [W/m2]
437      CALL iom_get  (inum, jpdom_data, 'field', ebot_iwm, 1 ) 
438      CALL iom_close(inum)
439      !
440      CALL iom_open('mixing_power_pyc',inum)       ! energy flux for pynocline-intensified wave breaking [W/m2]
441      CALL iom_get  (inum, jpdom_data, 'field', epyc_iwm, 1 )
442      CALL iom_close(inum)
443      !
444      CALL iom_open('mixing_power_cri',inum)       ! energy flux for critical slope wave breaking [W/m2]
445      CALL iom_get  (inum, jpdom_data, 'field', ecri_iwm, 1 )
446      CALL iom_close(inum)
447      !
448      CALL iom_open('decay_scale_bot',inum)        ! spatially variable decay scale for high-mode wave breaking [m]
449      CALL iom_get  (inum, jpdom_data, 'field', hbot_iwm, 1 )
450      CALL iom_close(inum)
451      !
452      CALL iom_open('decay_scale_cri',inum)        ! spatially variable decay scale for critical slope wave breaking [m]
453      CALL iom_get  (inum, jpdom_data, 'field', hcri_iwm, 1 )
454      CALL iom_close(inum)
455
456      ebot_iwm(:,:) = ebot_iwm(:,:) * ssmask(:,:)
457      epyc_iwm(:,:) = epyc_iwm(:,:) * ssmask(:,:)
458      ecri_iwm(:,:) = ecri_iwm(:,:) * ssmask(:,:)
459
460      ! Set once for all to zero the first and last vertical levels of appropriate variables
461      emix_iwm (:,:, 1 ) = 0._wp
462      emix_iwm (:,:,jpk) = 0._wp
463      zav_ratio(:,:, 1 ) = 0._wp
464      zav_ratio(:,:,jpk) = 0._wp
465      zav_wave (:,:, 1 ) = 0._wp
466      zav_wave (:,:,jpk) = 0._wp
467
468      zbot = glob_sum( e1e2t(:,:) * ebot_iwm(:,:) )
469      zpyc = glob_sum( e1e2t(:,:) * epyc_iwm(:,:) )
470      zcri = glob_sum( e1e2t(:,:) * ecri_iwm(:,:) )
471      IF(lwp) THEN
472         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
473         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
474         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
475      ENDIF
476      !
477      IF( nn_timing == 1 )  CALL timing_stop('zdf_iwm_init')
478      !
479   END SUBROUTINE zdf_iwm_init
480
481   !!======================================================================
482END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.