1 | #define TWO_WAY |
---|
2 | |
---|
3 | MODULE agrif_lim3_update |
---|
4 | !!===================================================================================== |
---|
5 | !! *** MODULE agrif_lim3_update *** |
---|
6 | !! Nesting module : update surface ocean boundary condition over ice from a child grid |
---|
7 | !! Sea-Ice model : LIM 3.6 Sea ice model time-stepping |
---|
8 | !!===================================================================================== |
---|
9 | !! History : 2.0 ! 04-2008 (F. Dupont) initial version |
---|
10 | !! 3.4 ! 08-2012 (R. Benshila, C. Herbaut) update and EVP |
---|
11 | !! 3.6 ! 05-2016 (C. Rousset) Add LIM3 compatibility |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | #if defined key_agrif && defined key_lim3 |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! 'key_lim3' : LIM 3.6 sea-ice model |
---|
16 | !! 'key_agrif' : AGRIF library |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | !! agrif_update_lim3 : update sea-ice on boundaries or total |
---|
19 | !! child domain for velocities and ice properties |
---|
20 | !! update_tra_ice : sea-ice properties |
---|
21 | !! update_u_ice : zonal ice velocity |
---|
22 | !! update_v_ice : meridional ice velocity |
---|
23 | !!---------------------------------------------------------------------- |
---|
24 | USE dom_oce |
---|
25 | USE sbc_oce |
---|
26 | USE agrif_oce |
---|
27 | USE ice |
---|
28 | USE agrif_ice |
---|
29 | |
---|
30 | IMPLICIT NONE |
---|
31 | PRIVATE |
---|
32 | |
---|
33 | PUBLIC agrif_update_lim3 |
---|
34 | |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | !! NEMO/NST 3.6 , LOCEAN-IPSL (2016) |
---|
37 | !! $Id: agrif_lim3_update.F90 6204 2016-01-04 13:47:06Z cetlod $ |
---|
38 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | |
---|
41 | CONTAINS |
---|
42 | |
---|
43 | SUBROUTINE agrif_update_lim3( kt ) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! *** ROUTINE agrif_update_lim3 *** |
---|
46 | !! ** Method : Call the hydrostaticupdate pressure at the boundary or the entire domain |
---|
47 | !! |
---|
48 | !! ** Action : - Update (u_ice,v_ice) and ice tracers |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | INTEGER, INTENT(in) :: kt |
---|
51 | !! |
---|
52 | !!---------------------------------------------------------------------- |
---|
53 | ! |
---|
54 | !! clem: I think the update should take place each time the ocean sees the surface forcings |
---|
55 | !! (but maybe I am wrong and we should update every rhot time steps) |
---|
56 | IF( ( MOD( (kt-nit000)/nn_fsbc + 1, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) /=0 ) .AND. (kt /= 0) ) RETURN ! do not update if nb of child time steps differ from time refinement |
---|
57 | ! i.e. update only at the parent time step |
---|
58 | Agrif_UseSpecialValueInUpdate = .TRUE. |
---|
59 | Agrif_SpecialValueFineGrid = -9999. |
---|
60 | # if defined TWO_WAY |
---|
61 | IF( MOD(nbcline,nbclineupdate) == 0) THEN ! update the whole basin at each nbclineupdate (=nn_cln_update) baroclinic parent time steps |
---|
62 | ! nbcline is incremented (+1) at the end of each parent time step from 0 (1st time step) |
---|
63 | CALL Agrif_Update_Variable( tra_ice_id , procname = update_tra_ice ) |
---|
64 | CALL Agrif_Update_Variable( u_ice_id , procname = update_u_ice ) |
---|
65 | CALL Agrif_Update_Variable( v_ice_id , procname = update_v_ice ) |
---|
66 | ELSE ! update only the boundaries defined par locupdate |
---|
67 | CALL Agrif_Update_Variable( tra_ice_id , locupdate=(/0,2/), procname = update_tra_ice ) |
---|
68 | CALL Agrif_Update_Variable( u_ice_id , locupdate=(/0,1/), procname = update_u_ice ) |
---|
69 | CALL Agrif_Update_Variable( v_ice_id , locupdate=(/0,1/), procname = update_v_ice ) |
---|
70 | ENDIF |
---|
71 | # endif |
---|
72 | Agrif_UseSpecialValueInUpdate = .FALSE. |
---|
73 | ! |
---|
74 | END SUBROUTINE agrif_update_lim3 |
---|
75 | |
---|
76 | |
---|
77 | !!------------------ |
---|
78 | !! Local subroutines |
---|
79 | !!------------------ |
---|
80 | SUBROUTINE update_tra_ice( ptab, i1, i2, j1, j2, k1, k2, before ) |
---|
81 | !!----------------------------------------------------------------------- |
---|
82 | !! *** ROUTINE update_tra_ice *** |
---|
83 | !! ** Method : Compute the mass properties on the fine grid and recover |
---|
84 | !! the properties per mass on the coarse grid |
---|
85 | !!----------------------------------------------------------------------- |
---|
86 | INTEGER , INTENT(in) :: i1, i2, j1, j2, k1, k2 |
---|
87 | REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2), INTENT(inout) :: ptab |
---|
88 | LOGICAL , INTENT(in) :: before |
---|
89 | !! |
---|
90 | INTEGER :: jk, jl, jm |
---|
91 | !!----------------------------------------------------------------------- |
---|
92 | ! it is ok not to multiply by e1*e2 since we conserve tracers here (same as in the ocean). |
---|
93 | IF( before ) THEN |
---|
94 | jm = 1 |
---|
95 | DO jl = 1, jpl |
---|
96 | ptab(:,:,jm) = a_i (i1:i2,j1:j2,jl) ; jm = jm + 1 |
---|
97 | ptab(:,:,jm) = v_i (i1:i2,j1:j2,jl) ; jm = jm + 1 |
---|
98 | ptab(:,:,jm) = v_s (i1:i2,j1:j2,jl) ; jm = jm + 1 |
---|
99 | ptab(:,:,jm) = smv_i(i1:i2,j1:j2,jl) ; jm = jm + 1 |
---|
100 | ptab(:,:,jm) = oa_i (i1:i2,j1:j2,jl) ; jm = jm + 1 |
---|
101 | DO jk = 1, nlay_s |
---|
102 | ptab(:,:,jm) = e_s(i1:i2,j1:j2,jk,jl) ; jm = jm + 1 |
---|
103 | ENDDO |
---|
104 | DO jk = 1, nlay_i |
---|
105 | ptab(:,:,jm) = e_i(i1:i2,j1:j2,jk,jl) ; jm = jm + 1 |
---|
106 | ENDDO |
---|
107 | ENDDO |
---|
108 | |
---|
109 | DO jk = k1, k2 |
---|
110 | WHERE( tmask(i1:i2,j1:j2,1) == 0. ) ptab(:,:,jk) = -9999. |
---|
111 | ENDDO |
---|
112 | |
---|
113 | ELSE |
---|
114 | jm = 1 |
---|
115 | DO jl = 1, jpl |
---|
116 | a_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
117 | v_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
118 | v_s (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
119 | smv_i(i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
120 | oa_i (i1:i2,j1:j2,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
121 | DO jk = 1, nlay_s |
---|
122 | e_s(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
123 | ENDDO |
---|
124 | DO jk = 1, nlay_i |
---|
125 | e_i(i1:i2,j1:j2,jk,jl) = ptab(:,:,jm) * tmask(i1:i2,j1:j2,1) ; jm = jm + 1 |
---|
126 | ENDDO |
---|
127 | ENDDO |
---|
128 | |
---|
129 | ! integrated values |
---|
130 | vt_i (i1:i2,j1:j2) = SUM( v_i(i1:i2,j1:j2,:), dim=3 ) |
---|
131 | vt_s (i1:i2,j1:j2) = SUM( v_s(i1:i2,j1:j2,:), dim=3 ) |
---|
132 | at_i (i1:i2,j1:j2) = SUM( a_i(i1:i2,j1:j2,:), dim=3 ) |
---|
133 | et_s(i1:i2,j1:j2) = SUM( SUM( e_s(i1:i2,j1:j2,:,:), dim=4 ), dim=3 ) |
---|
134 | et_i(i1:i2,j1:j2) = SUM( SUM( e_i(i1:i2,j1:j2,:,:), dim=4 ), dim=3 ) |
---|
135 | |
---|
136 | ENDIF |
---|
137 | ! |
---|
138 | END SUBROUTINE update_tra_ice |
---|
139 | |
---|
140 | |
---|
141 | SUBROUTINE update_u_ice( ptab, i1, i2, j1, j2, before ) |
---|
142 | !!----------------------------------------------------------------------- |
---|
143 | !! *** ROUTINE update_u_ice *** |
---|
144 | !! ** Method : Update the fluxes and recover the properties (C-grid) |
---|
145 | !!----------------------------------------------------------------------- |
---|
146 | INTEGER , INTENT(in) :: i1, i2, j1, j2 |
---|
147 | REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) :: ptab |
---|
148 | LOGICAL , INTENT(in) :: before |
---|
149 | !! |
---|
150 | REAL(wp) :: zrhoy |
---|
151 | !!----------------------------------------------------------------------- |
---|
152 | ! |
---|
153 | IF( before ) THEN |
---|
154 | zrhoy = Agrif_Rhoy() |
---|
155 | ptab(:,:) = e2u(i1:i2,j1:j2) * u_ice(i1:i2,j1:j2) * zrhoy |
---|
156 | WHERE( umask(i1:i2,j1:j2,1) == 0. ) ptab(:,:) = -9999. |
---|
157 | ELSE |
---|
158 | u_ice(i1:i2,j1:j2) = ptab(:,:) / e2u(i1:i2,j1:j2) * umask(i1:i2,j1:j2,1) |
---|
159 | ENDIF |
---|
160 | ! |
---|
161 | END SUBROUTINE update_u_ice |
---|
162 | |
---|
163 | |
---|
164 | SUBROUTINE update_v_ice( ptab, i1, i2, j1, j2, before ) |
---|
165 | !!----------------------------------------------------------------------- |
---|
166 | !! *** ROUTINE update_v_ice *** |
---|
167 | !! ** Method : Update the fluxes and recover the properties (C-grid) |
---|
168 | !!----------------------------------------------------------------------- |
---|
169 | INTEGER , INTENT(in) :: i1,i2,j1,j2 |
---|
170 | REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) :: ptab |
---|
171 | LOGICAL , INTENT(in) :: before |
---|
172 | !! |
---|
173 | REAL(wp) :: zrhox |
---|
174 | !!----------------------------------------------------------------------- |
---|
175 | ! |
---|
176 | IF( before ) THEN |
---|
177 | zrhox = Agrif_Rhox() |
---|
178 | ptab(:,:) = e1v(i1:i2,j1:j2) * v_ice(i1:i2,j1:j2) * zrhox |
---|
179 | WHERE( vmask(i1:i2,j1:j2,1) == 0. ) ptab(:,:) = -9999. |
---|
180 | ELSE |
---|
181 | v_ice(i1:i2,j1:j2) = ptab(:,:) / e1v(i1:i2,j1:j2) * vmask(i1:i2,j1:j2,1) |
---|
182 | ENDIF |
---|
183 | ! |
---|
184 | END SUBROUTINE update_v_ice |
---|
185 | |
---|
186 | #else |
---|
187 | CONTAINS |
---|
188 | SUBROUTINE agrif_lim3_update_empty |
---|
189 | !!--------------------------------------------- |
---|
190 | !! *** ROUTINE agrif_lim3_update_empty *** |
---|
191 | !!--------------------------------------------- |
---|
192 | WRITE(*,*) 'agrif_lim3_update : You should not have seen this print! error?' |
---|
193 | END SUBROUTINE agrif_lim3_update_empty |
---|
194 | #endif |
---|
195 | END MODULE agrif_lim3_update |
---|