| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and active tracers |
|---|
| 18 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 19 | USE dom_oce ! ocean space domain variables |
|---|
| 20 | USE phycst ! physical constant |
|---|
| 21 | USE eosbn2 ! Equation Of State |
|---|
| 22 | USE sbcmod ! ln_rnf |
|---|
| 23 | USE sbcrnf ! River runoff |
|---|
| 24 | USE sbcisf ! Ice shelf |
|---|
| 25 | USE iscplini ! Ice sheet coupling |
|---|
| 26 | USE traqsr ! solar radiation penetration |
|---|
| 27 | USE trd_oce ! trends: ocean variables |
|---|
| 28 | USE trdtra ! trends manager: tracers |
|---|
| 29 | ! |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE prtctl ! Print control |
|---|
| 32 | USE iom ! xIOS server |
|---|
| 33 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | !! *** ROUTINE tra_sbc *** |
|---|
| 53 | !! |
|---|
| 54 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 55 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 56 | !! and add it to the general trend of tracer equations. |
|---|
| 57 | !! |
|---|
| 58 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 59 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 60 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 61 | !! The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe, |
|---|
| 62 | !! they are simply added to the tracer trend (tsa). |
|---|
| 63 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 64 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 65 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 66 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 67 | !! |
|---|
| 68 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 69 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 72 | ! |
|---|
| 73 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 74 | INTEGER :: ikt, ikb ! local integers |
|---|
| 75 | REAL(wp) :: zfact, z1_e3t, zdep ! local scalar |
|---|
| 76 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztrdt, ztrds |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | ! |
|---|
| 79 | IF( nn_timing == 1 ) CALL timing_start('tra_sbc') |
|---|
| 80 | ! |
|---|
| 81 | IF( kt == nit000 ) THEN |
|---|
| 82 | IF(lwp) WRITE(numout,*) |
|---|
| 83 | IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 84 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 85 | ENDIF |
|---|
| 86 | ! |
|---|
| 87 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 88 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 89 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 90 | ENDIF |
|---|
| 91 | ! |
|---|
| 92 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 93 | IF( .NOT.ln_traqsr ) THEN ! no solar radiation penetration |
|---|
| 94 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 95 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 96 | ENDIF |
|---|
| 97 | |
|---|
| 98 | !---------------------------------------- |
|---|
| 99 | ! EMP, SFX and QNS effects |
|---|
| 100 | !---------------------------------------- |
|---|
| 101 | ! !== Set before sbc tracer content fields ==! |
|---|
| 102 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 103 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 104 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 105 | IF(lwp) WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 106 | zfact = 0.5_wp |
|---|
| 107 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 108 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) ) ! before heat content sbc trend |
|---|
| 109 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) ) ! before salt content sbc trend |
|---|
| 110 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 111 | zfact = 1._wp |
|---|
| 112 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 113 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 114 | ENDIF |
|---|
| 115 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 116 | zfact = 0.5_wp |
|---|
| 117 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 118 | ENDIF |
|---|
| 119 | ! !== Now sbc tracer content fields ==! |
|---|
| 120 | DO jj = 2, jpj |
|---|
| 121 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 122 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 123 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 124 | END DO |
|---|
| 125 | END DO |
|---|
| 126 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 127 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 128 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 129 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 130 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 131 | END DO |
|---|
| 132 | END DO !==>> output c./d. term |
|---|
| 133 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 134 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 135 | ENDIF |
|---|
| 136 | ! |
|---|
| 137 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 138 | DO jj = 2, jpj |
|---|
| 139 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 140 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 141 | END DO |
|---|
| 142 | END DO |
|---|
| 143 | END DO |
|---|
| 144 | ! |
|---|
| 145 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 146 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) ) |
|---|
| 147 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) ) |
|---|
| 148 | ENDIF |
|---|
| 149 | ! |
|---|
| 150 | !---------------------------------------- |
|---|
| 151 | ! Ice Shelf effects (ISF) |
|---|
| 152 | ! tbl treated as in Losh (2008) JGR |
|---|
| 153 | !---------------------------------------- |
|---|
| 154 | ! |
|---|
| 155 | !!gm BUG ? Why no differences between non-linear and linear free surface ? |
|---|
| 156 | !!gm probably taken into account in r1_hisf_tbl : to be verified |
|---|
| 157 | IF( ln_isf ) THEN |
|---|
| 158 | zfact = 0.5_wp |
|---|
| 159 | DO jj = 2, jpj |
|---|
| 160 | DO ji = fs_2, fs_jpim1 |
|---|
| 161 | ! |
|---|
| 162 | ikt = misfkt(ji,jj) |
|---|
| 163 | ikb = misfkb(ji,jj) |
|---|
| 164 | ! |
|---|
| 165 | ! level fully include in the ice shelf boundary layer |
|---|
| 166 | ! sign - because fwf sign of evapo (rnf sign of precip) |
|---|
| 167 | DO jk = ikt, ikb - 1 |
|---|
| 168 | ! compute trend |
|---|
| 169 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 170 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 171 | & * r1_hisf_tbl(ji,jj) |
|---|
| 172 | END DO |
|---|
| 173 | |
|---|
| 174 | ! level partially include in ice shelf boundary layer |
|---|
| 175 | ! compute trend |
|---|
| 176 | tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem) & |
|---|
| 177 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 178 | & * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 179 | |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | END IF |
|---|
| 183 | ! |
|---|
| 184 | !---------------------------------------- |
|---|
| 185 | ! River Runoff effects |
|---|
| 186 | !---------------------------------------- |
|---|
| 187 | ! |
|---|
| 188 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 189 | zfact = 0.5_wp |
|---|
| 190 | DO jj = 2, jpj |
|---|
| 191 | DO ji = fs_2, fs_jpim1 |
|---|
| 192 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 193 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 194 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 195 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 196 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 197 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 198 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 199 | END DO |
|---|
| 200 | ENDIF |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | ENDIF |
|---|
| 204 | |
|---|
| 205 | IF( iom_use('rnf_x_sst') ) CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) ) ! runoff term on sst |
|---|
| 206 | IF( iom_use('rnf_x_sss') ) CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) ) ! runoff term on sss |
|---|
| 207 | |
|---|
| 208 | ! |
|---|
| 209 | !---------------------------------------- |
|---|
| 210 | ! Ice Sheet coupling imbalance correction to have conservation |
|---|
| 211 | !---------------------------------------- |
|---|
| 212 | ! |
|---|
| 213 | IF( ln_iscpl .AND. ln_hsb) THEN ! input of heat and salt due to river runoff |
|---|
| 214 | DO jk = 1,jpk |
|---|
| 215 | DO jj = 2, jpj |
|---|
| 216 | DO ji = fs_2, fs_jpim1 |
|---|
| 217 | zdep = 1._wp / e3t_n(ji,jj,jk) |
|---|
| 218 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem) & |
|---|
| 219 | & * zdep |
|---|
| 220 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal) & |
|---|
| 221 | & * zdep |
|---|
| 222 | END DO |
|---|
| 223 | END DO |
|---|
| 224 | END DO |
|---|
| 225 | ENDIF |
|---|
| 226 | |
|---|
| 227 | IF( l_trdtra ) THEN ! save the horizontal diffusive trends for further diagnostics |
|---|
| 228 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 229 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 230 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 231 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 232 | ENDIF |
|---|
| 233 | ! |
|---|
| 234 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 235 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 236 | ! |
|---|
| 237 | IF( nn_timing == 1 ) CALL timing_stop('tra_sbc') |
|---|
| 238 | ! |
|---|
| 239 | END SUBROUTINE tra_sbc |
|---|
| 240 | |
|---|
| 241 | !!====================================================================== |
|---|
| 242 | END MODULE trasbc |
|---|
