| 1 | MODULE limhdf_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limhdf_2 *** |
|---|
| 4 | !! LIM 2.0 ice model : horizontal diffusion of sea-ice quantities |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : LIM ! 2000-01 (LIM) Original code |
|---|
| 7 | !! - ! 2001-05 (G. Madec, R. Hordoir) opa norm |
|---|
| 8 | !! 1.0 ! 2002-08 (C. Ethe) F90, free form |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_lim2 |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! lim_hdf_2 : diffusion trend on sea-ice variable |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE dom_oce ! ocean domain |
|---|
| 17 | USE ice_2 ! LIM-2: ice variables |
|---|
| 18 | USE lbclnk ! lateral boundary condition - MPP exchanges |
|---|
| 19 | USE lib_mpp ! MPP library |
|---|
| 20 | USE prtctl ! Print control |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 23 | |
|---|
| 24 | IMPLICIT NONE |
|---|
| 25 | PRIVATE |
|---|
| 26 | |
|---|
| 27 | PUBLIC lim_hdf_2 ! called by limtrp_2.F90 |
|---|
| 28 | |
|---|
| 29 | LOGICAL :: linit = .TRUE. ! ! initialization flag (set to flase after the 1st call) |
|---|
| 30 | REAL(wp) :: epsi04 = 1e-04 ! constant |
|---|
| 31 | |
|---|
| 32 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: efact ! metric coefficient |
|---|
| 33 | |
|---|
| 34 | !! * Substitution |
|---|
| 35 | # include "vectopt_loop_substitute.h90" |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2010) |
|---|
| 38 | !! $Id$ |
|---|
| 39 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | CONTAINS |
|---|
| 42 | |
|---|
| 43 | SUBROUTINE lim_hdf_2( ptab ) |
|---|
| 44 | !!------------------------------------------------------------------- |
|---|
| 45 | !! *** ROUTINE lim_hdf_2 *** |
|---|
| 46 | !! |
|---|
| 47 | !! ** purpose : Compute and add the diffusive trend on sea-ice variables |
|---|
| 48 | !! |
|---|
| 49 | !! ** method : Second order diffusive operator evaluated using a |
|---|
| 50 | !! Cranck-Nicholson time Scheme. |
|---|
| 51 | !! |
|---|
| 52 | !! ** Action : update ptab with the diffusive contribution |
|---|
| 53 | !!------------------------------------------------------------------- |
|---|
| 54 | REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) :: ptab ! Field on which the diffusion is applied |
|---|
| 55 | ! |
|---|
| 56 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 57 | INTEGER :: its, iter, ierr ! local integers |
|---|
| 58 | REAL(wp) :: zalfa, zrlxint, zconv, zeps ! local scalars |
|---|
| 59 | REAL(wp), DIMENSION(jpi,jpj) :: zrlx, zflu, zflv, zdiv0, zdiv, ztab0 |
|---|
| 60 | CHARACTER (len=55) :: charout |
|---|
| 61 | !!------------------------------------------------------------------- |
|---|
| 62 | |
|---|
| 63 | |
|---|
| 64 | ! !== Initialisation ==! |
|---|
| 65 | ! |
|---|
| 66 | IF( linit ) THEN ! Metric coefficient (compute at the first call and saved in efact) |
|---|
| 67 | ALLOCATE( efact(jpi,jpj) , STAT=ierr ) |
|---|
| 68 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
|---|
| 69 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'lim_hdf_2 : unable to allocate standard arrays' ) |
|---|
| 70 | DO jj = 2, jpjm1 |
|---|
| 71 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 72 | efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) / ( e1t(ji,jj) * e2t(ji,jj) ) |
|---|
| 73 | END DO |
|---|
| 74 | END DO |
|---|
| 75 | linit = .FALSE. |
|---|
| 76 | ENDIF |
|---|
| 77 | ! |
|---|
| 78 | ! ! Time integration parameters |
|---|
| 79 | zalfa = 0.5_wp ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit |
|---|
| 80 | its = 100 ! Maximum number of iteration |
|---|
| 81 | zeps = 2._wp * epsi04 |
|---|
| 82 | ! |
|---|
| 83 | ztab0(:, : ) = ptab(:,:) ! Arrays initialization |
|---|
| 84 | zdiv0(:, 1 ) = 0._wp |
|---|
| 85 | zdiv0(:,jpj) = 0._wp |
|---|
| 86 | zflu (jpi,:) = 0._wp |
|---|
| 87 | zflv (jpi,:) = 0._wp |
|---|
| 88 | zdiv0(1, :) = 0._wp |
|---|
| 89 | zdiv0(jpi,:) = 0._wp |
|---|
| 90 | |
|---|
| 91 | zconv = 1._wp !== horizontal diffusion using a Crant-Nicholson scheme ==! |
|---|
| 92 | iter = 0 |
|---|
| 93 | ! |
|---|
| 94 | DO WHILE ( zconv > zeps .AND. iter <= its ) ! Sub-time step loop |
|---|
| 95 | ! |
|---|
| 96 | iter = iter + 1 ! incrementation of the sub-time step number |
|---|
| 97 | ! |
|---|
| 98 | DO jj = 1, jpjm1 ! diffusive fluxes in U- and V- direction |
|---|
| 99 | DO ji = 1 , fs_jpim1 ! vector opt. |
|---|
| 100 | zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) / e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) ) |
|---|
| 101 | zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) / e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) ) |
|---|
| 102 | END DO |
|---|
| 103 | END DO |
|---|
| 104 | ! |
|---|
| 105 | DO jj= 2, jpjm1 ! diffusive trend : divergence of the fluxes |
|---|
| 106 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 107 | zdiv (ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj ) & |
|---|
| 108 | & + zflv(ji,jj) - zflv(ji ,jj-1) ) / ( e1t (ji,jj) * e2t (ji,jj) ) |
|---|
| 109 | END DO |
|---|
| 110 | END DO |
|---|
| 111 | ! |
|---|
| 112 | IF( iter == 1 ) zdiv0(:,:) = zdiv(:,:) ! save the 1st evaluation of the diffusive trend in zdiv0 |
|---|
| 113 | ! |
|---|
| 114 | DO jj = 2, jpjm1 ! iterative evaluation |
|---|
| 115 | DO ji = fs_2 , fs_jpim1 ! vector opt. |
|---|
| 116 | zrlxint = ( ztab0(ji,jj) & |
|---|
| 117 | & + rdt_ice * ( zalfa * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) ) & |
|---|
| 118 | & + ( 1.0 - zalfa ) * zdiv0(ji,jj) ) ) & |
|---|
| 119 | & / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) ) |
|---|
| 120 | zrlx(ji,jj) = ptab(ji,jj) + om * ( zrlxint - ptab(ji,jj) ) |
|---|
| 121 | END DO |
|---|
| 122 | END DO |
|---|
| 123 | CALL lbc_lnk( zrlx, 'T', 1. ) ! lateral boundary condition |
|---|
| 124 | |
|---|
| 125 | zconv = 0._wp ! convergence test |
|---|
| 126 | |
|---|
| 127 | DO jj = 2, jpjm1 |
|---|
| 128 | DO ji = 2, jpim1 |
|---|
| 129 | zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) ) ) |
|---|
| 130 | END DO |
|---|
| 131 | END DO |
|---|
| 132 | IF( lk_mpp ) CALL mpp_max( zconv ) ! max over the global domain |
|---|
| 133 | |
|---|
| 134 | ptab(:,:) = zrlx(:,:) |
|---|
| 135 | ! |
|---|
| 136 | END DO ! end of sub-time step loop |
|---|
| 137 | |
|---|
| 138 | IF(ln_ctl) THEN |
|---|
| 139 | zrlx(:,:) = ptab(:,:) - ztab0(:,:) |
|---|
| 140 | WRITE(charout,FMT="(' lim_hdf : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter |
|---|
| 141 | CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout ) |
|---|
| 142 | ENDIF |
|---|
| 143 | ! |
|---|
| 144 | ! |
|---|
| 145 | END SUBROUTINE lim_hdf_2 |
|---|
| 146 | |
|---|
| 147 | #else |
|---|
| 148 | !!---------------------------------------------------------------------- |
|---|
| 149 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 150 | !!---------------------------------------------------------------------- |
|---|
| 151 | CONTAINS |
|---|
| 152 | SUBROUTINE lim_hdf_2 ! Empty routine |
|---|
| 153 | END SUBROUTINE lim_hdf_2 |
|---|
| 154 | #endif |
|---|
| 155 | |
|---|
| 156 | !!====================================================================== |
|---|
| 157 | END MODULE limhdf_2 |
|---|
