Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

traadv.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago
All wrk_alloc removed
Property svn:keywords set to `Id`
File size: 16.9 KB

Line
1	MODULE traadv
2	!!==============================================================================
3	!! * MODULE traadv *
4	!! Ocean active tracers: advection trend
5	!!==============================================================================
6	!! History : 2.0 ! 2005-11 (G. Madec) Original code
7	!! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
8	!! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation
9	!! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes
10	!! - ! 2014-12 (G. Madec) suppression of cross land advection option
11	!! 3.6 ! 2015-06 (E. Clementi) Addition of Stokes drift in case of wave coupling
12	!!----------------------------------------------------------------------
13
14	!!----------------------------------------------------------------------
15	!! tra_adv : compute ocean tracer advection trend
16	!! tra_adv_ctl : control the different options of advection scheme
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and active tracers
19	USE dom_oce ! ocean space and time domain
20	USE domvvl ! variable vertical scale factors
21	USE traadv_cen ! centered scheme (tra_adv_cen routine)
22	USE traadv_fct ! FCT scheme (tra_adv_fct routine)
23	USE traadv_mus ! MUSCL scheme (tra_adv_mus routine)
24	USE traadv_ubs ! UBS scheme (tra_adv_ubs routine)
25	USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine)
26	USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine)
27	USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff.
28	USE ldfslp ! Lateral diffusion: slopes of neutral surfaces
29	USE trd_oce ! trends: ocean variables
30	USE trdtra ! trends manager: tracers
31	!
32	USE in_out_manager ! I/O manager
33	USE iom ! I/O module
34	USE prtctl ! Print control
35	USE lib_mpp ! MPP library
36	USE timing ! Timing
37	USE sbcwave ! wave module
38	USE sbc_oce ! surface boundary condition: ocean
39	USE diaptr ! Poleward heat transport
40
41	IMPLICIT NONE
42	PRIVATE
43
44	PUBLIC tra_adv ! routine called by step module
45	PUBLIC tra_adv_init ! routine called by opa module
46
47	! !!* Namelist namtra_adv *
48	LOGICAL :: ln_traadv_cen ! centered scheme flag
49	INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme
50	LOGICAL :: ln_traadv_fct ! FCT scheme flag
51	INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme
52	INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping
53	LOGICAL :: ln_traadv_mus ! MUSCL scheme flag
54	LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths
55	LOGICAL :: ln_traadv_ubs ! UBS scheme flag
56	INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme
57	LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag
58
59	INTEGER :: nadv ! choice of the type of advection scheme
60	!
61	! ! associated indices:
62	INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection
63	INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme
64	INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme
65	INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping
66	INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme
67	INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme
68	INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme
69
70	!! * Substitutions
71	# include "vectopt_loop_substitute.h90"
72	!!----------------------------------------------------------------------
73	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
74	!! $Id$
75	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
76	!!----------------------------------------------------------------------
77	CONTAINS
78
79	SUBROUTINE tra_adv( kt )
80	!!----------------------------------------------------------------------
81	!! * ROUTINE tra_adv *
82	!!
83	!! ** Purpose : compute the ocean tracer advection trend.
84	!!
85	!! ** Method : - Update (ua,va) with the advection term following nadv
86	!!----------------------------------------------------------------------
87	INTEGER, INTENT( in ) :: kt ! ocean time-step index
88	!
89	INTEGER :: jk ! dummy loop index
90	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zun, zvn, zwn
91	REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztrdt, ztrds ! 3D workspace
92	!!----------------------------------------------------------------------
93	!
94	IF( nn_timing == 1 ) CALL timing_start('tra_adv')
95	!
96	!
97	! ! set time step
98	zun(:,:,:) = 0.0
99	zvn(:,:,:) = 0.0
100	zwn(:,:,:) = 0.0
101	!
102	IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000
103	r2dt = rdt ! = rdt (restarting with Euler time stepping)
104	ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1
105	r2dt = 2._wp * rdt ! = 2 rdt (leapfrog)
106	ENDIF
107	!
108	! !== effective transport ==!
109	IF( ln_wave .AND. ln_sdw ) THEN
110	DO jk = 1, jpkm1 ! eulerian transport + Stokes Drift
111	zun(:,:,jk) = e2u (:,:) * e3u_n(:,:,jk) * ( un(:,:,jk) + usd(:,:,jk) )
112	zvn(:,:,jk) = e1v (:,:) * e3v_n(:,:,jk) * ( vn(:,:,jk) + vsd(:,:,jk) )
113	zwn(:,:,jk) = e1e2t(:,:) * ( wn(:,:,jk) + wsd(:,:,jk) )
114	END DO
115	ELSE
116	DO jk = 1, jpkm1
117	zun(:,:,jk) = e2u (:,:) * e3u_n(:,:,jk) * un(:,:,jk) ! eulerian transport only
118	zvn(:,:,jk) = e1v (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
119	zwn(:,:,jk) = e1e2t(:,:) * wn(:,:,jk)
120	END DO
121	ENDIF
122	!
123	IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections
124	zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
125	zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
126	ENDIF
127	!
128	zun(:,:,jpk) = 0._wp ! no transport trough the bottom
129	zvn(:,:,jpk) = 0._wp
130	zwn(:,:,jpk) = 0._wp
131	!
132	IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) &
133	& CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary)
134	!
135	IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary)
136	!
137	CALL iom_put( "uocetr_eff", zun ) ! output effective transport
138	CALL iom_put( "vocetr_eff", zvn )
139	CALL iom_put( "wocetr_eff", zwn )
140	!
141	!!gm ???
142	IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF
143	!!gm ???
144	!
145	IF( l_trdtra ) THEN !* Save ta and sa trends
146	ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
147	ztrds(:,:,:) = tsa(:,:,:,jp_sal)
148	ENDIF
149	!
150	SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==!
151	!
152	CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order
153	CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
154	CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order
155	CALL tra_adv_fct ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
156	CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting
157	CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts )
158	CASE ( np_MUS ) ! MUSCL
159	CALL tra_adv_mus ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups )
160	CASE ( np_UBS ) ! UBS
161	CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v )
162	CASE ( np_QCK ) ! QUICKEST
163	CALL tra_adv_qck ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )
164	!
165	END SELECT
166	!
167	IF( l_trdtra ) THEN ! save the advective trends for further diagnostics
168	DO jk = 1, jpkm1
169	ztrdt(:,:,jk) = tsa(:,:,jk,jp_tem) - ztrdt(:,:,jk)
170	ztrds(:,:,jk) = tsa(:,:,jk,jp_sal) - ztrds(:,:,jk)
171	END DO
172	CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
173	CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
174	ENDIF
175	! ! print mean trends (used for debugging)
176	IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, &
177	& tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' )
178	!
179	IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' )
180	!
181	!
182	END SUBROUTINE tra_adv
183
184
185	SUBROUTINE tra_adv_init
186	!!---------------------------------------------------------------------
187	!! * ROUTINE tra_adv_init *
188	!!
189	!! ** Purpose : Control the consistency between namelist options for
190	!! tracer advection schemes and set nadv
191	!!----------------------------------------------------------------------
192	INTEGER :: ioptio, ios ! Local integers
193	!
194	NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN
195	& ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT
196	& ln_traadv_mus, ln_mus_ups, & ! MUSCL
197	& ln_traadv_ubs, nn_ubs_v, & ! UBS
198	& ln_traadv_qck ! QCK
199	!!----------------------------------------------------------------------
200	!
201	! !== Namelist ==!
202	REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme
203	READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
204	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
205	!
206	REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
207	READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
208	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
209	IF(lwm) WRITE( numond, namtra_adv )
210	!
211	IF(lwp) THEN ! Namelist print
212	WRITE(numout,*)
213	WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
214	WRITE(numout,*) '~~~~~~~~~~~'
215	WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers'
216	WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen
217	WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h
218	WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v
219	WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct
220	WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h
221	WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v
222	WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts
223	WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus
224	WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups
225	WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs
226	WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v
227	WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck
228	ENDIF
229	!
230	ioptio = 0 !== Parameter control ==!
231	IF( ln_traadv_cen ) ioptio = ioptio + 1
232	IF( ln_traadv_fct ) ioptio = ioptio + 1
233	IF( ln_traadv_mus ) ioptio = ioptio + 1
234	IF( ln_traadv_ubs ) ioptio = ioptio + 1
235	IF( ln_traadv_qck ) ioptio = ioptio + 1
236	!
237	IF( ioptio == 0 ) THEN
238	nadv = np_NO_adv
239	CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
240	ENDIF
241	IF( ioptio /= 1 ) CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
242	!
243	IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered
244	.AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN
245	CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
246	ENDIF
247	IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT
248	.AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN
249	CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
250	ENDIF
251	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
252	IF( nn_fct_h == 4 ) THEN
253	nn_fct_h = 2
254	CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
255	ENDIF
256	IF( .NOT.ln_linssh ) THEN
257	CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
258	ENDIF
259	IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
260	ENDIF
261	IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS
262	CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
263	ENDIF
264	IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
265	CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
266	ENDIF
267	IF( ln_isfcav ) THEN ! ice-shelf cavities
268	IF( ln_traadv_cen .AND. nn_cen_v == 4 .OR. & ! NO 4th order with ISF
269	& ln_traadv_fct .AND. nn_fct_v == 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
270	ENDIF
271	!
272	! !== used advection scheme ==!
273	! ! set nadv
274	IF( ln_traadv_cen ) nadv = np_CEN
275	IF( ln_traadv_fct ) nadv = np_FCT
276	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts
277	IF( ln_traadv_mus ) nadv = np_MUS
278	IF( ln_traadv_ubs ) nadv = np_UBS
279	IF( ln_traadv_qck ) nadv = np_QCK
280	!
281	IF(lwp) THEN ! Print the choice
282	WRITE(numout,*)
283	SELECT CASE ( nadv )
284	CASE( np_NO_adv ) ; WRITE(numout,*) ' ===>> NO T-S advection'
285	CASE( np_CEN ) ; WRITE(numout,*) ' ===>> CEN scheme is used. Horizontal order: ', nn_cen_h, &
286	& ' Vertical order: ', nn_cen_v
287	CASE( np_FCT ) ; WRITE(numout,*) ' ===>> FCT scheme is used. Horizontal order: ', nn_fct_h, &
288	& ' Vertical order: ', nn_fct_v
289	CASE( np_FCT_zts ) ; WRITE(numout,*) ' ===>> use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
290	CASE( np_MUS ) ; WRITE(numout,*) ' ===>> MUSCL scheme is used'
291	CASE( np_UBS ) ; WRITE(numout,*) ' ===>> UBS scheme is used'
292	CASE( np_QCK ) ; WRITE(numout,*) ' ===>> QUICKEST scheme is used'
293	END SELECT
294	ENDIF
295	!
296	CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==!
297	!
298	END SUBROUTINE tra_adv_init
299
300	!!======================================================================
301	END MODULE traadv

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7910

Download in other formats: