| 1 | MODULE sbcblk_algo_ncar |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcblk_algo_ncar *** |
|---|
| 4 | !! Computes: |
|---|
| 5 | !! * bulk transfer coefficients C_D, C_E and C_H |
|---|
| 6 | !! * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed |
|---|
| 7 | !! * the effective bulk wind speed at 10m U_blk |
|---|
| 8 | !! => all these are used in bulk formulas in sbcblk.F90 |
|---|
| 9 | !! |
|---|
| 10 | !! Using the bulk formulation/param. of Large & Yeager 2008 |
|---|
| 11 | !! |
|---|
| 12 | !! Routine turb_ncar maintained and developed in AeroBulk |
|---|
| 13 | !! (http://aerobulk.sourceforge.net/) |
|---|
| 14 | !! |
|---|
| 15 | !! L. Brodeau, 2015 |
|---|
| 16 | !!===================================================================== |
|---|
| 17 | !! History : 3.6 ! 2016-02 (L.Brodeau) successor of old turb_ncar of former sbcblk_core.F90 |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | !! turb_ncar : computes the bulk turbulent transfer coefficients |
|---|
| 22 | !! adjusts t_air and q_air from zt to zu m |
|---|
| 23 | !! returns the effective bulk wind speed at 10m |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE oce ! ocean dynamics and tracers |
|---|
| 26 | USE dom_oce ! ocean space and time domain |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 29 | USE sbcwave, ONLY : cdn_wave ! wave module |
|---|
| 30 | #if defined key_lim3 || defined key_cice |
|---|
| 31 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 32 | #endif |
|---|
| 33 | ! |
|---|
| 34 | USE iom ! I/O manager library |
|---|
| 35 | USE lib_mpp ! distribued memory computing library |
|---|
| 36 | USE timing ! Timing |
|---|
| 37 | USE in_out_manager ! I/O manager |
|---|
| 38 | USE prtctl ! Print control |
|---|
| 39 | USE lib_fortran ! to use key_nosignedzero |
|---|
| 40 | |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | PRIVATE |
|---|
| 44 | |
|---|
| 45 | PUBLIC :: TURB_NCAR ! called by sbcblk.F90 |
|---|
| 46 | |
|---|
| 47 | ! ! NCAR own values for given constants: |
|---|
| 48 | REAL(wp), PARAMETER :: rctv0 = 0.608 ! constant to obtain virtual temperature... |
|---|
| 49 | |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | CONTAINS |
|---|
| 52 | |
|---|
| 53 | SUBROUTINE turb_ncar( zt, zu, sst, t_zt, ssq, q_zt, U_zu, & |
|---|
| 54 | & Cd, Ch, Ce, t_zu, q_zu, U_blk ) |
|---|
| 55 | !!---------------------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE turb_ncar *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Computes turbulent transfert coefficients of surface |
|---|
| 59 | !! fluxes according to Large & Yeager (2004) and Large & Yeager (2008) |
|---|
| 60 | !! If relevant (zt /= zu), adjust temperature and humidity from height zt to zu |
|---|
| 61 | !! Returns the effective bulk wind speed at 10m to be used in the bulk formulas |
|---|
| 62 | !! |
|---|
| 63 | !! ** Method : Monin Obukhov Similarity Theory |
|---|
| 64 | !! + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10) |
|---|
| 65 | !! |
|---|
| 66 | !! ** References : Large & Yeager, 2004 / Large & Yeager, 2008 |
|---|
| 67 | !! |
|---|
| 68 | !! ** Last update: Laurent Brodeau, June 2014: |
|---|
| 69 | !! - handles both cases zt=zu and zt/=zu |
|---|
| 70 | !! - optimized: less 2D arrays allocated and less operations |
|---|
| 71 | !! - better first guess of stability by checking air-sea difference of virtual temperature |
|---|
| 72 | !! rather than temperature difference only... |
|---|
| 73 | !! - added function "cd_neutral_10m" that uses the improved parametrization of |
|---|
| 74 | !! Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions! |
|---|
| 75 | !! - using code-wide physical constants defined into "phycst.mod" rather than redifining them |
|---|
| 76 | !! => 'vkarmn' and 'grav' |
|---|
| 77 | !! |
|---|
| 78 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
|---|
| 79 | !! |
|---|
| 80 | !! INPUT : |
|---|
| 81 | !! ------- |
|---|
| 82 | !! * zt : height for temperature and spec. hum. of air [m] |
|---|
| 83 | !! * zu : height for wind speed (generally 10m) [m] |
|---|
| 84 | !! * U_zu : scalar wind speed at 10m [m/s] |
|---|
| 85 | !! * sst : SST [K] |
|---|
| 86 | !! * t_zt : potential air temperature at zt [K] |
|---|
| 87 | !! * ssq : specific humidity at saturation at SST [kg/kg] |
|---|
| 88 | !! * q_zt : specific humidity of air at zt [kg/kg] |
|---|
| 89 | !! |
|---|
| 90 | !! |
|---|
| 91 | !! OUTPUT : |
|---|
| 92 | !! -------- |
|---|
| 93 | !! * Cd : drag coefficient |
|---|
| 94 | !! * Ch : sensible heat coefficient |
|---|
| 95 | !! * Ce : evaporation coefficient |
|---|
| 96 | !! * t_zu : pot. air temperature adjusted at wind height zu [K] |
|---|
| 97 | !! * q_zu : specific humidity of air // [kg/kg] |
|---|
| 98 | !! * U_blk : bulk wind at 10m [m/s] |
|---|
| 99 | !!---------------------------------------------------------------------------------- |
|---|
| 100 | REAL(wp), INTENT(in ) :: zt ! height for t_zt and q_zt [m] |
|---|
| 101 | REAL(wp), INTENT(in ) :: zu ! height for U_zu [m] |
|---|
| 102 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: sst ! sea surface temperature [Kelvin] |
|---|
| 103 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: t_zt ! potential air temperature [Kelvin] |
|---|
| 104 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: ssq ! sea surface specific humidity [kg/kg] |
|---|
| 105 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_zt ! specific air humidity [kg/kg] |
|---|
| 106 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: U_zu ! relative wind module at zu [m/s] |
|---|
| 107 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Cd ! transfer coefficient for momentum (tau) |
|---|
| 108 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ch ! transfer coefficient for sensible heat (Q_sens) |
|---|
| 109 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ce ! transfert coefficient for evaporation (Q_lat) |
|---|
| 110 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: t_zu ! pot. air temp. adjusted at zu [K] |
|---|
| 111 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: q_zu ! spec. humidity adjusted at zu [kg/kg] |
|---|
| 112 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: U_blk ! bulk wind at 10m [m/s] |
|---|
| 113 | ! |
|---|
| 114 | INTEGER :: j_itt |
|---|
| 115 | LOGICAL :: l_zt_equal_zu = .FALSE. ! if q and t are given at same height as U |
|---|
| 116 | INTEGER , PARAMETER :: nb_itt = 4 ! number of itterations |
|---|
| 117 | ! |
|---|
| 118 | REAL(wp), DIMENSION(jpi,jpj) :: Cx_n10 ! 10m neutral latent/sensible coefficient |
|---|
| 119 | REAL(wp), DIMENSION(jpi,jpj) :: sqrt_Cd_n10 ! root square of Cd_n10 |
|---|
| 120 | REAL(wp), DIMENSION(jpi,jpj) :: zeta_u ! stability parameter at height zu |
|---|
| 121 | REAL(wp), DIMENSION(jpi,jpj) :: zpsi_h_u |
|---|
| 122 | REAL(wp), DIMENSION(jpi,jpj) :: ztmp0, ztmp1, ztmp2 |
|---|
| 123 | REAL(wp), DIMENSION(jpi,jpj) :: stab ! stability test integer |
|---|
| 124 | !!---------------------------------------------------------------------------------- |
|---|
| 125 | ! |
|---|
| 126 | IF( nn_timing == 1 ) CALL timing_start('turb_ncar') |
|---|
| 127 | ! |
|---|
| 128 | ! |
|---|
| 129 | l_zt_equal_zu = .FALSE. |
|---|
| 130 | IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE. ! testing "zu == zt" is risky with double precision |
|---|
| 131 | |
|---|
| 132 | U_blk = MAX( 0.5 , U_zu ) ! relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s |
|---|
| 133 | |
|---|
| 134 | !! First guess of stability: |
|---|
| 135 | ztmp0 = t_zt*(1. + rctv0*q_zt) - sst*(1. + rctv0*ssq) ! air-sea difference of virtual pot. temp. at zt |
|---|
| 136 | stab = 0.5 + sign(0.5,ztmp0) ! stab = 1 if dTv > 0 => STABLE, 0 if unstable |
|---|
| 137 | |
|---|
| 138 | !! Neutral coefficients at 10m: |
|---|
| 139 | IF( ln_cdgw ) THEN ! wave drag case |
|---|
| 140 | cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) ) |
|---|
| 141 | ztmp0 (:,:) = cdn_wave(:,:) |
|---|
| 142 | ELSE |
|---|
| 143 | ztmp0 = cd_neutral_10m( U_blk ) |
|---|
| 144 | ENDIF |
|---|
| 145 | |
|---|
| 146 | sqrt_Cd_n10 = SQRT( ztmp0 ) |
|---|
| 147 | |
|---|
| 148 | !! Initializing transf. coeff. with their first guess neutral equivalents : |
|---|
| 149 | Cd = ztmp0 |
|---|
| 150 | Ce = 1.e-3*( 34.6 * sqrt_Cd_n10 ) |
|---|
| 151 | Ch = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab)) |
|---|
| 152 | stab = sqrt_Cd_n10 ! Temporaty array !!! stab == SQRT(Cd) |
|---|
| 153 | |
|---|
| 154 | !! Initializing values at z_u with z_t values: |
|---|
| 155 | t_zu = t_zt ; q_zu = q_zt |
|---|
| 156 | |
|---|
| 157 | !! * Now starting iteration loop |
|---|
| 158 | DO j_itt=1, nb_itt |
|---|
| 159 | ! |
|---|
| 160 | ztmp1 = t_zu - sst ! Updating air/sea differences |
|---|
| 161 | ztmp2 = q_zu - ssq |
|---|
| 162 | |
|---|
| 163 | ! Updating turbulent scales : (L&Y 2004 eq. (7)) |
|---|
| 164 | ztmp1 = Ch/stab*ztmp1 ! theta* (stab == SQRT(Cd)) |
|---|
| 165 | ztmp2 = Ce/stab*ztmp2 ! q* (stab == SQRT(Cd)) |
|---|
| 166 | |
|---|
| 167 | ztmp0 = 1. + rctv0*q_zu ! multiply this with t and you have the virtual temperature |
|---|
| 168 | |
|---|
| 169 | ! Estimate the inverse of Monin-Obukov length (1/L) at height zu: |
|---|
| 170 | ztmp0 = (grav*vkarmn/(t_zu*ztmp0)*(ztmp1*ztmp0 + rctv0*t_zu*ztmp2)) / (Cd*U_blk*U_blk) |
|---|
| 171 | ! ( Cd*U_blk*U_blk is U*^2 at zu ) |
|---|
| 172 | |
|---|
| 173 | !! Stability parameters : |
|---|
| 174 | zeta_u = zu*ztmp0 ; zeta_u = sign( min(abs(zeta_u),10.0), zeta_u ) |
|---|
| 175 | zpsi_h_u = psi_h( zeta_u ) |
|---|
| 176 | |
|---|
| 177 | !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c)) |
|---|
| 178 | IF( .NOT. l_zt_equal_zu ) THEN |
|---|
| 179 | !! Array 'stab' is free for the moment so using it to store 'zeta_t' |
|---|
| 180 | stab = zt*ztmp0 ; stab = SIGN( MIN(ABS(stab),10.0), stab ) ! Temporaty array stab == zeta_t !!! |
|---|
| 181 | stab = LOG(zt/zu) + zpsi_h_u - psi_h(stab) ! stab just used as temp array again! |
|---|
| 182 | t_zu = t_zt - ztmp1/vkarmn*stab ! ztmp1 is still theta* L&Y 2004 eq.(9b) |
|---|
| 183 | q_zu = q_zt - ztmp2/vkarmn*stab ! ztmp2 is still q* L&Y 2004 eq.(9c) |
|---|
| 184 | q_zu = max(0., q_zu) |
|---|
| 185 | END IF |
|---|
| 186 | |
|---|
| 187 | ztmp2 = psi_m(zeta_u) |
|---|
| 188 | IF( ln_cdgw ) THEN ! surface wave case |
|---|
| 189 | stab = vkarmn / ( vkarmn / sqrt_Cd_n10 - ztmp2 ) ! (stab == SQRT(Cd)) |
|---|
| 190 | Cd = stab * stab |
|---|
| 191 | ELSE |
|---|
| 192 | ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)... |
|---|
| 193 | ! In very rare low-wind conditions, the old way of estimating the |
|---|
| 194 | ! neutral wind speed at 10m leads to a negative value that causes the code |
|---|
| 195 | ! to crash. To prevent this a threshold of 0.25m/s is imposed. |
|---|
| 196 | ztmp0 = MAX( 0.25 , U_blk/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2)) ) ! U_n10 (ztmp2 == psi_m(zeta_u)) |
|---|
| 197 | ztmp0 = cd_neutral_10m(ztmp0) ! Cd_n10 |
|---|
| 198 | sqrt_Cd_n10 = sqrt(ztmp0) |
|---|
| 199 | |
|---|
| 200 | stab = 0.5 + sign(0.5,zeta_u) ! update stability |
|---|
| 201 | Cx_n10 = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab)) ! L&Y 2004 eq. (6c-6d) (Cx_n10 == Ch_n10) |
|---|
| 202 | |
|---|
| 203 | !! Update of transfer coefficients: |
|---|
| 204 | ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2) ! L&Y 2004 eq. (10a) (ztmp2 == psi_m(zeta_u)) |
|---|
| 205 | Cd = ztmp0 / ( ztmp1*ztmp1 ) |
|---|
| 206 | stab = SQRT( Cd ) ! Temporary array !!! (stab == SQRT(Cd)) |
|---|
| 207 | ENDIF |
|---|
| 208 | |
|---|
| 209 | ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10 |
|---|
| 210 | ztmp2 = stab / sqrt_Cd_n10 ! (stab == SQRT(Cd)) |
|---|
| 211 | ztmp1 = 1. + Cx_n10*ztmp0 ! (Cx_n10 == Ch_n10) |
|---|
| 212 | Ch = Cx_n10*ztmp2 / ztmp1 ! L&Y 2004 eq. (10b) |
|---|
| 213 | |
|---|
| 214 | Cx_n10 = 1.e-3 * (34.6 * sqrt_Cd_n10) ! L&Y 2004 eq. (6b) ! Cx_n10 == Ce_n10 |
|---|
| 215 | ztmp1 = 1. + Cx_n10*ztmp0 |
|---|
| 216 | Ce = Cx_n10*ztmp2 / ztmp1 ! L&Y 2004 eq. (10c) |
|---|
| 217 | |
|---|
| 218 | END DO |
|---|
| 219 | |
|---|
| 220 | |
|---|
| 221 | IF( nn_timing == 1 ) CALL timing_stop('turb_ncar') |
|---|
| 222 | |
|---|
| 223 | END SUBROUTINE turb_ncar |
|---|
| 224 | |
|---|
| 225 | |
|---|
| 226 | FUNCTION cd_neutral_10m( pw10 ) |
|---|
| 227 | !!---------------------------------------------------------------------------------- |
|---|
| 228 | !! Estimate of the neutral drag coefficient at 10m as a function |
|---|
| 229 | !! of neutral wind speed at 10m |
|---|
| 230 | !! |
|---|
| 231 | !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b) |
|---|
| 232 | !! |
|---|
| 233 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
|---|
| 234 | !!---------------------------------------------------------------------------------- |
|---|
| 235 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pw10 ! scalar wind speed at 10m (m/s) |
|---|
| 236 | REAL(wp), DIMENSION(jpi,jpj) :: cd_neutral_10m |
|---|
| 237 | ! |
|---|
| 238 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 239 | REAL(wp) :: zgt33, zw, zw6 ! local scalars |
|---|
| 240 | !!---------------------------------------------------------------------------------- |
|---|
| 241 | ! |
|---|
| 242 | DO jj = 1, jpj |
|---|
| 243 | DO ji = 1, jpi |
|---|
| 244 | ! |
|---|
| 245 | zw = pw10(ji,jj) |
|---|
| 246 | zw6 = zw*zw*zw |
|---|
| 247 | zw6 = zw6*zw6 |
|---|
| 248 | ! |
|---|
| 249 | ! When wind speed > 33 m/s => Cyclone conditions => special treatment |
|---|
| 250 | zgt33 = 0.5 + SIGN( 0.5, (zw - 33.) ) ! If pw10 < 33. => 0, else => 1 |
|---|
| 251 | ! |
|---|
| 252 | cd_neutral_10m(ji,jj) = 1.e-3 * ( & |
|---|
| 253 | & (1. - zgt33)*( 2.7/zw + 0.142 + zw/13.09 - 3.14807E-10*zw6) & ! wind < 33 m/s |
|---|
| 254 | & + zgt33 * 2.34 ) ! wind >= 33 m/s |
|---|
| 255 | ! |
|---|
| 256 | cd_neutral_10m(ji,jj) = MAX(cd_neutral_10m(ji,jj), 1.E-6) |
|---|
| 257 | ! |
|---|
| 258 | END DO |
|---|
| 259 | END DO |
|---|
| 260 | ! |
|---|
| 261 | END FUNCTION cd_neutral_10m |
|---|
| 262 | |
|---|
| 263 | |
|---|
| 264 | FUNCTION psi_m( pzeta ) |
|---|
| 265 | !!---------------------------------------------------------------------------------- |
|---|
| 266 | !! Universal profile stability function for momentum |
|---|
| 267 | !! !! Psis, L&Y 2004 eq. (8c), (8d), (8e) |
|---|
| 268 | !! |
|---|
| 269 | !! pzet0 : stability paramenter, z/L where z is altitude measurement |
|---|
| 270 | !! and L is M-O length |
|---|
| 271 | !! |
|---|
| 272 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
|---|
| 273 | !!---------------------------------------------------------------------------------- |
|---|
| 274 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta |
|---|
| 275 | REAL(wp), DIMENSION(jpi,jpj) :: psi_m |
|---|
| 276 | ! |
|---|
| 277 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 278 | REAL(wp) :: zx2, zx, zstab ! local scalars |
|---|
| 279 | !!---------------------------------------------------------------------------------- |
|---|
| 280 | ! |
|---|
| 281 | DO jj = 1, jpj |
|---|
| 282 | DO ji = 1, jpi |
|---|
| 283 | zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) ) |
|---|
| 284 | zx2 = MAX ( zx2 , 1. ) |
|---|
| 285 | zx = SQRT( zx2 ) |
|---|
| 286 | zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) ) |
|---|
| 287 | ! |
|---|
| 288 | psi_m(ji,jj) = zstab * (-5.*pzeta(ji,jj)) & ! Stable |
|---|
| 289 | & + (1. - zstab) * (2.*LOG((1. + zx)*0.5) & ! Unstable |
|---|
| 290 | & + LOG((1. + zx2)*0.5) - 2.*ATAN(zx) + rpi*0.5) ! " |
|---|
| 291 | ! |
|---|
| 292 | END DO |
|---|
| 293 | END DO |
|---|
| 294 | ! |
|---|
| 295 | END FUNCTION psi_m |
|---|
| 296 | |
|---|
| 297 | |
|---|
| 298 | FUNCTION psi_h( pzeta ) |
|---|
| 299 | !!---------------------------------------------------------------------------------- |
|---|
| 300 | !! Universal profile stability function for temperature and humidity |
|---|
| 301 | !! !! Psis, L&Y 2004 eq. (8c), (8d), (8e) |
|---|
| 302 | !! |
|---|
| 303 | !! pzet0 : stability paramenter, z/L where z is altitude measurement |
|---|
| 304 | !! and L is M-O length |
|---|
| 305 | !! |
|---|
| 306 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
|---|
| 307 | !!---------------------------------------------------------------------------------- |
|---|
| 308 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta |
|---|
| 309 | REAL(wp), DIMENSION(jpi,jpj) :: psi_h |
|---|
| 310 | ! |
|---|
| 311 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 312 | REAL(wp) :: zx2, zstab ! local scalars |
|---|
| 313 | !!---------------------------------------------------------------------------------- |
|---|
| 314 | ! |
|---|
| 315 | DO jj = 1, jpj |
|---|
| 316 | DO ji = 1, jpi |
|---|
| 317 | zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) ) |
|---|
| 318 | zx2 = MAX ( zx2 , 1. ) |
|---|
| 319 | zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) ) |
|---|
| 320 | ! |
|---|
| 321 | psi_h(ji,jj) = zstab * (-5.*pzeta(ji,jj)) & ! Stable |
|---|
| 322 | & + (1. - zstab) * (2.*LOG( (1. + zx2)*0.5 )) ! Unstable |
|---|
| 323 | ! |
|---|
| 324 | END DO |
|---|
| 325 | END DO |
|---|
| 326 | ! |
|---|
| 327 | END FUNCTION psi_h |
|---|
| 328 | |
|---|
| 329 | !!====================================================================== |
|---|
| 330 | END MODULE sbcblk_algo_ncar |
|---|
