New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limupdate2.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/LIM_SRC_3/limupdate2.F90 @ 8016

Last change on this file since 8016 was 8016, checked in by timgraham, 7 years ago

Delete some remaining "USE wrk_array" lines
  • Property svn:keywords set to Id
File size: 8.2 KB
Line 
1MODULE limupdate2
2   !!======================================================================
3   !!                     ***  MODULE  limupdate2  ***
4   !!   LIM-3 : Update of sea-ice global variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.5  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!----------------------------------------------------------------------
9#if defined key_lim3
10   !!----------------------------------------------------------------------
11   !!   'key_lim3'                                      LIM3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!    lim_update2   : computes update of sea-ice global variables from trend terms
14   !!----------------------------------------------------------------------
15   USE sbc_oce         ! Surface boundary condition: ocean fields
16   USE sbc_ice         ! Surface boundary condition: ice fields
17   USE dom_oce
18   USE phycst          ! physical constants
19   USE ice
20   USE thd_ice         ! LIM thermodynamic sea-ice variables
21   USE limitd_th
22   USE limvar
23   USE lbclnk          ! lateral boundary condition - MPP exchanges
24   USE timing          ! Timing
25   USE limcons         ! conservation tests
26   USE limctl
27   USE lib_mpp         ! MPP library
28   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   lim_update2   ! routine called by ice_step
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE lim_update2( kt )
46      !!-------------------------------------------------------------------
47      !!               ***  ROUTINE lim_update2  ***
48      !!               
49      !! ** Purpose :  Computes update of sea-ice global variables at
50      !!               the end of the time step.
51      !!
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt    ! number of iteration
54      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
55      REAL(wp) ::   zsal
56      REAL(wp) ::   zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
57      !!-------------------------------------------------------------------
58      IF( nn_timing == 1 )  CALL timing_start('limupdate2')
59
60      IF( kt == nit000 .AND. lwp ) THEN
61         WRITE(numout,*)''
62         WRITE(numout,*)' lim_update2 '
63         WRITE(numout,*)' ~~~~~~~~~~~ '
64      ENDIF
65
66      ! conservation test
67      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
68
69      !----------------------------------------------------------------------
70      ! Constrain the thickness of the smallest category above himin
71      !----------------------------------------------------------------------
72      DO jj = 1, jpj 
73         DO ji = 1, jpi
74            rswitch = MAX( 0._wp , SIGN( 1._wp, a_i(ji,jj,1) - epsi20 ) )   !0 if no ice and 1 if yes
75            ht_i(ji,jj,1) = v_i (ji,jj,1) / MAX( a_i(ji,jj,1) , epsi20 ) * rswitch
76            IF( v_i(ji,jj,1) > 0._wp .AND. ht_i(ji,jj,1) < rn_himin ) THEN
77               a_i (ji,jj,1) = a_i (ji,jj,1) * ht_i(ji,jj,1) / rn_himin
78               oa_i(ji,jj,1) = oa_i(ji,jj,1) * ht_i(ji,jj,1) / rn_himin
79            ENDIF
80         END DO
81      END DO
82     
83      !-----------------------------------------------------
84      ! ice concentration should not exceed amax
85      !-----------------------------------------------------
86      at_i(:,:) = 0._wp
87      DO jl = 1, jpl
88         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
89      END DO
90
91      DO jl  = 1, jpl
92         DO jj = 1, jpj
93            DO ji = 1, jpi
94               IF( at_i(ji,jj) > rn_amax_2d(ji,jj) .AND. a_i(ji,jj,jl) > 0._wp ) THEN
95                  a_i (ji,jj,jl) = a_i (ji,jj,jl) * ( 1._wp - ( 1._wp - rn_amax_2d(ji,jj) / at_i(ji,jj) ) )
96                  oa_i(ji,jj,jl) = oa_i(ji,jj,jl) * ( 1._wp - ( 1._wp - rn_amax_2d(ji,jj) / at_i(ji,jj) ) )
97               ENDIF
98            END DO
99         END DO
100      END DO
101
102      !---------------------
103      ! Ice salinity
104      !---------------------
105      IF (  nn_icesal == 2  ) THEN
106         DO jl = 1, jpl
107            DO jj = 1, jpj 
108               DO ji = 1, jpi
109                  zsal            = smv_i(ji,jj,jl)
110                  ! salinity stays in bounds
111                  rswitch         = 1._wp - MAX( 0._wp, SIGN( 1._wp, - v_i(ji,jj,jl) ) )
112                  smv_i(ji,jj,jl) = rswitch * MAX( MIN( rn_simax * v_i(ji,jj,jl), smv_i(ji,jj,jl) ), rn_simin * v_i(ji,jj,jl) )
113                  ! associated salt flux
114                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsal ) * rhoic * r1_rdtice
115               END DO
116            END DO
117         END DO
118      ENDIF
119
120      !----------------------------------------------------
121      ! Rebin categories with thickness out of bounds
122      !----------------------------------------------------
123      IF ( jpl > 1 ) CALL lim_itd_th_reb( 1, jpl )
124
125      !-----------------
126      ! zap small values
127      !-----------------
128      CALL lim_var_zapsmall
129
130      !------------------------------------------------------------------------------
131      ! Corrections to avoid wrong values                                        |
132      !------------------------------------------------------------------------------
133      ! Ice drift
134      !------------
135      DO jj = 2, jpjm1
136         DO ji = 2, jpim1
137            IF ( at_i(ji,jj) == 0._wp ) THEN ! what to do if there is no ice
138               IF ( at_i(ji+1,jj) == 0._wp ) u_ice(ji,jj)   = 0._wp ! right side
139               IF ( at_i(ji-1,jj) == 0._wp ) u_ice(ji-1,jj) = 0._wp ! left side
140               IF ( at_i(ji,jj+1) == 0._wp ) v_ice(ji,jj)   = 0._wp ! upper side
141               IF ( at_i(ji,jj-1) == 0._wp ) v_ice(ji,jj-1) = 0._wp ! bottom side
142            ENDIF
143         END DO
144      END DO
145      !lateral boundary conditions
146      CALL lbc_lnk( u_ice(:,:), 'U', -1. )
147      CALL lbc_lnk( v_ice(:,:), 'V', -1. )
148      !mask velocities
149      u_ice(:,:) = u_ice(:,:) * umask(:,:,1)
150      v_ice(:,:) = v_ice(:,:) * vmask(:,:,1)
151 
152      ! -------------------------------------------------
153      ! Diagnostics
154      ! -------------------------------------------------
155      DO jl  = 1, jpl
156         oa_i(:,:,jl) = oa_i(:,:,jl) + a_i(:,:,jl) * rdt_ice / rday   ! ice natural aging
157         afx_thd(:,:) = afx_thd(:,:) + ( a_i(:,:,jl) - a_i_b(:,:,jl) ) * r1_rdtice
158      END DO
159      afx_tot = afx_thd + afx_dyn
160
161      DO jj = 1, jpj
162         DO ji = 1, jpi           
163            ! heat content variation (W.m-2)
164            diag_heat(ji,jj) = diag_heat(ji,jj) -  &
165               &               ( SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) ) +  & 
166               &                 SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )    &
167               &               ) * r1_rdtice   
168            ! salt, volume
169            diag_smvi(ji,jj) = diag_smvi(ji,jj) + SUM( smv_i(ji,jj,:) - smv_i_b(ji,jj,:) ) * rhoic * r1_rdtice
170            diag_vice(ji,jj) = diag_vice(ji,jj) + SUM( v_i  (ji,jj,:) - v_i_b  (ji,jj,:) ) * rhoic * r1_rdtice
171            diag_vsnw(ji,jj) = diag_vsnw(ji,jj) + SUM( v_s  (ji,jj,:) - v_s_b  (ji,jj,:) ) * rhosn * r1_rdtice
172         END DO
173      END DO
174
175      ! conservation test
176      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
177
178      ! control prints
179      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 2, ' - Final state - ' )
180      IF( ln_ctl )       CALL lim_prt3D( 'limupdate2' )
181   
182      IF( nn_timing == 1 )  CALL timing_stop('limupdate2')
183
184   END SUBROUTINE lim_update2
185
186#else
187   !!----------------------------------------------------------------------
188   !!   Default option         Empty Module               No sea-ice model
189   !!----------------------------------------------------------------------
190CONTAINS
191   SUBROUTINE lim_update2     ! Empty routine
192   END SUBROUTINE lim_update2
193
194#endif
195
196END MODULE limupdate2
Note: See TracBrowser for help on using the repository browser.